DGL • Thema anzeigen - OpenGL Version

OpenGL Version

Moderator: DGL-Team

Seite 1 von 1

[ 10 Beiträge ]

Vorheriges Thema | Nächstes Thema

Autor

Nachricht

AMD

Betreff des Beitrags: OpenGL Version

Verfasst: Mi Dez 21, 2011 12:23

DGL Member

Registriert: Di Aug 09, 2011 07:33
Beiträge: 163
Programmiersprache: C/C++

Hey,

Ich bin gerade etwas verwirrt. Ich dachte eig. immer mit der neusten OpenGL Version zu programmieren aber dies scheint nicht der Fall zu sein. Ich habe hier letztens gelesen, dass z.B. Displaylisten in OpenGL 4.0 rausgeflogen sind oder auch Befehle wie glBegin oder glEnd nicht mehr vorhanden sein sollen. Da dies aber alle bei mir noch funktioniert, heißt es ja, dass ich eine ältere Version nehme (wobei ich 2.X vermute).
Wie kann ich denn herausfinden welche Version nun exakt bei meinem Programm läuft und wie kann ich aufs neuere setzen :?:

Nach oben

Sascha Willems

Betreff des Beitrags: Re: OpenGL Version

Verfasst: Mi Dez 21, 2011 15:58

DGL Member

Registriert: Mo Sep 23, 2002 19:27
Beiträge: 5812
Programmiersprache: C++

In neueren OpenGL-Versionen fallen alle Immediate-Funktionen weg, sofern man auf einen "puren" Renderkontext setzt. Sprich glBegin, glEnd, glColor, glVertex, Displayliste, etc. etc. fallen weg und man arbeitet nur noch mit VAs/VBOs und Co.

Welche Version du nutzen willst gibts du bei der Erstellung des Kontextes an, und auch ob du einen Kontext willst der rückwärtskompatibel ist (geht auch, also aktuelles OpenGL + alte Funktionen) oder einen der verschlankt ist und auf aktuelle Funktionen setzt.

Um die gewünschte Version (z.B. 3.1, 4.0) zu erhalten muss man zuerst einen normalen Renderkontext erstellen (damit man die Funktionszeiger hat), und dann mittels wglCreateContextAttribsARB (unter Windows) einen Kontext mit den gewünschten Parametern erstellen :

Code:

Attribs[0] := WGL_CONTEXT_MAJOR_VERSION_ARB;
Attribs[1] := MajorVersion;
Attribs[2] := WGL_CONTEXT_MINOR_VERSION_ARB;
Attribs[3] := MinorVersion; 

MajorVersion dann z.B. 4 und Minor 0 für einen 4.0 Renderkontext.

Willst du dann noch einen nur "vorwärtskompatiblen" Kontext, der ohne Altlasten kommt, sprich bei dem immediate Funktionen nicht mehr nutzbar sind, dann muss noch folgendes Attribute dran :

Code:

Attribs[4] := WGL_CONTEXT_FLAGS_ARB;
Attribs[5] := WGL_CONTEXT_FORWARD_COMPATIBLE_BIT_ARB; 

Nicht vergessen dass man die Attributflags mit ner 0 abschliessen muss!

Und dann den Kontext erstellen und den alten löschen :

Code:

Result := wglCreateContextAttribsARB(DC, 0, @Attribs[0]); 

_________________
www.SaschaWillems.de | GitHub | Twitter | GPU Datenbanken (Vulkan, GL, GLES)

Nach oben

SDH.Prod

Betreff des Beitrags: Re: OpenGL Version

Verfasst: Mi Dez 21, 2011 16:09

DGL Member

Registriert: Sa Okt 18, 2008 11:59
Beiträge: 180

Interessant ist hierbei welche Version deine Grafikkarte und der dazugehörige Treiber hat.

Eine Grafikkarte die OpenGL nur bis 2.0 unterstützt kann z.B. Probleme haben mit Funktionen für OpenGL 2.1 oder höher. Diese Funktionen umschifft der Treiber, was wesentlich langsamer ist weil die CPU das dann berechnet. (Im Grunde sollte es aber funktionieren.)

Nach oben

AMD

Betreff des Beitrags: Re: OpenGL Version

Verfasst: Mi Dez 21, 2011 17:24

DGL Member

Registriert: Di Aug 09, 2011 07:33
Beiträge: 163
Programmiersprache: C/C++

@Sascha Willems: Okay verstehe! Danke für die Hilfe

@SDH.Prod: Ist eine HD 5870 mit aktuellem Treiber, sollte also 4.2 unterstützen.

Edit// Hab dazu auch nochmal folgendes probiert:

Code:

    int OpenGLVersion[2];
    glGetIntegerv(GL_MAJOR_VERSION, &OpenGLVersion[0]);
    glGetIntegerv(GL_MINOR_VERSION, &OpenGLVersion[1]);

Kommt letztendlich 4 und 2 raus, also Version 4.2 ist verfügbar

Edit2//
Hab nun mal bisschen probiert und es war auf 2.1 eingestellt.
Ab Version 3.2 oder höher (3.3, 4.0 - 4.2) wird nix mehr gerendert bei mir - muss ich wohl mal die alten Befehle rausfischen :roll:

Gibt es eigentlich eine Übersicht wo man sieht was alles entfernt wurde?

Nach oben

SDH.Prod

Betreff des Beitrags: Re: OpenGL Version

Verfasst: Mi Dez 21, 2011 22:39

DGL Member

Registriert: Sa Okt 18, 2008 11:59
Beiträge: 180

Dabei hilft dir zum einen dies hier:
http://www.opengl.org/documentation/specs/

und im speziellen dies:
http://www.khronos.org/files/opengl41-q ... e-card.pdf
(sofern du nicht Farbenblind bist, diese... Übersicht... arbeitet viel mit Farben), das ist zwar 4.1, aber eine Referenz-Karte für 4.2 gibt es momentan (21.12.2011 22:43 GMT+1) auf der Seite nicht.

Nach oben

yunharla

Betreff des Beitrags: Re: OpenGL Version

Verfasst: Do Dez 22, 2011 08:41

DGL Member

Registriert: Mo Nov 08, 2010 18:41
Beiträge: 769
Programmiersprache: Gestern

was sind eigentlich die Vorteile dabei einen solchen Context aufzusetzen?

_________________
Meine Homepage

Nach oben

Sascha Willems

Betreff des Beitrags: Re: OpenGL Version

Verfasst: Do Dez 22, 2011 09:32

DGL Member

Registriert: Mo Sep 23, 2002 19:27
Beiträge: 5812
Programmiersprache: C++

Man kann dann nur noch neue Funktionen nutzen, also VAs, VBOs und benötigt auch Shader um irgendwas zu sehen. Das führt dann dazu dass man konsequent nach neuen Standards entwickelt (bzw. entwickeln muss). Die sind dann auf passender Hardware natürlich auch teilweise performanter.

_________________
www.SaschaWillems.de | GitHub | Twitter | GPU Datenbanken (Vulkan, GL, GLES)

Nach oben

AMD

Betreff des Beitrags: Re: OpenGL Version

Verfasst: Do Dez 22, 2011 11:26

DGL Member

Registriert: Di Aug 09, 2011 07:33
Beiträge: 163
Programmiersprache: C/C++

Also wenn ich garkeinen Shader habe, dann wird mir auch nix angezeigt?
Ich muss also mindest gl_Position festlegen und glColor (und alles was dazu gehört) mit einem Vertex-Shader und Fragment-Shader?!

Nach oben

Sascha Willems

Betreff des Beitrags: Re: OpenGL Version

Verfasst: Do Dez 22, 2011 11:34

DGL Member

Registriert: Mo Sep 23, 2002 19:27
Beiträge: 5812
Programmiersprache: C++

Bei nem Renderkontext der nur vorwärtskompatible ist ja, da muss man dann Shader nutzen, da es keine feste Funktionspipeline mehr gibt. Sprich man muss auch eigene Matrixberechnungen usw. machen.

Edit : Ich poste hier mal ne Funktion zum Erstellen eines Renderkontextes, bei der man auch die Versionsnummer angeben kann. Hab das während der Pulsar-Beta benutzt, im dglHeader ists nicht drin (kann ich aber bei Bedarf machen), KEINE Garantue dass es auch jederzeit und immer korrekt funktioniert :

Code:

function CreateRenderingContextVersion(DC: HDC; Options: TRCOptions; MajorVersion, MinorVersion : Integer; ForwardCompatible : Boolean; ColorBits, ZBits, StencilBits, AccumBits, AuxBuffers: Integer; Layer: Integer): HGLRC;
const
 OBJ_MEMDC          = 10;
 OBJ_ENHMETADC      = 12;
 OBJ_METADC         = 4;
 PFD_DOUBLEBUFFER   = $00000001;
 PFD_STEREO         = $00000002;
 PFD_DRAW_TO_WINDOW = $00000004;
 PFD_DRAW_TO_BITMAP = $00000008;
 PFD_SUPPORT_GDI    = $00000010;
 PFD_SUPPORT_OPENGL = $00000020;
 PFD_TYPE_RGBA      = 0;
 PFD_MAIN_PLANE     = 0;
 PFD_OVERLAY_PLANE  = 1;
 PFD_UNDERLAY_PLANE = LongWord(-1);
 MemoryDCs          = [OBJ_MEMDC, OBJ_METADC, OBJ_ENHMETADC];
var
 PFDescriptor : TPixelFormatDescriptor;
 PixelFormat  : Integer;
 AType        : DWORD;
 LegacyRC     : HGLRC;
 Attribs      : array of Integer;
begin
 
{$IFDEF DGL_WIN64}
 OutPutDebugString('64 Bit Windows');
{$ENDIF}
 
if GL_LibHandle = nil then
 InitOpenGL;
 
if not Assigned(GL_LibHandle) then
 raise Exception.Create('GL_LibHandle is NIL. Could not load OpenGL library!');
 
FillChar(PFDescriptor, SizeOf(PFDescriptor), 0);
 
with PFDescriptor do
 begin
 nSize    := SizeOf(PFDescriptor);
 nVersion := 1;
 dwFlags  := PFD_SUPPORT_OPENGL;
 AType    := GetObjectType(DC);
 
 if AType = 0 then
  RaiseLastOSError;
 
 if AType in MemoryDCs then
  dwFlags := dwFlags or PFD_DRAW_TO_BITMAP
 else
  dwFlags := dwFlags or PFD_DRAW_TO_WINDOW;
 
 if opDoubleBuffered in Options then
  dwFlags := dwFlags or PFD_DOUBLEBUFFER;
 
 if opGDI in Options then
  dwFlags := dwFlags or PFD_SUPPORT_GDI;
 
 if opStereo in Options then
  dwFlags := dwFlags or PFD_STEREO;
 
 iPixelType   := PFD_TYPE_RGBA;
 cColorBits   := ColorBits;
 cDepthBits   := zBits;
 cStencilBits := StencilBits;
 cAccumBits   := AccumBits;
 cAuxBuffers  := AuxBuffers;
 
 if Layer = 0 then
  iLayerType := PFD_MAIN_PLANE
 else
  if Layer > 0 then
   iLayerType := PFD_OVERLAY_PLANE
  else
   iLayerType := Byte(PFD_UNDERLAY_PLANE);
 end;
 
PixelFormat := ChoosePixelFormat(DC, @PFDescriptor);
 
if PixelFormat = 0 then
 RaiseLastOSError;
 
if GetPixelFormat(DC) <> PixelFormat then
 if not SetPixelFormat(DC, PixelFormat, @PFDescriptor) then
  RaiseLastOSError;
 
DescribePixelFormat(DC, PixelFormat, SizeOf(PFDescriptor), PFDescriptor);
 
// Create legacy render context first for we need function pointers to
// create new OpenGL render contexts
LegacyRC := wglCreateContext(DC);
wglMakeCurrent(DC, LegacyRC);
 
// Set attributes to describe our requested context
SetLength(Attribs, 5);
Attribs[0] := WGL_CONTEXT_MAJOR_VERSION_ARB;
Attribs[1] := MajorVersion;
Attribs[2] := WGL_CONTEXT_MINOR_VERSION_ARB;
Attribs[3] := MinorVersion;
 
// Add context flag for forward compatible context
//  Forward compatible means no more support for legacy functions like
//  immediate mode (glvertex, glrotate, gltranslate, etc.)
if ForwardCompatible then
 begin
 SetLength(Attribs, Length(Attribs)+2);
 Attribs[4] := WGL_CONTEXT_FLAGS_ARB;
 Attribs[5] := WGL_CONTEXT_FORWARD_COMPATIBLE_BIT_ARB;
 end;
 
// Attribute flags must be finalized with a zero
Attribs[High(Attribs)] := 0;
 
// Get function pointer for new context creation function
wglCreateContextAttribsARB := wglGetProcAddress('wglCreateContextAttribsARB');
 
if not Assigned(wglCreateContextAttribsARB) then
 begin
 raise Exception.Create('Could not get function pointer adress for wglCreateContextAttribsARB - OpenGL 3.x and above not supported!');
 wglDeleteContext(LegacyRC);
 exit;
 end;
 
// Create context
Result := wglCreateContextAttribsARB(DC, 0, @Attribs[0]);
 
if Result = 0 then
 begin
 raise Exception.Create('Could not create the desired OpenGL rendering context!');
 wglDeleteContext(LegacyRC);
 exit;
 end;
 
wglDeleteContext(LegacyRC);
 
if Result = 0 then
 RaiseLastOSError
else
 LastPixelFormat := 0;
end;

_________________
www.SaschaWillems.de | GitHub | Twitter | GPU Datenbanken (Vulkan, GL, GLES)

Nach oben

FrenK

Betreff des Beitrags: Re: OpenGL Version

Verfasst: Do Dez 22, 2011 14:34

DGL Member

Registriert: Mi Jan 31, 2007 18:32
Beiträge: 150
Programmiersprache: Pascal

Des weiteren emöglicht diese art der Contexterstellung einen debug Context zu bekommen :

Code:

 
WGL_CONTEXT_FLAGS_ARB, WGL_CONTEXT_FORWARD_COMPATIBLE_BIT_ARB or WGL_CONTEXT_DEBUG_BIT_ARB
 

Nach oben

Seite 1 von 1

[ 10 Beiträge ]

Foren-Übersicht » Programmierung » OpenGL

Wer ist online?

Mitglieder in diesem Forum: 0 Mitglieder und 3 Gäste

Du darfst keine neuen Themen in diesem Forum erstellen.
Du darfst keine Antworten zu Themen in diesem Forum erstellen.
Du darfst deine Beiträge in diesem Forum nicht ändern.
Du darfst deine Beiträge in diesem Forum nicht löschen.
Du darfst keine Dateianhänge in diesem Forum erstellen.