DGL • Thema anzeigen - FrameBufferObject

FrameBufferObject

Moderator: DGL-Team

Seite 1 von 1

[ 11 Beiträge ]

Vorheriges Thema | Nächstes Thema

Autor

Nachricht

Andyh

Betreff des Beitrags: FrameBufferObject

Verfasst: Di Nov 24, 2009 15:59

DGL Member

Registriert: Do Jun 09, 2005 13:48
Beiträge: 117
Wohnort: Sankt Augustin

Hallo,

ich habe das Tutorial bezüglich der FrameBufferObjekte durchgearbeitet und eine dazu passende Komponente entwickelt. Leider bekomme ich beim Anlegen des Objekts in der Funktion CheckFBO immer den Fehler >> GL_FRAMEBUFFER_INCOMPLETE_ATTACHMENT_EXT <<, so dass die Komponente nicht korrekt angelegt wird. Meiner Meinung nach habe ich alles so umgesetzt wie vorgegeben. Ich habe auch die Existenz der Erweiterung abgeprüft, bekomme den Fehler aber trotzdem.

Kann mir jemand weiterhelfen?

Danke,

Andree

___________________
Hier die Abprüfung der Extension:
___________________

Code:

 
var
  FBO: TFrameBufferObject;
.
.
.
  if CheckGLExtension ('GL_EXT_framebuffer_object') then begin
    FBO := TFrameBufferObject.Create(512, 512);
  end else begin
    FBO := nil;
    raise Exception.Create('Spiegelanzeige ist nicht möglich, da die'+#10+#13+
                                   'Grafikkarte dies nicht unterstützt.');
  end;
.
.
.
 
 
function TFMain.CheckGLExtension (cExt: string): boolean;
var
  cGLExt: string;
begin
  result := false;
  cGLExt := glGetString (GL_EXTENSIONS);
  if UpperPos (cExt, cGLExt) > 0 then begin
    result := true;
  end;
end;
 

___________________
Hier die Komponente:
___________________

Code:

 
unit FrameBufferObjectClass;
 
interface
 
uses
  dglopenGL,
  Windows,
  Classes;
 
type
  TFrameBufferObject = class(TComponent)
    public
      Log        : TstringList;
      procedure Bind;
      procedure PrepareRender;
      procedure FinishRender;
      constructor Create (pWidth, pHeight: GLUInt); reintroduce;
      destructor Destroy; override;
    private
      fbo        : GLUInt;
      depthbuffer: GLUInt;
      Width,
      Height     : GLUInt;
      FBO_tex    : GLUInt;
      procedure CheckFBO;
    procedure WriteLog(s: string);
  end;
 
implementation
 
uses
  SysUtils;
 
destructor TFrameBufferObject.Destroy;
begin
  Log.Free;
  glDeleteTextures(1, @FBO_tex);
  glDeleteFramebuffersEXT(1, @fbo);
  glDeleteRenderbuffersEXT(1, @depthbuffer);
  inherited;
end;
 
constructor TFrameBufferObject.Create (pWidth, pHeight: GLUInt);
begin
  Width  := pWidth;
  Height := pHeight;
 
  Log    := TStringlist.Create;
 
  // Zuerst einmal muss das Framebufferobjekt generiert werden. Dies läuft
  // ähnlich wie das Erstellen einer Textur ab.
  WriteLog ('glGenFramebuffersEXT(1, @fbo)');
  glGenFramebuffersEXT(1, @fbo);
  // Wie bei allem anderen auch müssen wir das Framebufferobjekt jetzt binden,
  // damit alles, was folgt sich auf dieses Objekt bezieht
  WriteLog ('glBindFramebufferEXT(GL_FRAMEBUFFER_EXT, fbo)');
  glBindFramebufferEXT(GL_FRAMEBUFFER_EXT, fbo);
 
  // Ein einfaches Framebufferobjekt ist noch ziemlich nutzlos. Deswegen
  // fügen wir zuerst einmal einen der neu eingeführten Renderbuffer als
  // Depthbuffer hinzu. Renderbuffer sind im Prinzip Objekte, die benutzt
  // werden wenn ein Buffer kein zugehöriges Texturformat besitzt. Dazu zählen
  // u.a. der Stencilbuffer, der Accumulationbuffer und der Depthbuffer. Das
  // Binden an den Accumulationbuffer wurde allerdings auf eine spätere
  // Extension verschoben. Wie auch beim Framebufferobjekt müssen wir einen
  // Renderbuffer zuerst generieren und dann binden:
  WriteLog ('glGenRenderbuffersEXT(1, @depthbuffer)');
  glGenRenderbuffersEXT(1, @depthbuffer);
  WriteLog ('glBindRenderbufferEXT(GL_RENDERBUFFER_EXT, depthbuffer)');
  glBindRenderbufferEXT(GL_RENDERBUFFER_EXT, depthbuffer);
 
  // Derzeit hat der Renderbuffer allerdings noch keinen Speicher zugeteilt
  // bekommen. Deswegen sagen wir OpenGL, wie wir den Renderbuffer benutzen
  // wollen und welche Größe er haben soll:
  WriteLog ('glRenderbufferStorageEXT(GL_RENDERBUFFER_EXT, GL_DEPTH_COMPONENT, '+IntToStr(pWidth)+', '+IntToStr(pHeight)+')');
  glRenderbufferStorageEXT(GL_RENDERBUFFER_EXT, GL_DEPTH_COMPONENT, pWidth, pHeight);
 
  // Mit glRenderbufferStorageEXT hat OpenGL den Speicher für den Renderbuffer,
  // den wir als Depthbuffer nutzen, reserviert. Jetzt können wir unseren
  // Depthbuffer zum FBO hinzufügen:
  WriteLog ('glFramebufferRenderbufferEXT(GL_FRAMEBUFFER_EXT,'+
                                         'GL_DEPTH_ATTACHMENT_EXT,'+
                                         'GL_RENDERBUFFER_EXT, depthbuffer)');
  glFramebufferRenderbufferEXT(GL_FRAMEBUFFER_EXT,
                               GL_DEPTH_ATTACHMENT_EXT,
                               GL_RENDERBUFFER_EXT, depthbuffer);
  // Die letzte Anweisung sollte ziemlich einfach zu verstehen sein. Der zweite
  // Parameter sagt einfach, als was der Renderbuffer genutzt werden soll
 
  // Um Farbinformationen in unser Framebufferobjekt schreiben zu können,
  // fügen wir eine Textur hinzu. Bevor wir sie hinzufügen können müssen wir
  // sie natürlich noch erstellen:
  WriteLog ('glGenTextures(1, @FBO_tex)');
  glGenTextures(1, @FBO_tex);
  WriteLog ('glBindTexture(GL_TEXTURE_2D, FBO_tex)');
  glBindTexture(GL_TEXTURE_2D, FBO_tex);
  WriteLog ('glTexParameteri(GL_TEXTURE_2D,GL_TEXTURE_MAG_FILTER, GL_NEAREST)');
  glTexParameteri(GL_TEXTURE_2D,GL_TEXTURE_MAG_FILTER, GL_NEAREST);
  WriteLog ('glTexParameteri(GL_TEXTURE_2D,GL_TEXTURE_MIN_FILTER, GL_NEAREST)');
  glTexParameteri(GL_TEXTURE_2D,GL_TEXTURE_MIN_FILTER, GL_NEAREST);
  WriteLog ('glTexImage2D(GL_TEXTURE_2D, 0, GL_RGB8, '+IntToStr(pWidth)+', '+IntToStr(pHeight)+', 0, GL_RGB8, GL_UNSIGNED_BYTE, nil)');
  glTexImage2D(GL_TEXTURE_2D, 0, GL_RGB8, pWidth, pHeight, 0, GL_RGB8, GL_UNSIGNED_BYTE, nil);
  // Es dürfte eigentlich nichts völlig Unverständliches da stehen. Wir
  // erstellen die Textur, binden sie, stellen die Filtermodi ein und erzeugen
  // im Speicher den entsprechenden Platz. Anzumerken ist aber, dass die Textur
  // die gleiche Größe wie der Renderbuffer haben muss. Alle Größen müssen
  // einheitlich sein. Man kann also nicht einen Renderbuffer von 512*512 und
  // eine Textur von 256*256 erstellen und sie zusammen in einem FBO nutzen.
  // Hinzugefügt wird sie nach dem gleichen Schema wie der Depthbuffer:
  WriteLog ('glFramebufferTexture2DEXT(GL_FRAMEBUFFER_EXT, GL_COLOR_ATTACHMENT0_EXT, GL_TEXTURE_2D, FBO_tex, 0)');
  glFramebufferTexture2DEXT(GL_FRAMEBUFFER_EXT, GL_COLOR_ATTACHMENT0_EXT, GL_TEXTURE_2D, FBO_tex, 0);
  // Wie gesagt, nicht viel neues hier. Der zweite Parameter,
  // GL_COLOR_ATTACHMENT0_EXT sagt OpenGL wo die Textur hinzugefügt werden
  // soll (man kann mehrere hinzufügen, doch dazu später mehr). Der letzte
  // Parameter beschreibt das Mipmaping-Level.
 
  WriteLog ('checking error');
  CheckFBO;
end;
 
procedure TFrameBufferObject.CheckFBO;
var
  error: GlEnum;
begin
  error := glCheckFramebufferStatusEXT(GL_FRAMEBUFFER_EXT);
  WriteLog ('error: '+IntToStr(error));
  case error of
    GL_FRAMEBUFFER_COMPLETE_EXT:
      Exit;
    GL_FRAMEBUFFER_INCOMPLETE_ATTACHMENT_EXT:
      raise Exception.Create('FBO: Incomplete attachment');
    GL_FRAMEBUFFER_INCOMPLETE_MISSING_ATTACHMENT_EXT:
      raise Exception.Create('FBO: Missing attachment');
    GL_FRAMEBUFFER_INCOMPLETE_DIMENSIONS_EXT:
      raise Exception.Create('FBO: Incomplete dimensions');
    GL_FRAMEBUFFER_INCOMPLETE_FORMATS_EXT:
      raise Exception.Create('FBO: Incomplete formats');
    GL_FRAMEBUFFER_INCOMPLETE_DRAW_BUFFER_EXT:
      raise Exception.Create('FBO: Incomplete draw buffer');
    GL_FRAMEBUFFER_INCOMPLETE_READ_BUFFER_EXT:
      raise Exception.Create('FBO: Incomplete read buffer');
    GL_FRAMEBUFFER_UNSUPPORTED_EXT:
      raise Exception.Create('FBO: Framebufferobjects unsupported');
  end;
end;
 
procedure TFrameBufferObject.WriteLog (s: string);
begin
  Log.Add(s);
end;
 
procedure TFrameBufferObject.PrepareRender;
// bind vor dem rendern auf die textur aufrufen und dann einfach rendern.
// den viewport dann nicht mehr verändern.
begin
  glBindFramebufferEXT(GL_FRAMEBUFFER_EXT, fbo);
  glPushAttrib(GL_VIEWPORT_BIT);
  glViewPort(0, 0, Width, Height);
end;
 
procedure TFrameBufferObject.FinishRender;
// release nach dem rendern auf die textur aufrufen um den viewport
// zurückzusetzen.
begin
  glPopAttrib;
  glBindFramebufferEXT(GL_FRAMEBUFFER_EXT, 0);
end;
 
procedure TFrameBufferObject.Bind;
// vor dem Benutzen der Textur aufrufen
begin
  glBindTexture(GL_TEXTURE_2D, FBO_tex);
  glGenerateMipmapEXT(GL_TEXTURE_2D);
  //Textur danach ganz normal benutzen
end;
 
end.
 

Nach oben

Lord Horazont

Betreff des Beitrags: Re: FrameBufferObject

Verfasst: Di Nov 24, 2009 16:34

DGL Member

Registriert: Do Sep 02, 2004 19:42
Beiträge: 4158
Programmiersprache: FreePascal, C++

Ich habe mit FBOs noch nicht so viel gemacht, erinnere mich aber, dass man Texturen, die als Puffer fungieren, nicht gebunden haben sollte... Mal ein glBind(GL_TEXTURE_2D, 0); vorm CheckFBO versucht?

greetings
(*schuss ins blaue*)

_________________
If you find any deadlinks, please send me a notification – Wenn du tote Links findest, sende mir eine Benachrichtigung.
current projects: ManiacLab; aioxmpp
zombofant network • my photostream
„Writing code is like writing poetry“ - source unknown

„Give a man a fish, and you feed him for a day. Teach a man to fish and you feed him for a lifetime. “ ~ A Chinese Proverb

Nach oben

Andyh

Betreff des Beitrags: Re: FrameBufferObject

Verfasst: Di Nov 24, 2009 16:41

DGL Member

Registriert: Do Jun 09, 2005 13:48
Beiträge: 117
Wohnort: Sankt Augustin

Hallo,

glBindTexture(GL_TEXTURE_2D, 0) hat es leider nicht gebracht, das habe ich sofort ausprobiert.

Trotzdem danke,

Andree

Nach oben

Lossy eX

Betreff des Beitrags: Re: FrameBufferObject

Verfasst: Di Nov 24, 2009 16:45

DGL Member

Registriert: Do Dez 05, 2002 10:35
Beiträge: 4234
Wohnort: Dortmund

Ich denke nicht, dass es Probleme mit der Erweiterung gibt. Also wenn deine Grafikkarte FBOs nicht könnte, dann würde bereits der Befehl glGenFramebuffersEXT eine Zugriffsverletzung werfen. Weil die Funktionen erst dann existieren wenn deine Karte sie auch kann.

Also spontan kann ich nur eines finde woran sich eine empfindliche OpenGL Implementation stören könnte. Und zwar nimm mal als Format (Siebte Parameter/Zweite GL_RGB8 ) bei glTexImage2D GL_RGB und nicht GL_RGB8. Weiß nicht ob deine OpenGL Implementation da irgendwie empfindlicher ist. Ist vielleicht sogar auch ein bisschen an den Haaren herbeigezogen.

Falls das nichts ändernt kannst du mal folgendes versuchen.
- RGBA8 als Texturformat. Grafikkarten mögen 32 Bit Alignment.
- Überall mit glGetError auf Fehler prüfen. Wenn du irgendwo eine falschen Konstante rein reichst, dann sorgt das natürlich dafür, dass das FBO nicht funktioniert. Allerdings sieht man nicht ob ein Befehl eventuell einen Fehler geworfen hat. Also so etwas wie glBegin(GL_RGB) wird von OpenGL verworfen, weil er es nicht auswerten kann. Dein Programm wird aber trotzdem ganz normal weiter laufen. Allerdings wird in OpenGL ein Fehler gesetzt. Den kann man mit glGetError abfragen. Das solltest du dann idealerweise mit in dein Log Schreiben. Also nach jedem Befehl. Oder kombinieren. Also dein Writelog nach dem OpenGL Befehl aufrufen und das Ergebniss von glGetError direkt übergeben und gleich zusammen wegschreiben.

Nach oben

Andyh

Betreff des Beitrags: Re: FrameBufferObject

Verfasst: Di Nov 24, 2009 17:11

DGL Member

Registriert: Do Jun 09, 2005 13:48
Beiträge: 117
Wohnort: Sankt Augustin

Hallo Lossy Ex,

war nicht an den Haaren herbeigezogen. Da ich in unterschiedlichen Tutorials und Beispielen für diesen Parameter auch unterschiedliche Einstellungen gefunden hatte, habe ich anscheinend einiges durcheinandergebracht. Der Fehler ist jetzt weg, dafür ist mein Bildschirm schwarz. Wo ich vorher umherfliegende Kacheln sah, ist jetzt nur noch eine schwarze Fläche. Welche Einstellung muss ich den sichern und wiederherstellen? Ich habe glPush- und Popmatrix und glPush- und PopAttrib mit GL_ALL_ATTRIB_BITS probiert. Bringt null und nix.

Ich sehe nichts.

Danke,

Andree

-------------------
Hier der neue Code:
-------------------

Code:

 
unit FrameBufferObjectClass;
 
interface
 
uses
  dglopenGL,
  Windows,
  Classes;
 
type
  TFrameBufferObject = class(TComponent)
    public
      Log        : TstringList;
      procedure Bind;
      procedure PrepareRender;
      procedure FinishRender;
      constructor Create (pWidth, pHeight: GLUInt); reintroduce;
      destructor Destroy; override;
    private
      fbo        : GLUInt;
      depthbuffer: GLUInt;
      Width,
      Height     : GLUInt;
      FBO_tex    : GLUInt;
      procedure CheckFBO;
    procedure WriteLog(s: string);
  end;
 
implementation
 
uses
  SysUtils,
  Forms;
 
destructor TFrameBufferObject.Destroy;
begin
  Log.Free;
  glDeleteTextures(1, @FBO_tex);
  glDeleteFramebuffersEXT(1, @fbo);
  glDeleteRenderbuffersEXT(1, @depthbuffer);
  inherited;
end;
 
constructor TFrameBufferObject.Create (pWidth, pHeight: GLUInt);
begin
  Width  := pWidth;
  Height := pHeight;
 
  Log    := TStringlist.Create;
 
  // Zuerst einmal muss das Framebufferobjekt generiert werden. Dies läuft
  // ähnlich wie das Erstellen einer Textur ab.
  WriteLog ('glGenFramebuffersEXT(1, @fbo)');
  glGenFramebuffersEXT(1, @fbo);
  WriteLog ('error: '+IntToStr(glGetError));
  // Wie bei allem anderen auch müssen wir das Framebufferobjekt jetzt binden,
  // damit alles, was folgt sich auf dieses Objekt bezieht
  WriteLog ('glBindFramebufferEXT(GL_FRAMEBUFFER_EXT, fbo)');
  glBindFramebufferEXT(GL_FRAMEBUFFER_EXT, fbo);
  WriteLog ('error: '+IntToStr(glGetError));
 
  // Ein einfaches Framebufferobjekt ist noch ziemlich nutzlos. Deswegen
  // fügen wir zuerst einmal einen der neu eingeführten Renderbuffer als
  // Depthbuffer hinzu. Renderbuffer sind im Prinzip Objekte, die benutzt
  // werden wenn ein Buffer kein zugehöriges Texturformat besitzt. Dazu zählen
  // u.a. der Stencilbuffer, der Accumulationbuffer und der Depthbuffer. Das
  // Binden an den Accumulationbuffer wurde allerdings auf eine spätere
  // Extension verschoben. Wie auch beim Framebufferobjekt müssen wir einen
  // Renderbuffer zuerst generieren und dann binden:
  WriteLog ('glGenRenderbuffersEXT(1, @depthbuffer)');
  glGenRenderbuffersEXT(1, @depthbuffer);
  WriteLog ('error: '+IntToStr(glGetError));
 
  WriteLog ('glBindRenderbufferEXT(GL_RENDERBUFFER_EXT, depthbuffer)');
  glBindRenderbufferEXT(GL_RENDERBUFFER_EXT, depthbuffer);
  WriteLog ('error: '+IntToStr(glGetError));
 
  // Derzeit hat der Renderbuffer allerdings noch keinen Speicher zugeteilt
  // bekommen. Deswegen sagen wir OpenGL, wie wir den Renderbuffer benutzen
  // wollen und welche Größe er haben soll:
  WriteLog ('glRenderbufferStorageEXT(GL_RENDERBUFFER_EXT, GL_DEPTH_COMPONENT, '+IntToStr(pWidth)+', '+IntToStr(pHeight)+')');
  glRenderbufferStorageEXT(GL_RENDERBUFFER_EXT, GL_DEPTH_COMPONENT, pWidth, pHeight);
  WriteLog ('error: '+IntToStr(glGetError));
 
  // Mit glRenderbufferStorageEXT hat OpenGL den Speicher für den Renderbuffer,
  // den wir als Depthbuffer nutzen, reserviert. Jetzt können wir unseren
  // Depthbuffer zum FBO hinzufügen:
  WriteLog ('glFramebufferRenderbufferEXT(GL_FRAMEBUFFER_EXT,'+
                                         'GL_DEPTH_ATTACHMENT_EXT,'+
                                         'GL_RENDERBUFFER_EXT, depthbuffer)');
  glFramebufferRenderbufferEXT(GL_FRAMEBUFFER_EXT,
                               GL_DEPTH_ATTACHMENT_EXT,
                               GL_RENDERBUFFER_EXT, depthbuffer);
  WriteLog ('error: '+IntToStr(glGetError));
  // Die letzte Anweisung sollte ziemlich einfach zu verstehen sein. Der zweite
  // Parameter sagt einfach, als was der Renderbuffer genutzt werden soll
 
  // Um Farbinformationen in unser Framebufferobjekt schreiben zu können,
  // fügen wir eine Textur hinzu. Bevor wir sie hinzufügen können müssen wir
  // sie natürlich noch erstellen:
  WriteLog ('glGenTextures(1, @FBO_tex)');
  glGenTextures(1, @FBO_tex);
  WriteLog ('error: '+IntToStr(glGetError));
 
  WriteLog ('glBindTexture(GL_TEXTURE_2D, FBO_tex)');
  glBindTexture(GL_TEXTURE_2D, FBO_tex);
  WriteLog ('error: '+IntToStr(glGetError));
 
  WriteLog ('glTexParameteri(GL_TEXTURE_2D,GL_TEXTURE_MAG_FILTER, GL_NEAREST)');
  glTexParameteri(GL_TEXTURE_2D,GL_TEXTURE_MAG_FILTER, GL_NEAREST);
  WriteLog ('error: '+IntToStr(glGetError));
 
  WriteLog ('glTexParameteri(GL_TEXTURE_2D,GL_TEXTURE_MIN_FILTER, GL_NEAREST)');
  glTexParameteri(GL_TEXTURE_2D,GL_TEXTURE_MIN_FILTER, GL_NEAREST);
  WriteLog ('error: '+IntToStr(glGetError));
 
  WriteLog ('glTexImage2D(GL_TEXTURE_2D, 0, GL_RGB8, '+IntToStr(pWidth)+', '+IntToStr(pHeight)+', 0, GL_RGB8, GL_UNSIGNED_BYTE, nil)');
  glTexImage2D(GL_TEXTURE_2D, 0, GL_RGB8, pWidth, pHeight, 0, GL_RGB, GL_UNSIGNED_BYTE, nil);
  WriteLog ('error: '+IntToStr(glGetError));
 
  // Es dürfte eigentlich nichts völlig Unverständliches da stehen. Wir
  // erstellen die Textur, binden sie, stellen die Filtermodi ein und erzeugen
  // im Speicher den entsprechenden Platz. Anzumerken ist aber, dass die Textur
  // die gleiche Größe wie der Renderbuffer haben muss. Alle Größen müssen
  // einheitlich sein. Man kann also nicht einen Renderbuffer von 512*512 und
  // eine Textur von 256*256 erstellen und sie zusammen in einem FBO nutzen.
  // Hinzugefügt wird sie nach dem gleichen Schema wie der Depthbuffer:
  WriteLog ('glFramebufferTexture2DEXT(GL_FRAMEBUFFER_EXT, GL_COLOR_ATTACHMENT0_EXT, GL_TEXTURE_2D, FBO_tex, 0)');
  glFramebufferTexture2DEXT(GL_FRAMEBUFFER_EXT, GL_COLOR_ATTACHMENT0_EXT, GL_TEXTURE_2D, FBO_tex, 0);
  WriteLog ('error: '+IntToStr(glGetError));
 
  // Wie gesagt, nicht viel neues hier. Der zweite Parameter,
  // GL_COLOR_ATTACHMENT0_EXT sagt OpenGL wo die Textur hinzugefügt werden
  // soll (man kann mehrere hinzufügen, doch dazu später mehr). Der letzte
  // Parameter beschreibt das Mipmaping-Level.
 
  WriteLog ('checking error');
  CheckFBO;
end;
 
procedure TFrameBufferObject.CheckFBO;
var
  error: GlEnum;
  i: integer;
begin
  error := glCheckFramebufferStatusEXT(GL_FRAMEBUFFER_EXT);
  WriteLog ('error: '+IntToStr(error));
  if error <> GL_FRAMEBUFFER_COMPLETE_EXT then begin
    for i := 0 to Log.Count-1 do begin
      Application.MessageBox(pchar('error '+IntToStr (i+1)+': '+Log.Strings[i]),
                             'Error', MB_OK);
    end;
  end;
  case error of
    GL_FRAMEBUFFER_COMPLETE_EXT:
      Exit;
    GL_FRAMEBUFFER_INCOMPLETE_ATTACHMENT_EXT:
      raise Exception.Create('FBO: Incomplete attachment');
    GL_FRAMEBUFFER_INCOMPLETE_MISSING_ATTACHMENT_EXT:
      raise Exception.Create('FBO: Missing attachment');
    GL_FRAMEBUFFER_INCOMPLETE_DIMENSIONS_EXT:
      raise Exception.Create('FBO: Incomplete dimensions');
    GL_FRAMEBUFFER_INCOMPLETE_FORMATS_EXT:
      raise Exception.Create('FBO: Incomplete formats');
    GL_FRAMEBUFFER_INCOMPLETE_DRAW_BUFFER_EXT:
      raise Exception.Create('FBO: Incomplete draw buffer');
    GL_FRAMEBUFFER_INCOMPLETE_READ_BUFFER_EXT:
      raise Exception.Create('FBO: Incomplete read buffer');
    GL_FRAMEBUFFER_UNSUPPORTED_EXT:
      raise Exception.Create('FBO: Framebufferobjects unsupported');
  end;
end;
 
procedure TFrameBufferObject.WriteLog (s: string);
begin
  Log.Add(s);
end;
 
procedure TFrameBufferObject.PrepareRender;
// bind vor dem rendern auf die textur aufrufen und dann einfach rendern.
// den viewport dann nicht mehr verändern.
begin
  glBindFramebufferEXT(GL_FRAMEBUFFER_EXT, fbo);
  glPushAttrib(GL_VIEWPORT_BIT);
  glViewPort(0, 0, Width, Height);
end;
 
procedure TFrameBufferObject.FinishRender;
// release nach dem rendern auf die textur aufrufen um den viewport
// zurückzusetzen.
begin
  glPopAttrib;
  glBindFramebufferEXT(GL_FRAMEBUFFER_EXT, 0);
end;
 
procedure TFrameBufferObject.Bind;
// vor dem Benutzen der Textur aufrufen
begin
  glBindTexture(GL_TEXTURE_2D, FBO_tex);
  glGenerateMipmapEXT(GL_TEXTURE_2D);
  //Textur danach ganz normal benutzen
end;
 
end.
 

Nach oben

Lord Horazont

Betreff des Beitrags: Re: FrameBufferObject

Verfasst: Di Nov 24, 2009 17:36

DGL Member

Registriert: Do Sep 02, 2004 19:42
Beiträge: 4158
Programmiersprache: FreePascal, C++

Dazu wäre interessant zu wissen, wie du überhaupt zeichnest und was du mit deinem FBO anstellst. Wenn du da reingezeichnet hast, musst du das noch irgendwo wieder aufbringen, als Textur. Ist ja meistens der Sinn der Übung.

greetings

Nach oben

Andyh

Betreff des Beitrags: Re: FrameBufferObject

Verfasst: Di Nov 24, 2009 17:53

DGL Member

Registriert: Do Jun 09, 2005 13:48
Beiträge: 117
Wohnort: Sankt Augustin

Hallo Lord,

bisher zeichne ich die Textur des FBOs überhaupt nicht. Dafür habe ich aber die Methoden FBO.PrepareRender und FBO.FinishRender vorgesehen. Die dann geschriebene Textur kann man mit der Methode FBO.Bind aktivieren. Mein Bildschirm bleibt schwarz, wenn ich das Objekt anlege, also die Methode FBO.Create (512, 512) aufrufe. Alle meine bisherigen Zeichenanweisungen, die funktionieren wenn ich das Objekt nicht anlege, sind dann wirkungslos.

Andree

Nach oben

Lord Horazont

Betreff des Beitrags: Re: FrameBufferObject

Verfasst: Di Nov 24, 2009 17:56

DGL Member

Registriert: Do Sep 02, 2004 19:42
Beiträge: 4158
Programmiersprache: FreePascal, C++

Ah, das könnte damit zusammenhängen, dass du beim Erzeugen das VBO zwar bindest (»glBindFramebufferEXT(GL_FRAMEBUFFER_EXT, fbo);«), aber später nicht wieder entbindest, mit:
glBindFramebufferEXT(GL_FRAMEBUFFER_EXT, 0);

das sollte helfen, nach CheckFBO wäre das angebracht.

Denn solange das FBO gebunden ist, wird dort auch reingerendert. Zumindest meines Wissens nach.

greetings

Nach oben

Coolcat

Betreff des Beitrags: Re: FrameBufferObject

Verfasst: Di Nov 24, 2009 18:09

DGL Member

Registriert: Do Dez 29, 2005 12:28
Beiträge: 2249
Wohnort: Düsseldorf
Programmiersprache: C++, C#, Java

Zitat:

Denn solange das FBO gebunden ist, wird dort auch reingerendert. Zumindest meines Wissens nach.

Korrekt. Die zugehörige Textur ist auch erst verfügbar, wenn ein anderes FBO gebunden wird (z.B. das Default-FBO mit der ID 0)

_________________
Yeah! :mrgreen:

Nach oben

Andyh

Betreff des Beitrags: Re: FrameBufferObject

Verfasst: Di Nov 24, 2009 18:54

DGL Member

Registriert: Do Jun 09, 2005 13:48
Beiträge: 117
Wohnort: Sankt Augustin

Danke,

das war es. Jetzt werde ich meine Klasse austesten und wenn die jemanden interessiert, kann er sich die dann hier abholen. Bisher sieht alles prima aus. Sollten sich noch etwaige Änderungen ergeben, werde ich die hier veröffentlichen.

Andree

Code:

 
unit FrameBufferObjectClass;
 
interface
 
uses
  dglopenGL,
  Windows,
  Classes;
 
type
  TFrameBufferObject = class(TComponent)
    public
      Log        : TstringList;
      Rendering  : boolean;
      procedure Bind;
      procedure PrepareRender;
      procedure FinishRender;
      constructor Create (pWidth, pHeight: GLUInt); reintroduce;
      destructor Destroy; override;
    private
      fbo        : GLUInt;
      depthbuffer: GLUInt;
      Width,
      Height     : GLUInt;
      FBO_tex    : GLUInt;
      procedure CheckFBO;
    procedure WriteLog(s: string);
  end;
 
implementation
 
uses
  SysUtils,
  Forms;
 
destructor TFrameBufferObject.Destroy;
begin
  Log.Free;
  glDeleteTextures(1, @FBO_tex);
  glDeleteFramebuffersEXT(1, @fbo);
  glDeleteRenderbuffersEXT(1, @depthbuffer);
  inherited;
end;
 
constructor TFrameBufferObject.Create (pWidth, pHeight: GLUInt);
begin
  Width     := pWidth;
  Height    := pHeight;
 
  Rendering := false;
 
  Log       := TStringlist.Create;
 
  // Zuerst einmal muss das Framebufferobjekt generiert werden. Dies läuft
  // ähnlich wie das Erstellen einer Textur ab.
  WriteLog ('glGenFramebuffersEXT(1, @fbo)');
  glGenFramebuffersEXT(1, @fbo);
  WriteLog ('error: '+IntToStr(glGetError));
  // Wie bei allem anderen auch müssen wir das Framebufferobjekt jetzt binden,
  // damit alles, was folgt sich auf dieses Objekt bezieht
  WriteLog ('glBindFramebufferEXT(GL_FRAMEBUFFER_EXT, fbo)');
  glBindFramebufferEXT(GL_FRAMEBUFFER_EXT, fbo);
  WriteLog ('error: '+IntToStr(glGetError));
 
  // Ein einfaches Framebufferobjekt ist noch ziemlich nutzlos. Deswegen
  // fügen wir zuerst einmal einen der neu eingeführten Renderbuffer als
  // Depthbuffer hinzu. Renderbuffer sind im Prinzip Objekte, die benutzt
  // werden wenn ein Buffer kein zugehöriges Texturformat besitzt. Dazu zählen
  // u.a. der Stencilbuffer, der Accumulationbuffer und der Depthbuffer. Das
  // Binden an den Accumulationbuffer wurde allerdings auf eine spätere
  // Extension verschoben. Wie auch beim Framebufferobjekt müssen wir einen
  // Renderbuffer zuerst generieren und dann binden:
  WriteLog ('glGenRenderbuffersEXT(1, @depthbuffer)');
  glGenRenderbuffersEXT(1, @depthbuffer);
  WriteLog ('error: '+IntToStr(glGetError));
 
  WriteLog ('glBindRenderbufferEXT(GL_RENDERBUFFER_EXT, depthbuffer)');
  glBindRenderbufferEXT(GL_RENDERBUFFER_EXT, depthbuffer);
  WriteLog ('error: '+IntToStr(glGetError));
 
  // Derzeit hat der Renderbuffer allerdings noch keinen Speicher zugeteilt
  // bekommen. Deswegen sagen wir OpenGL, wie wir den Renderbuffer benutzen
  // wollen und welche Größe er haben soll:
  WriteLog ('glRenderbufferStorageEXT(GL_RENDERBUFFER_EXT, GL_DEPTH_COMPONENT, '+IntToStr(pWidth)+', '+IntToStr(pHeight)+')');
  glRenderbufferStorageEXT(GL_RENDERBUFFER_EXT, GL_DEPTH_COMPONENT, pWidth, pHeight);
  WriteLog ('error: '+IntToStr(glGetError));
 
  // Mit glRenderbufferStorageEXT hat OpenGL den Speicher für den Renderbuffer,
  // den wir als Depthbuffer nutzen, reserviert. Jetzt können wir unseren
  // Depthbuffer zum FBO hinzufügen:
  WriteLog ('glFramebufferRenderbufferEXT(GL_FRAMEBUFFER_EXT,'+
                                         'GL_DEPTH_ATTACHMENT_EXT,'+
                                         'GL_RENDERBUFFER_EXT, depthbuffer)');
  glFramebufferRenderbufferEXT(GL_FRAMEBUFFER_EXT,
                               GL_DEPTH_ATTACHMENT_EXT,
                               GL_RENDERBUFFER_EXT, depthbuffer);
  WriteLog ('error: '+IntToStr(glGetError));
  // Die letzte Anweisung sollte ziemlich einfach zu verstehen sein. Der zweite
  // Parameter sagt einfach, als was der Renderbuffer genutzt werden soll
 
  // Um Farbinformationen in unser Framebufferobjekt schreiben zu können,
  // fügen wir eine Textur hinzu. Bevor wir sie hinzufügen können müssen wir
  // sie natürlich noch erstellen:
  WriteLog ('glGenTextures(1, @FBO_tex)');
  glGenTextures(1, @FBO_tex);
  WriteLog ('error: '+IntToStr(glGetError));
 
  WriteLog ('glBindTexture(GL_TEXTURE_2D, FBO_tex)');
  glBindTexture(GL_TEXTURE_2D, FBO_tex);
  WriteLog ('error: '+IntToStr(glGetError));
 
  WriteLog ('glTexParameteri(GL_TEXTURE_2D,GL_TEXTURE_MAG_FILTER, GL_NEAREST)');
  glTexParameteri(GL_TEXTURE_2D,GL_TEXTURE_MAG_FILTER, GL_NEAREST);
  WriteLog ('error: '+IntToStr(glGetError));
 
  WriteLog ('glTexParameteri(GL_TEXTURE_2D,GL_TEXTURE_MIN_FILTER, GL_NEAREST)');
  glTexParameteri(GL_TEXTURE_2D,GL_TEXTURE_MIN_FILTER, GL_NEAREST);
  WriteLog ('error: '+IntToStr(glGetError));
 
  WriteLog ('glTexImage2D(GL_TEXTURE_2D, 0, GL_RGB8, '+IntToStr(pWidth)+', '+IntToStr(pHeight)+', 0, GL_RGB8, GL_UNSIGNED_BYTE, nil)');
  glTexImage2D(GL_TEXTURE_2D, 0, GL_RGB8, pWidth, pHeight, 0, GL_RGB, GL_UNSIGNED_BYTE, nil);
  WriteLog ('error: '+IntToStr(glGetError));
 
  // Es dürfte eigentlich nichts völlig Unverständliches da stehen. Wir
  // erstellen die Textur, binden sie, stellen die Filtermodi ein und erzeugen
  // im Speicher den entsprechenden Platz. Anzumerken ist aber, dass die Textur
  // die gleiche Größe wie der Renderbuffer haben muss. Alle Größen müssen
  // einheitlich sein. Man kann also nicht einen Renderbuffer von 512*512 und
  // eine Textur von 256*256 erstellen und sie zusammen in einem FBO nutzen.
  // Hinzugefügt wird sie nach dem gleichen Schema wie der Depthbuffer:
  WriteLog ('glFramebufferTexture2DEXT(GL_FRAMEBUFFER_EXT, GL_COLOR_ATTACHMENT0_EXT, GL_TEXTURE_2D, FBO_tex, 0)');
  glFramebufferTexture2DEXT(GL_FRAMEBUFFER_EXT, GL_COLOR_ATTACHMENT0_EXT, GL_TEXTURE_2D, FBO_tex, 0);
  WriteLog ('error: '+IntToStr(glGetError));
 
  // Wie gesagt, nicht viel neues hier. Der zweite Parameter,
  // GL_COLOR_ATTACHMENT0_EXT sagt OpenGL wo die Textur hinzugefügt werden
  // soll (man kann mehrere hinzufügen, doch dazu später mehr). Der letzte
  // Parameter beschreibt das Mipmaping-Level.
 
  WriteLog ('checking error');
  CheckFBO;
 
  // FBO "entbinden", damit wieder normal gezeichnet werden kann.
  glBindFramebufferEXT(GL_FRAMEBUFFER_EXT, 0);
end;
 
procedure TFrameBufferObject.CheckFBO;
var
  error: GlEnum;
  i: integer;
begin
  error := glCheckFramebufferStatusEXT(GL_FRAMEBUFFER_EXT);
  WriteLog ('error: '+IntToStr(error));
  if error <> GL_FRAMEBUFFER_COMPLETE_EXT then begin
    for i := 0 to Log.Count-1 do begin
      Application.MessageBox(pchar('error '+IntToStr (i+1)+': '+Log.Strings[i]),
                             'Error', MB_OK);
    end;
  end;
  case error of
    GL_FRAMEBUFFER_COMPLETE_EXT:
      Exit;
    GL_FRAMEBUFFER_INCOMPLETE_ATTACHMENT_EXT:
      raise Exception.Create('FBO: Incomplete attachment');
    GL_FRAMEBUFFER_INCOMPLETE_MISSING_ATTACHMENT_EXT:
      raise Exception.Create('FBO: Missing attachment');
    GL_FRAMEBUFFER_INCOMPLETE_DIMENSIONS_EXT:
      raise Exception.Create('FBO: Incomplete dimensions');
    GL_FRAMEBUFFER_INCOMPLETE_FORMATS_EXT:
      raise Exception.Create('FBO: Incomplete formats');
    GL_FRAMEBUFFER_INCOMPLETE_DRAW_BUFFER_EXT:
      raise Exception.Create('FBO: Incomplete draw buffer');
    GL_FRAMEBUFFER_INCOMPLETE_READ_BUFFER_EXT:
      raise Exception.Create('FBO: Incomplete read buffer');
    GL_FRAMEBUFFER_UNSUPPORTED_EXT:
      raise Exception.Create('FBO: Framebufferobjects unsupported');
  end;
end;
 
procedure TFrameBufferObject.WriteLog (s: string);
begin
  Log.Add(s);
end;
 
procedure TFrameBufferObject.PrepareRender;
// bind vor dem rendern auf die textur aufrufen und dann einfach rendern.
// den viewport dann nicht mehr verändern.
begin
  glBindFramebufferEXT(GL_FRAMEBUFFER_EXT, fbo);
  glPushAttrib(GL_VIEWPORT_BIT);
  glViewPort(0, 0, Width, Height);
  Rendering := true;
end;
 
procedure TFrameBufferObject.FinishRender;
// release nach dem rendern auf die textur aufrufen um den viewport
// zurückzusetzen.
begin
  glPopAttrib;
  glBindFramebufferEXT(GL_FRAMEBUFFER_EXT, 0);
  Rendering := false;
end;
 
procedure TFrameBufferObject.Bind;
// vor dem Benutzen der Textur aufrufen
begin
  glBindTexture(GL_TEXTURE_2D, FBO_tex);
  glGenerateMipmapEXT(GL_TEXTURE_2D);
  //Textur danach ganz normal benutzen
end;
 
end.
 

Zuletzt geändert von Lord Horazont am Di Nov 24, 2009 19:29, insgesamt 1-mal geändert.

Code-Tag auf Pascal umgestellt

Nach oben

Andyh

Betreff des Beitrags: Ready: FrameBufferObject

Verfasst: Mi Nov 25, 2009 04:30

DGL Member

Registriert: Do Jun 09, 2005 13:48
Beiträge: 117
Wohnort: Sankt Augustin

Hallo,

ich bin soweit fertig. Da ich leider hier keine ZIP-Datei anhängen kann, habe ich die fertige Software (EXE) als Archiv auf meine Homepage gestellt. Wer mich kontaktiert, bekommt auch den Sourcecode. Direkter Link zum Download: http://www.heyroths.de/main.html?src=%2F#2,3
Diese Anwendung ist nur als Test für die neue Klasse und weitere meiner Versuche gedacht. Trotzdem viel Spaß,

Andree

Nach oben

Seite 1 von 1

[ 11 Beiträge ]

Foren-Übersicht » Programmierung » OpenGL

Wer ist online?

Mitglieder in diesem Forum: 0 Mitglieder und 2 Gäste

Du darfst keine neuen Themen in diesem Forum erstellen.
Du darfst keine Antworten zu Themen in diesem Forum erstellen.
Du darfst deine Beiträge in diesem Forum nicht ändern.
Du darfst deine Beiträge in diesem Forum nicht löschen.
Du darfst keine Dateianhänge in diesem Forum erstellen.