DGL • Thema anzeigen - SDL Texturen funktionieren nicht :-(

SDL Texturen funktionieren nicht :-(

Moderator: DGL-Team

Seite 1 von 1

[ 5 Beiträge ]

Vorheriges Thema | Nächstes Thema

Autor

Nachricht

Lord Horazont

Betreff des Beitrags: SDL Texturen funktionieren nicht :-(

Verfasst: Mo Sep 04, 2006 15:33

DGL Member

Registriert: Do Sep 02, 2004 19:42
Beiträge: 4158
Programmiersprache: FreePascal, C++

Hi @ll

Ich stehe jetzt schon seit einigen Tagen auf dem sprichwörtlichen Schlauch, ich hab den Code schon mehrfach durchsucht, aber ich finde den Fehler nicht.
Das Problem:
Ich lade die Texturen mit einem eigenen Texturmanager / Loader basierend auf SDL_Image. Dort werden ID's und alles generiert, die Textur geladen und mittels glTexImage2D geuploaded. Allerdings muss ich mich mit einem Texturlosen grau zufriedengeben, obwohl keine Fehler auftreten. Die Textur ist 512x512 Pixel groß, also an der größe dürfte es auch nicht hapern.

Hier ein paar Sourcecodes

1. Texturloader

Code:

 
function TstwEngineTexture.LoadFromSurface(const Surface: PSDL_Surface): Boolean;
var
  SavedFlags: UInt32;
  SavedAlpha: UInt8;
  Area: SDL_Rect;
begin
  Result := False;
  if FImage <> nil then
    SDL_FreeSurface(FImage);
  FImage := SDL_CreateRGBSurface(
      SDL_SWSURFACE,
      Surface.w,
      Surface.h,
      32,
      $000000FF,
      $0000FF00,
      $00FF0000,
      $FF000000
    );
 
  if (FImage = nil) then
  begin
    FEngine.Log.WriteError('Textures', 'LoadFromSurface', 'Couldn''t create SDL-Surface (%s)', [StrPas(SDL_GetError)]);
    Exit;
  end;
 
  SavedFlags := Surface.flags and (SDL_SRCALPHA or SDL_RLEACCELOK);
  SavedAlpha := Surface.format.alpha;
 
  if ((SavedFlags and SDL_SRCALPHA) = SDL_SRCALPHA) then
    SDL_SetAlpha(Surface, 0, 0);
 
  Area.x := 0;
  Area.y := 0;
  Area.w := Surface.w;
  Area.h := Surface.h;
 
  Result := SDL_BlitSurface(Surface, @Area, FImage, @Area) > -1;
 
  if ((SavedFlags and SDL_SRCALPHA) = SDL_SRCALPHA) then
    SDL_SetAlpha(Surface, SavedFlags, SavedAlpha);
 
end;
 
procedure TstwEngineTexture.LoadFromFile(const FileName: String);
var
  Surface: PSDL_Surface;
begin
  if not FileExists(FileName) then
  begin
    FEngine.Log.WriteError('Textures', 'LoadFromFile', 'File doesn''t exists (%s)', [FileName]);
    Exit;
  end;
  Surface := IMG_Load(PChar(FileName));
  if (Surface = nil) then
  begin
    FEngine.Log.WriteError('Textures', 'LoadFromFile', 'Couldn''t load file (%s)', [StrPas(IMG_GetError)]);
    Exit;
  end;
 
  LoadFromSurface(Surface);
  SDL_FreeSurface(Surface);
 
  UploadTexture;
end;
 

2. UploadTexture

Code:

 
function TstwEngineTexture2D.UploadTexture: Boolean; 
begin
  FEngine.ClearError;
  Result := False;
  if FImage = nil then
  begin
    FEngine.Log.WriteError('Textures', 'UploadTexture', 'No image loaded', []);
    Exit;
  end;
 
  if FID = 0 then
  begin
    FEngine.Log.WriteError('Textures', 'UploadTexture', 'Texture not generated', []);
    Exit;
  end;
 
  glBindTexture(FTarget, FID);
  glTexImage2D(FTarget, 0, 4, FImage.w, FImage.h, 0, GL_RGBA,
    GL_UNSIGNED_BYTE, FImage.pixels);
  Result := FEngine.Error('Textures', 'UploadTexture') = 0;
end;
 

3. Rendern

Code:

 
        with Engine.TextureByIdentifier['Worldmap'] as TstwEngineTexture2D do
        begin
          glEnable(GL_TEXTURE_2D);
          glBindTexture(GL_TEXTURE_2D, ID);
          glBegin(GL_QUADS);
            glTexCoord2f(0, 0);
            glVertex2f(0, 0);
            glTexCoord2f(0, 1.0);
            glVertex2f(0, 511);
            glTexCoord2f(1.0, 1.0);
            glVertex2f(511, 511);
            glTexCoord2f(1.0, 0);
            glVertex2f(511, 0);
          glEnd;
        end;
 

4. Initialisieren der Texturen

Code:

 
  LogLn('Initializing Engine...');
  Engine := TstwEngine.Create;
  LogLn('Setting up sound variables...');
  Engine.Log.WirteDirect := True;          
  LogLn('Preparing textures...');
  Engine.TextureByIndex[Engine.CreateTexture2D('Worldmap')].GenTexture;
  with (Engine.TextureByIdentifier['Worldmap'] as TstwEngineTexture2D) do
  begin
    LoadFromFile(AppPath + 'gfx\worldmap_1.jpg');
  end;
  {...}
 

Ich find den Fehler nicht, falls noch mehr Source benötigt wird, kann ich gerne noch was rausrücken.

Gruß, ein verzweifelter Lord Horazont

_________________
If you find any deadlinks, please send me a notification – Wenn du tote Links findest, sende mir eine Benachrichtigung.
current projects: ManiacLab; aioxmpp
zombofant network • my photostream
„Writing code is like writing poetry“ - source unknown

„Give a man a fish, and you feed him for a day. Teach a man to fish and you feed him for a lifetime. “ ~ A Chinese Proverb

Nach oben

i0n0s

Betreff des Beitrags: Re: SDL Texturen funktionieren nicht :-(

Verfasst: Mo Sep 04, 2006 16:28

Ernährungsberater

Registriert: Sa Jan 01, 2005 17:11
Beiträge: 2068
Programmiersprache: C++

Das einzige was mir gross aufgefallen ist war das: SDL_RLEACCELOK als Flag.
Ansonsten könntest du temporär das Blitten in eine Extrasurface weglassen, da dies nur bei 8-Bit-Surfaces richtig zu empfehlen ist.

_________________
Steppity,✲steppity,✴step,❆step,✳step! :twisted:

❆ ❄ ❄ ❄ ❅ ❄ ❆ ❄ ❅ ❄ ❅ ❄ ❅ ❄ ❄
❅ ☃ ❄ ❄ ❄ ❅ ❄ ❄ ❄ ❅ ❄ ☃ ❄ ❆ ❄ ❄

Nach oben

Lord Horazont

Betreff des Beitrags:

Verfasst: Mo Sep 04, 2006 17:11

DGL Member

Registriert: Do Sep 02, 2004 19:42
Beiträge: 4158
Programmiersprache: FreePascal, C++

Das Blitten mache ich, damit das übergeben an OpenGL immer mit dem Farbformat GL_RGBA geht, für den Fall, dass ich z.B. mal eine ABGR-Textur habe. Und das SDL_RLEACCELOK habe ich auch erst zum testen hinzugefügt, das hatte ich aus dem Textausgabe-mit-SDL-Tut.

Gruß Lord Horazont

Nach oben

Lossy eX

Betreff des Beitrags:

Verfasst: Di Sep 05, 2006 08:23

DGL Member

Registriert: Do Dez 05, 2002 10:35
Beiträge: 4234
Wohnort: Dortmund

Ich denke das Problem liegt nicht an SDL. Was setzt du denn eigentlich für Filterungen bei deiner Textur? Setzt du überhaupt eine?

Wenn du zum Beispiel als Minfilter GL_LINEAR_MIPMAP_LINEAR angegeben hast und du aber keine MipMaps erzeugen lässt, dann streikt OpenGL. Bzw wenn du gar keine Filterung angegeben hast benutzt der Treiber einen Standardmodus. Optimiert auf Geschwindigkeit und aussehen dürfte das auch GL_LINEAR_MIPMAP_LINEAR sein.

Ach ja. Resultierend aus den fehlenden MipMaps stellt OpenGL natürlich keine Textur dar.

Du hast jetzt 2 Möglichkeiten.
1. Du setzt einen Filter der keine MipMaps vorraussetzt. Also GL_LINEAR

oder

2. du lässt OpenGL MipMaps erzeugen. Ich bin faul deswegen hier nur ein Stück Code aus meiner glBitmap.

Code:

    if (GL_VERSION_1_4 or GL_SGIS_generate_mipmap)
      then glTexParameteri(Target, GL_GENERATE_MIPMAP, GL_TRUE)

PS: Bevor sich jemand wundert. Die "Möglichkeit" mit gluBuild2DMipmaps MipMaps zu erzeugen habe ich bewusst rausgelassen, da das Heutzutage keine Möglichkeit mehr sein sollte.

Nach oben

Lord Horazont

Betreff des Beitrags:

Verfasst: Di Sep 05, 2006 15:25

DGL Member

Registriert: Do Sep 02, 2004 19:42
Beiträge: 4158
Programmiersprache: FreePascal, C++

*duck*

War klar, das ich das mal wieder übersehen musste. Aber dennoch danke, dass ihr mir trotzdem geholfen habt. Mein Threadtitel kommt davon, dass bis jetzt immer Texturen funktioniert haben, aber nie mit SDL.
Jetzt gehts. *freu*

Gruß Lord Horazont

Nach oben

Seite 1 von 1

[ 5 Beiträge ]

Foren-Übersicht » Programmierung » OpenGL

Wer ist online?

Mitglieder in diesem Forum: 0 Mitglieder und 1 Gast

Du darfst keine neuen Themen in diesem Forum erstellen.
Du darfst keine Antworten zu Themen in diesem Forum erstellen.
Du darfst deine Beiträge in diesem Forum nicht ändern.
Du darfst deine Beiträge in diesem Forum nicht löschen.
Du darfst keine Dateianhänge in diesem Forum erstellen.