DGL • Thema anzeigen

Screenshots

Moderator: DGL-Team

Seite 1 von 1

[ 9 Beiträge ]

Druckansicht

Vorheriges Thema | Nächstes Thema

Autor

Nachricht

Stucuk

Betreff des Beitrags: Screenshots

Verfasst: Fr Aug 20, 2004 01:09

DGL Member

Registriert: Mi Jul 21, 2004 22:39
Beiträge: 360
Wohnort: UK, Scotland

Below is code based on Q2Delphi code for screenshots

Code:

 
function ScreenShot_BitmapResult : TBitmap;
var
  buffer: array of byte;
  x,y, i: integer;
  Bitmap : TBitmap;
  Stream : TMemoryStream;
  WW : integer;
begin
  {
  WW forces the thing to Get an image that has an even width, even when its ment to b odd
  this fixes the prob with an odd width.
  }
  if MainViewWidth div 2 = MainViewWidth / 2 then
  WW := MainViewWidth
  else
  WW := MainViewWidth+1;
 
  SetLength(buffer, (WW * MainViewHeight * 3)+1);
 
  glReadPixels(0, 0, WW, MainViewHeight, GL_RGB, GL_UNSIGNED_BYTE, Pointer(Cardinal(buffer) {+ 18}));
 
  i := 0;
  Bitmap := TBitmap.Create;
  Bitmap.Canvas.Brush.Color := TVector3fToTColor(BGColor);
  Bitmap.Width := MainViewWidth;
  Bitmap.Height := MainViewHeight;
  for y := 1 to MainViewHeight do
  for x := 1 to WW do
  begin
  if x <= MainViewWidth then
  Bitmap.Canvas.Pixels[x-1,MainViewHeight-y] := RGB(buffer[(i*3)],buffer[(i*3)+1],buffer[(i*3)+2]);
  inc(i);
  end;
  finalize(buffer);
  Result := Bitmap;
end;
 

The problem being at some sizes the images are not converted to the bitmap properly, results below:

Bild

EDIT: whats with the "u can't post so soon, bla bla bla" crap that happens if u spot a mistake n try n edit it in under 30 secs.

Dateianhänge:

Dateikommentar: Normal Image

_0052.jpg [140.21 KiB]
101-mal heruntergeladen

_________________
Free Map Editor - Game Requirements - Stucuk.Net
-Stu

Nach oben

BTierens

Betreff des Beitrags:

Verfasst: Fr Aug 20, 2004 07:15

DGL Member

Registriert: Fr Aug 13, 2004 17:43
Beiträge: 60
Wohnort: Belgien

I don't see an error but why does your for loop start by 1 and not by 0?

Code:

 
  for y := 1 to MainViewHeight do
  for x := 1 to WW do
  begin
  if x <= MainViewWidth then
  Bitmap.Canvas.Pixels[x-1,MainViewHeight-y] := RGB(buffer[(i*3)],buffer[(i*3)+1],buffer[(i*3)+2]);
  inc(i);
  end;
 

Nach oben

rochus

Betreff des Beitrags:

Verfasst: Fr Aug 20, 2004 12:29

DGL Member

Registriert: So Dez 29, 2002 10:37
Beiträge: 251
Wohnort: Ulm

the 1 minute "crap" is that no one floods the forum.

so far
rochus

_________________
http://www.rochus.net

Nach oben

Stucuk

Betreff des Beitrags:

Verfasst: Fr Aug 20, 2004 16:11

DGL Member

Registriert: Mi Jul 21, 2004 22:39
Beiträge: 360
Wohnort: UK, Scotland

BTierens hat geschrieben:

I don't see an error but why does your for loop start by 1 and not by 0?

Code:

 
  for y := 1 to MainViewHeight do
  for x := 1 to WW do
  begin
  if x <= MainViewWidth then
  Bitmap.Canvas.Pixels[x-1,MainViewHeight-y] := RGB(buffer[(i*3)],buffer[(i*3)+1],buffer[(i*3)+2]);
  inc(i);
  end;
 

I is the thing that is increased, it is the varible that detrmins which bit of the buffer gets turned into a colour for the canvas.pixels at any one time.

Zitat:

Bitmap.Canvas.Pixels[x-1,MainViewHeight-y] := RGB(buffer[(i*3)],buffer[(i*3)+1],buffer[(i*3)+2]);

Having the loop like

Code:

 
for y := 0 to MainViewHeight-1 do
for x := 0 to WW-1 do

Wouldn't change a thing.

Zitat:

the 1 minute "crap" is that no one floods the forum.

so far
rochus

Yes but u can't flood a forum by EDITING a post, which is my point. Anti Floods shouldn't ever happen when u edit posts.

_________________
Free Map Editor - Game Requirements - Stucuk.Net
-Stu

Nach oben

Sascha Willems

Betreff des Beitrags:

Verfasst: Fr Aug 20, 2004 16:20

DGL Member

Registriert: Mo Sep 23, 2002 19:27
Beiträge: 5812
Programmiersprache: C++

Don't know if it'll change something, but have you tried to explicit set the pixelformat of the bitmap, something like this :

Code:

Bitmap.PixelFormat := pf24bit;

before writing pixels to it? I had to do that when I used bitmaps to create some terrain textures in an app.

_________________
www.SaschaWillems.de | GitHub | Twitter | GPU Datenbanken (Vulkan, GL, GLES)

Nach oben

Stucuk

Betreff des Beitrags:

Verfasst: Fr Aug 20, 2004 16:36

DGL Member

Registriert: Mi Jul 21, 2004 22:39
Beiträge: 360
Wohnort: UK, Scotland

Didn't change a thing, one thing i have noticed is that even if the order of the buffer is wrongly worked out, each pixel on the image should retain its correct colours, since the buffer is always made up of 3 bytes of colour to one pixel..... yet its not keeping the correct colours.... glReadPixels is wierd (and unstable, crashed my pc months ago when i was playing with values...)

_________________
Free Map Editor - Game Requirements - Stucuk.Net
-Stu

Nach oben

Sascha Willems

Betreff des Beitrags:

Verfasst: Fr Aug 20, 2004 19:13

DGL Member

Registriert: Mo Sep 23, 2002 19:27
Beiträge: 5812
Programmiersprache: C++

Uh, I almost forgot that I (long time ago) wrote a function that takes a screenshot from the GL and stores it as a JPG. So if you don't mind the JPG format, then feel free to use my procedure in your app :

Code:

// =============================================================================
//  glSaveScreen
// =============================================================================
//  Speichert einen Screenshot des aktuellen Pufferinhaltes
// =============================================================================
procedure glSaveScreen(pFilename : String);
var
 Viewport : array[0..3] of TGLint;
 JPG      : TJPEGImage;
 RGBBits  : PRGBQuad;
 Pixel    : PRGBQuad;
 BMP      : TBitmap;
 Header   : PBitmapInfo;
 x,y      : Integer;
 Temp     : Byte;
begin
glGetIntegerv(GL_VIEWPORT, @Viewport);
GetMem(RGBBits, Viewport[2]*Viewport[3]*4);
glFinish;
glPixelStorei(GL_PACK_ALIGNMENT, 4);
glPixelStorei(GL_PACK_ROW_LENGTH, 0);
glPixelStorei(GL_PACK_SKIP_ROWS, 0);
glPixelStorei(GL_PACK_SKIP_PIXELS, 0);
glReadPixels(0, 0, Viewport[2], Viewport[3], GL_RGBA, GL_UNSIGNED_BYTE, RGBBits);
// Screenshot als JPG speichern
JPG := TJPEGImage.Create;
BMP := TBitmap.Create;
BMP.PixelFormat := pf32Bit;
BMP.Width       := Viewport[2];
BMP.Height      := Viewport[3];
GetMem(Header, SizeOf(TBitmapInfoHeader));
with Header^.bmiHeader do
 begin
 biSize        := SizeOf(TBitmapInfoHeader);
 biWidth       := Viewport[2];
 biHeight      := Viewport[3];
 biPlanes      := 1;
 biBitCount    := 32;
 biCompression := BI_RGB;
 biSizeImage   := Viewport[2]*Viewport[3]*4;
 end;
// Rot und Blau vertauschen
Pixel := RGBBits;
for x := 0 to Viewport[2]-1 do
 for y := 0 to Viewport[3]-1 do
  begin
  Temp       := Pixel.Red;
  Pixel.Red  := Pixel.Blue;
  Pixel.Blue := Temp;
  inc(Pixel);
  end;
SetDIBits(Bmp.Canvas.Handle, Bmp.Handle, 0, Viewport[3], RGBBits, TBitmapInfo(Header^), DIB_RGB_COLORS);
JPG.CompressionQuality := 100;
JPG.Assign(BMP);
JPG.SaveToFile(pFileName);
FreeMem(Header);
FreeMem(RGBBits);
JPG.Free;
BMP.Free;
end;

P.S. : I've just tested it with different window sizes (odd and even) and it always worked.

_________________
www.SaschaWillems.de | GitHub | Twitter | GPU Datenbanken (Vulkan, GL, GLES)

Nach oben

Stucuk

Betreff des Beitrags:

Verfasst: Fr Aug 20, 2004 20:32

DGL Member

Registriert: Mi Jul 21, 2004 22:39
Beiträge: 360
Wohnort: UK, Scotland

Thanks

works perfectly (simple to convert it so it outputs a bmp as a result)

Btw did u manaualy declare PRGBQuad cos windows has the red and blue as rgbred and rgbblue.

_________________
Free Map Editor - Game Requirements - Stucuk.Net
-Stu

Nach oben

Sascha Willems

Betreff des Beitrags:

Verfasst: Fr Aug 20, 2004 20:36

DGL Member

Registriert: Mo Sep 23, 2002 19:27
Beiträge: 5812
Programmiersprache: C++

Yes, I declared it manually, sry for forgetting that part :

Code:

 PRGBQuad = ^TRGBQuad;
 TRGBQuad = packed record
   Red   : Byte;
   Green : Byte;
   Blue  : Byte;
   Alpha : Byte;
  end;

_________________
www.SaschaWillems.de | GitHub | Twitter | GPU Datenbanken (Vulkan, GL, GLES)

Nach oben

Seite 1 von 1

[ 9 Beiträge ]

Foren-Übersicht » English » English Programming Forum

Wer ist online?

Mitglieder in diesem Forum: 0 Mitglieder und 0 Gäste

Du darfst keine neuen Themen in diesem Forum erstellen.
Du darfst keine Antworten zu Themen in diesem Forum erstellen.
Du darfst deine Beiträge in diesem Forum nicht ändern.
Du darfst deine Beiträge in diesem Forum nicht löschen.
Du darfst keine Dateianhänge in diesem Forum erstellen.