DGL • Thema anzeigen - Frame Buffer Object (FBO) [solved]

Frame Buffer Object (FBO) [solved]

Moderator: DGL-Team

Seite 1 von 1

[ 2 Beiträge ]

Vorheriges Thema | Nächstes Thema

Autor

Nachricht

littleDave

Betreff des Beitrags: Frame Buffer Object (FBO) [solved]

Verfasst: Mi Dez 05, 2007 12:50

DGL Member

Registriert: Mi Mär 09, 2005 15:54
Beiträge: 372
Wohnort: München
Programmiersprache: Delphi, C#, FPC

Ich hab mir mal vorgenommen, die Extension Frame Buffer Object mal auszuprobieren. Aber ich bekomms einfach nicht hin. Ich hab bereits folgende Papers angeschaut, doch irgendwie funktioniert es bei mir nicht so ganz:

- http://www.gamedev.net/reference/programming/features/fbo1/
- http://http.download.nvidia.com/developer/presentations/2005/GDC/OpenGL_Day/OpenGL_FrameBuffer_Object.pdf

Egal was ich mache, ich schaff es einfach nicht, den FrameBuffer zu erstellen. Hier ist mein Code:

Dieser Code überprüft den FrameBuffer Status

Code:

 
procedure CheckFrameBufferStatus;
var
  s: GLenum;
begin
  s := glCheckFramebufferStatusEXT(GL_FRAMEBUFFER_EXT);
  case s of
  GL_FRAMEBUFFER_COMPLETE_EXT:                         Exit;
  GL_FRAMEBUFFER_INCOMPLETE_ATTACHMENT_EXT:           raise Exception.Create('Incomplete attachment');
  GL_FRAMEBUFFER_INCOMPLETE_MISSING_ATTACHMENT_EXT:   raise Exception.Create('Missing attachment');
  GL_FRAMEBUFFER_INCOMPLETE_DUPLICATE_ATTACHMENT_EXT: raise Exception.Create('Duplicate attachment');
  GL_FRAMEBUFFER_INCOMPLETE_DIMENSIONS_EXT:           raise Exception.Create('Incomplete dimensions');
  GL_FRAMEBUFFER_INCOMPLETE_FORMATS_EXT:              raise Exception.Create('Incomplete formats');
  GL_FRAMEBUFFER_INCOMPLETE_DRAW_BUFFER_EXT:          raise Exception.Create('Incomplete draw buffer');
  GL_FRAMEBUFFER_INCOMPLETE_READ_BUFFER_EXT:          raise Exception.Create('Incomplete read buffer');
  GL_FRAMEBUFFER_UNSUPPORTED_EXT:                     raise Exception.Create('Framebuffer configuration unsupported');
  end;
end;
 

So Initialisiere ich den FrameBuffer:

Code:

 
var    FBO, DepthBuffer, Texture : TGLuint;
 
procedure CreateFrameBufferObject;
begin
  glEnable(GL_TEXTURE_2D);
 
  glGenFramebuffersEXT(1, @FBO);
  glGenRenderbuffersEXT(1, @DepthBuffer);
  glGenTextures(1, @Texture);
 
  glBindFramebufferEXT(GL_FRAMEBUFFER_EXT, FBO);
  glBindTexture(GL_TEXTURE_2D, Texture);
  glTexImage2D(GL_TEXTURE_2D, 0, GL_RGBA8, 512, 512, 0, GL_RGBA, GL_UNSIGNED_BYTE, nil);
 
  glFramebufferTexture2DEXT(GL_FRAMEBUFFER_EXT, GL_COLOR_ATTACHMENT0_EXT, GL_TEXTURE_2D, Texture, 0);
 
  glBindRenderbufferEXT(GL_RENDERBUFFER_EXT, DepthBuffer);
  glRenderbufferStorageEXT(GL_RENDERBUFFER_EXT, GL_DEPTH_COMPONENT24, 512, 512);
 
  glFramebufferRenderbufferEXT(GL_FRAMEBUFFER_EXT, GL_DEPTH_ATTACHMENT_EXT, GL_RENDERBUFFER_EXT, DepthBuffer);
 
  CheckFrameBufferStatus;
end;
 

Und hier sind die Start- bzw Endroutinen die beim Rendern in den FrameBuffer angewendet werden

Code:

 
procedure BeginFrameBufferRendering;
begin
  glBindFramebufferEXT(GL_FRAMEBUFFER_EXT, FBO);
  glPushAttrib(GL_VIEWPORT_BIT);
  glViewport(0, 0, 512, 512);
end;
 
procedure EndFrameBufferRendering;
begin
  glPopAttrib();
  glBindFramebufferEXT(GL_FRAMEBUFFER_EXT, 0);
end;
 

Ich bekomms einfach nicht gebacken, was mach ich falsch? Ich bekomm die ganze Zeit die Meldung "Framebuffer configuration unsupported".

_________________
Aktuelles Projekt: Gael - Development Blog
Website: LightBlackSoft.com

Zuletzt geändert von littleDave am Mi Dez 05, 2007 13:15, insgesamt 1-mal geändert.

Nach oben

littleDave

Betreff des Beitrags:

Verfasst: Mi Dez 05, 2007 13:15

DGL Member

Registriert: Mi Mär 09, 2005 15:54
Beiträge: 372
Wohnort: München
Programmiersprache: Delphi, C#, FPC

Ah, habs gerade selbst noch hinbekommen: Es lag daran, dass ich das Filtering der Textur nicht eingestellt hatte. Musste nach
glTexImage2D(GL_TEXTURE_2D, 0, GL_RGBA8, 512, 512, 0, GL_RGBA, GL_UNSIGNED_BYTE, nil); (Zeile 14) noch folgendes einfügen:

Code:

 
glTexParameterf(GL_TEXTURE_2D, GL_TEXTURE_MAG_FILTER, GL_LINEAR);
glTexParameterf(GL_TEXTURE_2D, GL_TEXTURE_MIN_FILTER, GL_LINEAR);

So, jetzt funktionierts

_________________
Aktuelles Projekt: Gael - Development Blog
Website: LightBlackSoft.com

Nach oben

Seite 1 von 1

[ 2 Beiträge ]

Foren-Übersicht » Programmierung » OpenGL

Wer ist online?

Mitglieder in diesem Forum: Bing [Bot] und 7 Gäste

Du darfst keine neuen Themen in diesem Forum erstellen.
Du darfst keine Antworten zu Themen in diesem Forum erstellen.
Du darfst deine Beiträge in diesem Forum nicht ändern.
Du darfst deine Beiträge in diesem Forum nicht löschen.
Du darfst keine Dateianhänge in diesem Forum erstellen.