DGL • Thema anzeigen - Displaylisten funktionieren nicht richtig

Displaylisten funktionieren nicht richtig

Moderator: DGL-Team

Seite 1 von 1

[ 5 Beiträge ]

Vorheriges Thema | Nächstes Thema

Autor

Nachricht

Typhox

Betreff des Beitrags: Displaylisten funktionieren nicht richtig

Verfasst: Di Feb 17, 2009 20:38

DGL Member

Registriert: Di Aug 12, 2008 16:50
Beiträge: 22

Hallo,

Ich bn gerade dabei, mich an de NeHe-Tutorials zu schulen. Leider funktioniert der Teil mit den Displaylisten nicht richtig, obwohl ich sogar Teile davon aus dem Quelltext übernommen habe...
Es zeichnet zwar die Boxen, nicht aber die Deckel und so ganz will mir nicht einleuchten, warum. Es wird wohl an der Funktion glGenLists(2) liegen oder ich habe irgendwo was übersehen, was ich aber nicht glaube, weil ich mir den Code inzwischen eigentlich auch schon ziemlich genau angeschaut habe.

Hier ist er jedenfalls:

Code:

 
unit Unit1;
 
interface
 
uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, DGLOpenGL, ExtCtrls, glBitmap;
 
type
  TForm1 = class(TForm)
    Timer1: TTimer;
    procedure FormCreate(Sender: TObject);
    procedure InitGL;
    procedure FormResize(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
    procedure Render;
    procedure Timer1Timer(Sender: TObject);
    procedure ErrorHandler;
    procedure LoadGLTextures;
  private
    fTexture: TglBitmap2D;
    FrameCount: Cardinal;
  public
    DC: HDC;
    RC: HGLRC;
  end;
 
var
  Form1: TForm1;
  box, top: GLuint;
  xrot, yrot: GLfloat;
  texture: Array[0..0] of Gluint;
  TextureImage: Array[0..0] of TglBitmap2D;
  boxcol: Array[0..4] of Array[0..2] of GLfloat = ((1.0, 0.0, 0.0),(1.0, 0.5, 0.0),
                                                   (1.0, 1.0, 0.0),(0.0, 1.0, 0.0),
                                                   (0.0, 1.0, 1.0));
  topcol: Array[0..4] of Array[0..2] of GLfloat = ((0.5, 0.0, 0.0),(0.5, 0.25, 0.0),
                                                   (0.5, 0.5, 0.0),(0.0, 0.5, 0.0),
                                                   (0.0, 0.5, 0.5));
 
implementation
 
{$R *.dfm}
 
const
  NearClipping = 0.1;
  FarClipping = 100.0;
 
procedure BuildLists;
begin
  box := glGenLists(2);
  glNewList(box, GL_COMPILE);
  glBegin(GL_QUADS);
    glNormal3f(0.0,-1.0,0.0);
    glTexCoord2f(1.0, 1.0); glVertex3f(-1.0, -1.0, -1.0);
    glTexCoord2f(0.0, 1.0); glVertex3f( 1.0, -1.0, -1.0);
    glTexCoord2f(0.0, 0.0); glVertex3f( 1.0, -1.0, 1.0);
    glTexCoord2f(1.0, 0.0); glVertex3f(-1.0, -1.0, 1.0);
 
    glNormal3f(0.0,0.0,1.0);
    glTexCoord2f(0.0, 0.0); glVertex3f(-1.0, -1.0, 1.0);
    glTexCoord2f(1.0, 0.0); glVertex3f( 1.0, -1.0, 1.0);
    glTexCoord2f(1.0, 1.0); glVertex3f( 1.0, 1.0, 1.0);
    glTexCoord2f(0.0, 1.0); glVertex3f(-1.0, 1.0, 1.0);
 
    glNormal3f(0.0,0.0,-1.0);
    glTexCoord2f(1.0, 0.0); glVertex3f(-1.0, -1.0, -1.0);
    glTexCoord2f(1.0, 1.0); glVertex3f(-1.0, 1.0, -1.0);
    glTexCoord2f(0.0, 1.0); glVertex3f( 1.0, 1.0, -1.0);
    glTexCoord2f(0.0, 0.0); glVertex3f( 1.0, -1.0, -1.0);
 
    glNormal3f(1.0,0.0,0.0);
    glTexCoord2f(1.0, 0.0); glVertex3f( 1.0, -1.0, -1.0);
    glTexCoord2f(1.0, 1.0); glVertex3f( 1.0, 1.0, -1.0);
    glTexCoord2f(0.0, 1.0); glVertex3f( 1.0, 1.0, 1.0);
    glTexCoord2f(0.0, 0.0); glVertex3f( 1.0, -1.0, 1.0);
 
    glNormal3f(-1.0,0.0,0.0);
    glTexCoord2f(0.0, 0.0); glVertex3f(-1.0, -1.0, -1.0);
    glTexCoord2f(1.0, 0.0); glVertex3f(-1.0, -1.0, 1.0);
    glTexCoord2f(1.0, 1.0); glVertex3f(-1.0, 1.0, 1.0);
    glTexCoord2f(0.0, 1.0); glVertex3f(-1.0, 1.0, -1.0);
  glEnd;
  glEndList;
  top := box + 1;
  glNewList(top, GL_COMPILE);
  glBegin(GL_QUADS);
    glNormal3f(0.0,1.0,0.0);
    glTexCoord2f(0.0, 1.0); glVertex3f(-1.0, 1.0, -1.0);
    glTexCoord2f(0.0, 0.0); glVertex3f(-1.0, 1.0, 1.0);
    glTexCoord2f(1.0, 0.0); glVertex3f( 1.0, 1.0, 1.0);
    glTexCoord2f(1.0, 1.0); glVertex3f( 1.0, 1.0, -1.0);
  glEnd;
  glEndList;
 
end;
 
procedure TForm1.Render;
var
  xloop, yloop: GLuint;
begin
  FormResize(nil);
  glClear(GL_COLOR_BUFFER_BIT or GL_DEPTH_BUFFER_BIT);
  glBindTexture(GL_TEXTURE_2D, texture[0]);
 
  for yloop := 1 to 5 do
  begin
    for xloop := 0 to yloop-1 do
    begin
      glLoadIdentity;
      glTranslatef(1.4+(xloop*2.8)-(yloop*1.4),((6.0-yloop)*2.4)-7.0,-20.0); 
      glRotatef(45.0-(2.0*yloop)+xrot,1.0,0.0,0.0);
      glRotatef(45.0+yrot,0.0,1.0,0.0);
      glColor3fv(@boxcol[yloop-1]);
      glCallList(box);
      glColor3fv(@topcol[yloop-1]);
      glCallList(top);
    end;
  end;
  SwapBuffers(DC);
end;
 
procedure TForm1.LoadGLTextures;
begin
  TextureImage[0] := TglBitmap2D.Create(PChar(ExtractFileDir(paramStr(0))+'\Data\cube.bmp'));
  TextureImage[0].FlipVert;
  glGenTextures(1, @texture[0]);
  glBindTexture(GL_TEXTURE_2D, texture[0]);
  glTexParameteri(GL_TEXTURE_2D, GL_TEXTURE_MAG_FILTER, GL_LINEAR);
  glTexParameteri(GL_TEXTURE_2D, GL_TEXTURE_MIN_FILTER, GL_LINEAR);
  glTexImage2D(GL_TEXTURE_2D, 0, 3, TextureImage[0].Width, TextureImage[0].Height,0, GL_BGR, GL_UNSIGNED_BYTE, TextureImage[0].DataPtr);
  TextureImage[0].Free;
end;
 
procedure TForm1.FormCreate(Sender: TObject);
begin
  DC := GetDC(Handle);
  if not InitOpenGL then Application.Terminate;
  RC := CreateRenderingContext( DC, [opDoubleBuffered], 32, 24, 0,0,0, 0);
  ActivateRenderingContext(DC, RC);
  InitGL;
end;
 
procedure TForm1.InitGL;
begin
  LoadGLTextures;
  BuildLists;
  glEnable(GL_TEXTURE_2D);
  glShadeModel(GL_SMOOTH);
  glClearColor(0.0, 0.0, 0.0, 0.0);
  glClearDepth(1.0);
  glEnable(GL_DEPTH_TEST);
  glDepthFunc(GL_LEQUAL);
  glEnable(GL_LIGHT0);
  glEnable(GL_LIGHTING);
  glEnable(GL_COLOR_MATERIAL);
  glHint(GL_PERSPECTIVE_CORRECTION_HINT, GL_NICEST);
end;
 
procedure TForm1.FormResize(Sender: TObject);
begin
  glViewPort(0, 0, ClientWidth, ClientHeight);
  glMatrixMode(GL_PROJECTION);
  glLoadIdentity;
  gluPerspective(45.0, ClientWidth/ClientHeight, NearClipping, FarClipping);
 
  glMatrixMode(GL_MODELVIEW);
  glLoadIdentity;
end;
 
procedure TForm1.FormDestroy(Sender: TObject);
begin
  fTexture.Free;
  DeactivateRenderingContext;
  DestroyRenderingContext(RC);
  ReleaseDC(Handle, DC);
end;
 
procedure TForm1.Timer1Timer(Sender: TObject);
begin
  inc(FrameCount);
  Render;
  If FrameCount = 20 then
    begin
      ErrorHandler;
      FrameCount := 0;
    end;
end;
 
procedure TForm1.ErrorHandler;
begin
  Form1.Caption := gluErrorString(glGetError);
end;
 
end.
 

Könnt ihr mir sagen, was ich falsch gemacht habe?

Zuletzt geändert von Typhox am Mi Feb 18, 2009 07:24, insgesamt 1-mal geändert.

Nach oben

Traude

Betreff des Beitrags:

Verfasst: Di Feb 17, 2009 23:25

DGL Member

Registriert: Di Okt 03, 2006 14:07
Beiträge: 1277
Wohnort: Wien

In der Renderschleife kurz vor dem Swapbuffers steht ein "glBegin(GL_QUADS);" bei dem ich kein "glEnd" entdecken kann. Sieht aus, als wär es dort vergessen worden.

Nach oben

Typhox

Betreff des Beitrags:

Verfasst: Mi Feb 18, 2009 07:23

DGL Member

Registriert: Di Aug 12, 2008 16:50
Beiträge: 22

Hm, gut, das habe ich dort bei meinen Tests irgendwie vergessen^^
Leider ist es nicht der Grund dafür, dass es nicht geht, denn es funktioniert immer noch nicht

Trotzdem danke.

Nach oben

Sascha Willems

Betreff des Beitrags:

Verfasst: Mi Feb 18, 2009 12:54

DGL Member

Registriert: Mo Sep 23, 2002 19:27
Beiträge: 5812
Programmiersprache: C++

Wenn bestimmte Teile nicht gerendert werden liegts evtl. an einer falschen Renderreihenfolge deiner Eckpunkte. Entweder die einfach mal umdrehen oder Backfaceculling deaktivieren. Ausserdem muss es nicht sein dass gelGenLists hintereinanderliegende IDs liefert, also ist box+1 evtl. keine der von glGenLists erzeugten IDs, also auch hier besser jeweils für box und top ein eigenes glGenLists(1) aufrufen.

_________________
www.SaschaWillems.de | GitHub | Twitter | GPU Datenbanken (Vulkan, GL, GLES)

Nach oben

Typhox

Betreff des Beitrags:

Verfasst: Mi Feb 18, 2009 14:31

DGL Member

Registriert: Di Aug 12, 2008 16:50
Beiträge: 22

Gut, vielen Dank, backface-culling hatte ich sowieso aus Sicherheitsgründen deaktiviert und das mit glGenLists wollte ich gerade ausprobieren, vorher jedoch noch was anderes was mir gerade so zufällig eingefallen ist^^
Es lag einfach daran, dass ich die Variable "top" genannt habe und diese wohl im Laufe der Geschichte aufgrund ihres Namens neu zugeordnet oder falsch interpretiert worden ist. Inzwischen heißt sie "topi", und jetzt funktioniert endlich alles :-)
Vielen Dank, ich denke mal, das mit glGenLists() wird mir eventuell noch wann anders weiterhelfen.

Nach oben

Seite 1 von 1

[ 5 Beiträge ]

Foren-Übersicht » Programmierung » OpenGL

Wer ist online?

Mitglieder in diesem Forum: 0 Mitglieder und 3 Gäste

Du darfst keine neuen Themen in diesem Forum erstellen.
Du darfst keine Antworten zu Themen in diesem Forum erstellen.
Du darfst deine Beiträge in diesem Forum nicht ändern.
Du darfst deine Beiträge in diesem Forum nicht löschen.
Du darfst keine Dateianhänge in diesem Forum erstellen.