DGL • Thema anzeigen - OpenGL friert ein...

OpenGL friert ein...

Moderator: DGL-Team

Seite 1 von 1

[ 11 Beiträge ]

Vorheriges Thema | Nächstes Thema

Autor

Nachricht

Kathmai

Betreff des Beitrags: OpenGL friert ein...

Verfasst: Mi Feb 04, 2009 21:14

DGL Member

Registriert: Do Mai 27, 2004 15:22
Beiträge: 25
Wohnort: Stuttgart

Hi Leute,

ich hab mich seit langem mal wieder mit OpenGL beschäftigt und musste feststellen das jedes Programm (mit OpenGL) sobald ich die Maus auf den Rendercontext bewege einfriert. Keine Animationen mehr, keine FPS - Aktualisierungen mehr - nix... Maus ausserhalb des Rendercontextes - läuft wieder wie geschmiert.

Alle Programm das heisst....

Alle Demos von Euch (auch die von dem 2D-Tutorial) und meine eigenen kleinen Test's.

Ausstattung:

Athlon 64 X2 5600+ Dual Core
2 GB RAM
WinXP Pro SP2
Geforce 8800 GT 256 MB RAM (aktueller Treiber drauf 181.22)
Delphi 7 prof.

Treiber davor (weiss nicht mehr welcher genau hat auch nicht funktioniert).

Was läuft da schief?

Bei meinem Demoprogramm wird nur ein Hintergrundbild angezeigt und die FPS per Font ausgegeben. Andere Demos frieren auch ein. Warum?! :roll:

Danke im voraus!

_________________
cya
Tom

Nach oben

Flash

Betreff des Beitrags:

Verfasst: Mi Feb 04, 2009 23:51

Guitar Hero

Registriert: Do Sep 25, 2003 15:56
Beiträge: 7810
Wohnort: Sachsen - ERZ / C
Programmiersprache: Java (, Pascal)

Versuch mal den Renderloop mit einem Timerevent zu steuern. Vielleicht ist dein Betriebssystem so fleißig, dass es nie onIdle ruft. Wäre zwar komisch, aber seltsame Begebenheiten rufen seltsame Erklärungen hervor.

_________________
Blog: kevin-fleischer.de und fbaingermany.com

Nach oben

Lossy eX

Betreff des Beitrags:

Verfasst: Do Feb 05, 2009 09:48

DGL Member

Registriert: Do Dez 05, 2002 10:35
Beiträge: 4234
Wohnort: Dortmund

Sozusagen alle OpenGL Anwenungen haben bei dir dieses Problem?

Ich hatte früher häufiger mal Probleme mit dem Mausschatten. Der muss von Windows nachträglich über alles gezeichnet werden. Allerdings sollte dein System mit so etwas ja eigentlich überhaupt keine Probleme haben dürfen.

Nach oben

Kathmai

Betreff des Beitrags:

Verfasst: Do Feb 05, 2009 14:29

DGL Member

Registriert: Do Mai 27, 2004 15:22
Beiträge: 25
Wohnort: Stuttgart

Lossy eX hat geschrieben:

Sozusagen alle OpenGL Anwenungen haben bei dir dieses Problem?

Ja, aber ich habe gemerkt, die Anwendungen die über die api (also nicht über VCL und onidle gehen) funktionieren. Komisch oder?!

Ich bewege nur die blöde Maus über das Fenster und schon hängt es. Bei dem 2D Tuts an dem zwei beispielen mit dem Raumschiff (Rotation um eigene Achse und der FLug über eine Grasfläche mit Schatten) funz alles wenn ich die Maus nicht im Fenster hab - beweg ich sie hinein - pumpe... nix mehr animiert.

Hab auch schon versucht die Anwendung(en) über den Taskmanager nur einer CPU zuzuweisen aber hat nix gebracht.

Flash hat geschrieben:

Hab ich jetzt mal auch versucht... Hab die Demo Nr. 2 (mit dem Feuer) des 2D Tuts umgeschrieben per Timer (10 ms).
Ergebnis: Maus Ausserhalb des RenderContextes funzt - Maus im RC funzt net. :-(

Keine Ahnung was da los is....??

PS: Aktuellste glBitmap / dglopengl ist wird benutzt (hat davor aber auch nicht mehr funktioniert mit den alten im dglsdk)

_________________
cya
Tom

Nach oben

Flash

Betreff des Beitrags:

Verfasst: Do Feb 05, 2009 16:32

Guitar Hero

Registriert: Do Sep 25, 2003 15:56
Beiträge: 7810
Wohnort: Sachsen - ERZ / C
Programmiersprache: Java (, Pascal)

Kann es sein, dass deine Maussensitivität zu hoch eingestellt ist? Wenn deine Maus das Formular mit Mousevents bombardiert, könnte es so zu problemen kommen.

_________________
Blog: kevin-fleischer.de und fbaingermany.com

Nach oben

Kathmai

Betreff des Beitrags:

Verfasst: Do Feb 05, 2009 16:47

DGL Member

Registriert: Do Mai 27, 2004 15:22
Beiträge: 25
Wohnort: Stuttgart

Flash hat geschrieben:

Kann es sein, dass deine Maussensitivität zu hoch eingestellt ist? Wenn deine Maus das Formular mit Mousevents bombardiert, könnte es so zu problemen kommen.

Nein daran liegt es auch nicht, hab gerade rumgespielt an den Einstellungen (Hab ne Logitech Funkmaus /-Tastatur) in SetPoint.
Beschleunigung auf Aus und Sensibilität auf Niedrig. Nix. Geht immer noch nicht. Selbst über nen Timer müsste dies doch egal sein (JvTimer über Thread) geht auch net.

_________________
cya
Tom

Nach oben

Flash

Betreff des Beitrags:

Verfasst: Do Feb 05, 2009 17:43

Guitar Hero

Registriert: Do Sep 25, 2003 15:56
Beiträge: 7810
Wohnort: Sachsen - ERZ / C
Programmiersprache: Java (, Pascal)

Interessant wäre was Windows so für Nachrichten rumschleudert, wenn deine Maus dein Formular betritt.
Für mich siehts auf alle Fälle nach einem Konfigurationsproblem aus.

DX Anwendungen gehen?

_________________
Blog: kevin-fleischer.de und fbaingermany.com

Nach oben

Sascha Willems

Betreff des Beitrags:

Verfasst: Do Feb 05, 2009 17:58

DGL Member

Registriert: Mo Sep 23, 2002 19:27
Beiträge: 5812
Programmiersprache: C++

Hast du den DualCore Optimizer von AMD installiert? Für XP braucht man den wenn man einen X2 benutzt. Ohne den hatte ich früher (habe inzwischen Vista x64 am Laufen) auch Timingprobleme wenn ich z.B. OnIdle genutzt hab. An sich sollte ohne den keine Anwendung komplett einfrieren, aber unter XP sollte der auf jeden Fall installiert sein.

_________________
www.SaschaWillems.de | GitHub | Twitter | GPU Datenbanken (Vulkan, GL, GLES)

Nach oben

Kathmai

Betreff des Beitrags:

Verfasst: Do Feb 05, 2009 22:19

DGL Member

Registriert: Do Mai 27, 2004 15:22
Beiträge: 25
Wohnort: Stuttgart

Flash hat geschrieben:

Interessant wäre was Windows so für Nachrichten rumschleudert, wenn deine Maus dein Formular betritt.
Für mich siehts auf alle Fälle nach einem Konfigurationsproblem aus.

DX Anwendungen gehen?

Wie kann man denn rausfinden ob Windows Anwendungen mit messages bomardiert?
DX Progs funzen ohne Probleme. OpenGL auch aber nur mit API - bei VCL kackts ab.

Sascha Willems hat geschrieben:

Ja hab ich jetzt. Keine Veränderung - gleiches Problem.

Hab jetzt mal weiter getestet...

Bitte schaut Euch mal wenns keine Umstände macht zwei Codes an (komplette Codes von 2 Beispielen mit VCL Code was funktioniert und eines was nicht funktioniert).

1. Codebeispiel. Selcetiontut VCL funktioniert. mit TAppEvent

Code:

//==============================================================================
// Selection tutorial
// 2002-2004 by Sascha Willems
// http://www.delphigl.de
//==============================================================================
// Updated 19.01.2004 :
//  - Renamed TForm1 to TGLForm
//  - Replaced OpenGL12.pas with dglOpenGL.pas (GL1.5)
//  - DC and RC now released on destroy
//==============================================================================
unit selection1;
 
interface
 
uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, dglOpenGL, AppEvnts, GLBmp, ExtCtrls, StdCtrls;
 
type
  TGLForm = class(TForm)
    ApplicationEvents1: TApplicationEvents;
    Timer1: TTimer;
    Panel1: TPanel;
    Timer2: TTimer;
    Label1: TLabel;
    Label2: TLabel;
    Label3: TLabel;
    procedure FormCreate(Sender: TObject);
    procedure ApplicationEvents1Idle(Sender: TObject; var Done: Boolean);
    procedure Timer1Timer(Sender: TObject);
    procedure FormResize(Sender: TObject);
    procedure Timer2Timer(Sender: TObject);
    procedure FormClick(Sender: TObject);
    procedure FormMouseMove(Sender: TObject; Shift: TShiftState; X,
      Y: Integer);
    procedure FormDestroy(Sender: TObject);
  private
  public
    FDC    : HDC;
    FRC    : HGLRC;
    List   : Cardinal;
    yrot   : TGLFloat;
    Frames : Integer;
    mx,my  : Word;
    function GetSelectBufferHit : Integer;
    procedure GLInit;
    procedure LoadTextures;
    procedure DrawScene;
  end;
 
var
  Texture     : array[0..4] of TGLBmp;
  GLForm      : TGLForm;
  DisplayList : array[0..3] of Cardinal;
  Rotation    : array[0..3] of TGLFloat;
  SelfRot     : array[0..3] of TGLFloat;
 
const
 // These are names for our planets to use for selection
 Sun   = 0;
 Mars  = 1;
 Earth = 2;
 Moon  = 3;
 
implementation
 
{$R *.dfm}
 
// =============================================================================
// Generates a Sphere and returns the number of the displaylist
// =============================================================================
function CreateSphere(CX, CY, CZ, Radius : TGLFloat; N : Integer) : Cardinal;
var
 i,j                  : Integer;
 theta1,theta2,theta3 : TGLFloat;
 X, Y, Z, px, py, pz  : TGLFloat;
begin
Result := glGenLists(1);
glNewList(Result, GL_COMPILE);
if Radius < 0 then
 Radius :=-Radius;
if n < 0 then
 n := -n;
if (n < 4) or (Radius <= 0) then
 begin
 glBegin(GL_POINTS);
  glVertex3f(CX, CY, CZ);
 glEnd;
 exit;
 end;
for j := 0 to n div 2 -1 do
 begin
 theta1 := J*2*PI/N - PI/2;
 theta2 := (J+1)*2*PI/n - PI/2;
 glBegin(GL_QUAD_STRIP);
 for i := 0 to n do
  begin
  theta3 := i*2*PI/N;
  x := cos(theta2) * cos(theta3);
  y := sin(theta2);
  z := cos(theta2) * sin(theta3);
  px := CX + Radius*x;
  py := CY + Radius*y;
  pz := CZ + Radius*z;
  glNormal3f(X,Y,Z);
  glTexCoord2f(1-I/n, 2*(J+1)/n);
  glVertex3f(px,py,pz);
  X := cos(theta1) * cos(theta3);
  Y := sin(theta1);
  Z := cos(theta1) * sin(theta3);
  px := CX + Radius*X;
  py := CY + Radius*Y;
  pz := CZ + Radius*Z;
  glNormal3f(X,Y,Z);
  glTexCoord2f(1-i/n, 2*j/n);
  glVertex3f(px,py,pz);
  end;
 glEnd;
 end;
glEndList;
end;
 
procedure TGLForm.FormCreate(Sender: TObject);
begin
InitOpenGL;
// Get a handle from our Window
FDC := GetDC(Handle);
// Generate our rendering context with a color depth of 32Bpp
FRC := CreateRenderingContext(FDC, [opDoubleBuffered], 32, 24, 0, 0, 0, 0);
ActivateRenderingContext(FDC, FRC);
Frames := 0;
GLInit;
LoadTextures;
end;
 
// =============================================================================
// Sets up all needed OpenGL properties
// =============================================================================
procedure TGLForm.GLInit;
var
 nStackDepth : TGLUInt;
begin
glEnable(GL_TEXTURE_2D);
glEnable(GL_DEPTH_TEST);
glEnable(GL_LIGHTING);
glEnable(GL_COLOR_MATERIAL);
glLightModeli(GL_LIGHT_MODEL_LOCAL_VIEWER, GL_TRUE);
DisplayList[0] := CreateSphere(0,0,0,48,100); // Sun
DisplayList[1] := CreateSphere(0,0,0,16,100); // Mars
DisplayList[2] := CreateSphere(0,0,0,20,100); // Earth
DisplayList[3] := CreateSphere(0,0,0,8,75);   // Moon
glGetIntegerV(GL_MAX_NAME_STACK_DEPTH, @nStackDepth);
Label3.Caption := 'Depth of Name Stack : '+IntToStr(nStackDepth);
end;
 
// =============================================================================
// Loads all needed textures
// =============================================================================
procedure TGLForm.LoadTextures;
const
 Name : array[0..4] of String = ('sun','mars','earth','moon','space');
var
 i : Integer;
begin
for i := 0 to High(Name) do
 begin
 Texture[i] := TGLBmp.Create;
 Texture[i].LoadImage(Name[i]+'.jpg');
 Texture[i].GenTexture(False,False);
 end;
end;
 
// =============================================================================
// Draws the Scene
// =============================================================================
procedure TGLForm.DrawScene;
const
 Position   : array[0..3] of TGLFLoat = (0, 0, 0, 0);
 Ambient    : array[0..3] of TGLFloat = (0.3, 0.3, 0.3, 0);
 Diffuse    : array[0..3] of TGLFloat = (0.8, 0.8, 0.8, 0);
 Specular   : array[0..3] of TGLFloat = (0.8, 0.8, 0.8, 0);
 mSpecular  : array[0..3] of TGLFloat = (1.0, 1.0, 1.0, 1.0);
 mShininess : TGLFloat = 10.0;
begin
glMatrixMode(GL_MODELVIEW);
glClear(GL_DEPTH_BUFFER_BIT or GL_COLOR_BUFFER_BIT);
glLoadIdentity;
glMaterialfv(GL_FRONT, GL_SPECULAR, @mSpecular);
glMaterialfv(GL_FRONT, GL_SHININESS, @mShininess);
// Enable one Light and set it's properties
glEnable(GL_LIGHTING);
glEnable(GL_LIGHT0);
glLightfv(GL_LIGHT0, GL_POSITION, @Position);
glLightfv(GL_LIGHT0, GL_AMBIENT, @Ambient);
glLightfv(GL_LIGHT0, GL_DIFFUSE, @Diffuse);
glLightfv(GL_LIGHT0, GL_SPECULAR, @specular);
glTranslatef(0,0,-500);
glInitNames;
glPushName(0);
// Sun
glLoadName(Sun);       // Push the ID of the sun on the namestack
Texture[0].Bind;
glPushMatrix;
glRotatef(SelfRot[0], 0, 1, 0);
glCallList(DisplayList[0]);
glPopMatrix;
// Mars
glLoadName(Mars);       // Push the ID of the mars on the namestack
Texture[1].Bind;
glPushMatrix;
glRotatef(Rotation[1], 0, 1, 0);
glTranslatef(0,0,100);
glRotatef(SelfRot[1], 0, 1, 0);
glCallList(DisplayList[1]);
glPopMatrix;
// Earth
glLoadName(Earth);       // Push the ID of the earth on the namestack
Texture[2].Bind;
glPushMatrix;
glRotatef(Rotation[2], 0, 1, 0);
glTranslatef(0,0,200);
glRotatef(SelfRot[2], 0, 1, 0);
glCallList(DisplayList[2]);
// Moon
glLoadName(Moon);       // Push the ID of the moon on the namestack
Texture[3].Bind;
glRotatef(Rotation[3], 0, 1, 0);
glTranslatef(0,0,35);
glCallList(DisplayList[3]);
glPopMatrix;
// Background
// Note that you need to load another name on the stack.Otherwise
// the background would have the same name attached to as the moon!
glLoadName(1000);
Texture[4].Bind;
glBegin(GL_QUADS);
 glTexCoord2f(0, 0); glVertex3f(-470,  -350, -300);
 glTexCoord2f(0, 2); glVertex3f(-470,   350, -300);
 glTexCoord2f(2, 2); glVertex3f( 470,   350, -300);
 glTexCoord2f(2, 0); glVertex3f( 470,  -350, -300);
glEnd;
SwapBuffers(FDC);
end;
 
procedure TGLForm.ApplicationEvents1Idle(Sender: TObject;
  var Done: Boolean);
begin
DrawScene;
Done := False;
inc(Frames);
end;
 
procedure TGLForm.Timer1Timer(Sender: TObject);
var
 i : Integer;
begin
SelfRot[0]  := SelfRot[0]+0.1;  // Sun
SelfRot[1]  := SelfRot[1]+1;    // Mars
SelfRot[2]  := SelfRot[2]+1;    // Earth
SelfRot[3]  := SelfRot[3]+1;    // Moon
for i := 0 to High(SelfRot) do
 if SelfRot[i] > 360 then
  SelfRot[i] := 0;
Rotation[3] := Rotation[3]-2.5; // Moon
Rotation[2] := Rotation[2]+0.5; // Earth
Rotation[1] := Rotation[1]+0.3; // Mars
for i := 0 to High(Rotation) do
 begin
 if Rotation[i] > 360 then
  Rotation[i] := 0;
 if Rotation[i] < 0 then
  Rotation[i] := 360;
 end;
end;
 
procedure TGLForm.FormResize(Sender: TObject);
begin
if HandleAllocated then
 begin
 glViewport(0, 0, ClientWidth, ClientHeight);
 glMatrixMode(GL_PROJECTION);
 glLoadIdentity;
 gluPerspective(45, ClientWidth/ClientHeight, 0.1, 1000);
 end;
end;
 
procedure TGLForm.Timer2Timer(Sender: TObject);
begin
Caption := 'www.DelphiGL.de -Tutorial no.3 - Selection - '+IntToStr(Frames)+' FPS';
Frames := 0;
end;
 
function TGLForm.GetSelectBufferHit : Integer;
var
 SelectBuffer : array[0..512] of TGLUInt;
 Viewport     : TGLArrayi4;
 Hits,i       : Integer;
 HitZValue    : TGLUInt;
 Hit          : TGLUInt;
begin
// Store our Viewport
glGetIntegerv(GL_VIEWPORT, @viewport);
// Tell OpenGL the size of our select buffer
glSelectBuffer(512, @SelectBuffer);
// Change our render mode to GL_SELECT
glRenderMode(GL_SELECT);
// Init the namestack
glInitNames;
glPushName(0);
glMatrixMode(GL_PROJECTION);
glPushMatrix;
glLoadIdentity;
// Zoom the view to one pixel around the mouse position
gluPickMatrix(mx, viewport[3]-my, 1.0, 1.0, viewport);
gluPerspective(45.0, ClientWidth/ClientHeight, 0.1, 1000);
// Now we draw our scene in the select render mode
DrawScene;
glMatrixMode(GL_PROJECTION);
glPopMatrix;
// Now store the number of hits in Hits
Hits := glRenderMode(GL_RENDER);
// Now we look which hit has the lowest Z-Value i.e. was in front
Hit       := High(TGLUInt);
HitZValue := High(TGLUInt);
for i := 0 to Hits-1 do
 if SelectBuffer[(i*4)+1] < HitZValue then
  begin
  Hit       := SelectBuffer[(i*4)+3];
  HitZValue := SelectBuffer[(i*4)+1];
  end;
Result := Hit;
end;
 
procedure TGLForm.FormClick(Sender: TObject);
var
 Hit : Integer;
begin
Hit := GetSelectBufferHit;
case Hit of
 0 : Label2.Caption := 'sun';
 1 : Label2.Caption := 'mars';
 2 : Label2.Caption := 'earth';
 3 : Label2.Caption := 'moon';
else
 Label2.Caption := 'none';
end;
end;
 
procedure TGLForm.FormMouseMove(Sender: TObject; Shift: TShiftState; X,
  Y: Integer);
begin
mx := x;
my := y;
end;
 
procedure TGLForm.FormDestroy(Sender: TObject);
begin
DeactivateRenderingContext;
wglDeleteContext(FRC);
ReleaseDC(Handle, FDC);
end;
 
end.
 

2. Codebeispiel 2D Tutorial Nr. 2 mit der Feueranimation welches nicht funktioniert - also einfriert. Hab mal es abgeändert mit TAppEvent. Ohne Erfolg - friert auch ein. Also was ist der Unterschied bei den beiden was so gravierend ist?

Code:

unit opengl2D_demo2_MainForm;
 
interface
 
uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms,
  Dialogs,
 
  dglOpenGL,
  Textures;
 
type
  TGLForm = class(TForm)
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
    private
     { Private-Deklarationen }
    public
     procedure Render(Sender : TObject; var Done : Boolean);
   end;
 
  TVertex = record
    x,y,z : Single;
   end;
 
const
 // Hier definieren wie die virtuellen Ausmaße unserer 2D-Ansicht
 // Dadurch das diese Werte fest sind, müssen wir nicht bei abweichender
 // Auflösung die Koordinaten umrechnen.
 SizeX   : Integer = 640;
 SizeY   : Integer = 480;
 // Hier legen wir fest wie unsere Animationstextur aussieht. Wenn man Texturen
 // dynamisch lädt sollte man deren Aufbau irgendwo aus einer Textdatei laden
 AnimCols : Integer = 4;
 AnimRows : Integer = 4;
 
 MaxSize : Integer =   3;
 
var
 GLForm     : TGLForm;
 DC         : HDC;
 RC         : HGLRC;
 QPCFreq    : Int64;
 TimeFactor : Single;
 
 AnimTex    : glUInt;
 AnimX      : Single;
 AnimY      : Single;
 AnimPos    : Single;
 
implementation
 
{$R *.dfm}
 
// =============================================================================
//   TGLForm
// =============================================================================
 
// =============================================================================
//   TGLForm.FormCreate
// =============================================================================
procedure TGLForm.FormCreate(Sender: TObject);
begin
// Zeitmessung
QueryPerformanceFrequency(QPCFreq);
 
InitOpenGL;
DC := GetDC(Handle);
RC := CreateRenderingContext(DC, [opDoubleBuffered], 32, 24, 0, 0, 0, 0);
ActivateRenderingContext(DC, RC);
// Auch in 2D werden wir den Z-Puffer (und Tiefentest) nutzen, denn damit sparen
// wir uns das eigenhändige Sortieren von Objekten anhand ihres Layers
glEnable(GL_DEPTH_TEST);
glDepthFunc(GL_LESS);
glEnable(GL_TEXTURE_2D);
Application.OnIdle := Render;
// Die Explosionstextur laden auf der sich alle Animationsframes befinden
LoadTexture('textures\explosion.tga', AnimTex, False);
end;
 
// =============================================================================
//   TGLForm.FormDestroy
// =============================================================================
procedure TGLForm.FormDestroy(Sender: TObject);
begin
DeactivateRenderingContext;
DestroyRenderingContext(RC);
ReleaseDC(Handle, DC);
end;
 
// =============================================================================
//   TGLForm.Render
// =============================================================================
procedure TGLForm.Render(Sender : TObject; var Done : Boolean);
var
 QPCStart, QPCEnd : Int64;
begin
// Zeitmessung
QueryPerformanceCounter(QPCStart);
 
glClear(GL_COLOR_BUFFER_BIT or GL_DEPTH_BUFFER_BIT);
 
glMatrixMode(GL_PROJECTION);
glLoadIdentity;
glViewport(0,0,ClientWidth,ClientHeight);
glOrtho(0, SizeX, 0, SizeY, 0, 128);
 
glMatrixMode(GL_MODELVIEW);
glLoadIdentity;
 
glBindTexture(GL_TEXTURE_2D, AnimTex);
glEnable(GL_ALPHA_TEST);
glAlphaFunc(GL_GREATER, 0.1);
glTranslatef(320, 240, 0);
 
// Das Quad zeichnen wir jetzt von Hand, da wir ja je nach aktuellem Animationsframe
// die Texturkoordinaten ändern müssen
glEnable(GL_CULL_FACE);
glBegin(GL_QUADS);
 glTexCoord2f(AnimX,            1-AnimY-1/AnimRows);  glVertex3f(-192, -192, 0);
 glTexCoord2f(AnimX+1/AnimCols, 1-AnimY-1/AnimRows);  glVertex3f( 192, -192, 0);
 glTexCoord2f(AnimX+1/AnimCols, 1-AnimY);             glVertex3f( 192, 192, 0);
 glTexCoord2f(AnimX,            1-AnimY);             glVertex3f(-192, 192, 0);
glEnd;
 
SwapBuffers(DC);
// Zeitmessung
QueryPerformanceCounter(QPCEnd);
TimeFactor := (QPCEnd-QPCStart) / QPCFreq;
 
// Animation weiterlaufen lassen
AnimPos := AnimPos + 10 * TimeFactor;
if AnimPos > 1 then
 begin
 AnimX   := AnimX + 1/AnimRows;
 AnimPos := 0;
 end;
if AnimX >= 1 then
 begin
 AnimY := AnimY + 1/AnimCols;
 AnimX := 0;
 end;
if AnimY >= 1 then
 begin
 AnimX := 0;
 AnimY := 0;
 end;
 
Done := False;
end;
 
end.

_________________
cya
Tom

Nach oben

Kathmai

Betreff des Beitrags:

Verfasst: Do Feb 05, 2009 22:35

DGL Member

Registriert: Do Mai 27, 2004 15:22
Beiträge: 25
Wohnort: Stuttgart

@Sascha:

War bei Dir auf der Seite und hab paar Demos von Dir zum ausprobieren gezogen.

glslwater - friert ein bei Maus über dem Fenster
SimpleBump_V2 - funktioniert
MotionBlur - funktioniert

hoffe das Hilft was.

Danke im voraus!

_________________
cya
Tom

Nach oben

Sascha Willems

Betreff des Beitrags:

Verfasst: Do Feb 05, 2009 22:43

DGL Member

Registriert: Mo Sep 23, 2002 19:27
Beiträge: 5812
Programmiersprache: C++

Ich tippe auf ein Problem mit deinem System. Insgesamt wurde meine Spiele, Anwendungen und Demos sicherlich mehrere Hundertausend Male runtergeladen (und waren auch auf Heft-CDs), und bisher hat noch niemand ein solches Problem moniert. Wenn, dann waren dass i.d.R. Probleme mit deren Grafikkartentreibern die durch neue Treiber behoben wurden.

Also würde ich mal dein System genau überprüfen und aktuelle Treiber installieren. Ausserdem auch mal solche Sachen wie Cool'n'Quiet ausschalten, alle unnützen Hintergrundprozesse sowie Energiesparmaßnahmen. Wenn das nichts hilft, lad dir mal eine Linux-Live-Distro (läuft direkt von CD/DVD) und schau ob du da das selbe Problem hast.

_________________
www.SaschaWillems.de | GitHub | Twitter | GPU Datenbanken (Vulkan, GL, GLES)

Nach oben

Seite 1 von 1

[ 11 Beiträge ]

Foren-Übersicht » Programmierung » OpenGL

Wer ist online?

Mitglieder in diesem Forum: 0 Mitglieder und 4 Gäste

Du darfst keine neuen Themen in diesem Forum erstellen.
Du darfst keine Antworten zu Themen in diesem Forum erstellen.
Du darfst deine Beiträge in diesem Forum nicht ändern.
Du darfst deine Beiträge in diesem Forum nicht löschen.
Du darfst keine Dateianhänge in diesem Forum erstellen.