DGL • Thema anzeigen - TextSuite-Textausgabe verfälscht Farben

TextSuite-Textausgabe verfälscht Farben

Moderator: DGL-Team

Seite 1 von 1

[ 5 Beiträge ]

Vorheriges Thema | Nächstes Thema

Autor

Nachricht

Bergmann89

Betreff des Beitrags: TextSuite-Textausgabe verfälscht Farben

Verfasst: Do Aug 28, 2008 11:49

DGL Member

Registriert: Di Apr 29, 2008 18:56
Beiträge: 1213
Programmiersprache: Delphi/FPC

HI,

langsam komm ich mir wie der blutigste Anfänger vor, hab schon wieder irgendein sinnloses Problem, was ich mir nich erklären kann:
Ich bin grad dabei mir ein Menü zu basteln. Mit Farbselektion such ich mir den Button raus, der gerade selektiert ist. Hab 3 Buttons: Einloggen, Optionen und Beenden. Farbeselektion wird mit ClearColor(1,0,0,1); und grün abgestuften Buttons gerendert und dann ausgelesen. Sobald ich aber sowas wie ein Label ("Hauptmenü") über den Buttons ausgeben will, dann werden die Farben bei der Farbselektion dunkler. Dann hab ich ma n bisl rum probiert und rausgefunden, das wenn ich in das label "TEST" rein schreib, das die Farben wieder normal sind?? Ich blick einfach nich mehr durch. kann mir da jmd helfen?

Code:

fMenuFont: TFont;
 
procedure TMainMenu.Render;
var i:Integer;
begin
  if not((fFlashScreenCounter < FlashScreenVisTime) or (fFlashScreenAlpha > 0)) then
    fSelection := Selected(fMenu);       //Farbselektion   
  //Form1.Caption := IntToStr(fSelection);
 
  glClearColor(0,0,0,1);  //ClearColor setzen
  glClear(GL_COLOR_BUFFER_BIT or GL_DEPTH_BUFFER_BIT);
 
  glMatrixMode(GL_PROJECTION);
  glLoadIdentity;
 
  gluPerspective(45, Form1.ClientWidth/Form1.ClientHeight, NearClipping, FarClipping);
 
  glMatrixMode(GL_MODELVIEW);
  glLoadIdentity;
 
  glTranslatef(0,0,-10);
 
  if (fFlashScreenCounter < FlashScreenVisTime) or (fFlashScreenAlpha > 0) then  //FlashScreen anzeigen
    begin
      fFontBig.SetColor(fFlashScreenAlpha,fFlashScreenAlpha,fFlashScreenAlpha,1);
      fFontSmall.SetColor(fFlashScreenAlpha,fFlashScreenAlpha,fFlashScreenAlpha,1);
      fFontBig.TextOut('Freind Hotel',0,0,10,2,TS_ALIGN_CENTER);
      fFontSmall.TextOut('by Bergmann',0,1.2,8,2,TS_ALIGN_RIGHT);
    end
  else
    begin
      for i := 0 to High(fActiveMenu.fButton) do //von 0 bis ButtonAnzahl-1
        begin
          glPushMatrix;
            if i = fSelection then glTranslatef(sin(fSinCount/2)/5,sin(fSinCount)/10,0); //Wenn Selektion = ButtonNr dann bewege Button
            fMenuFont.SetColor(fActiveMenu.fButton[i].Color[0],   //FontColor setzen
                               fActiveMenu.fButton[i].Color[1],
                               fActiveMenu.fButton[i].Color[2],
                               fActiveMenu.fButton[i].Color[3]);
            fMenuFont.TextOut( fActiveMenu.fButton[i].Text,    //Textausgabe
                               fActiveMenu.fButton[i].X,
                              -fActiveMenu.fButton[i].Y,
                               fActiveMenu.fButton[i].Width,
                               fActiveMenu.fButton[i].Height,
                               TS_ALIGN_CENTER);
          glPopMatrix;
        end;
      fMenuFont.SetColor(0.7,0.7,0.7,1);        //FontColor setzen
      fMenuFont.TextOut('TEST',0,-2,5,1,TS_ALIGN_CENTER);  //Textausgabe, hier liegt der fehler...so gehts aber wenn ich z.b: "abc" ausgeb, 
                                                          //dann werden die farben der farbselektion wieder dunkler!
    end;
end;
 
function TMainMenu.Selected(Menu: TMenu): Integer;
var PixelColor: record r,g,b,a: glFloat; end;
var i,Max:Integer;
var Width, Height: Real;
begin
  glClearColor(0,0,1,0);
  glClear(GL_COLOR_BUFFER_BIT or GL_DEPTH_BUFFER_BIT);
 
  glMatrixMode(GL_PROJECTION);
  glLoadIdentity;
 
  gluPerspective(45, Form1.ClientWidth/Form1.ClientHeight, NearClipping, FarClipping);
 
  glMatrixMode(GL_MODELVIEW);
  glLoadIdentity;
 
  glTranslatef(0,0,-10);
 
  max := High(fActiveMenu.fButton);  //von 0 bis ButtonAnzahl-1
  for i := 0 to Max do
    begin
      Width  := fActiveMenu.fButton[i].Width;  //Buttons rendern
      Height := fActiveMenu.fButton[i].Height;
      glPushMatrix;
        glTranslatef(fActiveMenu.fButton[i].X,fActiveMenu.fButton[i].Y,0);
        glBegin(GL_QUADS);
          glColor4f(0,(i+1)/(max+1),0,1);    //Selektions-Farbe festlegen   
          glVertex3f(-Width/2, Height/2, 0);
          glVertex3f(-Width/2,-Height/2, 0);
          glVertex3f( Width/2,-Height/2, 0);
          glVertex3f( Width/2, Height/2, 0);
        glEnd;
 
      glPopMatrix;
    end;
 
 
  //Buffer auslesen
  glReadPixels(Mouse.CursorPos.X-Form1.Left,Form1.Height-(Mouse.CursorPos.Y-Form1.Top),1,1,GL_RED,GL_FLOAT,@PixelColor.r);
  glReadPixels(Mouse.CursorPos.X-Form1.Left,Form1.Height-(Mouse.CursorPos.Y-Form1.Top),1,1,GL_GREEN,GL_FLOAT,@PixelColor.g);
  glReadPixels(Mouse.CursorPos.X-Form1.Left,Form1.Height-(Mouse.CursorPos.Y-Form1.Top),1,1,GL_BLUE,GL_FLOAT,@PixelColor.b);
  glReadPixels(Mouse.CursorPos.X-Form1.Left,Form1.Height-(Mouse.CursorPos.Y-Form1.Top),1,1,GL_ALPHA,GL_FLOAT,@PixelColor.a);
 
  if PixelColor.b > 0.5 then result := -1  //result berechnen
                        else result := round(PixelColor.g*(Max+1))-1;
end;
 
procedure TFont.TextOut(Text: String; X,Y,Width,Height: Single; Align: Cardinal);
begin
  glBlendFunc(GL_SRC_ALPHA, GL_ONE_MINUS_SRC_ALPHA);
  glEnable(GL_BLEND);
 
  glPushMatrix;
    glScalef(0.01,-0.01,0.01);
    glColor4fv(@fColor);
    tsSetParameteri(TS_ALIGN, Align);
    tsTextBeginBlock(round((X*100)-(Width*50)),
                     round((Y*100)-(Height*50)),
                     round(Width*100),
                     round(Height*100),
                     TS_BLOCKFLAG_WORD_WRAP);
      tsFontBind(fFontID);
      tsTextOutA(PAnsiChar(Text));
    tsTextEndBlock;
  glPopMatrix;
 
  glDisable(GL_BLEND);
end;
 
constructor TFont.Create(FontContextID: tsContextID; FontFileName: String; FontWidth: Integer; Style: Cardinal);
begin
  inherited Create;
 
  fColor[0] := 0;
  fColor[1] := 0;
  fColor[2] := 0;
  fColor[3] := 1;
 
  fFileName := FontFileName;
  fWidth    := FontWidth;
  fStyle    := Style;
 
  tsContextBind(FontContextID);
 
  tsSetParameteri(TS_RENDERER, TS_RENDERER_OPENGL); CheckError;
  tsSetParameteri(TS_CREATOR, TS_CREATOR_GDI); CheckError;
  tsFontCreateCreator(pAnsiChar(fFileName), fWidth, fStyle, TS_DEFAULT, TS_DEFAULT, @fFontID); CheckError;
  tsPostAddShadow4f(1,0,0,1,1,1,0);
end;

Wenn Code fehlt oder wenn ihr noch Bilder braucht sagt bescheid...

MfG & Thx Bergmann.

Nach oben

i0n0s

Betreff des Beitrags:

Verfasst: Do Aug 28, 2008 14:21

Ernährungsberater

Registriert: Sa Jan 01, 2005 17:11
Beiträge: 2068
Programmiersprache: C++

Die Farbselektion ist normalerweise ein neuer Renderschritt, da du dann andere Farben nehmen kannst.
Somit lässt du im Renderschritt die Schrift und sonstige Texturen weg.

_________________
Steppity,✲steppity,✴step,❆step,✳step! :twisted:

❆ ❄ ❄ ❄ ❅ ❄ ❆ ❄ ❅ ❄ ❅ ❄ ❅ ❄ ❄
❅ ☃ ❄ ❄ ❄ ❅ ❄ ❄ ❄ ❅ ❄ ☃ ❄ ❆ ❄ ❄

Nach oben

Bergmann89

Betreff des Beitrags:

Verfasst: Do Aug 28, 2008 16:58

DGL Member

Registriert: Di Apr 29, 2008 18:56
Beiträge: 1213
Programmiersprache: Delphi/FPC

Hab ich doch gemacht, wird bloß im normalen Renderschritt aufgerufen (ich weiß is n bisl blöd).
Auf jedenfall wird erst alles gelöscht, dann kommt die Farbselektion und dann wird nochma alles gelöscht und die normale Szene wird gerendert, und am Ende ausgegeben.

MfG Bergmann.

Nach oben

Lossy eX

Betreff des Beitrags:

Verfasst: Sa Sep 06, 2008 15:53

DGL Member

Registriert: Do Dez 05, 2002 10:35
Beiträge: 4234
Wohnort: Dortmund

Keine Ahnung ob du das Problem immer noch hast. Aber ich hoffe du denkst daran, dass die Texte durch Texturen erstellt werden und sobald der Text gerendert wurde bleiben die Texturen weiterhin gebunden und aktiv. Das kann unter Umständen deine Farben verändern.

Nach oben

Bergmann89

Betreff des Beitrags:

Verfasst: Mi Sep 17, 2008 15:12

DGL Member

Registriert: Di Apr 29, 2008 18:56
Beiträge: 1213
Programmiersprache: Delphi/FPC

HI,

hab'sch net dran gedacht^^
hab jetzt nach der Textausgabe glBindTexture(GL_TEXTURE_2D,0); aufgerufen und siehe da: es geht xD
DANKE!

MfG Bergmann.

Nach oben

Seite 1 von 1

[ 5 Beiträge ]

Foren-Übersicht » Programmierung » Einsteiger-Fragen

Wer ist online?

Mitglieder in diesem Forum: 0 Mitglieder und 7 Gäste

Du darfst keine neuen Themen in diesem Forum erstellen.
Du darfst keine Antworten zu Themen in diesem Forum erstellen.
Du darfst deine Beiträge in diesem Forum nicht ändern.
Du darfst deine Beiträge in diesem Forum nicht löschen.
Du darfst keine Dateianhänge in diesem Forum erstellen.