DGL • Thema anzeigen - auslesen einer opengl textur

auslesen einer opengl textur

Moderator: DGL-Team

Seite 1 von 1

[ 4 Beiträge ]

Vorheriges Thema | Nächstes Thema

Autor

Nachricht

trifox

Betreff des Beitrags: auslesen einer opengl textur

Verfasst: Di Aug 15, 2006 11:08

DGL Member

Registriert: Do Sep 19, 2002 12:14
Beiträge: 9

hallo leute, ist es irgendwie moeglich eine textur die mittels glTexImage2D in opengl hochgeladen wurde
auch wieder herunterzuladen ? also quasi wieder in einen speicherbereich zu kopieren?

_________________
divide and rule, recure and imperate...

Nach oben

La Boda

Betreff des Beitrags:

Verfasst: Di Aug 15, 2006 11:42

DGL Member

Registriert: Mi Jul 17, 2002 12:07
Beiträge: 976
Wohnort: Tübingen

Also die Hau-drauf-Methode wär ja, einfach die Textur auf ein möglichst großes Quad zu zeichnen und dann einen Screenshot bzw. die Pixelfarben auszulesen.

_________________
"Du musst ein Schwein sein in dieser Welt, sangen die Prinzen, das ist so 1.0. Du musst auf YouTube zeigen, dass dir dein Schweinsein gefällt, das ist leuchtendes, echtes Web 2.0."
- Hal Faber
Meine Homepage: http://laboda.delphigl.com

Nach oben

Lossy eX

Betreff des Beitrags:

Verfasst: Di Aug 15, 2006 12:15

DGL Member

Registriert: Do Dez 05, 2002 10:35
Beiträge: 4234
Wohnort: Dortmund

La Boda. Das ist wirklich "Hau drauf". Speziell dafür gibt es Methoden. In der glBitmap habe ich dafür auch eine Methode implementiert. GetDataFromTexture

Diese lauten glGetTexImage und glGetCompressedTexImage. Außerdem solltest du mit glGetTexLevelParameter die Parameter der Textur auslesen. Diese können sich zum Hochgeladenen unterscheiden. Bei 8 Bit aber eher unwahrscheinlich. Vorstellbar wäre aber etwas mit dem Alphakanal.

Zur kompletten Verwirrung hier aber noch das Stück aus der glBitmap. Ich übernehme aber keine Garantie darauf, dass das auch so funktioniert wie es sein sollte.

Code:

procedure TglBitmap2D.GetDataFromTexture;
var
  Temp: pByte;
  TempWidth, TempHeight, RedSize, GreenSize, BlueSize, AlphaSize, LumSize: Integer;
  TempType, TempIntFormat: Cardinal;
  IntFormat: TglBitmapInternalFormat;
begin
  Bind;
 
  // Request Data
  glGetTexLevelParameteriv(Target, 0, GL_TEXTURE_WIDTH, @TempWidth);
  glGetTexLevelParameteriv(Target, 0, GL_TEXTURE_HEIGHT, @TempHeight);
  glGetTexLevelParameteriv(Target, 0, GL_TEXTURE_INTERNAL_FORMAT, @TempIntFormat);
 
  glGetTexLevelParameteriv(Target, 0, GL_TEXTURE_RED_SIZE, @RedSize);
  glGetTexLevelParameteriv(Target, 0, GL_TEXTURE_GREEN_SIZE, @GreenSize);
  glGetTexLevelParameteriv(Target, 0, GL_TEXTURE_BLUE_SIZE, @BlueSize);
  glGetTexLevelParameteriv(Target, 0, GL_TEXTURE_ALPHA_SIZE, @AlphaSize);
  glGetTexLevelParameteriv(Target, 0, GL_TEXTURE_LUMINANCE_SIZE, @LumSize);
 
  // Get glBitmapInternalFormat from TempIntFormat
  TempType := GL_UNSIGNED_BYTE;
  case TempIntFormat of
    GL_ALPHA:
      IntFormat := ifAlpha;
    GL_LUMINANCE:
      IntFormat := ifLuminance;
    GL_LUMINANCE_ALPHA:
      IntFormat := ifLuminanceAlpha;
    GL_RGB4:
      begin
        IntFormat := ifR5G6B5;
        TempIntFormat := GL_RGB;
        TempType := GL_UNSIGNED_SHORT_5_6_5;
      end;
    GL_RGB, GL_RGB8:
      IntFormat := ifRGB8;
    GL_RGBA, GL_RGBA4, GL_RGBA8:
      begin
        if (RedSize = 4) and (BlueSize = 4) and (GreenSize = 4) and (AlphaSize = 4) then begin
          IntFormat := ifRGBA4;
          TempIntFormat := GL_BGRA;
          TempType := GL_UNSIGNED_SHORT_4_4_4_4_REV;
        end else
        if (RedSize = 5) and (BlueSize = 5) and (GreenSize = 5) and (AlphaSize = 1) then begin
          IntFormat := ifRGB5A1;
          TempIntFormat := GL_BGRA;
          TempType := GL_UNSIGNED_SHORT_1_5_5_5_REV;
        end else begin
          IntFormat := ifRGBA8;
        end;
      end;
    GL_BGR:
      IntFormat := ifBGR8;
    GL_BGRA:
      IntFormat := ifBGRA8;
    GL_COMPRESSED_RGB_S3TC_DXT1_EXT:
      IntFormat := ifDXT1;
    GL_COMPRESSED_RGBA_S3TC_DXT1_EXT:
      IntFormat := ifDXT1;
    GL_COMPRESSED_RGBA_S3TC_DXT3_EXT:
      IntFormat := ifDXT3;
    GL_COMPRESSED_RGBA_S3TC_DXT5_EXT:
      IntFormat := ifDXT5;
  else
    IntFormat := ifEmpty;
  end;
 
  // Getting data from OpenGL
  GetMem(Temp, FormatGetImageSize(glBitmapPosition(TempWidth, TempHeight), IntFormat));
  try
    if FormatIsCompressed(IntFormat) and (GL_VERSION_1_3 or GL_ARB_texture_compression) then
      glGetCompressedTexImage(Target, 0, Temp)
    else
      glGetTexImage(Target, 0, TempIntFormat, TempType, Temp);
 
    SetDataPtr(Temp, IntFormat, TempWidth, TempHeight);
  except
    FreeMem(Temp);    
  end;  
end;

Nach oben

trifox

Betreff des Beitrags:

Verfasst: Di Aug 15, 2006 13:12

DGL Member

Registriert: Do Sep 19, 2002 12:14
Beiträge: 9

super, danke

_________________
divide and rule, recure and imperate...

Nach oben

Seite 1 von 1

[ 4 Beiträge ]

Foren-Übersicht » Programmierung » OpenGL

Wer ist online?

Mitglieder in diesem Forum: 0 Mitglieder und 9 Gäste

Du darfst keine neuen Themen in diesem Forum erstellen.
Du darfst keine Antworten zu Themen in diesem Forum erstellen.
Du darfst deine Beiträge in diesem Forum nicht ändern.
Du darfst deine Beiträge in diesem Forum nicht löschen.
Du darfst keine Dateianhänge in diesem Forum erstellen.