DGL • Thema anzeigen - WinAPI und Function in Klasse

WinAPI und Function in Klasse

Moderator: DGL-Team

Seite 1 von 1

[ 3 Beiträge ]

Vorheriges Thema | Nächstes Thema

Autor

Nachricht

Thunderman

Betreff des Beitrags: WinAPI und Function in Klasse

Verfasst: Sa Mär 27, 2004 22:41

DGL Member

Registriert: Sa Okt 26, 2002 17:14
Beiträge: 188
Wohnort: Hannover/Lüneburg

Hallo!

Ich schreibe gerade meinen Basecode neu auf Basis einer ebsseren Objekt-Orientierten Struktur. Dabei benutze ich weiterhin nicht die VCL, sondern die reine WinAPI bzw. Xlib unter Linux. Nun habe ich das "Problem", dass ich für ein Fenster ja eine Function zur Message-Behandlung brauche:

Code:

function WndProc(hWnd: HWND; Msg: UINT; wParam: WPARAM; lParam: LPARAM): LRESULT; stdcall;

Diese würde ich aber gerne in meine Klasse integrieren, also etwa TFensterklasse.WndProc... Dabei stellt sich das Problem, dass diese dann zwar aufgerufen wird, aber nur 3x mit dem Wert 0 für Msg und das Fenster nicht erstellt werden kann. Ich musste das ganze so lösen, damit er überhaupt erstmal compilierte:

Code:

type
  TWndProc = function (hWnd: HWND; Msg: UINT; wParam: WPARAM; lParam: LPARAM): LRESULT of object; stdcall;
 
...
 
  TFenster = class(TComponent)
  private
    FWndProc : TWndProc;
    ...
  public
    function WndProc(hWnd: HWND; Msg: UINT; wParam: WPARAM; lParam: LPARAM): LRESULT; stdcall;
  end;
 
...
 
procedure TFenster.Initialize;
  ...
  FWndProc := WndProc;
  with FwndClass do begin
    ...
    lpfnWndProc   := @FWndProc;
    ...
  end;
  ...
end;
 
...
 
function TFenster.WndProc(hWnd: HWND; Msg: UINT; wParam: WPARAM; lParam: LPARAM): LRESULT; stdcall;
...

Gibt es eine Möglichkeit, das innerhalb einer Klasse zu lösen, oder muss ich den etwas uneleganteren Weg gehen, die Function außerhalb der Klasse zu definieren und aus ihr eine Funktion innerhalb der Klasse aufzurufen?

_________________
Thunderman
Bei schwierigen Problemen entscheiden wir uns einfach für die richtige Lösung. Klar?

Nach oben

LarsMiddendorf

Betreff des Beitrags:

Verfasst: So Mär 28, 2004 00:05

DGL Member

Registriert: Sa Dez 28, 2002 11:13
Beiträge: 2244

Methoden haben noch den impliziten Self Parameter und deshalb besteht ein Zeiger auf eine Methode (procedure of object) auch aus der Objektreferenz und dem Zeiger auf die Methode. Daher kann diese Methode nicht direkt wie eine normale Funktion aufgerufen werden.

Die Funktion MakeObjectInstance aus der Unit Forms erzeugt für eine Methode einen kurzen Code Block, der zusätzlich noch den Self Parameter auf den Stack legt:

function MakeObjectInstance(Method: TWndMethod): Pointer;

Mit FreeObjectInstance gibt man das wieder frei.

procedure FreeObjectInstance(ObjectInstance: Pointer);

Das kann man aber auch auf ähnliche Art und Weise selber machen.
Dazu fügt man folgenden Assembler Code ein:

Code:

pop edx;
push Objectreferenz;
mov eax,Sprungaddresse;
push edx;
jmp eax;

EAX und EDX können bei stdcall Aufrufen sowieso verändert werden. Daher ist das kein Problem. Das ganze speichert man am besten in einem Record:

Code:

 PJMPFunc=^TJMPFunc;
 TJMPFunc=packed record
  popedx:byte;
  push:byte;
  obj:TObject;
  mov:byte;
  target:pointer;
  pushedx:byte;
  jmp:word;
 end;
 
function MakeObjectInstance(m:TMethod):Pointer;
var
 func:PJMPFunc;
 obj:TObject;
 p:pointer;
begin
obj:=m.data;
p:=m.code;
func:=VirtualAlloc(nil,sizeof(TJMPFunc),MEM_COMMIT,PAGE_EXECUTE_READWRITE);
func.popedx:=$5A;
func.push:=$68;
func.obj:=obj;
func.mov:=$B8;
func.target:=p
func.pushedx:=$52;
func.jmp:=$E0FF;
result:=func;
end;
 
procedure FreeObjectInstance(p:pointer);
begin
VirtualFree(p,0,MEM_RELEASE);
end;
 

Man muß hierbei VirtualAlloc benutzen weil bei Speicher, der mit GetMem belegt wird, das Execute Bit nicht gesetzt wird und das sonst bei neueren Prozessoren Probleme bereiten würde.

Nach oben

Thunderman

Betreff des Beitrags:

Verfasst: So Mär 28, 2004 00:30

DGL Member

Registriert: Sa Okt 26, 2002 17:14
Beiträge: 188
Wohnort: Hannover/Lüneburg

Danke, funktioniert einwandfrei.

_________________
Thunderman
Bei schwierigen Problemen entscheiden wir uns einfach für die richtige Lösung. Klar?

Nach oben

Seite 1 von 1

[ 3 Beiträge ]

Foren-Übersicht » Programmierung » Allgemein

Wer ist online?

Mitglieder in diesem Forum: 0 Mitglieder und 9 Gäste

Du darfst keine neuen Themen in diesem Forum erstellen.
Du darfst keine Antworten zu Themen in diesem Forum erstellen.
Du darfst deine Beiträge in diesem Forum nicht ändern.
Du darfst deine Beiträge in diesem Forum nicht löschen.
Du darfst keine Dateianhänge in diesem Forum erstellen.