DGL • Thema anzeigen - unerklärlicher Beleuchtungs winkel

unerklärlicher Beleuchtungs winkel

Moderator: DGL-Team

Seite 1 von 1

[ 5 Beiträge ]

Druckansicht

Vorheriges Thema | Nächstes Thema

Autor

Nachricht

Sellmann

Betreff des Beitrags: unerklärlicher Beleuchtungs winkel

Verfasst: So Jan 06, 2008 00:13

DGL Member

Registriert: Fr Jan 04, 2008 21:29
Beiträge: 419
Wohnort: Lübeck

Hi, ich habe mich gerade gefreut, dass ich einen Phongshader in glsl geschrieben habe und der auch soweit richtig gut aussieht, allerdings will ich nicht nur diffuse und specular texturabhängig haben, sondern auch die normalen, also bump mapping (oder normal mapping, kA was richtiger ist).

Ich habe dazu diverse papers im Netz durchgelesen und verschieden Varianten ausprobiert aus dem phong shader einen bump shader zu machen. Im Prinzip habe ich den light und den View vector mit der TBN matrix an den Normalspace angepasst und berechne ansonsten alles so wie vorher. Die Texturen und Daten werden komplett richtig übergeben, aber irgendwie scheint in dem bumpshader ein Problem mit dem Beleuchtungswinkel aufzutauchen. ebenfalls verändert sich as verhalten der Specular auf der Oberfläche erheblich.

Wenn jemand eine Ahnung hat, was ich falschgemacht habe, oder so, dann darf er mich das ruhig wissen lassen.

Das phong shader vertex object:

Code:

 
varying vec3 normal;
varying vec3 v;
varying vec3 lightvec;
 
void main(void)
{
  normal          = normalize(gl_NormalMatrix * gl_Normal);
  v               = vec3(gl_ModelViewMatrix * gl_Vertex);
  lightvec        = normalize(gl_LightSource[0].position.xyz - v);
 
  gl_Position     = gl_ModelViewProjectionMatrix * gl_Vertex;
 
  gl_TexCoord[0]  = gl_MultiTexCoord0;
}
 

Das phong shader fragment object:

Code:

 
uniform sampler2D diffspec;
 
varying vec3 normal;
varying vec3 v;
varying vec3 lightvec;
 
void main(void)
{
 vec3 Eye             = normalize(-v);
 vec3 Reflected       = normalize( 2.0 * dot(normal, lightvec) * normal - lightvec);
 vec3 base        = texture2D(diffspec,vec2(gl_TexCoord[0])).xyz;
 
 vec4 IAmbient        = gl_LightSource[0].ambient;
 
 vec4 IDiffuse        = gl_LightSource[0].diffuse * max(dot(normal, lightvec), 0.0);
 
 float lambertTerm    = dot(normal,lightvec);
 
 vec4 finalcolor      = gl_LightSource[0].ambient * vec4(base,1.0) * (1.0-lambertTerm);
 
    if (lambertTerm > 0.0)
    {
        finalcolor += gl_LightSource[0].diffuse * vec4(base,1.0) * lambertTerm; 
        
        vec3 E = normalize(-v);
        vec3 R = reflect(-lightvec, normal);
        float specular = pow( max(dot(R, E), 0.0), 
                         120.0 );
        finalcolor += gl_LightSource[0].diffuse * texture2D(diffspec,vec2(gl_TexCoord[0])).a * (specular*3.0);  
    }
 
 gl_FragColor         = vec4(finalcolor.xyz,1.0);
}
 

Das bump shader vertex object:

Code:

 
varying vec3 eyevec;
varying vec3 lightvec;
 
attribute vec3 vTangent;
 
void main(void)
{
  gl_Position     = gl_ModelViewProjectionMatrix * gl_Vertex;
  gl_TexCoord[0]  = gl_MultiTexCoord0;
 
  vec3 v          = vec3(gl_ModelViewMatrix * gl_Vertex);
  vec3 tmpvec     = normalize(gl_LightSource[0].position.xyz - v);
 
  vec3 n = normalize(gl_NormalMatrix * gl_Normal);
  vec3 t = normalize(gl_NormalMatrix * vTangent);
  vec3 b = cross(t, n);
 
  lightvec.x = dot(tmpvec, t);
  lightvec.y = dot(tmpvec, b);
  lightvec.z = dot(tmpvec, n);
 
  tmpvec = -v;
  eyevec.x = dot(tmpvec, t);
  eyevec.y = dot(tmpvec, b);
  eyevec.z = dot(tmpvec, n);
}
 

Das bump shader fragment object:

Code:

 
uniform sampler2D diffspec;
uniform sampler2D normhei;
 
varying vec3 eyevec;
varying vec3 lightvec;
 
void main(void)
{
 vec3 normal          = texture2D(normhei,vec2(gl_TexCoord[0])).xyz;
 vec3 Reflected       = normalize( 2.0 * dot(normal, lightvec) * normal - lightvec);
 vec3 base        = texture2D(diffspec,vec2(gl_TexCoord[0])).xyz;
 
 float lambertTerm    = dot(normal,lightvec);
 
 vec4 finalcolor      = gl_LightSource[0].ambient * vec4(base,1.0) * (1.0-lambertTerm);
 
    if (lambertTerm > 0.0)
    {
        finalcolor += gl_LightSource[0].diffuse * vec4(base,1.0) * lambertTerm; 
        
        vec3 E = normalize(-eyevec);
        vec3 R = reflect(-lightvec, normal);
        float specular = pow( max(dot(R, E), 0.0), 
                         120.0 );
        finalcolor += gl_LightSource[0].diffuse * texture2D(diffspec,vec2(gl_TexCoord[0])).a * (specular*3.0);  
    }
 
gl_FragColor          = vec4(finalcolor.xyz,1.0);
}
 

Ich denke, es ist offensichtlich, dass sich kaum etwas geändert hat, trotzdem strahlt das Lich aus einer falschen Richtung.
dank vorweg;

[Edit] -> falsch c&p;

_________________
Klar Soweit?

Nach oben

oc2k1

Betreff des Beitrags:

Verfasst: So Jan 06, 2008 03:52

DGL Member

Registriert: So Jun 04, 2006 12:54
Beiträge: 263

Beim dot3 bumpmapping gibt es zwei Varianten: Eine arbeitet im texturspace das war füher nötig, da Register combiner keine matrixmultiplikation durchführen konnten, Der nachteil ist, das jede Lichtquelle ebenfalls in den texturspace transformiert werden muss.

Heute kann man es sich ohne Probleme erlauben. Den Normalvektor aus der normalmap in den modelviewspace zu projezieren. Über gib einfach die TBN matrix an den Fragmentshader. Da dieser Code immer wieder gebraucht wird hab ich ihn hier als Tutorial abgelegt:
http://lumina.sourceforge.net/?id=23

_________________
Lumina plattform unabhängige GLSL IDE

Nach oben

Sellmann

Betreff des Beitrags:

Verfasst: So Jan 06, 2008 14:20

DGL Member

Registriert: Fr Jan 04, 2008 21:29
Beiträge: 419
Wohnort: Lübeck

Aller besten Dank!

Ich habe nichtbeachtet, dass die Normalmap einen Bereich von 0 bis 1 besitzt, die normalen aber einen bereich von -1 bis +1.
Richtig siehts so aus:

Code:

 
vec3 normal       = texture2D(normhei,vec2(gl_TexCoord[0])).xyz -0.5;
 

wichtig ist das -0.5 am ende der Zeile gewesen, die den Bereich verschiebt/korrigiert.
Ja dumm gelaufen, dieser Fehler hat mich verfolgt.

Danke du hast mir sehr geholfen!!

Freude~

_________________
Klar Soweit?

Nach oben

Lord Horazont

Betreff des Beitrags:

Verfasst: So Jan 06, 2008 14:44

DGL Member

Registriert: Do Sep 02, 2004 19:42
Beiträge: 4158
Programmiersprache: FreePascal, C++

Moment, fehlt da nicht noch ein * 2.0?
Wenn du werte von 0 bis 1 hast und diese -0.5 nimmst, hast du werte von -0.5 bis 0.5. Da müsstest du doch noch mal zwei nehmen, damit du werte von -1.0 bis 1.0 hast, oder?

Gruß Lord Horazont

_________________
If you find any deadlinks, please send me a notification – Wenn du tote Links findest, sende mir eine Benachrichtigung.
current projects: ManiacLab; aioxmpp
zombofant network • my photostream
„Writing code is like writing poetry“ - source unknown

„Give a man a fish, and you feed him for a day. Teach a man to fish and you feed him for a lifetime. “ ~ A Chinese Proverb

Nach oben

oc2k1

Betreff des Beitrags:

Verfasst: So Jan 06, 2008 15:00

DGL Member

Registriert: So Jun 04, 2006 12:54
Beiträge: 263

in dem Fall nicht, da in der nächten Zeile. der normalmapvektor aus dem texturspace ind den Modelviewspace rotiert wird und dann anschließend normalisiert wird. Noch besser wäre die variante ein signed texture format zu verweden...

_________________
Lumina plattform unabhängige GLSL IDE

Nach oben

Seite 1 von 1

[ 5 Beiträge ]

Foren-Übersicht » Programmierung » Shader

Wer ist online?

Mitglieder in diesem Forum: 0 Mitglieder und 6 Gäste

Du darfst keine neuen Themen in diesem Forum erstellen.
Du darfst keine Antworten zu Themen in diesem Forum erstellen.
Du darfst deine Beiträge in diesem Forum nicht ändern.
Du darfst deine Beiträge in diesem Forum nicht löschen.
Du darfst keine Dateianhänge in diesem Forum erstellen.