DGL • Thema anzeigen - Partikel Emitter tuts net Oo

Partikel Emitter tuts net Oo

Moderator: DGL-Team

Seite 1 von 1

[ 9 Beiträge ]

Vorheriges Thema | Nächstes Thema

Autor

Nachricht

Seth

Betreff des Beitrags: Partikel Emitter tuts net Oo

Verfasst: Fr Jul 28, 2006 13:16

DGL Member

Registriert: Di Mai 24, 2005 16:43
Beiträge: 710

Hi, ich habe mir einen kleinen Partikelemitter geschrieben, aber so richtig tut er es nicht.
man sollte zunächst einmal 2 keyframes angeben können (anfang und ende), die position, die richtung,
den grad der streuung, lebensdauer etc. aber ich sehe nichts, und als ich ein bild hatte, hats net so funktioniert wie es sollte und nach einiger zeit bekam ich eine fehlermeldung. jemand ne idee ?

TVector2D ist einfach ein record

Code:

 
function angle_to_v2d(angle: single): TVector2D;
begin
  result := to_v2d(cos(degtorad(angle)), sin(degtorad(angle)));
end;
 

Code:

 
// Unit ParticleEngine
(**************************************************
 
- Enthält: TParticleEmitter
 
**************************************************)
 
unit F2D_ParticleEngine;
 
interface
 
uses
  dglOpenGL,
  graphics,
  F2D_Vectors,
  F2D_Math,
  F2D_Colors,
  F2D_Core,
  F2D_Const;
 
type
  TKeyFrame = record
    velocity: single;
    alpha: single;
    size: TVector2D;
  end;
 
  TParticle = record
    dir,
    position: TVector2D;
    age: single;
  end;
 
  TParticleEmitter = class
    constructor Create(pEngine: TEngine);
    procedure Free;
  private
    FEngine: TEngine;
    FAngle,
    FEmissionAngle: integer;
    FParticle: TParticle;
    FParticles: array of TParticle;
    EmissionTime: single;
    FLifeSpan: single;
    function GetParticleCount: integer;
    procedure Add(pParticle: TParticle);
    procedure SetLifeSpan(const Value: single);
    procedure CleanUp;
    procedure SetAngle(const Value: integer);
    procedure SetEmissionAngle(const Value: integer);
    procedure NextStep;   
  public
    position: TVector2D;
    EmissionRate,
    ParticlesPerEmission: integer;
    LifeBegin,
    LifeEnd: TKeyFrame;
    Texture: string;
    Color: TColor;
    z: integer;
    property Angle: integer read FAngle write SetAngle;
    property EmissionAngle: integer read FEmissionAngle write SetEmissionAngle;
    property LifeSpan: single read FLifeSpan write SetLifeSpan;
    property NumParticles: integer read GetParticleCount;
    procedure Render;
  end;
 
implementation
 
constructor TParticleEmitter.Create(pEngine: TEngine);
begin
  inherited Create;
  FEngine := pEngine;
  setlength(FParticles, 0);
  FAngle := 0;
  FEmissionAngle := 0;
  EmissionTime := 0;
  FLifeSpan := 0;
  Emissionrate := 0;
  ParticlesPerEmission := 0;
  Color := clwhite;
  z := 0;
end;
 
function TParticleEmitter.GetParticleCount: integer;
begin
  result := length(FParticles);
end;
 
procedure TParticleEmitter.SetLifeSpan(const Value: single);
begin
  if Value > 0 then
    FLifeSpan := Value;
end;
 
procedure TParticleEmitter.CleanUp;
var
  i, j: integer;
begin
  for i := 0 to high(FParticles) do
    if FParticles[i].Age >= FLifeSpan then
    begin
      for j := i to high(FParticles) - 1 do
        FParticles[j] := FParticles[j + 1];
      setlength(FParticles, length(FParticles) - 1);
    end;
end;
 
procedure TParticleEmitter.Add(pParticle: TParticle);
begin
  setlength(FParticles, length(FParticles) + 1);
  FParticles[high(FParticles)] := pParticle;
end;
 
procedure TParticleEmitter.Free;
begin
  if Self <> nil then
    Destroy;
end;
 
procedure TParticleEmitter.SetAngle(const Value: integer);
begin
  if (Value >= 360) OR (Value <= -360) then
  begin
    FAngle := 0;
    Exit;
  end;
  if Value < 0 then
  begin
    FAngle := 360 + Value;
    Exit;
  end;
 
  FAngle := Value;
end;
 
procedure TParticleEmitter.SetEmissionAngle(const Value: integer);
begin
  if (Value >= 360) OR (Value <= -360) then
  begin
    FEmissionAngle := 0;
    Exit;
  end;
  if Value < 0 then
  begin
    FEmissionAngle := 360 + Value;
    Exit;
  end;
 
  FEmissionAngle := Value;
end;
 
procedure TParticleEmitter.NextStep;
var
  i, c: integer;
  vel: single;
begin
  //Emissionszeit erhöhen
  EmissionTime := EmissionTime + FEngine.Timestep;
  //Partikel Emittieren
  if round(EmissionTime / EmissionRate) = 0 then
    for c := 1 to ParticlesPerEmission do
    begin
      with FParticle do
      begin
        dir := v2d_normalize(angle_to_v2d(random(EmissionAngle) - 90 + Angle));
        age := 0;
      end;
      FParticle.position := position;
      Add(FParticle);    
      EmissionTime := 0;
    end;
  //Bewegen
  for i := 0 to high(FParticles) do
    with FParticles[i] do
    begin
      age := age + FEngine.Timestep;
      vel := (age * (LifeEnd.velocity - LifeBegin.velocity)) / FLifeSpan;
      position.x := position.x + dir.x * vel;
      position.y := position.y + dir.y * vel;
    end;
  CleanUp;
end;
 
procedure TParticleEmitter.Render;
var
  i: integer;
  TmpWidth, TmpHeight: Extended;
  size: TVector2D;
  alpha: single;
begin
  NextStep;
  glPushMatrix;
 
  for i := 0 to high(FParticles) do
  begin
   alpha := (FParticles[i].age * (LifeEnd.alpha - LifeBegin.alpha)) / FLifeSpan;
 
    // Matrix auf die Zeichenposition setzen
    glTranslatef(FParticles[i].Position.X * (FEngine.Form.ClientWidth / FEngine.Width),
                 FParticles[i].Position.Y * (FEngine.Form.ClientHeight / FEngine.Height), 0);
 
    FEngine.TextureManager.BindTexture(Texture);
 
    RGBAf(Color, round(alpha));
    glBlendFunc(GL_SRC_ALPHA, GL_ONE);
    glEnable(GL_BLEND);
 
    size.x := (FParticles[i].age * (LifeEnd.size.x - LifeBegin.size.x)) / FLifeSpan;
    size.y := (FParticles[i].age * (LifeEnd.size.y - LifeBegin.size.y)) / FLifeSpan;
 
    TmpWidth  := (Size.X * (FEngine.Form.ClientWidth  / FEngine.Width))  / 2;
    TmpHeight := (Size.Y * (FEngine.Form.ClientHeight / FEngine.Height)) / 2;
 
    glBegin(GL_QUADS);
      glTexCoord2f(0,1); glVertex3f(-TmpWidth, -TmpHeight, Z - MaxDepth + 2);
      glTexCoord2f(1,1); glVertex3f( TmpWidth, -TmpHeight, Z - MaxDepth + 2);
      glTexCoord2f(1,0); glVertex3f( TmpWidth,  TmpHeight, Z - MaxDepth + 2);
      glTexCoord2f(0,0); glVertex3f(-TmpWidth,  TmpHeight, Z - MaxDepth + 2);
    glEnd;
  end;
 
  glDisable(GL_BLEND);
 
  glPopMatrix;
end;
 
Initialization
  randomize;
 
end.
 

und die Engine liefert nur timestep und streckung für die fenster, sonst ist der code halbwegs eigenständig.

mfg und danke, ich bin irgendwie schon total am verzweifeln

Nach oben

i0n0s

Betreff des Beitrags:

Verfasst: Fr Jul 28, 2006 13:42

Ernährungsberater

Registriert: Sa Jan 01, 2005 17:11
Beiträge: 2068
Programmiersprache: C++

Vielleicht solltest du uns noch verraten, was für eine Fehlermeldung kommt, und an welcher Stelle sie auftritt.
Auch halte ich den Code hier für riskant:

Code:

for i := 0 to high(FParticles) do
    if FParticles[i].Age >= FLifeSpan then
    begin
        for j := i to high(FParticles) - 1 do
        FParticles[j] := FParticles[j + 1];
        setlength(FParticles, length(FParticles) - 1);
    end;

Hier hängt es wirklich vom (intelligenten) Compiler ab, ob der Code so läuft.

Und könnte es sein, dass du einfach Size zu klein und MaxDepth zu gross gewählt hast?

Nach oben

The-Winner

Betreff des Beitrags:

Verfasst: Fr Jul 28, 2006 14:32

DGL Member

Registriert: Di Jun 06, 2006 09:59
Beiträge: 474

i0n0s hat geschrieben:

Vielleicht solltest du uns noch verraten, was für eine Fehlermeldung kommt, und an welcher Stelle sie auftritt.
Auch halte ich den Code hier für riskant:

Code:

for i := 0 to high(FParticles) do
    if FParticles[i].Age >= FLifeSpan then
    begin
        for j := i to high(FParticles) - 1 do
        FParticles[j] := FParticles[j + 1];
        setlength(FParticles, length(FParticles) - 1);
    end;

Also in Delphi wird der Code wohl kaum wie erwünscht funktionieren, da die Parameter von FOR-Schleifen nur einmal berechnet werden. Er würde wohl funktionieren wenn du die erste schleife auf rückwärtszählen ändern würdest.
Trotzdem ist der Algo so nicht gerade effizient (O(N^2)) und dazu noch viele SetLength.

Probier mal folgendes (Achtung ungetestet), sollte aber funzen

Code:

 
j:=0;
for i:=0 to high(FParticles)do
 if FParticles[i].Age<FLifeSpan then
  begin
   FParticles[j]:=FParticles[i];
   inc(j);
  end;
setlength(FParticles,j);
 

Nach oben

Seth

Betreff des Beitrags:

Verfasst: Fr Jul 28, 2006 15:27

DGL Member

Registriert: Di Mai 24, 2005 16:43
Beiträge: 710

i0n0s hat geschrieben:

Vielleicht solltest du uns noch verraten, was für eine Fehlermeldung kommt, und an welcher Stelle sie auftritt.
Auch halte ich den Code hier für riskant:

Code:

for i := 0 to high(FParticles) do
    if FParticles[i].Age >= FLifeSpan then
    begin
        for j := i to high(FParticles) - 1 do
        FParticles[j] := FParticles[j + 1];
        setlength(FParticles, length(FParticles) - 1);
    end;

Hier hängt es wirklich vom (intelligenten) Compiler ab, ob der Code so läuft.

Und könnte es sein, dass du einfach Size zu klein und MaxDepth zu gross gewählt hast?

im moment tritt kein fehler auf, und ich dachte mir, dass diese stelle probleme macht, ich werde mal the-winners lösung testen

//EDIT: habs getestet, leider immer noch nichts zu sehen, das setup sieht so aus:

Code:

 
  Emitter := TParticleEmitter.Create(Engine);
  with Emitter do
  begin
    position := to_v2d(Engine.width / 2, Engine.Height / 2);
    angle := 0;
    emissionangle := 180;
    Emissionrate := 5000;
    ParticlesPerEmission := 12;
    Texture := 'spark';
    LifeSpan := 5000;
 
    with LifeBegin do
    begin
      velocity := 100;
      alpha := 255;
      size := to_v2d(25, 25);
    end;
 
    with LifeEnd do
    begin
      velocity := 0;
      alpha := 0;
      size := to_v2d(25, 25);
    end;
    
  end;
 

und an size und maxdepth liegt es nicht, da diese auch bei normalen objekten funktionieren,
korrekterweise muss beim zeichnen auch ein z / maxdepth + 1 dahin, statt + 2
maxdepth ist 512

man merkt aber, wie der emitter zunehmend fps schluckt und letztenendes konstant bleibt, nur irgendetwas
stimmt net....

es liegt an der interpolation von LifeBegin und LifeEnd, wenn ich das weglasse, funktioniert es zum teil, die größe ist dann einfach zu klein

Code:

 
    size.x := (FParticles[i].age * (LifeEnd.size.x - LifeBegin.size.x)) / FLifeSpan;
    size.y := (FParticles[i].age * (LifeEnd.size.y - LifeBegin.size.y)) / FLifeSpan;
 
    TmpWidth  := (Size.X * (FEngine.Form.ClientWidth  / FEngine.Width))  / 2;
    TmpHeight := (Size.Y * (FEngine.Form.ClientHeight / FEngine.Height)) / 2;

hier gibts das komplette projekt zum download:

http://www.exec-dev.de/ParticleEngine.zip

manchmal sieht man sogar viele partikel, aber das ist alles net so wie gewollt

Nach oben

Seth

Betreff des Beitrags:

Verfasst: Mo Jul 31, 2006 12:54

DGL Member

Registriert: Di Mai 24, 2005 16:43
Beiträge: 710

ich stehe leider immernoch ratlos davor und weiß net, was ich noch machen soll :/

Nach oben

i0n0s

Betreff des Beitrags:

Verfasst: Mo Jul 31, 2006 15:33

Ernährungsberater

Registriert: Sa Jan 01, 2005 17:11
Beiträge: 2068
Programmiersprache: C++

Also ohne Doku gehe ich deinen Code nicht weiter durch.
Aber das ist mir bisher aufgefallen:

Code:

  glPushMatrix;
 
  for i := 0 to high(FParticles) do
  begin
   .
   // Matrix auf die Zeichenposition setzen
    glTranslatef(FParticles[i].Position.X * (FEngine.Form.ClientWidth / FEngine.Width),
                 FParticles[i].Position.Y * (FEngine.Form.ClientHeight / FEngine.Height), 0);
   .
   .
   .
  end;
   .
  glPopMatrix;

Ist natürlich die perfekte Routine um die Position der Partikel zu setzen. Oder hängen die alle relativ von ihrem Vorgänger ab?

Nach oben

Seth

Betreff des Beitrags:

Verfasst: Mo Jul 31, 2006 15:42

DGL Member

Registriert: Di Mai 24, 2005 16:43
Beiträge: 710

ich verstehe nicht genau was du meinst, das translaten mache ich damit sich die größe am ende der fenstergröße anpasst, man kann dafür auch glScalef nehmen, aber ich hab das erstmal so gemacht.

ich denke probleme macht sowas hier:

Code:

 
(FParticles[i].age * (LifeEnd.size.x - LifeBegin.size.x)) / FLifeSpan
 

man gibt ja die größe / geschwindigkeit etc für anfang und ende des lebens eines partikels an, und jetzt soll eben anhand des alters des partikels, die geschwindigkeit etc interpoliert werden, beispiel:

geg:
geschwindigkeit am anfang: 100

geschwindigkeit am ende: 0

lebensdauer: 1000 ms

ges:

geschwindigkeit zum zeitpunkt X

bei 500ms wäre das dann 50

eine dokumentation gibts, wenn das alles fertig ist, bzw wenn text und partikel engine funzen, dann schreiben ich noch ein paar samples und dokumentier den ganzen kram, ich kann aber in die partikel unit noch ein paar kommentare setzen

Nach oben

i0n0s

Betreff des Beitrags:

Verfasst: Mo Jul 31, 2006 15:45

Ernährungsberater

Registriert: Sa Jan 01, 2005 17:11
Beiträge: 2068
Programmiersprache: C++

Seth hat geschrieben:

ich verstehe nicht genau was du meinst, das translaten mache ich damit sich die größe am ende der fenstergröße anpasst, man kann dafür auch glScalef nehmen, aber ich hab das erstmal so gemacht.

Du hast 2 Partikel. Das erste wird korrekt mit Abstand vom Ursprung gezeichnet (mit deiner Skalierung). Das zweite wird aber nicht mehr korrekt gezeichnet, da es nicht vom Ursprung aus verschoben wird, sondern von der Position des ersten Partikels.
Daher wirst du wohl alle Partikel gezeichnet haben, nur sind diese irgendwo im nichtsichtbaren Bereich.

Nach oben

Seth

Betreff des Beitrags:

Verfasst: Mo Jul 31, 2006 15:51

DGL Member

Registriert: Di Mai 24, 2005 16:43
Beiträge: 710

ups, ich sehe, push und popmatrix müssen in die schleife ^^ ok hätten wir das gelöst ^^ dann fehlen noch die interpolationen
und bewegen tut sich auch grad nichts, aber wir werden sehen ^^

EDIT: ja es lag an der berechnung, es fehlte überall noch ein LifeBegin + davor

hier gibts jetzt ne schöne demo zu sehen: http://www.exec-dev.de/

Nach oben

Seite 1 von 1

[ 9 Beiträge ]

Foren-Übersicht » Programmierung » Allgemein

Wer ist online?

Mitglieder in diesem Forum: 0 Mitglieder und 7 Gäste

Du darfst keine neuen Themen in diesem Forum erstellen.
Du darfst keine Antworten zu Themen in diesem Forum erstellen.
Du darfst deine Beiträge in diesem Forum nicht ändern.
Du darfst deine Beiträge in diesem Forum nicht löschen.
Du darfst keine Dateianhänge in diesem Forum erstellen.