Files |  Tutorials |  Articles |  Links |  Home |  Team |  Forum |  Wiki |  Impressum

Aktuelle Zeit: Sa Jul 12, 2025 19:30

Foren-Übersicht » Programmierung » Allgemein 		Unbeantwortete Themen | Aktive Themen


Ein neues Thema erstellen Auf das Thema antworten  Seite 1 von 2
  [ 24 Beiträge ]  Gehe zu Seite 1, 2  Nächste
  Vorheriges Thema | Nächstes Thema 
Autor Nachricht
Gamer 2000
BeitragVerfasst: Mi Feb 22, 2006 11:00 
Offline
DGL Member

Registriert: Mi Feb 22, 2006 10:41
Beiträge: 12
Wohnort: St. Gallen - Schweiz
Hallo Leute

Bis jetzt habe ich den OpenGL-Header "OpenGL12.pas" benützt und bin nun auf "dglOpenGL.pas" umgestiegen, weil es einen sehr guten Eindruck auf mich macht. Ich möchte nun Multisampling einbauen, aber leider scheitere ich schon bei der Erstellung des PixelFormats... wglChoosePixelFormatARB produziert nämlich die ganze Zeit eine Access Violation at address 00000000. Meine Grafikkarte unterstützt Multisample sicher, da ich das Programm von NeHe http://nehe.gamedev.net/data/lessons/le ... ?lesson=46 problemlos compilieren und ausführen kann.

Hier mal die wesentlichen Teile des Codes, alles nach wglChoosePixelFormatARB hab ich noch nicht ganz fertig, da zuerst mal wglChoosePixelFormatARB funktionieren muss...

Code:
  1. {...}
  2.  
  3. uses
  4.   Windows, Messages, SysUtils, Classes, Controls, Forms, Dialogs,
  5.   ExtCtrls, StdCtrls, Math, dglOpenGL, SDL, SDL_Image;
  6.  
  7. {...}
  8.  
  9. var
  10.   WndDC: HDC;
  11.  
  12. {...}
  13.  
  14. //InitializeOpenGL wird bei OnCreate ausgeführt
  15. procedure TForm1.InitializeOpenGL;
  16.  
  17.   procedure InitializePixelFormat;
  18.   var
  19.     IAtrib: array of GLint;
  20.     FAtrib: array of GLfloat;
  21.     PixelFormat: GLint;
  22.     numPixelFormats: GLuint;
  23.   begin
  24.     setLength(IAtrib,22);
  25.     IAtrib[0] := WGL_DRAW_TO_WINDOW_ARB;
  26.     IAtrib[1] := 1;
  27.     IAtrib[2] := WGL_SUPPORT_OPENGL_ARB;
  28.     IAtrib[3] := 1;
  29.     IAtrib[4] := WGL_DOUBLE_BUFFER_ARB;
  30.     IAtrib[5] := 1;
  31.     IAtrib[6] := WGL_PIXEL_TYPE_ARB;
  32.     IAtrib[7] := WGL_TYPE_RGBA_ARB;
  33.     IAtrib[8] := WGL_COLOR_BITS_ARB;
  34.     IAtrib[9] := 24;
  35.     IAtrib[10] := WGL_ALPHA_BITS_ARB;
  36.     IAtrib[11] := 0;
  37.     IAtrib[12] := WGL_DEPTH_BITS_ARB;
  38.     IAtrib[13] := 8;
  39.     IAtrib[14] := WGL_STENCIL_BITS_ARB;
  40.     IAtrib[15] := 0;
  41.     IAtrib[16] := WGL_SAMPLE_BUFFERS_ARB;
  42.     IAtrib[17] := 1;
  43.     IAtrib[18] := WGL_SAMPLES_ARB;
  44.     IAtrib[19] := 4;
  45.     IAtrib[20] := 0;
  46.     IAtrib[21] := 0;
  47.  
  48.     setLength(FAtrib,2);
  49.     FAtrib[0] := 0;
  50.     FAtrib[1] := 0;
  51.  
  52.     wglChoosePixelFormatARB(WndDC,@IAtrib,@FAtrib,1,@PixelFormat,@numPixelFormats);
  53.  
  54.     {...}
  55.   end;
  56.  
  57. begin
  58.   WndDC := getDC(Form1.Handle);
  59.  
  60.   if WndDC = 0 then
  61.   begin
  62.     MessageDlg('Getting Divice Context faild! Application terminated!',mtError,[mbOK],0);
  63.     Application.Terminate;
  64.   end;
  65.  
  66.   if not InitOpenGL then
  67.   begin
  68.     MessageDlg('Initializing OpenGL faild! Application terminated!',mtError,[mbOK],0);
  69.     Application.Terminate;
  70.   end;
  71.  
  72.   InitializePixelFormat;
  73.  
  74.   {...}
  75.  
  76. end;

Die Access Violation kommt sicher vom wglChoosePixelFormatARB (das habe ich mit Breakpoints getestet).

Ich habe keine Ahnung, wieso diese Access Violation zustande kommt, aber ich hoffe, Ihr könnt mir da weiterhelfen...

Vielen Dank für Eure Hilfe!
Gamer 2000
Nach oben
 Profil  
Mit Zitat antworten  
Lossy eX
 Betreff des Beitrags:
BeitragVerfasst: Mi Feb 22, 2006 11:35 
Offline
DGL Member
Benutzeravatar

Registriert: Do Dez 05, 2002 10:35
Beiträge: 4234
Wohnort: Dortmund
Erst mal Willkommen am Board.

Zitat:
Ich habe keine Ahnung, wieso diese Access Violation zustande kommt, aber ich hoffe, Ihr könnt mir da weiterhelfen...

Bestimmt. ;-)

So dann wollen wir dir mal auf die Sprünge helfen. Wenn du verstehst was das eigentliche Problem ist dann wirst du auch sicherlich sehen wie du es beheben kannst.

Die Zugriffsverletzung entsteht dadurch, da du versuchst eine Methode zu benutzen dessen Pointer noch nicht geladen wurde. Die Adresse 00000000 ist ein eindeutiges Zeichen dafür, dass der Wert Nil ist.

Warum ist der Pointer noch nil. Weil die Methode zu einer Extension gehört dessen Pointer erst geladen werden kann, wenn bereits ein Kontext erstellt wurde. Das ist so, weil die Extensions auch abhängig vom verwendeten Kontext sein können. Je nachdem kann es sein, dass die ein oder andere Extension bei gewissen Einstellungen gar nicht existiert.

Das Paradoxon an der Stelle ist nun mal die Sache, dass du eigentlich den Kontext mit der Extension WGL_ARB_pixel_format erstellen möchtest diese aber erst Verfügbar ist sofern auch ein Kontext existiert.

Du müsstest entsprechend zu Begin einen Kontext erstellen der nur dazu dient um festzustellen ob die Extension verfügbar ist. Und wenn ja, dann kannst du sie benutzen und erstellst einen weiteren Kontext der MultiSampling unterstützt. Den anderen kannst du dann wieder löschen. Entweder bevor du den anderen erstellst oder danach. Das weiß ich jetzt nicht so genau.
Nach oben
 Profil  
Mit Zitat antworten  
Gamer 2000
 Betreff des Beitrags:
BeitragVerfasst: Mi Feb 22, 2006 19:12 
Offline
DGL Member

Registriert: Mi Feb 22, 2006 10:41
Beiträge: 12
Wohnort: St. Gallen - Schweiz
Zuerst mal vielen Dank für die schnelle und informative Antwort!

Problem erkannt, Problem gebannt - neues Problem noch nicht ganz erkannt....

wglChoosePixelFormatARB liefert jetzt keine Access Violation mehr aber dafür leider auch kein Pixelformat...

Ich hoffe, mir kann auch dieses Mal geholfen werden... Ich habe schon einige Variationen ausprobiert, aber leider alle ohne Erfolg :(

Code:
  1. {...}
  2.  
  3. uses
  4.   Windows, Messages, SysUtils, Classes, Controls, Forms, Dialogs, ExtCtrls,
  5.   StdCtrls, Math, dglOpenGL, SDL, SDL_Image;
  6.  
  7. {...}
  8.  
  9. var
  10.   DC: HDC;
  11.   RC: HGLRC;
  12.  
  13. {...}
  14.  
  15. //InitializeOpenGL wird als erstes bei OnCreate ausgeführt
  16. procedure TForm1.InitializeOpenGL;
  17.  
  18.   procedure InitializePixelFormat;
  19.   var
  20.     PixelFormat: GLuint;
  21.     pfd: TPixelFormatDescriptor;
  22.   begin
  23.     with pfd do
  24.     begin
  25.       nSize           := SizeOf(TPixelFormatDescriptor);
  26.       nVersion        := 1;
  27.       dwFlags         := PFD_DRAW_TO_WINDOW
  28.                          or PFD_SUPPORT_OPENGL
  29.                          or PFD_DOUBLEBUFFER;
  30.       iPixelType      := PFD_TYPE_RGBA;
  31.       cColorBits      := 24;
  32.       cAlphaBits      := 8;
  33.       cDepthBits      := 32;
  34.       cStencilBits    := 0;
  35.     end;
  36.  
  37.     PixelFormat := ChoosePixelFormat(DC, @pfd);
  38.  
  39.     if PixelFormat = 0 then
  40.     begin
  41.       MessageDlg('Initializing Pixelformat faild! Application terminated!',mtError,[mbOK],0);
  42.       Application.Terminate;
  43.     end;
  44.  
  45.     if not SetPixelFormat(DC,PixelFormat,@pfd) then
  46.     begin
  47.       MessageDlg('Setting Pixelformat faild! Application terminated!',mtError,[mbOK],0);
  48.       Application.Terminate;
  49.     end;
  50.  
  51.   end;
  52.  
  53.   procedure InitializePixelFormatExt;
  54.   var
  55.     IAtrib: array of GLint;
  56.     FAtrib: array of GLfloat;
  57.     PixelFormat: GLint;
  58.     numPixelFormats: GLuint;
  59.   begin
  60.     setLength(IAtrib,22);
  61.     IAtrib[0] := WGL_DRAW_TO_WINDOW_ARB;
  62.     IAtrib[1] := 1;
  63.     IAtrib[2] := WGL_SUPPORT_OPENGL_ARB;
  64.     IAtrib[3] := 1;
  65.     IAtrib[4] := WGL_DOUBLE_BUFFER_ARB;
  66.     IAtrib[5] := 1;
  67.     IAtrib[6] := WGL_PIXEL_TYPE_ARB;
  68.     IAtrib[7] := WGL_TYPE_RGBA_ARB;
  69.     IAtrib[8] := WGL_COLOR_BITS_ARB;
  70.     IAtrib[9] := 24;
  71.     IAtrib[10] := WGL_ALPHA_BITS_ARB;
  72.     IAtrib[11] := 0;
  73.     IAtrib[12] := WGL_DEPTH_BITS_ARB;
  74.     IAtrib[13] := 32;
  75.     IAtrib[14] := WGL_STENCIL_BITS_ARB;
  76.     IAtrib[15] := 0;
  77.     IAtrib[16] := WGL_SAMPLE_BUFFERS_ARB;
  78.     IAtrib[17] := 1;
  79.     IAtrib[18] := WGL_SAMPLES_ARB;
  80.     IAtrib[19] := 4;
  81.     IAtrib[20] := 0;
  82.     IAtrib[21] := 0;
  83.  
  84.     setLength(FAtrib,2);
  85.     FAtrib[0] := 0;
  86.     FAtrib[1] := 0;
  87.  
  88.     wglChoosePixelFormatARB(DC,@IAtrib,@FAtrib,1,@PixelFormat,@numPixelFormats);
  89.  
  90.     if numPixelFormats = 0 then
  91.     begin
  92.       MessageDlg('Initializing Pixelformat faild! Application terminated!',mtError,[mbOK],0);
  93.       Application.Terminate;
  94.     end;
  95.  
  96.     if not SetPixelFormat(DC,PixelFormat,nil) then    //set PixelFormat to the window
  97.     begin
  98.       MessageDlg('Setting Pixelformat faild! Application terminated!',mtError,[mbOK],0);
  99.       Application.Terminate;
  100.     end;
  101.  
  102.   end;
  103.  
  104.   procedure InitializeRenderingContext;
  105.   begin
  106.     RC := wglCreateContext(DC);
  107.  
  108.     if RC = 0 then
  109.     begin
  110.       MessageDlg('Creating Rendering Context faild! Application terminated!',mtError,[mbOK],0);
  111.       Application.Terminate;
  112.     end;
  113.  
  114.     if not wglMakeCurrent(DC,RC) then
  115.     begin
  116.       MessageDlg('Activating Rendering Context faild! Application terminated!',mtError,[mbOK],0);
  117.       Application.Terminate;
  118.     end;
  119.   end;
  120.  
  121.   procedure InitializeSettings;
  122.   begin
  123.    
  124.   {...}
  125.  
  126.   end;
  127.  
  128. begin
  129.   DC := getDC(Form1.Handle);
  130.  
  131.   if DC = 0 then
  132.   begin
  133.     MessageDlg('Getting Divice Context faild! Application terminated!',mtError,[mbOK],0);
  134.     Application.Terminate;
  135.   end;
  136.  
  137.   if not InitOpenGL then
  138.   begin
  139.     MessageDlg('Initializing OpenGL faild! Application terminated!',mtError,[mbOK],0);
  140.     Application.Terminate;
  141.   end;
  142.  
  143.   InitializePixelFormat;
  144.  
  145.   InitializeRenderingContext;
  146.  
  147.   InitializePixelFormatExt;
  148.  
  149.   InitializeRenderingContext;
  150.  
  151.   InitializeSettings;
  152.  
  153.   {...}
  154.  
  155. end;


ChoosePixelFormat funktioniert einwandfrei, aber wglChoosePixelFormatARB liefert mir einfach kein PixelFormat...

Nochmals vielen Dank für Eure Hilfe! Ich bin echt froh, dass es so ne super Community gibt!! (ohne Delphigl.com hätte ich wahrscheinlich kein einziges OpenGL-Programm programmiert)
Gamer 2000
Nach oben
 Profil  
Mit Zitat antworten  
Gamer 2000
 Betreff des Beitrags:
BeitragVerfasst: Mi Feb 22, 2006 22:30 
Offline
DGL Member

Registriert: Mi Feb 22, 2006 10:41
Beiträge: 12
Wohnort: St. Gallen - Schweiz
Ich musste soeben eine schreckliche Entdeckung machen: Das Beispiel-Programm, welches ich im ersten Post angegeben habe, bekommt von wglChoosePixelFormatARB auch kein PixelFormat!! Leider gibt's dort keine Fehlermeldung oder so...

Ich weiss wirklich nicht, was los ist, oder was ich falsch mache...

Ein wglGetExtensionsStringARB gibt folgendes aus:
Code:
  1. WGL_ARB_extensions_string WGL_ARB_make_current_read WGL_ARB_multisample WGL_ARB_pbuffer WGL_ARB_pixel_format WGL_ARB_render_texture WGL_ATI_pixel_format_float WGL_EXT_extensions_string WGL_EXT_swap_control WGL_ATI_render_texture_rectangle


WGL_ARB_pixel_format und WGL_ARB_multisample werden also unterstützt, aber wieso läuft's nicht :cry:


Ich bin wieder mal mehr den je auf die Hilfe von Profis angewiesen... und ich glaube, dass ich meine Frage am richtigen Ort stelle :wink:


Vielen Dank für Eure Hilfe
Gamer 2000
Nach oben
 Profil  
Mit Zitat antworten  
Lossy eX
 Betreff des Beitrags:
BeitragVerfasst: Do Feb 23, 2006 09:58 
Offline
DGL Member
Benutzeravatar

Registriert: Do Dez 05, 2002 10:35
Beiträge: 4234
Wohnort: Dortmund
Ich muss ehrlich gestehen, dass ich so etwas auch schon ein paar Mal ausprobiert habe es aber selber bisher noch nicht hinbekommen habe. Ich weiß aber, dass es geht. Die glScene Komponenten können das. Die machen das in etwa auch genau so. Na ja. Fast. Die erstellen dafür eine extra Fensterklasse und benutzen diesen zum auslesen der Methoden. Und dann erstellen sie den richtigen Kontex. Habe aber derzeit weder die Quellen noch den dafür notwendigen Kopf um mich da jetzt durchzuwühlen.
Nach oben
 Profil  
Mit Zitat antworten  
Gamer 2000
 Betreff des Beitrags:
BeitragVerfasst: Do Feb 23, 2006 16:59 
Offline
DGL Member

Registriert: Mi Feb 22, 2006 10:41
Beiträge: 12
Wohnort: St. Gallen - Schweiz
Ich habe mal mit dem "OpenGL Extensions Viewer" http://www.realtech-vr.com/glview/index.html meine Grafikkarte ein bisschen erkundet. Dieses kleine Tool kann auch alle PixelFormate anzeigen. Ich habe mir ein passendes PixelFormat ausgesucht (eines, das Multisampling unterstützt) und habe einfach dessen ID bei SetPixelFormat eingesetzt... SetPixelFormat hat mir false zurückgegeben :cry:

Ich habe viel Zeit damit verbraucht, im Internet nach Dokumentation über Multisampling mit OpenGL zu suchen. Leider habe ich nur viele kleine Artikel gefunden, welche sagen, dass Multisampling mit OpenGL möglich ist. Konkrete Informationen oder Code-Beispiele habe ich keine gefunden...

Ich wäre wirklich froh, wenn jemand, der Erfahrung mit Multisampling hat, sein Wissen kund tun könnte...

Vielen Dank schon im Voraus
Gamer 2000
Nach oben
 Profil  
Mit Zitat antworten  
Gamer 2000
 Betreff des Beitrags:
BeitragVerfasst: Do Feb 23, 2006 19:49 
Offline
DGL Member

Registriert: Mi Feb 22, 2006 10:41
Beiträge: 12
Wohnort: St. Gallen - Schweiz
Gute Nachricht! Ich hab's geschafft!! :D 8)

naja... zumindest teilweise... :roll:

Ich habe mal das Tutorial "Pixelbuffer" unter die Lupe genommen. Dort wird auch ein PixelFormat mittels WGL_ARB_pixel_format erstellt. Diese Teile habe ich einfach übernommen und siehe da, wglChoosePixelFormatARB liefert die gewünschten PixelFormats.

Aber leider kann ich das PixelFormat dann nicht setzten... SetPixelFormat liefert einfach immer false... ich kann mir aber nicht vorstellen, wieso... evtl. liegt's an diesem PixelFormatDescriptor...

Hier mal der Code, ich hoffe jemand findet den Fehler...

Code:
  1. {...}
  2.  
  3. uses
  4.   Windows, Messages, SysUtils, Classes, Controls, Forms,
  5.   Dialogs, ExtCtrls, StdCtrls, Math, dglOpenGL, SDL, SDL_Image;
  6.  
  7. {...}
  8.  
  9. var
  10.   DC: HDC;
  11.   RC: HGLRC;
  12.  
  13. {...}
  14.  
  15. //InitializeOpenGL wird als erstes bei OnCreate aufgerufen
  16. procedure TForm1.InitializeOpenGL;
  17.  
  18.   procedure InitializePixelFormat;
  19.   var
  20.     IAtrib: array[0..20] of TGLUInt;
  21.     FAtrib: TGLFloat;
  22.     PixelFormat: array[0..64] of TGLUInt;
  23.     numPixelFormats: TGLUInt;
  24.     tmpDC: TGLUInt;
  25.     pfd: TPixelFormatDescriptor;
  26.   begin
  27.     with pfd do
  28.     begin
  29.       nSize           := SizeOf(TPixelFormatDescriptor);
  30.       nVersion        := 1;
  31.       dwFlags         := PFD_DRAW_TO_WINDOW
  32.                          or PFD_SUPPORT_OPENGL
  33.                          or PFD_DOUBLEBUFFER;
  34.       iPixelType      := PFD_TYPE_RGBA;
  35.       cColorBits      := 24;
  36.       cAlphaBits      := 0;
  37.       cDepthBits      := 24;
  38.       cStencilBits    := 0;
  39.     end;
  40.  
  41.     IAtrib[0] := WGL_DRAW_TO_WINDOW_ARB;
  42.     IAtrib[1] := 1;
  43.     IAtrib[2] := WGL_SUPPORT_OPENGL_ARB;
  44.     IAtrib[3] := 1;
  45.     IAtrib[4] := WGL_DOUBLE_BUFFER_ARB;
  46.     IAtrib[5] := 1;
  47.     IAtrib[6] := WGL_PIXEL_TYPE_ARB;
  48.     IAtrib[7] := WGL_TYPE_RGBA_ARB;
  49.     IAtrib[8] := WGL_COLOR_BITS_ARB;
  50.     IAtrib[9] := 24;
  51.     IAtrib[10] := WGL_ALPHA_BITS_ARB;
  52.     IAtrib[11] := 0;
  53.     IAtrib[12] := WGL_DEPTH_BITS_ARB;
  54.     IAtrib[13] := 24;
  55.     IAtrib[14] := WGL_STENCIL_BITS_ARB;
  56.     IAtrib[15] := 0;
  57.     IAtrib[16] := WGL_SAMPLE_BUFFERS_ARB;
  58.     IAtrib[17] := 1;
  59.     IAtrib[18] := WGL_SAMPLES_ARB;
  60.     IAtrib[19] := 4;
  61.     IAtrib[20] := 0;
  62.  
  63.     FAtrib := 0;
  64.  
  65.     tmpDC := wglGetCurrentDC();
  66.  
  67.     wglChoosePixelFormatARB(tmpDC,@IAtrib,@FAtrib,length(PixelFormat),
  68.       @PixelFormat,@numPixelFormats);
  69.  
  70.     if numPixelFormats = 0 then
  71.     begin
  72.       MessageDlg('Initializing Pixelformat faild! Application terminated!',mtError,[mbOK],0);
  73.       Application.Terminate;
  74.     end;
  75.  
  76.     if not SetPixelFormat(DC,PixelFormat[0],@pfd) then
  77.     begin
  78.       MessageDlg('Setting Pixelformat faild! Application terminated!',mtError,[mbOK],0);
  79.       Application.Terminate;
  80.     end;
  81.  
  82.   end;
  83.  
  84.   {..}
  85.  
  86. begin
  87.   if not InitOpenGL then
  88.   begin
  89.     MessageDlg('Initializing OpenGL faild! Application terminated!',mtError,[mbOK],0);
  90.     Application.Terminate;
  91.   end;
  92.  
  93.   DC := GetDC(Handle);
  94.  
  95.   if DC = 0 then
  96.   begin
  97.     MessageDlg('Getting Divice Context faild! Application terminated!',mtError,[mbOK],0);
  98.     Application.Terminate;
  99.   end;
  100.  
  101.   RC := CreateRenderingContext(DC, [opDoubleBuffered], 32, 24, 0, 0, 0, 0);
  102.  
  103.   if RC = 0 then
  104.     begin
  105.       MessageDlg('Creating Rendering Context faild! Application terminated!',mtError,[mbOK],0);
  106.       Application.Terminate;
  107.     end;
  108.  
  109.   if not wglMakeCurrent(DC,RC) then
  110.     begin
  111.       MessageDlg('Activating Rendering Context faild! Application terminated!',mtError,[mbOK],0);
  112.       Application.Terminate;
  113.     end;
  114.  
  115.   InitializePixelFormat;
  116.  
  117.   {...}
  118.  
  119. end;


Ich bin überaus zuversichtlich, dass ich auch dieses Problem mit Eurer Hilfe schnell lösen kann.

Herzlichen Dank im Voraus
Gamer 2000
Nach oben
 Profil  
Mit Zitat antworten  
Gamer 2000
 Betreff des Beitrags:
BeitragVerfasst: Do Feb 23, 2006 21:40 
Offline
DGL Member

Registriert: Mi Feb 22, 2006 10:41
Beiträge: 12
Wohnort: St. Gallen - Schweiz
So, ich hab das Problem nun endgültig gelöst! :D 8) :D

Die Lösung habe ich mehr oder weniger durch Zufall gefunden. Weil es mich wunder nahm, wann der letzte Post geschrieben wurde, stiess ich auf viewtopic.php?t=5241 gestossen und da liegt die Antwort:

Zitat:
Setting the pixel format of a window more than once can lead to significant complications for the Window Manager and for multithread applications, so it is not allowed. An application can only set the pixel format of a window one time. Once a window's pixel format is set, it cannot be changed.


Weil mein Fenster ja schon ein PixelFormat hat (das muss ich ja zuerst erstellen, um die Extensions nutzen zu können) muss ich das Fenster, nachdem das PixelFormat, welches Multisampling unterstützt gefunden ist, zerstören und es anschliessend neu konstruieren...

Für alle Interessierten hier der Code, mit dem es nun endlich funktioniert:

Code:
  1. {...}
  2.  
  3. uses
  4.   Windows, Messages, SysUtils, Classes, Controls, Forms, Dialogs,
  5.   ExtCtrls, StdCtrls, Math, dglOpenGL, SDL, SDL_Image;
  6.  
  7. {...}
  8.  
  9. var
  10.   DC: HDC;
  11.   RC: HGLRC;
  12.   Init: Boolean = false;
  13.   SuitablePF: TGLUInt = 0;
  14.  
  15. {...}
  16.  
  17. //InitializeOpenGL wird als erstes bei OnCreate ausgeführt
  18. procedure TForm1.InitializeOpenGL;
  19.  
  20.   procedure InitializePixelFormat;
  21.   var
  22.     IAtrib: array[0..20] of TGLUInt;
  23.     FAtrib: TGLFloat;
  24.     PixelFormat: array[0..64] of TGLUInt;
  25.     numPixelFormats, tmpDC: TGLUInt;
  26.   begin
  27.     IAtrib[0] := WGL_DRAW_TO_WINDOW_ARB;
  28.     IAtrib[1] := 1;
  29.     IAtrib[2] := WGL_SUPPORT_OPENGL_ARB;
  30.     IAtrib[3] := 1;
  31.     IAtrib[4] := WGL_DOUBLE_BUFFER_ARB;
  32.     IAtrib[5] := 1;
  33.     IAtrib[6] := WGL_PIXEL_TYPE_ARB;
  34.     IAtrib[7] := WGL_TYPE_RGBA_ARB;
  35.     IAtrib[8] := WGL_COLOR_BITS_ARB;
  36.     IAtrib[9] := 24;
  37.     IAtrib[10] := WGL_ALPHA_BITS_ARB;
  38.     IAtrib[11] := 0;
  39.     IAtrib[12] := WGL_DEPTH_BITS_ARB;
  40.     IAtrib[13] := 24;
  41.     IAtrib[14] := WGL_STENCIL_BITS_ARB;
  42.     IAtrib[15] := 0;
  43.     IAtrib[16] := WGL_SAMPLE_BUFFERS_ARB;
  44.     IAtrib[17] := 1;
  45.     IAtrib[18] := WGL_SAMPLES_ARB;
  46.     IAtrib[19] := 6;
  47.     IAtrib[20] := 0;
  48.  
  49.     FAtrib := 0;
  50.  
  51.     tmpDC := wglGetCurrentDC();
  52.  
  53.     wglChoosePixelFormatARB(tmpDC,@IAtrib,@FAtrib,length(PixelFormat),
  54.       @PixelFormat,@numPixelFormats);
  55.  
  56.     if numPixelFormats = 0 then
  57.     begin
  58.       MessageDlg('Initializing Pixelformat faild! Application terminated!',mtError,[mbOK],0);
  59.       Application.Terminate;
  60.     end;
  61.  
  62.     Init := true;
  63.     SuitablePF := PixelFormat[0];
  64.   end;
  65.  
  66.   procedure InitializeSettings;
  67.   begin
  68.    
  69.   {was man halt so braucht...}
  70.  
  71.   end;
  72.  
  73. begin
  74.   if not Init then
  75.   begin
  76.     if not InitOpenGL then
  77.     begin
  78.       MessageDlg('Initializing OpenGL faild! Application terminated!',mtError,[mbOK],0);
  79.       Application.Terminate;
  80.     end;
  81.   end;
  82.  
  83.   DC := GetDC(Handle);
  84.  
  85.   if DC = 0 then
  86.   begin
  87.     MessageDlg('Getting Divice Context faild! Application terminated!',mtError,[mbOK],0);
  88.     Application.Terminate;
  89.   end;
  90.  
  91.   if not Init then
  92.     RC := CreateRenderingContext(DC, [opDoubleBuffered], 32, 24, 0, 0, 0, 0)
  93.   else
  94.   begin
  95.     if not SetPixelFormat(DC,SuitablePF,nil) then
  96.     begin
  97.       MessageDlg('Setting Pixelformat faild! Application terminated!',mtError,[mbOK],0);
  98.       Application.Terminate;
  99.     end;
  100.     RC := wglCreateContext(DC);
  101.   end;
  102.  
  103.   if RC = 0 then
  104.     begin
  105.       MessageDlg('Creating Rendering Context faild! Application terminated!',mtError,[mbOK],0);
  106.       Application.Terminate;
  107.     end;
  108.  
  109.   if not wglMakeCurrent(DC,RC) then
  110.     begin
  111.       MessageDlg('Activating Rendering Context faild! Application terminated!',mtError,[mbOK],0);
  112.       Application.Terminate;
  113.     end;
  114.  
  115.   if not Init then
  116.   begin
  117.     InitializePixelFormat;
  118.     Form1.DestroyWnd;
  119.     Form1.CreateWnd;
  120.     InitializeOpenGL;
  121.   end
  122.   else
  123.   begin
  124.     InitializeSettings;
  125.  
  126.     {weitere Dinge, wie Projektions-Matrix, Kamera etc. initisieren...}
  127.  
  128.   end;
  129. end;


Ich hoffe damit ist nicht nur mir sondern auch noch anderen, welche ebenfalls Multisampling in ihr Projekt einbauen wollen, gedient. Ich kann nur sagen, Multisampling ist echt der Hammer... kein Vergleich zu den elenden Pixel-Treppen, also wenn's die Grafikkarte unterstützt -> sofort implementieren :wink:

Grüsse
Gamer 2000
Nach oben
 Profil  
Mit Zitat antworten  
Frase
 Betreff des Beitrags:
BeitragVerfasst: Do Feb 23, 2006 21:47 
Offline
Forenkatze
Benutzeravatar

Registriert: Mi Okt 22, 2003 18:30
Beiträge: 1945
Wohnort: Närnberch
Programmiersprache: Scala, Java, C*
ah... das ist allerdings wirklich interessant. Könnte durchaus nützlich werden ;)

_________________
"Für kein Tier wird so viel gearbeitet wie für die Katz'."
Nach oben
 Profil  
Mit Zitat antworten  
Flash
 Betreff des Beitrags:
BeitragVerfasst: Do Feb 23, 2006 21:50 
Offline
Guitar Hero
Benutzeravatar

Registriert: Do Sep 25, 2003 15:56
Beiträge: 7810
Wohnort: Sachsen - ERZ / C
Programmiersprache: Java (, Pascal)
Öhm ein Fall fürs Wiki oder? Plus erklärung was Multisampling ist bei den Hintergrundinfos bitte. 8)

_________________
Blog: kevin-fleischer.de und fbaingermany.com
Nach oben
 Profil  
Mit Zitat antworten  
Frase
 Betreff des Beitrags:
BeitragVerfasst: Do Feb 23, 2006 22:15 
Offline
Forenkatze
Benutzeravatar

Registriert: Mi Okt 22, 2003 18:30
Beiträge: 1945
Wohnort: Närnberch
Programmiersprache: Scala, Java, C*
Was ich mich frage... Wieso erst Fenster erzeugen, dann zerstören und dann wieder erzeugen? Kann man denn nicht gleich nach nem Pixelformat suchen, was Multisampling unterstützt?

_________________
"Für kein Tier wird so viel gearbeitet wie für die Katz'."
Nach oben
 Profil  
Mit Zitat antworten  
Gamer 2000
 Betreff des Beitrags:
BeitragVerfasst: Do Feb 23, 2006 22:31 
Offline
DGL Member

Registriert: Mi Feb 22, 2006 10:41
Beiträge: 12
Wohnort: St. Gallen - Schweiz
Also erst einmal: Eintrag ins Wiki sollte bald folgen (heute hab ich keine Zeit mehr dafür, aber ziemlich sicher morgen Abend).


Zur Frage von Frase:

Wie schon Lossy eX gesagt hat, ist folgendes das Problem: Um ein PixelFormat zu finden, welches Multisampling unterstützt, muss man die WGL_ARB_pixel_format Extensions nutzen können. Diese Extension wird aber erst verfügbar, wenn man bereits ein Fenster mit Kontext erstellt hat. Dann kann man das PixelFormat für Multisampling suchen und wird es hoffentlich auch finden :wink:

Aber das Fenster hat ja schon ein PixelFormat (braucht es, damit man überhaupt nach Multisample-PixelFormat suche kann) und Windows erlaubt es nicht, einem Fenster, das schon ein PixelFormat hat, ein neues PixelFormat zuzuordnen. Also muss man das gefundene Multisample-PixelFormat speichern (ich mach das mit SuitablePF), das Fenster mit dem "Such-PixelFormat" zerstören, ein neus Fenster erzeugen und diesem neuen Fenster kann man das gespeicherte Multisample-PixelFormat zuordnen.

Das PixelFormat an sich ist nur ein Integerwert und repräsentiert die ID eines auf der Grafikkarte gespeicherten PixelFormates. Wenn man also für sein Programm immer die gleiche Grafikkarte verwendet, kann man einmal das PixelFormat mit der oben beschriebenen Methode suchen, sich den Integerwert aufschreiben oder ganz gut merken :wink: und dann das Fenster immer sofort mit diesem PixelFormat erstellen.


Ich hoffe das war verständlich genug... sonst frag einfach nochmal...
Nach oben
 Profil  
Mit Zitat antworten  
Frase
 Betreff des Beitrags:
BeitragVerfasst: Do Feb 23, 2006 22:34 
Offline
Forenkatze
Benutzeravatar

Registriert: Mi Okt 22, 2003 18:30
Beiträge: 1945
Wohnort: Närnberch
Programmiersprache: Scala, Java, C*
joah klar ;) Ich halte aber das Speichern der ID für bedenklich.... Was ist bei einem Treiber-Update?

_________________
"Für kein Tier wird so viel gearbeitet wie für die Katz'."
Nach oben
 Profil  
Mit Zitat antworten  
Lossy eX
 Betreff des Beitrags:
BeitragVerfasst: Fr Feb 24, 2006 09:07 
Offline
DGL Member
Benutzeravatar

Registriert: Do Dez 05, 2002 10:35
Beiträge: 4234
Wohnort: Dortmund
Frase: Das isn Zeitraum von weniger als 500 MilliSekunde. Wie willst du denn da nen Treiber updaten? Das auf die Festplatte zu speichern und beim nächsten Start wieder zu benutzten wäre höchst fragwürdig. Nein. Diese Aktion muss bei jedem Programmaufruf neu gemacht werden.

Gamer: Der Vollständigkeit halber solltest du evtl auch die Extension WGL_EXT_pixel_format mit unterstützen. Die ist Baugleich zu der ARB nur die Methoden sind anders. Die Konstanten sind da auch gleich.

Wo lädst du eigentlich die ARB Extension? Habe das so jetzt nicht gesehen. Und ein Fallback für den Fall, dass sie nicht unterstützt wird wäre auch gut. Bzw finde ich den Code ein wenig wirr (Nicht böse gemeint). Ich denke mal ein etwas unerfahrener User dürfte daraus nichts lernen. Sollte man noch mal ein bisschen überarbeiten bevor es ins Wiki übernommen wird. Aber sonst wirklich klasse. Werde mir das Prinzip mit sicherheit auch aneignen. Weiter so. :-)

[edit] Bereich zu RecreateWnd entfernt, da der anscheinend im Vergleich zu DestroyWnd und CreateWnd die Sichtbarkeit des Fensters ändert. Was in einem OnShow definitiv nicht klappt. Habe ich gerade schmerzlich erfahren. ;-)
Nach oben
 Profil  
Mit Zitat antworten  
Gamer 2000
 Betreff des Beitrags:
BeitragVerfasst: Fr Feb 24, 2006 10:18 
Offline
DGL Member

Registriert: Mi Feb 22, 2006 10:41
Beiträge: 12
Wohnort: St. Gallen - Schweiz
Ehrlich gesagt, war das das erste Mal, das ich mit Extensions gearbeitet habe (darum auch die Startschwierigkeiten...) und ich habe gedacht, dass die Extensions einfach immer verfügbar sind; also dass man die nicht laden muss...

Ein Fallback gehört bestimmt dazu! Ich bin jetzt auch noch an einer Version dran, die auslesen kann, wie viele Samples die Grafikkarte unterstützt. Aber beim obigen Code ging es mir primär darum, einfach Multisampling mal aktivieren zu können, darum habe ich mich noch nicht um Fallback etc. gekümmert...
Nach oben
 Profil  
Mit Zitat antworten  
Beiträge der letzten Zeit anzeigen:  Sortiere nach  
Ein neues Thema erstellen Auf das Thema antworten  Seite 1 von 2
  [ 24 Beiträge ]  Gehe zu Seite 1, 2  Nächste
Foren-Übersicht » Programmierung » Allgemein


Wer ist online?

Mitglieder in diesem Forum: 0 Mitglieder und 5 Gäste

Du darfst keine neuen Themen in diesem Forum erstellen.
Du darfst keine Antworten zu Themen in diesem Forum erstellen.
Du darfst deine Beiträge in diesem Forum nicht ändern.
Du darfst deine Beiträge in diesem Forum nicht löschen.
Du darfst keine Dateianhänge in diesem Forum erstellen.

Suche nach:
Gehe zu:  
  Powered by phpBB® Forum Software © phpBB Group
Deutsche Übersetzung durch phpBB.de
[ Time : 0.013s | 15 Queries | GZIP : On ]