DGL • Thema anzeigen - Objekte unsichtbar durch falsche Anwendung von glTranslatef

Objekte unsichtbar durch falsche Anwendung von glTranslatef

Moderator: DGL-Team

Seite 1 von 1

[ 10 Beiträge ]

Vorheriges Thema | Nächstes Thema

Autor

Nachricht

Betreff des Beitrags: Objekte unsichtbar durch falsche Anwendung von glTranslatef

Verfasst: Mo Jan 31, 2005 19:29

DGL Member

Registriert: Mo Jan 31, 2005 18:25
Beiträge: 4

Ich habe vor wenigen Tagen mit OpenGL angefangen und hatte gehofft, jetzt bereits ein (für einen Anfänger) ordentliches Programm beisammen zu haben. Ich nehme dabei die Einsteiger-Tuts von Phobeus zur Hilfe. Leider versuche ich seit gestern vergeblich, mit Translatef(-1.5,0,-6) ein Dreieck etwas von der Kamera wegzubewegen, ohne dass es dabei ganz verschwindet. Ich hab übrigens nicht sofort gemerkt, dass es an Translatef liegt, sondern hab davor mehrere Stunden rumprobiert und im Internet nach möglichen Erklärungen gesucht.
Das Dreieck wird wie im Tutorial gezeichnet:

Code:

  glClear(GL_COLOR_BUFFER_BIT or GL_DEPTH_BUFFER_BIT);
  glBegin(GL_TRIANGLES);
    glColor3f(1,0,0);
    glVertex3f(-1.0,-1.0, 1.0);
    glColor3f(0,1,0);
    glVertex3f( 0.0, 1.0, 1.0);
    glColor3f(0,0,1);
    glVertex3f( 1.0,-1.0, 1.0);
  glEnd;
  SwapBuffers(h_DC);

Ich kann es sehen, sofern der z-Wert aller Eckpunkte (also in diesem Fall 0) in einem Bereich von 0 bis 1 von der Kamera entfernt ist. Wenn ich also mit Translatef(0,0,-1) um 1 nach hinten gehe, ist das Ding gerade noch sichtbar (folglich mit Translatef(0,0,-1.1) nicht mehr). Es füllt übrigens immer die ganze Höhe/Breite des Fensters aus.

Und bevor jemand fragt, hier noch der gesamte Initialisierungscode:

Code:

function glInit: Boolean;
begin
  FrameRate := 0;
  FillChar(pfd, SizeOf(pfd), 0);
  h_DC := GetDC(Form1.Handle);
  with pfd do
  begin
    nSize           := SizeOf(TPIXELFORMATDESCRIPTOR);
    nVersion        := 1;
    dwFlags         := PFD_DRAW_TO_WINDOW
                       or PFD_SUPPORT_OPENGL
                       or PFD_DOUBLEBUFFER;
    iPixelType      := PFD_TYPE_RGBA;
    cColorBits      := 32;
    cRedBits        := 0;
    cRedShift       := 0;
    cGreenBits      := 0;
    cGreenShift     := 0;
    cBlueBits       := 0;
    cBlueShift      := 0;
    cAlphaBits      := 0;
    cAlphaShift     := 0;
    cAccumBits      := 0;
    cAccumRedBits   := 0;
    cAccumGreenBits := 0;
    cAccumBlueBits  := 0;
    cAccumAlphaBits := 0;
    cDepthBits      := 16;
    cStencilBits    := 0;
    cAuxBuffers     := 0;
    iLayerType      := PFD_MAIN_PLANE;
    bReserved       := 0;
    dwLayerMask     := 0;
    dwVisibleMask   := 0;
    dwDamageMask    := 0;
  end;
  PixelFormat := ChoosePixelFormat(h_DC, @pfd);
  SetPixelFormat(h_DC, PixelFormat, @pfd)
  h_RC := wglCreateContext(h_DC);
  wglMakeCurrent(h_DC, h_RC)
  glEnable(GL_TEXTURE_2D);         // Aktiviert Texture Mapping
  glShadeModel(GL_SMOOTH);         // Aktiviert weiches Shading
  glClearColor(0.0, 0.0, 0.0, 0.0);    // Bildschirm löschen (schwarz)
  glClearDepth(1.0);               // Depth Buffer Setup
  glEnable(GL_DEPTH_TEST);         // Aktiviert Depth Testing
  glDepthFunc(GL_LEQUAL);          // Bestimmt den Typ des Depth Testing
  glHint(GL_PERSPECTIVE_CORRECTION_HINT, GL_NICEST);
end;
 
procedure TForm1.FormCreate(Sender: TObject);
begin
  if not glInit then Application.Terminate;
  glClear(GL_COLOR_BUFFER_BIT or GL_DEPTH_BUFFER_BIT);
  glViewPort(0,0,ClientWidth,ClientHeight);
  glMatrixMode(GL_PROJECTION);
  glLoadIdentity;
  gluPerspective(0,ClientWidth/ClientHeight,0,10);
  glTranslatef(0,0,-2);
  glMatrixMode(GL_MODELVIEW);
 
  Application.OnIdle := OnIdle;
end;
 

Nach oben

La Boda

Betreff des Beitrags:

Verfasst: Mo Jan 31, 2005 19:42

DGL Member

Registriert: Mi Jul 17, 2002 12:07
Beiträge: 976
Wohnort: Tübingen

Hmmm. Du hast da einen etwas komischen Aufbau in deinem Programm, vor allem im Create-Teil.

Code:

 
  gluPerspective(0,ClientWidth/ClientHeight,0,10);      
//Den vorletzten Wert auf > 0 setzen und denn letzten erhöhen (128)
  glTranslatef(0,0,-2);                                              
//Das hier ist komplettt fehl am Platze (normalerweise <!-- s;) --><img src=\"{SMILIES_PATH}/icon_wink.gif\" alt=\";)\" title=\"Wink\" /><!-- s;) --> )
 

Das Translate muss in deine Application.Idle-Prozedur, da sie bei jedem Frame ausgeführt werden muss. Probiers mal aus und sag Bescheid!

EDIT: Und gib Translatef einen größeren Z-Wert!

_________________
"Du musst ein Schwein sein in dieser Welt, sangen die Prinzen, das ist so 1.0. Du musst auf YouTube zeigen, dass dir dein Schweinsein gefällt, das ist leuchtendes, echtes Web 2.0."
- Hal Faber
Meine Homepage: http://laboda.delphigl.com

Nach oben

Betreff des Beitrags:

Verfasst: Mo Jan 31, 2005 20:04

DGL Member

Registriert: Mo Jan 31, 2005 18:25
Beiträge: 4

Danke für die schnelle Antwort.
Das mit dem 'komischen' Programmaufbau liegt wahrscheinlich daran, dass ich aus dem Tutorial nicht ganz genau herauslesen konnte, wohin ich welche Anweisung schreiben muss.

Jetzt hab ich "gluPerspective(0,ClientWidth/ClientHeight,1,128)"; und glTranslatef(0,0,-6) ist direkt nach dem Zeichnen des Dreiecks, was dazu führt, dass es nur einmal kurz aufblitzt. (wenn ichs vorher mache, kommt gar nichts)

(ich hab jetzt einfach mal angenommen, dass du mit größerem z-Wert mehr negativ meinst, da positiv ja keinen Sinn machen würde)

Nach oben

Flash

Betreff des Beitrags:

Verfasst: Mo Jan 31, 2005 20:19

Guitar Hero

Registriert: Do Sep 25, 2003 15:56
Beiträge: 7810
Wohnort: Sachsen - ERZ / C
Programmiersprache: Java (, Pascal)

Ladt dir mal ein Template hier von der Seite runter (das 1.2VCL z.B. Da musst du nur noch den Header austauschen).

Du kannst dann entweder dieses als Basis nehmen, oder an diesem mal studieren was du falsch machst. :wink:

_________________
Blog: kevin-fleischer.de und fbaingermany.com

Nach oben

La Boda

Betreff des Beitrags:

Verfasst: Mo Jan 31, 2005 20:30

DGL Member

Registriert: Mi Jul 17, 2002 12:07
Beiträge: 976
Wohnort: Tübingen

Zitat:

(wenn ichs vorher mache, kommt gar nichts)

Auch vor dem glBegin(GL_TRIANGLES), denn nachher ist es total sinnlos

Nach oben

Betreff des Beitrags:

Verfasst: Mo Jan 31, 2005 20:53

DGL Member

Registriert: Mo Jan 31, 2005 18:25
Beiträge: 4

Das Problem mit diesem Template ist, dass schon soviel Zeug drin ist, dass es schon wieder zu kompliziert wird.
Außerdem hab ich eine unit namens "Geometry" nicht, ohne die das ganze nicht kompilieren will.

Ok, ich hab jetzt mal die entsprechende Stelle im Template gefunden und ein "glLoadIdentity" vor dem glTranslatef in meiner Renderroutine eingefügt. Es funktioniert allerdings immer noch nicht. Und ich hab auch keine Lust, den ganzen Code einfach zu kopieren, ohne zu verstehen, wozu er gut ist.

Edit: ja, dass es vor dem glBegin kommen muss, ist mir jetzt auch klar. Bewirkt aber nichts.

Edit2:
um das nochmal genauer auszudrücken:

Code:

Procedure DrawObjects;
Begin
  glClear(GL_COLOR_BUFFER_BIT or GL_DEPTH_BUFFER_BIT);
  glLoadIdentity;
  glTranslatef(0,0,-n);
  glBegin(GL_TRIANGLES);
    glColor3f(1,0,0);
    glVertex3f(-1.0,-1.0, 0.0);
    glColor3f(0,1,0);
    glVertex3f( 0.0, 1.0, 0.0);
    glColor3f(0,0,1);
    glVertex3f( 1.0,-1.0, 0.0);
  glEnd;
  SwapBuffers(h_DC);
End;
 

ist meine Renderroutine. mit 0<=n<=1 funktioniert sie, mit n>1 nicht.

Nach oben

Flash

Betreff des Beitrags:

Verfasst: Di Feb 01, 2005 01:04

Guitar Hero

Registriert: Do Sep 25, 2003 15:56
Beiträge: 7810
Wohnort: Sachsen - ERZ / C
Programmiersprache: Java (, Pascal)

Ok...dann nimm mal mein Template. Das hat nur das wichtigste. Is net wirklich schön, und die Pros wie Sascha würden bestimmt manches anders machen. Aber es geht bei mir (Delphi 5)

Code:

unit UMain;
 
interface
 
uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
  dglOpenGL;
 
const
  NearClipping = 1;
  FarClipping  = 1000;
 
type
  TForm1 = class(TForm)
    procedure FormCreate(Sender: TObject);
    procedure IdleHandler(Sender: TObject; var Done: Boolean);
    procedure FormResize(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
  private
    { Private-Deklarationen }
    StartTime, TimeCount, FrameCount  : Cardinal; //FrameCounter
    Frames, DrawTime                  : Cardinal; //& Timebased Movement
    GLError                           : Cardinal;
    procedure SetupGL;
    procedure Init;
    procedure Render;
    procedure ErrorHandler;
  public
    { Public-Deklarationen }
    DC                                : HDC;  //Handle auf Zeichenfläche
    RC                                : HGLRC;//Rendering Context
  end;
 
var
  Form1: TForm1;
 
implementation
 
{$R *.DFM}
 
procedure TForm1.FormCreate(Sender: TObject);
begin
  DC:= GetDC(Handle);
  Application.OnIdle:= IdleHandler;
 
  if not InitOpenGL then Application.Terminate;
 
  RC:= CreateRenderingContext( DC,
                               [opDoubleBuffered],
                               32,
                               24,
                               0,0,0,
                               0);
  ActivateRenderingContext(DC, RC);
 
  SetupGL;
  Init;
end;
 
procedure TForm1.SetupGL;
begin
  glClearColor(0.3, 0.4, 0.7, 0.0); //Hintergrundfarbe
  glEnable(GL_DEPTH_TEST);          //Tiefenpuffer aktivieren
  glEnable(GL_CULL_FACE);           //Backface Culling aktivieren
end;
 
procedure TForm1.Init;
begin
  GLError:= GL_NO_ERROR;
end;
 
procedure TForm1.IdleHandler(Sender: TObject; var Done: Boolean);
begin
//
  StartTime:= GetTickCount;
 
  Render;
 
  DrawTime:= GetTickCount - StartTime;
 
  inc(TimeCount, DrawTime);
  inc(FrameCount);
 
  if TimeCount >= 1000 then begin
    Frames:= FrameCount;
    TimeCount:= TimeCount - 1000;
    FrameCount:= 0;
 
    Caption:= InttoStr(Frames) + 'FPS';
    ErrorHandler;
  end;
 
  Done:= false;
end;
 
procedure TForm1.Render;
begin
//
  glClear(GL_COLOR_BUFFER_BIT or GL_DEPTH_BUFFER_BIT);
 
  glMatrixMode(GL_PROJECTION);
  glLoadIdentity;
  gluPerspective(45.0, ClientWidth/ClientHeight, NearClipping, FarClipping);
 
  glTranslatef(0, 0, -5);
 
  glMatrixMode(GL_MODELVIEW);
  glLoadIdentity;
 
  glBegin(GL_QUADS);
    glColor3f(1, 0, 0); glVertex3f(0, 0, 0);
    glColor3f(0, 1, 0); glVertex3f(1, 0, 0);
    glColor3f(0, 0, 1); glVertex3f(1, 1, 0);
    glColor3f(1, 1, 0); glVertex3f(0, 1, 0);
  glEnd;
 
  SwapBuffers(DC);
end;
 
procedure TForm1.ErrorHandler;
begin
  GLError := glGetError;
  if GLError <> GL_NO_ERROR then
     Caption := gluErrorString(GLError);
 
end;
 
procedure TForm1.FormResize(Sender: TObject);
var tmpBool : Boolean;
begin
  glViewport(0, 0, ClientWidth, ClientHeight);
  glMatrixMode(GL_PROJECTION);
  glLoadIdentity;
  gluPerspective(45.0, ClientWidth/ClientHeight, NearClipping, FarClipping);
  glMatrixMode(GL_MODELVIEW);
  glLoadIdentity;
  IdleHandler(Sender, tmpBool);
end;
 
procedure TForm1.FormDestroy(Sender: TObject);
begin
  DeactivateRenderingContext;
  DestroyRenderingContext(RC);
  ReleaseDC(Handle, DC);
end;
 
end.
 

Copy Paste. Brauchst nur ne leere Form.

_________________
Blog: kevin-fleischer.de und fbaingermany.com

Nach oben

Betreff des Beitrags:

Verfasst: Di Feb 01, 2005 11:07

DGL Member

Registriert: Mo Jan 31, 2005 18:25
Beiträge: 4

Danke, hat mir sehr geholfen.
Mein Fehler war ganz einfach, dass ich

Code:

gluPerspective(0,ClientWidth/ClientHeight,1,128);

gemacht hab, wobei ich davon ausging, dass es sich um den Winkel zur z-Achse handelt. Es ist aber der Winkel zur y-Achse. Mit

Code:

gluPerspective(90.0,ClientWidth/ClientHeight,1,128);

funktionierts.

Mir ist übrigens aufgefallen, dass mit 'dglOpenGL' ein paar Dinge anders gemacht werden müssen als mit der Delphi-eigenen unit 'OpenGL'. Gibt es dazu vielleicht noch ein Turorial? Ansonsten werde ich versuchen, selbst herauszufinden, wie man damit umgeht. Dein Template scheint mir da ein guter Anfang zu sein.

Nach oben

luketheduke

Betreff des Beitrags:

Verfasst: Di Feb 01, 2005 16:48

DGL Member

Registriert: Fr Mai 14, 2004 18:56
Beiträge: 804
Wohnort: GER/OBB/TÖL-WOR/Greiling

Die Delphi-Unit "OpenGL" ist veraltet. dglopengl unterstützt sogar schon die neuesten ARB-Extensions(meines wissens nach)!

Mit der Unit arbeitet hier niemand mehr.

_________________

"User Error. Replace User and hit Continue."

Nach oben

Flash

Betreff des Beitrags:

Verfasst: Di Feb 01, 2005 16:57

Guitar Hero

Registriert: Do Sep 25, 2003 15:56
Beiträge: 7810
Wohnort: Sachsen - ERZ / C
Programmiersprache: Java (, Pascal)

Veraltet? Ungenau is richtiger. Die orginal OpenGL.pas von Borland hat teilweise anders benannte Befehle (entsprechen nicht der OpenGL Synthax) und außerdem ist sie auf dem stand von OpenGL 1.0 (?). Unser Header is auf dem Stand von OpenGL 1.5 und wird immer gepflegt. Außerdem entspricht er Synthaxmäßig wirklich dem OpenGL Standart.

Die Initialisierung wurde durch den DGLOpenGL-Header vereinfacht. Das sollte vorallem Anfänger recht gelegen kommen. (Außerdem bleibt der Code dann hübscher, wenn man die Initialisierung net so sieht.) :wink:

_________________
Blog: kevin-fleischer.de und fbaingermany.com

Nach oben

Seite 1 von 1

[ 10 Beiträge ]

Foren-Übersicht » Programmierung » Einsteiger-Fragen

Wer ist online?

Mitglieder in diesem Forum: 0 Mitglieder und 7 Gäste

Du darfst keine neuen Themen in diesem Forum erstellen.
Du darfst keine Antworten zu Themen in diesem Forum erstellen.
Du darfst deine Beiträge in diesem Forum nicht ändern.
Du darfst deine Beiträge in diesem Forum nicht löschen.
Du darfst keine Dateianhänge in diesem Forum erstellen.