DGL • Thema anzeigen - TestSzene erscheint nicht

TestSzene erscheint nicht

Moderator: DGL-Team

Seite 1 von 1

[ 9 Beiträge ]

Vorheriges Thema | Nächstes Thema

Autor

Nachricht

M. Raab

Betreff des Beitrags: TestSzene erscheint nicht

Verfasst: So Nov 14, 2004 13:03

DGL Member

Registriert: Fr Jan 03, 2003 14:15
Beiträge: 36

Hallo NG,

bin neu hier und alle können jetzt mal über meinen Fehler kräftig lachen ---

So, hier der Code aus Eurer Sammlung:

Code:

 
unit OpenGL15_MainForm;
 
interface
 
uses
  Windows,
  Messages,
  SysUtils,
  Classes,
  Graphics,
  Controls,
  Forms,
  Dialogs,
 
  dglOpenGL;
 
type
  TGLForm = class(TForm)
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
    procedure ApplicationEventsIdle(Sender: TObject; var Done: Boolean);
    procedure FormKeyPress(Sender: TObject; var Key: Char);
    procedure DrawScene;
  private
    { Private-Deklarationen }
  public
    RC        : HGLRC;
    DC        : HDC;
    ShowFPS   : Boolean;
    FontBase  : GLUInt;
    StartTick : Cardinal;
    Frames    : Integer;
    FPS       : Single;
    procedure GoToFullScreen(pWidth, pHeight, pBPP, pFrequency : Word);
    procedure BuildFont(pFontName : String);
    procedure PrintText(pX,pY : Integer; const pText : String);
    procedure ShowText;
  end;
 
var
  GLForm: TGLForm;
 
implementation
 
{$R *.dfm}
 
procedure TGLForm.DrawScene;
begin
glBegin(gl_lines);
glcolor3f(1,0,0);
glVertex3f(-1,0,0);
glVertex3f(1,0,0);
glEnd;
end;
 
// =============================================================================
//  TForm1.GoToFullScreen
// =============================================================================
//  Wechselt in den mit den Parametern angegebenen Vollbildmodus
// =============================================================================
procedure TGLForm.GoToFullScreen(pWidth, pHeight, pBPP, pFrequency : Word);
var
 dmScreenSettings : DevMode;
begin
// Fenster vor Vollbild vorbereiten
WindowState := wsMaximized;
BorderStyle := bsNone;
ZeroMemory(@dmScreenSettings, SizeOf(dmScreenSettings));
with dmScreenSettings do
 begin
 dmSize              := SizeOf(dmScreenSettings);
 dmPelsWidth         := pWidth;                    // Breite
 dmPelsHeight        := pHeight;                   // Höhe
 dmBitsPerPel        := pBPP;                      // Farbtiefe
 dmDisplayFrequency  := pFrequency;                // Bildwiederholfrequenz
 dmFields            := DM_PELSWIDTH or DM_PELSHEIGHT or DM_BITSPERPEL or DM_DISPLAYFREQUENCY;
 end;
if (ChangeDisplaySettings(dmScreenSettings, CDS_FULLSCREEN) = DISP_CHANGE_FAILED) then
 begin
 MessageBox(0, 'Konnte Vollbildmodus nicht aktivieren!', 'Error', MB_OK or MB_ICONERROR);
 exit
 end;
end;
 
// =============================================================================
//  TForm1.BuildFont
// =============================================================================
//  Displaylisten für Bitmapfont erstellen
// =============================================================================
procedure TGLForm.BuildFont(pFontName : String);
var
 Font : HFONT;
begin
// Displaylisten für 256 Zeichen erstellen
FontBase := glGenLists(96);
// Fontobjekt erstellen
Font     := CreateFont(16, 0, 0, 0, FW_MEDIUM, 0, 0, 0, ANSI_CHARSET, OUT_TT_PRECIS, CLIP_DEFAULT_PRECIS,
                       ANTIALIASED_QUALITY, FF_DONTCARE or DEFAULT_PITCH, PChar(pFontName));
// Fontobjekt als aktuell setzen
SelectObject(DC, Font);
// Displaylisten erstellen
wglUseFontBitmaps(DC, 0, 256, FontBase);
// Fontobjekt wieder freigeben
DeleteObject(Font)
end;
 
// =============================================================================
//  TForm1.PrintText
// =============================================================================
//  Gibt einen Text an Position x/y aus
// =============================================================================
procedure TGLForm.PrintText(pX,pY : Integer; const pText : String);
begin
if (pText = '') then
 exit;
glPushAttrib(GL_LIST_BIT);
 glRasterPos2i(pX, pY);
 glListBase(FontBase);
 glCallLists(Length(pText), GL_UNSIGNED_BYTE, PChar(pText));
glPopAttrib;
end;
 
// =============================================================================
//  TForm1.ShowText
// =============================================================================
//  FPS, Hilfstext usw. ausgeben
// =============================================================================
procedure TGLForm.ShowText;
begin
// Tiefentest und Texturierung für Textanzeige deaktivieren
glDisable(GL_DEPTH_TEST);
glDisable(GL_TEXTURE_2D);
// In orthagonale (2D) Ansicht wechseln
glMatrixMode(GL_PROJECTION);
glLoadIdentity;
glOrtho(0,640,480,0, -1,1);
glMatrixMode(GL_MODELVIEW);
glLoadIdentity;
PrintText(5,15, FloatToStr(FPS)+' fps');
glEnable(GL_DEPTH_TEST);
glEnable(GL_TEXTURE_2D);
end;
 
// =============================================================================
//  TForm1.FormCreate
// =============================================================================
//  OpenGL-Initialisierungen kommen hier rein
// =============================================================================
procedure TGLForm.FormCreate(Sender: TObject);
begin
// Wenn gewollt, dann hier in den Vollbildmodus wechseln
// Muss vorm Erstellen des Kontextes geschehen, da durch den Wechsel der
// Gerätekontext ungültig wird!
// GoToFullscreen(1600, 1200, 32, 75);
                     
// OpenGL-Funtionen initialisieren
InitOpenGL;
// Gerätekontext holen
DC := GetDC(Handle);
// Renderkontext erstellen (32 Bit Farbtiefe, 24 Bit Tiefenpuffer, Doublebuffering)
RC := CreateRenderingContext(DC, [opDoubleBuffered], 32, 24, 0, 0, 0, 0);
// Erstellten Renderkontext aktivieren
ActivateRenderingContext(DC, RC);
// Tiefenpuffer aktivieren
glEnable(GL_DEPTH_TEST);
// Nur Fragmente mit niedrigerem Z-Wert (näher an Betrachter) "durchlassen"
glDepthFunc(GL_LESS);
// Löschfarbe für Farbpuffer setzen
glClearColor(1,1,1,0);
// Displayfont erstellen
BuildFont('MS Sans Serif');
// Idleevent für Rendervorgang zuweisen
Application.OnIdle := ApplicationEventsIdle;
// Zeitpunkt des Programmstarts für FPS-Messung speichern
StartTick := GetTickCount;
end;
 
// =============================================================================
//  TForm1.FormDestroy
// =============================================================================
//  Hier sollte man wieder alles freigeben was man so im Speicher belegt hat
// =============================================================================
procedure TGLForm.FormDestroy(Sender: TObject);
begin
// Renderkontext deaktiveren
DeactivateRenderingContext;
// Renderkontext "befreien"
wglDeleteContext(RC);
// Erhaltenen Gerätekontext auch wieder freigeben
ReleaseDC(Handle, DC);
// Falls wir im Vollbild sind, Bildschirmmodus wieder zurücksetzen
ChangeDisplaySettings(devmode(nil^), 0);
end;
 
// =============================================================================
//  TForm1.ApplicationEventsIdle
// =============================================================================
//  Hier wird gerendert. Der Idle-Event wird bei Done=False permanent aufgerufen
// =============================================================================
procedure TGLForm.ApplicationEventsIdle(Sender: TObject; var Done: Boolean);
begin
// In die Projektionsmatrix wechseln
glMatrixMode(GL_PROJECTION);
// Identitätsmatrix laden
glLoadIdentity;
// Viewport an Clientareal des Fensters anpassen
glViewPort(0, 0, ClientWidth, ClientHeight);
// Perspective, FOV und Tiefenreichweite setzen
gluPerspective(60, ClientWidth/ClientHeight, 1, 128);
 
// In die Modelansichtsmatrix wechseln
glMatrixMode(GL_MODELVIEW);
// Identitätsmatrix laden
glLoadIdentity;
// Farb- und Tiefenpuffer löschen
glClear(GL_COLOR_BUFFER_BIT or GL_DEPTH_BUFFER_BIT);
 
DrawScene;
ShowText;
 
// Hinteren Puffer nach vorne bringen
SwapBuffers(DC);
 
// Windows denken lassen, das wir noch nicht fertig wären
Done := False;
 
// Nummer des gezeichneten Frames erhöhen
inc(Frames);
// FPS aktualisieren
if GetTickCount - StartTick >= 500 then
 begin
 FPS       := round(Frames/(GetTickCount-StartTick)*1000);
 Frames    := 0;
 StartTick := GetTickCount
 end;
end;
 
// =============================================================================
//  TForm1.FormKeyPress
// =============================================================================
procedure TGLForm.FormKeyPress(Sender: TObject; var Key: Char);
begin
case Key of
 #27 : Close;
end;
end;
 
end.
 

In meiner DrawScene möchte ich nur ne Linie zeichnen - aber: nur die Schrift des FPS Counters wird rot - der Rest bleibt weiß. Eine Linie erscheint nicht ------- ???????????????ß

Kann mir jemand helfen ?

Gruss

Markus

Nach oben

Magellan

Betreff des Beitrags:

Verfasst: So Nov 14, 2004 13:10

DGL Member

Registriert: Di Nov 26, 2002 22:12
Beiträge: 259
Wohnort: Dresden

Du musst dein Objekt noch so verschieben, dass es sichtbar wird.
Im Moment liegt es praktisch direkt auf der „Linse“ und wird von deiner Near-Clipping-Plane weg geschnitten.
glTranslatef(0, 0, -5) sollte das Problem beheben.

_________________
Nichts auf der Welt ist so gerecht verteilt wie der Verstand. Denn jederman ist überzeugt, dass er genug davon habe.
Rene Descartes, frz. Mathematiker u. Philosoph, 1596-1650

Nach oben

M. Raab

Betreff des Beitrags:

Verfasst: So Nov 14, 2004 13:16

DGL Member

Registriert: Fr Jan 03, 2003 14:15
Beiträge: 36

Hallo,

nützt nix - mach ich da noch was falsch ?

Gruss

Markus

Nach oben

Magellan

Betreff des Beitrags:

Verfasst: So Nov 14, 2004 13:36

DGL Member

Registriert: Di Nov 26, 2002 22:12
Beiträge: 259
Wohnort: Dresden

Ich habe mir den Code jetzt nicht genau angesehen (ich vermute du hast auch nichts außer der Renderprozedur geändert). Auf Anhieb konnte ich keinen weiteren Fehler finden.
Wo genau rufst du denn dein glTranslatef auf?

Code:

 
procedure TGLForm.DrawScene; 
begin 
  glTranslatef(0, 0, -5);
  glBegin(GL_LINES);
    glcolor3f(1,0,0);
    glVertex3f(-1,0,0);
    glVertex3f(1,0,0);
  glEnd; 
end;
 

_________________
Nichts auf der Welt ist so gerecht verteilt wie der Verstand. Denn jederman ist überzeugt, dass er genug davon habe.
Rene Descartes, frz. Mathematiker u. Philosoph, 1596-1650

Nach oben

M. Raab

Betreff des Beitrags:

Verfasst: So Nov 14, 2004 13:41

DGL Member

Registriert: Fr Jan 03, 2003 14:15
Beiträge: 36

Hallo Magellan,

das war der Fehler ..... jetzt klappt es.

Noch eine Frage: Du sagst, es sei in der Linse. Was meinst Du damit ?

Ich dachte, dass 0,0,0 das Zentrum sei und daher eine Linie mit -1,0,0 nach 1,0,0 in x-Richtung über den Bildschirm geht. Warum ist das nicht so ? Wieso diese Verschiebung ?

Gruss

Markus

Nach oben

Flash

Betreff des Beitrags:

Verfasst: So Nov 14, 2004 13:51

Guitar Hero

Registriert: Do Sep 25, 2003 15:56
Beiträge: 7810
Wohnort: Sachsen - ERZ / C
Programmiersprache: Java (, Pascal)

Du hast 2 Matrizen die für sowas benutzt werden. (Die 3. = Textur ist hier unwichtig)

Die Modelviewmatrix kannst du dir wie eineMaschiene (mathematisch Korrekt einen Operator) vorstellen, mit dem du deine 3D Welt verschieben, drehen, Strecken,etc kannst.
Die 2. Matrix (die Projektionsmatrix) die es gibt ermöglicht dir die Sicht auf deine Welt zu verändern.

Wenn du einen Würfel an 0,0,-5 setzt dannbedeutet dass nicht, dass du auch an die Position gucken musst. Du kannst deinen sichtbereich auch irgendwo anders hingucken lassen.

Stell dir OpenGL und die Matrizen mal so vor:

Du hast einen Glaskasten (deine 3D Welt)und zwei zugriffsmöglichkeiten auf deren inhalt. Mit einem "Greifarm" (= Modelviewmatrix) kannst du Elemente in die Welt hineinbringen. Mit dem "Kameraarm" (=Projektionsmatrix) kannst du Ansichten aus der 3DWelt heraus holen.
Beide "Arme"kannst du unabhängig von einander Bewegen mittels glRotate/glTranslate etc. Welche Matrix du gerade steuerst legst du mit glMatrixMode fest.

Hier noch ein Wikibeitrag zum MatrixMode.
Und hier nochwas zu Matrizen.

_________________
Blog: kevin-fleischer.de und fbaingermany.com

Nach oben

M. Raab

Betreff des Beitrags:

Verfasst: So Nov 14, 2004 13:55

DGL Member

Registriert: Fr Jan 03, 2003 14:15
Beiträge: 36

Hallo Danke !!!

Das guck ich mir mal an ....

Gruss und Vielen Dank

Markus

Nach oben

Frase

Betreff des Beitrags:

Verfasst: So Nov 14, 2004 13:56

Forenkatze

Registriert: Mi Okt 22, 2003 18:30
Beiträge: 1945
Wohnort: Närnberch
Programmiersprache: Scala, Java, C*

Nicht umsonst entstand der Spruch

Zitat:

Ein Brett vorm Kopf haben

Die "Kamera" aus deren Sicht die ganze Szene gezeichnet wird ist nach der Initialisierung am Punkt (0,0,0).
Im Prinzip läufts so, wie im echten Leben auch. Man sieht nur etwas, wenn es VOR dem Betrachter ist. Wenn ein Objekt hinter dem Betrachter (der Kamera) liegt, kann man es logischerweise nicht sehen. Wer sich jetzt dunkel an die Tatsache erinnert, dass Geschwister, die sich von hinten anschleichen, auch nicht gesehen werden können ist auf dem richtigen Weg

(Das funktioniert übrigens auch, wenn man keine Geschwister hat)
In deinem Fall ist die Kamera bei (0,0,0), also im momentanen Zentrum.
Deine Linie zeichnest du von (-1,0,0) (links) nach (1,0,0) (rechts) mitten durch deine Kamera hindurch.
Die "Linse" der Kamera liegt also in der Linie. Aus verständlichen Gründen ist die Kamera darüber nicht sehr erfreut und "sieht" die Linie nicht. Wenn du einen Faden ganz nahe vor dein Auge hältst (meinetwegen auch in dein Auge

dann siehst du ihn auch nicht. Oder nur sehr schlecht. (Das liegt zwar daran, dass er sehr unscharf dadurch wird, aber das tut hier nix zur Sache

Lösung: Platz schaffen. Du brauchst etwas Platz zwischen Kamera und deinen Objekten. Dieses Entfernung nennt sich in den OpenGL-Templates Near_Clipping_Plane oder so ähnlich. Die Scihtweite deiner Kamera wird durch die andere ClippingPlane definiert. Ist also quasi sowas wie der Horizont der Kamera. Dahinter wird nichts mehr dargestellt.

So. Hoffe, ich hab die Materie anschaulich vermittelt

Nach oben

luketheduke

Betreff des Beitrags:

Verfasst: Di Nov 16, 2004 17:58

DGL Member

Registriert: Fr Mai 14, 2004 18:56
Beiträge: 804
Wohnort: GER/OBB/TÖL-WOR/Greiling

@spacejunkey:

sehr schöne erklärung.

aber:

znear zu verändern, ist da nicht besonders elegant. denn es heißt, der kamera zu sagen, sie soll gefälligst auch die sachen sehen, die hinter ihr liegen(bei znear=-1 zum beispiel). gltranslate ist da besser.

_________________

"User Error. Replace User and hit Continue."

Nach oben

Seite 1 von 1

[ 9 Beiträge ]

Foren-Übersicht » Programmierung » Einsteiger-Fragen

Wer ist online?

Mitglieder in diesem Forum: 0 Mitglieder und 1 Gast

Du darfst keine neuen Themen in diesem Forum erstellen.
Du darfst keine Antworten zu Themen in diesem Forum erstellen.
Du darfst deine Beiträge in diesem Forum nicht ändern.
Du darfst deine Beiträge in diesem Forum nicht löschen.
Du darfst keine Dateianhänge in diesem Forum erstellen.