DGL • Thema anzeigen - glUseProgramObjectARB und GL_INVALID

glUseProgramObjectARB und GL_INVALID_OPERATION

Moderator: DGL-Team

Seite 1 von 1

[ 8 Beiträge ]

Druckansicht

Vorheriges Thema | Nächstes Thema

Autor

Nachricht

Blechwolf

Betreff des Beitrags: glUseProgramObjectARB und GL_INVALID_OPERATION

Verfasst: Mo Jun 20, 2005 09:54

DGL Member

Registriert: Fr Nov 12, 2004 14:58
Beiträge: 76
Wohnort: Aachen

Salut,

ich habe das Problem, das mein Proggi beim Aufruf von glUseProgramObjectARB eine GL_INVALID_OPERATION wirft.

Ein Blick ins WIKI zeigt mir folgende Möglichkeiten:

Zitat:

GL_INVALID_OPERATION wird generierrt wenn programObj nicht vom Typ GL_PROGRAM_OBJECT_ARB ist.
GL_INVALID_OPERATION wird generiert wenn das Programm nicht installiert werden konnte.
GL_INVALID_OPERATION wird generiert wenn glUseProgramObjectARB zwischen einem glBegin und dem zugehörigen glEnd aufgerufen wird.

Die letzte Möglichkeit kann ich definitiv ausschliessen. Die beiden anderen nicht zu 100%. Eigentlich sollte dann ja das folgende nicht passieren:

Ein Aufruf von

Code:

 
glValidateProgramARB(SlangProg);
glGetObjectParameterivARB(SlangProg,GL_OBJECT_VALIDATE_STATUS_ARB,@Validate);

gibt mir aber in der Variable Validate eine 1 zurück. (1 = TRUE = Valid) und das GLSL InfoLog ist auch leer.

Der Shader wird ordnungsgemäß gelinkt (zumindest ohne Fehlermeldung). Auch mit glIsValidate von 3DLabs meldet er keine Probleme.

Kann ich irgendwie rausbekommen, warum der sowas macht?

So sieht es aus wenn ich den Shader erzeuge:

Code:

 
SlangProg := glCreateProgramObjectARB();
VertSlang := glCreateShaderObjectARB(GL_VERTEX_SHADER_ARB);
FragSlang := glCreateShaderObjectARB(GL_FRAGMENT_SHADER_ARB);
 
VertLength := Length(GLSL_VERT_COORDINATE);
FragLength := Length(GLSL_FRAG_SHADERMAP);
 
glShaderSourceARB(VertSlang,1,@GLSL_VERT_COORDINATE,@VertLength);
glShaderSourceARB(FragSlang,1,@GLSL_FRAG_SHADERMAP,@FragLength);
 
glCompileShaderARB(VertSlang);
ShowMessage(glSlang_GetInfoLog(VertSlang));
glCompileShaderARB(FragSlang);
ShowMessage(glSlang_GetInfoLog(FragSlang));
 
glAttachObjectARB(SlangProg,VertSlang);
glAttachObjectARB(SlangProg,FragSlang);
 
glDeleteObjectARB(VertSlang);
glDeleteObjectARB(FragSlang);
 
glLinkProgramARB(SlangProg);
ShowMessage(glSlang_GetInfoLog(SlangProg));
 

Hier wird er aufgerufen und mit Variablen gefüttert:

Code:

 
glValidateProgramARB(SlangProg);
glGetObjectParameterivARB(SlangProg,GL_OBJECT_VALIDATE_STATUS_ARB,@Validate);
 
Mesg := glSlang_GetInfoLog(SlangProg);
if Mesg <> '' then
  ShowMessage(Mesg);
 
glUseProgramObjectARB(SlangProg);
 
glUniform1iARB(glGetUniformLocationARB(SlangProg,PGLCharARB('DataTexture')),0);
glUniformMatrix4fvARB(glGetUniformLocationARB(SlangProg,PGLCharARB('CM')),16,false,PGLFloat(@CM));
glUniform4fARB(glGetUniformLocationARB(SlangProg,PGLCharARB('kd')),1.0,1.0,1.0,1.0);
glUniform4fARB(glGetUniformLocationARB(SlangProg,PGLCharARB('Ia')),0.0,0.0,0.0,0.0);
 

Und das sind die zwei Shader:

Vertex Shader: (GLSL_VERT_COORDINATE)

Code:

 
void main(void) {
    vec4 EyeVertex = gl_ModelViewMatrix*gl_Vertex;
    gl_TexCoord[0].s = dot( EyeVertex, gl_EyePlaneS[0] );
    gl_TexCoord[0].t = dot( EyeVertex, gl_EyePlaneT[0] );
    gl_TexCoord[0].p = dot( EyeVertex, gl_EyePlaneR[0] );
    gl_TexCoord[0].q = dot( EyeVertex, gl_EyePlaneQ[0] );
    gl_Position = ftransform();
}
 

Fragment Shader (GLSL_FRAG_SHADERMAP)

Code:

 
uniform sampler3D DataTexture;
uniform mat4 CM;
uniform vec4 kd;
uniform vec4 Ia;
 
void main(void) {
    vec4 DepVec;
    DepVec.rgba = texture3D(DataTexture,gl_TexCoord[0].stp);
    gl_FragColor = Ia + kd*CM*DepVec;
}
 

Lustigerweise funktioniert es ohne Probleme, wenn ich den folgenden Fragment-Shader nehme:

Code:

 
uniform sampler3D DataTexture;
uniform sampler1D MyColorMap;
 
void main(void) {
    vec4 DepVec;
    vec4 NewVec;
 
    DepVec.rgba = texture3D(DataTexture,gl_TexCoord[0].stp);
    NewVec.rgba = texture1D(MyColorMap,DepVec.a);
 
    gl_FragColor = vec4(NewVec.rgb,DepVec.a);
}
 

Init-Teil habe ich einfach kopiert, eingefügt und lediglich die Namen geändert.

Hat jemand ne schöne Idee?

_________________
Ein Schiff im Hafen ist sicher. Aber dafür werden Schiffe nicht gebaut. (Engl. Sprichwort)

Nach oben

Blechwolf

Betreff des Beitrags:

Verfasst: Mo Jun 20, 2005 10:49

DGL Member

Registriert: Fr Nov 12, 2004 14:58
Beiträge: 76
Wohnort: Aachen

Ok, hab den Fehler weiter eingeschränkt.

Also in der folgenden Prozedur funktioniert es mit beiden Shadern (GLSL_FRAG_SHADERMAP und GLSL_FRAG_COLORMAP)

Code:

 
procedure TVolumeViewer.AssignColorMap(var _d : array of Single; _Length : Integer; _GLTexType : Cardinal);
var
  i : Integer;
  s : String;
  VertSlang : GLHandleARB;
  FragSlang : GLHandleARB;
  VertLength,
  FragLength : Integer;
begin
  ActivateRenderingContext(DC,RC,false);
 
  if @glTexImage3D <> nil then
      glDisable(GL_TEXTURE_3D)
  else
    glDisable(GL_TEXTURE_3D_EXT);
 
  glActiveTexture(GL_TEXTURE1);
  glEnable(GL_TEXTURE_1D);
  glGenTextures(1,@TexColorMap);
  glBindTexture(GL_TEXTURE_1D,TexColorMap);
 
  glTexParameteri(GL_TEXTURE_1D,GL_TEXTURE_MAG_FILTER, GL_LINEAR);
  glTexParameteri(GL_TEXTURE_1D,GL_TEXTURE_MIN_FILTER, GL_LINEAR);
  glTexParameteri(GL_TEXTURE_1D,GL_TEXTURE_WRAP_S, GL_CLAMP);
 
  glTexImage1D(GL_TEXTURE_1D,0,GL_RGBA,_Length,0,_GLTexType,GL_FLOAT,PGLFLOAT(@_d));
  glDisable(GL_TEXTURE_1D);
 
    FColorMap := true;
  setLength(MyColorMap, Length(_d));
  for i := Low(MyColorMap) to High(MyColorMap) do
    MyColorMap[i] := _d[i];
 
  if FUseSlang then begin
    SlangProg := glCreateProgramObjectARB();
    VertSlang := glCreateShaderObjectARB(GL_VERTEX_SHADER_ARB);
    FragSlang := glCreateShaderObjectARB(GL_FRAGMENT_SHADER_ARB);
 
    VertLength := Length(GLSL_VERT_COORDINATE);
    FragLength := Length(GLSL_FRAG_COLORMAP);
 
    glShaderSourceARB(VertSlang,1,@GLSL_VERT_COORDINATE,@VertLength);
    glShaderSourceARB(FragSlang,1,@GLSL_FRAG_COLORMAP,@FragLength);
 
    glCompileShaderARB(VertSlang);
    ShowMessage(glSlang_GetInfoLog(VertSlang));
    glCompileShaderARB(FragSlang);
    ShowMessage(glSlang_GetInfoLog(FragSlang));
 
    glAttachObjectARB(SlangProg,VertSlang);
    glAttachObjectARB(SlangProg,FragSlang);
 
    glDeleteObjectARB(VertSlang);
    glDeleteObjectARB(FragSlang);
 
    glLinkProgramARB(SlangProg);
    ShowMessage(glSlang_GetInfoLog(SlangProg));
 
    glUseProgramObjectARB(SlangProg);
 
    ShowMessage(format('%d',[glGetHandleARB(GL_PROGRAM_OBJECT_ARB)]));
 
  end else begin
  // Alternativ wird hier ein Fragment Program genutzt, falls FUseSlang auf False gesetzt ist.
  end;
end;
 

Der Aufruf glGetHandleARB(GL_PROGRAM_OBJECT_ARB) liefert mir erwartungsgemäss eine 1 zurück.

in der folgenden Prozedur funktioniert es nicht (weder mit GLSL_FRAG_COLORMAP noch mit GLSL_FRAG_SHADERMAP)

Code:

 
procedure TVolumeViewer.AssignData(var _d : array of Single; _DimsX, _DimsY, _DimsZ : Integer; _GLTexType : Cardinal);
var
  VertSlang  : GLHandleARB;
  FragSlang  : GLHandleARB;
  VertLength : Integer;
  FragLength : Integer;
begin
  EnableCube := True;
 
  Dimensions['x'] := _DimsX;
  Dimensions['y'] := _DimsY;
  Dimensions['z'] := _DimsZ;
 
  MaxDim := max(_DimsX,max(_DimsY,_DimsZ));
 
  // Resize Surrounding Volume
  SetCube(_DimsX/MaxDim,_DimsY/MaxDim,_DimsZ/MaxDim);
 
  GLTexType := _GLTexType;
 
  ActivateRenderingContext(DC,RC,false);
 
  Assert(TextureSizeSupported(),'Texture too large or TexSize not Power of 2');
 
  // Set Default number of slices
  if Slices = 0 then
    Slices := 2*ceil(sqrt(Dimensions['x']*Dimensions['x']+Dimensions['y']*Dimensions['y']+Dimensions['z']*Dimensions['z']));
 
  // Set Texture Parameters and Texture
  if @glTexImage3D = nil then begin
    glGenTextures(1,@TexData);
    glActiveTexture(GL_TEXTURE0);
    glEnable(GL_TEXTURE_3D_EXT);
    glBindTexture(GL_TEXTURE_3D_EXT, TexData);
    glTexParameteri(GL_TEXTURE_3D_EXT,GL_TEXTURE_MAG_FILTER, GL_LINEAR);
    glTexParameteri(GL_TEXTURE_3D_EXT,GL_TEXTURE_MIN_FILTER, GL_LINEAR);
    glTexParameteri(GL_TEXTURE_3D_EXT,GL_TEXTURE_WRAP_S, GL_CLAMP_TO_BORDER);
    glTexParameteri(GL_TEXTURE_3D_EXT,GL_TEXTURE_WRAP_T, GL_CLAMP_TO_BORDER);
    glTexParameteri(GL_TEXTURE_3D_EXT,GL_TEXTURE_WRAP_R, GL_CLAMP_TO_BORDER);
    glTexImage3DEXT(GL_TEXTURE_3D_EXT,0,GLTexType,Dimensions['x'],Dimensions['y'],Dimensions['z'],0,GLTexType,GL_FLOAT,PGLFloat(@_d));
    glDisable(GL_TEXTURE_3D_EXT);
  end else begin
    glGenTextures(1,@TexData);
    glActiveTexture(GL_TEXTURE0);
    glEnable(GL_TEXTURE_3D);
    glBindTexture(GL_TEXTURE_3D, TexData);
    glTexParameteri(GL_TEXTURE_3D,GL_TEXTURE_MAG_FILTER, GL_LINEAR);
    glTexParameteri(GL_TEXTURE_3D,GL_TEXTURE_MIN_FILTER, GL_LINEAR);
    glTexParameteri(GL_TEXTURE_3D,GL_TEXTURE_WRAP_S, GL_CLAMP_TO_BORDER);
    glTexParameteri(GL_TEXTURE_3D,GL_TEXTURE_WRAP_T, GL_CLAMP_TO_BORDER);
    glTexParameteri(GL_TEXTURE_3D,GL_TEXTURE_WRAP_R, GL_CLAMP_TO_BORDER);
    glTexImage3D(GL_TEXTURE_3D,0,GLTexType,Dimensions['x'],Dimensions['y'],Dimensions['z'],0,GLTexType,GL_FLOAT,PGLFloat(@_d));
    glDisable(GL_TEXTURE_3D);
  end;
 
  FTexture := True;
 
  if FShading then begin
    SlangProg := glCreateProgramObjectARB();
 
    VertSlang := glCreateShaderObjectARB(GL_VERTEX_SHADER_ARB);
    FragSlang := glCreateShaderObjectARB(GL_FRAGMENT_SHADER_ARB);
 
    VertLength := Length(GLSL_VERT_COORDINATE);
    FragLength := Length(GLSL_FRAG_SHADERMAP);
 
    glShaderSourceARB(VertSlang,1,@GLSL_VERT_COORDINATE,@VertLength);
    glShaderSourceARB(FragSlang,1,@GLSL_FRAG_SHADERMAP,@FragLength);
 
    glCompileShaderARB(VertSlang);
    ShowMessage(glSlang_GetInfoLog(VertSlang));
    glCompileShaderARB(FragSlang);
    ShowMessage(glSlang_GetInfoLog(FragSlang));
 
    glAttachObjectARB(SlangProg,VertSlang);
    glAttachObjectARB(SlangProg,FragSlang);
 
    glLinkProgramARB(SlangProg);
    ShowMessage(glSlang_GetInfoLog(SlangProg));
 
    glDeleteObjectARB(VertSlang);
    glDeleteObjectARB(FragSlang);
 
    glUseProgramObjectARB(SlangProg);
    if glGetError() = GL_INVALID_OPERATION then
      ShowMessage('Invalid Operation');
    ShowMessage(format('%d',[glGetHandleARB(GL_PROGRAM_OBJECT_ARB)]));
  end;
end;
 

Hier bekomme ich mit dem gleichen Aufruf eine 0. Obwohl eigentlich nix anders ist. Oder seh ich jetzt den Wald vor lauter Bäumen nicht mehr?

_________________
Ein Schiff im Hafen ist sicher. Aber dafür werden Schiffe nicht gebaut. (Engl. Sprichwort)

Nach oben

Lossy eX

Betreff des Beitrags:

Verfasst: Mo Jun 20, 2005 11:15

DGL Member

Registriert: Do Dez 05, 2002 10:35
Beiträge: 4234
Wohnort: Dortmund

Hast du schon mal versucht den Fehler häufiger abzufragen? Also das Stück mit glGetError in eine Procedure und dann zwischen jede Zeile. Also so, dass du genau sehen kannst wann der fehler denn genau auftritt. Evtl liegt er ja nur ganz wo anders und wird erst nur dann bemerkt.

Ist das Ergebnis was du erhält denn eigentlich korrekt oder wird auch nichts dargestellt?

Eine Anmerkung am Rande. Das mit den Texturen kann du auch einfacher haben. GL_TEXTURE_3D und GL_TEXTURE_3D_EXT haben beide ein und den selben Wert. Sind also auch für OpenGL ein und das Selbe. GL_TEXTURE_3D wird seit OpenGL 1.2 im Core unterstützt. Sollte es aber nicht unterstützt werden so setzt du GL_EXT_texture3D stillschweigend vorraus. Ich denke es wäre besser wenn du überprüfst ob OpenGL > 1.2 ist oder ob die Extension unterstützt wird.

Nach oben

Blechwolf

Betreff des Beitrags:

Verfasst: Mo Jun 20, 2005 11:31

DGL Member

Registriert: Fr Nov 12, 2004 14:58
Beiträge: 76
Wohnort: Aachen

Letztlich mache ich die Fehlerabfrage mit GLIntercept v0.42 und der sagt mir explizit, das der Fehler von glUseProgramObjectARB aufgerufen wird.

Ich habe das ganze nochmal ein wenig modifiziert:
Das Laden/Linken der Shader steht jetzt in einer eigenen Prozedur

Code:

 
procedure TVolumeViewer.LoadShader(var Shader : GLHandleARB; COLORMAP: Boolean);
var
  VertSlang,
  FragSlang : GLHandleARB;
  VertLength,
  FragLength : Integer;
begin
  ActivateRenderingContext(DC,RC,true);
 
  if Shader <> 0 then
    glDeleteObjectARB(Shader);    
 
  Shader := glCreateProgramObjectARB();
  VertSlang := glCreateShaderObjectARB(GL_VERTEX_SHADER_ARB);
  FragSlang := glCreateShaderObjectARB(GL_FRAGMENT_SHADER_ARB);
 
  VertLength := Length(GLSL_VERT_COORDINATE);
  if COLORMAP then
    FragLength := Length(GLSL_FRAG_COLORMAP)
  else
    FragLength := Length(GLSL_FRAG_SHADERMAP);
 
  glShaderSourceARB(VertSlang,1,@GLSL_VERT_COORDINATE,@VertLength);
 
  if COLORMAP then
    glShaderSourceARB(FragSlang,1,@GLSL_FRAG_COLORMAP,@FragLength)
  else
    glShaderSourceARB(FragSlang,1,@GLSL_FRAG_SHADERMAP,@FragLength);
 
  glCompileShaderARB(VertSlang);
  ShowMessage(glSlang_GetInfoLog(VertSlang));
  glCompileShaderARB(FragSlang);
  ShowMessage(glSlang_GetInfoLog(FragSlang));
 
  glAttachObjectARB(Shader,VertSlang);
  glAttachObjectARB(Shader,FragSlang);
 
  glDeleteObjectARB(VertSlang);
  glDeleteObjectARB(FragSlang);
 
  glLinkProgramARB(Shader);
  ShowMessage(glSlang_GetInfoLog(Shader));
 
  glUseProgramObjectARB(Shader);
end;
 

und in meiner OnRender-Routine findet sich jetzt nur noch das glUseProgramObjectARB.
Geladen werden die Shader wie vorher in AssignData bzw. AssignColormap.

Hier die Render Routine (gekürzt wo möglich)

Code:

 
procedure TVolumeViewer.Render();
var
  CM : array[0..15] of Single;
  MV : array[0..15] of Single;
begin
  ActivateRenderingContext(DC,RC,false);
  SetupContext();
 
  glPolygonMode(GL_FRONT_AND_BACK, GL_FILL);
 
  case FBlendMode of
  // BlendFunc, BlendEquation und GL_BLEND setzen
  end;
 
  // Rotate
  glRotatef(Rot[0],1,0,0);
  glRotatef(Rot[1],0,1,0);
  glRotatef(Rot[2],0,0,1);
  // Move to draw centered
  glTranslatef(-VV_Cube_Corners[6,0]/2,-VV_Cube_Corners[6,1]/2,-VV_Cube_Corners[6,2]/2);
 
  if FTexture then begin
    glActiveTexture(GL_TEXTURE0);
 
    if @glTexImage3D <> nil then
      glBindTexture(GL_TEXTURE_3D,TexData)
    else
      glBindTexture(GL_TEXTURE_3D_EXT,TexData);
 
    // Automatic Texture Coordinate Generation
    glTexGeni (GL_S, GL_TEXTURE_GEN_MODE, GL_EYE_LINEAR);
    glTexGeni (GL_T, GL_TEXTURE_GEN_MODE, GL_EYE_LINEAR);
    glTexGeni (GL_R, GL_TEXTURE_GEN_MODE, GL_EYE_LINEAR);
    glTexGenfv(GL_S, GL_EYE_PLANE, PGLFloat(@VV_XVEC));
    glTexGenfv(GL_T, GL_EYE_PLANE, PGLFloat(@VV_YVEC));
    glTexGenfv(GL_R, GL_EYE_PLANE, PGLFloat(@VV_ZVEC));
    glEnable  (GL_TEXTURE_GEN_S);
    glEnable  (GL_TEXTURE_GEN_T);
    glEnable  (GL_TEXTURE_GEN_R);
 
    // Enable Alpha-Blending and Texture Modulation
 
    case FTexFunc of
      // Abfrage der versch. Texture Modi
    else
      glTexEnvi(GL_TEXTURE_ENV, GL_TEXTURE_ENV_MODE, GL_BLEND);
    end;
 
    case FAlphaFunc of
      // Alpha-Func Abfragen
    else
      glAlphaFunc(GL_GEQUAL,(Isoval-FMin)/FMax);
    end;
    glEnable(GL_ALPHA_TEST);
 
    if @glTexImage3D <> nil then
        glEnable(GL_TEXTURE_3D)
    else
        glEnable(GL_TEXTURE_3D_EXT);
 
// ---------------------------------------
// Wichtiger Teil
// ---------------------------------------
 
 
    if FShading then begin
      glMatrixMode(GL_MODELVIEW);
      glGetFloatv(GL_MODELVIEW_MATRIX,PGLFloat(@MV));
      // Light Direction -> LightSource = Camera Position
      CM[ 0] := -CameraX;
      CM[ 1] := -CameraX;
      CM[ 2] := -CameraX;
      CM[ 3] := 0;
      CM[ 4] := -CameraY;
      CM[ 5] := -CameraY;
      CM[ 6] := -CameraY;
      CM[ 7] := 0;
      CM[ 8] := -CameraZ;
      CM[ 9] := -CameraZ;
      CM[10] := -CameraZ;
      CM[11] := 0;
      CM[12] := 0;
      CM[13] := 0;
      CM[14] := 0;
      CM[15] := 1;
 
      MV[ 3] := 0;
      MV[ 7] := 0;
      MV[11] := 0;
      MV[12] := 0;
      MV[13] := 0;
      MV[14] := 0;
      MV[15] := 1;
 
      glPushMatrix();
      glLoadIdentity();
      glMultMatrixf(PGLFloat(@CM));
      glGetFloatv(GL_MODELVIEW_MATRIX,PGLFloat(@CM));
      glMultMatrixf(PGLFloat(@MV));
      glGetFloatv(GL_MODELVIEW_MATRIX,PGLFloat(@CM));      
 
      CM[ 0] := 2;
      CM[ 1] := 0;
      CM[ 2] := 0;
      CM[ 3] := 0;
      CM[ 4] := 0;
      CM[ 5] := 2;
      CM[ 6] := 0;
      CM[ 7] := 0;
      CM[ 8] := 0;
      CM[ 9] := 0;
      CM[10] := 2;
      CM[11] := 0;
      CM[12] := -1;
      CM[13] := -1;
      CM[14] := -1;
      CM[15] := 1;
 
      glMultMatrixf(PGLFloat(@CM));
      glGetFloatv(GL_MODELVIEW_MATRIX,PGLFloat(@CM));
 
      glPopMatrix();
 
// Hiernach kommt der Fehler
      glUseProgramObjectARB(SlangProg);      
 
// Gaaanz viele Folgefehler
      glUniform1iARB(glGetUniformLocationARB(SlangProg,PGLCharARB('DataTexture')),0);
      glUniformMatrix4fvARB(glGetUniformLocationARB(SlangProg,PGLCharARB('CM')),16,false,PGLFloat(@CM));
      glUniform4fARB(glGetUniformLocationARB(SlangProg,PGLCharARB('kd')),1.0,1.0,1.0,1.0);
      glUniform4fARB(glGetUniformLocationARB(SlangProg,PGLCharARB('Ia')),0.0,0.0,0.0,0.0);
    end;
 
    if FColorMap then begin
      glActiveTexture(GL_TEXTURE1);
      glBindTexture(GL_TEXTURE_1D,TexColorMap);
      glEnable(GL_TEXTURE_1D);
      if FUseSlang then begin
// Hier kommt komischerweise kein Fehler
        glUseProgramObjectARB(SlangProg);
 
        glUniform1iARB(glGetUniformLocationARB(SlangProg,PGLCharARB('DataTexture')),0);
        glUniform1iARB(glGetUniformLocationARB(SlangProg,PGLCharARB('MyColorMap')),1);
      end else begin
        glBindProgramARB(GL_FRAGMENT_PROGRAM_ARB,FragProg);
        glEnable(GL_FRAGMENT_PROGRAM_ARB);
      end;
    end;
 
// Würfel zeichnen
    DrawSlices(Slices);
  end;
 
  // Restore Defaults
  glDisable(GL_ALPHA_TEST);
  glDisable(GL_BLEND);
  glDisable(GL_TEXTURE_1D);
  if @glTexImage3D <> nil then
    glDisable(GL_TEXTURE_3D)
  else
    glDisable(GL_TEXTURE_3D_EXT);
  glDisable(GL_TEXTURE_GEN_S);
  glDisable(GL_TEXTURE_GEN_T);
  glDisable(GL_TEXTURE_GEN_R);
 
  if FColorMap then
    if FUseSlang then
      glUseProgramObjectARB(0)
    else
      glDisable(GL_FRAGMENT_PROGRAM_ARB);
 
  if FShading then
    glUseProgramObjectARB(0);
 
  if EnableCube then
    DrawCube();
  if FDrawMark then
    DrawMarker();
 
  SwapBuffers(DC);
end;
 

Mein Ergebnis ist leider falsch, sofern ich FShading einschalte. mit FColorMap ist es korrekt. Aber da bekomme ich auch keine Fehler.

_________________
Ein Schiff im Hafen ist sicher. Aber dafür werden Schiffe nicht gebaut. (Engl. Sprichwort)

Nach oben

Lossy eX

Betreff des Beitrags:

Verfasst: Mo Jun 20, 2005 12:20

DGL Member

Registriert: Do Dez 05, 2002 10:35
Beiträge: 4234
Wohnort: Dortmund

Also wegen dem glUseProgramObjectARB muss ich passen. Für mich sieht es in Ordnung aus aber ich kenne mich damit auch nicht so super aus. Liefert dir glSlang_GetInfoLog(Shader) eigentlich einen Text, wenn das Benutzen des Shaders nicht geklappt hat?

Ich denke aber auch mal, dass glUseProgramObjectARB(SlangProg); nur ein Übertragungsfehler ist. Denn eigentlich sollte das ja bestimmt Shader heißen.

3D Textur: Auch auf die Gefahr hin, dass ich mich unglücklich mache.

Anstelle von

Code:

  if @glTexImage3D <> nil then
    glEnable(GL_TEXTURE_3D)
  else
    glEnable(GL_TEXTURE_3D_EXT);

kannst du auch vollgendes schreiben.

Code:

  if @glTexImage3D <> nil then
    glEnable(GL_TEXTURE_3D)
  else
    glEnable(GL_TEXTURE_3D);

Und damit könntest du es auch auf glEnable(GL_TEXTURE_3D); beschränken. Das hat den gleichen Effekt, da GL_TEXTURE_3D = GL_TEXTURE_3D_EXT ist. Die beiden Extensions unterscheiden sich lediglich im Namen und der Variable in der ihre Funktionspointer abgelegt werden. Ich würde sogar fast Wetten, dass die Funktionspointer die Gleichen sind.

Nach oben

Blechwolf

Betreff des Beitrags:

Verfasst: Mo Jun 20, 2005 12:39

DGL Member

Registriert: Fr Nov 12, 2004 14:58
Beiträge: 76
Wohnort: Aachen

Lossy eX hat geschrieben:

Im Prinzip hast Du Recht. Nur bevor ich die jetzige Grafikkarte bekommen habe (GF6600) lief das ganze (ok es kroch...) auf nem OnBoard Grafikchipsatz. (Müßte eigentlich Intel SiS gewesen sein. - Weiß schon nicht mehr)
Der hat sich mit OpenGL 1.2 kompatibel gemeldet, kannte aber die GL_TEXTURE_3D nicht. Von daher ist die Abfrage da noch drin...
Ist leider nicht alles so heile in der OpenGL-Welt wie man sich das manchmal wünschen würde. Noch ein Beispiel? Such mal auf ner ATI 9x00 nach GL_IMAGING-Subset. Gibts auf den Apple Karten, aber für Windows gibts das nicht. Obwohl es seit OpenGL 1.2 eigentlich Standard sein sollte...

Habe eben den ganzen Kram gelöscht (zumindest den Shader Teil) und baue das nochmal neu. Vielleicht habe ich ja irgendwo einfach was übersehen.

Danke für die Hilfe.

_________________
Ein Schiff im Hafen ist sicher. Aber dafür werden Schiffe nicht gebaut. (Engl. Sprichwort)

Nach oben

Grizzly

Betreff des Beitrags:

Verfasst: Mo Jun 20, 2005 15:56

DGL Member

Registriert: Sa Nov 13, 2004 11:00
Beiträge: 229
Wohnort: Steinhude

GL_TEXTURE_3D und GL_TEXTURE_3D_EXT sind allerdings 2 constanten, die beide den selben Wert ($806F) haben. Insofern sollte es vollkommen egal sein, welchen der beiden Werte man einsetzt. Entweder die Graka kann 3D texturen, dann ist es egal welchen der beiden man einsetzt, oder sie kann es nicht, dann funktionieren aber beide nicht.

Durch den Programmcode wollte ich mich jetzt nich wühlen, hättest du nicht die benötigten Dateien hochladen können, dass man mal testen könnte? so auf den ersten Blick find ich das jedenfalls nicht ersichtlich.

Nach oben

Blechwolf

Betreff des Beitrags:

Verfasst: Di Jun 21, 2005 11:12

DGL Member

Registriert: Fr Nov 12, 2004 14:58
Beiträge: 76
Wohnort: Aachen

Das Problem hat sich auf wundersame Weise gelöst. Nachdem ich das alles nochmal neu geschrieben habe, funktioniert es jetzt. Warum auch immer.
EDV = Ende der Vernunft

3D Textures
Hm, ok. Überzeugt. Sind tatsächlich die gleichen Konstanten. Dann brauche ich die Abfrage nur noch bei,

Code:

 
if @glTexImage3D = nil then
      glTexImage3DExt([...])
    else
      glTexImage3D   ([...]);
 

Bedankt.

Zu den benötigten Dateien gehören (leider) ein paar Komponenten, ein kleines Framework aussen drum sowie mindestens ein Datensatz. Und allein der ist schon 16MB groß.
Sonst gerne die Dateien, aber da das so schlecht zu trennen ist, indem Fall lieber den Quellcode.

_________________
Ein Schiff im Hafen ist sicher. Aber dafür werden Schiffe nicht gebaut. (Engl. Sprichwort)

Nach oben

Seite 1 von 1

[ 8 Beiträge ]

Foren-Übersicht » Programmierung » Shader

Wer ist online?

Mitglieder in diesem Forum: 0 Mitglieder und 4 Gäste

Du darfst keine neuen Themen in diesem Forum erstellen.
Du darfst keine Antworten zu Themen in diesem Forum erstellen.
Du darfst deine Beiträge in diesem Forum nicht ändern.
Du darfst deine Beiträge in diesem Forum nicht löschen.
Du darfst keine Dateianhänge in diesem Forum erstellen.