DGL • Thema anzeigen - Textur soll immer im Hintergrund sein...

Textur soll immer im Hintergrund sein...

Moderator: DGL-Team

Seite 1 von 1

[ 5 Beiträge ]

Vorheriges Thema | Nächstes Thema

Autor

Nachricht

LH_Freak

Betreff des Beitrags: Textur soll immer im Hintergrund sein...

Verfasst: Mo Mär 13, 2006 17:41

DGL Member

Registriert: So Dez 19, 2004 00:27
Beiträge: 454
Wohnort: Nürnberg

Ich arbeite ja gerade daran, dass meine "Engine" Himmel anzeigen kann ^^. Der Himmel soll vor dem Terrain usw. gerendert werden, aber immer ganz hinten sein. Ich hab's schon so versucht:

Code:

glDisable(GL_DEPTH_TEST);
glDepthMask(0);

das ging dann auch, wenn ich ein Viereck gezeichnet hab, dass größer war als der Bildschirm.
Da ich aber will, dass die Textur den Bildschirm ausfüllt, hab ich anschließend

Code:

glOrtho(0,1,0,1,-1,1);

dazu. Tja, und danach geht's aus irgendeinem Grund nicht mehr...

Nach oben

sniper

Betreff des Beitrags:

Verfasst: Mo Mär 13, 2006 18:10

DGL Member

Registriert: Mi Dez 15, 2004 20:36
Beiträge: 454
Wohnort: Wien, Österreich

Code:

  glViewport(0, 0, SCREEN_WIDTH, SCREEN_HEIGHT);
  glMatrixMode(GL_PROJECTION);
    glLoadIdentity();
    glOrtho(0,SCREEN_WIDTH,0,SCREEN_HEIGHT,-10,10); // go to 2d mode
  glMatrixMode(GL_MODELVIEW);
    glLoadIdentity();
  glDisable(GL_DEPTH_TEST);
  glDisable(GL_BLEND);
  FBackGroundTexture.Bind();
  glColor3f(1,1,1);
  glLoadIdentity();
  glScalef(SCREEN_WIDTH,SCREEN_HEIGHT,1);
    glBegin(GL_QUADS);
      glTexCoord2f(0,0); glVertex2f(0,0);
      glTexCoord2f(1,0); glVertex2f(1,0);
      glTexCoord2f(1,1); glVertex2f(1,1);
      glTexCoord2f(0,1); glVertex2f(0,1);
    glEnd();
 

_________________
"Meine Mutter sagt : 'Dumm ist der, der Dummes tut'." - Forrest Gump

Nach oben

LH_Freak

Betreff des Beitrags:

Verfasst: Mo Mär 13, 2006 18:42

DGL Member

Registriert: So Dez 19, 2004 00:27
Beiträge: 454
Wohnort: Nürnberg

Jetzt zeigt er komischerweise die Textur nicht mehr an, sondern nur einen blauen bildschirm...

Nach oben

Flash

Betreff des Beitrags:

Verfasst: Mo Mär 13, 2006 18:49

Guitar Hero

Registriert: Do Sep 25, 2003 15:56
Beiträge: 7810
Wohnort: Sachsen - ERZ / C
Programmiersprache: Java (, Pascal)

Der Code kann so auch net gehen. Das Letzte glLoadIdentity muss denk ich mal ganz ans ende. Und dann musst du vermutlich auch wieder aus dem Orthomodus zurückkehren.

_________________
Blog: kevin-fleischer.de und fbaingermany.com

Nach oben

sniper

Betreff des Beitrags:

Verfasst: Mo Mär 13, 2006 20:59

DGL Member

Registriert: Mi Dez 15, 2004 20:36
Beiträge: 454
Wohnort: Wien, Österreich

Code funct sicherlich, ist schliesslich aus dem Ballonkiller. Wenn du jetzt etwas in 3D darstellen möchtest, dann musst du via gluPerspective die Projection-Matrix ändern.

Code:

unit Unit1;
 
interface
 
uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, dglOpenGl, glBitmap;
 
type
  TForm1 = class(TForm)
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
    procedure FormPaint(Sender: TObject);
    procedure FormKeyDown(Sender: TObject; var Key: Word;
      Shift: TShiftState);
    procedure FormResize(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
    myRc, myDc : Cardinal;
    GL_Texture:TglBitmap2D;
    procedure InitGl();
    procedure DeInitGl();
    procedure glRender();
  end;
 
var
  Form1: TForm1;
 
implementation
 
{$R *.dfm}
 
procedure TForm1.DeInitGl;
begin//
  DeactivateRenderingContext();
  DestroyRenderingContext(myRc);
  ReleaseDC(Handle,myDc);
end;
 
procedure TForm1.FormCreate(Sender: TObject);
begin//
  OnResize := nil;
 
  InitGl();
  Caption := 'OpenGL VCL Template by sniper (haris_201@hotmail.com)';
  KeyPreview := True;
 
  GL_Texture := TglBitmap2D.Create();
  GL_Texture.BuildMipMaps := False;
  GL_Texture.LoadFromFile('Back.bmp');
  GL_Texture.FreeDataAfterGenTexture := True;
  GL_Texture.GenTexture();
 
  OnResize := FormResize;
  Resize();
end;
 
procedure TForm1.FormDestroy(Sender: TObject);
begin//
  GL_Texture.Free();
  DeInitGl();
end;
 
procedure TForm1.InitGl;
begin//
 InitOpenGL();
 myDc := GetDC(Handle);
 myRc := CreateRenderingContext(myDc,[opDoubleBuffered],24,16,8,0,0,0);
 ActivateRenderingContext(myDc,myRc);
 glClearColor(0, 0,0, 0);
 glShadeModel(GL_SMOOTH);
 glClearDepth(1.5);
 glDisable(GL_DEPTH_TEST);
 glDepthFunc (GL_LEQUAL);
 glHint(GL_PERSPECTIVE_CORRECTION_HINT, GL_NICEST);
 glEnable(GL_TEXTURE_2D);
end;
 
procedure TForm1.FormPaint(Sender: TObject);
begin
  //glClear(GL_COLOR_BUFFER_BIT or GL_DEPTH_BUFFER_BIT);
  // TODO : Draw Hier
  glRender();
  // End Drawing
  SwapBuffers(myDc);
end;
 
procedure TForm1.FormKeyDown(Sender: TObject; var Key: Word;
  Shift: TShiftState);
begin
  if Key=27 then Close();
end;
 
procedure TForm1.FormResize(Sender: TObject);
begin//
  if (ClientHeight=0) then
  begin
    ClientHeight := 1;
  end;
  glViewport(0, 0, ClientWidth, ClientHeight);
  glMatrixMode(GL_PROJECTION);
  glLoadIdentity();
  // for 2d
  glOrtho(0, ClientWidth, ClientHeight,0, -10,10);
  // for 3d
  //gluPerspective(45, Width/Height, 0.1, 1000);
  glMatrixMode(GL_MODELVIEW);
  glLoadIdentity();
 
  FormPaint(nil);
end;
 
procedure TForm1.glRender();
begin
  GL_Texture.Bind();
 
  glLoadIdentity();
  //glTranslatef( ClientWidth/2 - GL_Texture.Width/2, ClientHeight/2 - GL_Texture.Height/2, 0 );
  //glScalef(GL_Texture.Width, GL_Texture.Height, 1);
  glScalef( ClientWidth, ClientHeight, 1 );
  glBegin(GL_QUADS);
  glTexCoord2f(0,0);
  glVertex2f(0,0);
  glTexCoord2f(1,0);
  glVertex2f(1,0);
  glTexCoord2f(1,1);
  glVertex2f(1,1);
  glTexCoord2f(0,1);
  glVertex2f(0,1);
  glEnd();
end;
 
end.

_________________
"Meine Mutter sagt : 'Dumm ist der, der Dummes tut'." - Forrest Gump

Nach oben

Seite 1 von 1

[ 5 Beiträge ]

Foren-Übersicht » Programmierung » OpenGL

Wer ist online?

Mitglieder in diesem Forum: 0 Mitglieder und 7 Gäste

Du darfst keine neuen Themen in diesem Forum erstellen.
Du darfst keine Antworten zu Themen in diesem Forum erstellen.
Du darfst deine Beiträge in diesem Forum nicht ändern.
Du darfst deine Beiträge in diesem Forum nicht löschen.
Du darfst keine Dateianhänge in diesem Forum erstellen.