DGL • Thema anzeigen - Torus - neues Geometrie Objekt für Wiki?!

Torus - neues Geometrie Objekt für Wiki?!

Moderator: DGL-Team

Seite 1 von 1

[ 3 Beiträge ]

Vorheriges Thema | Nächstes Thema

Autor

Nachricht

Emre

Betreff des Beitrags: Torus - neues Geometrie Objekt für Wiki?!

Verfasst: Do Jun 11, 2009 07:47

DGL Member

Registriert: Mo Jun 30, 2008 12:47
Beiträge: 69

Hab heute beim Nachgrübeln der Wiki das Fehlen des Toruses bei "Wiki-Techniken und Algorithmen-2.3.1 Geometrie Objekte" entdeckt.

Hier mein Vorschlagscode:

MainFunctions:
-CreateTorus
-RenderTorus

Code:

 
//Auszüge aus uVector ..
const
  toRad: Single = 0.0174532925199433; // = PI / 180
  vecX = 0;
  vecY = 1;
  vecZ = 2;
 
type
  PVector3F = ^TVector3F;
  TVector3F = Array[0..2] of Single;
 
  TTorus = Array of Array of TVector3F;
 
function Vec3F( const X, Y, Z: Single ): TVector3F;
begin
  Result[vecX] := X;
  Result[vecY] := Y;
  Result[vecZ] := Z;
end;
 
function NormalizeVec3F( const A: PVector3F ): TVector3F;
var
  d: Single;
begin
  d := SQRT( A^[vecX] * A^[vecX] + A^[vecY] * A^[vecY] + A^[vecZ] * A^[vecZ] );
  if d > 0 then
    Result := Vec3F( A^[vecX]/d, A^[vecY]/d, A^[vecZ]/d );
end;
 
function SubVec3F( const A, B: PVector3F ): TVector3F; 
begin
  Result := Vec3F( A^[vecX] - B^[vecX], A^[vecY] - B^[vecY], A^[vecZ] - B^[vecZ] );
end;
 
function CrossProduct3F( const A, B: PVector3F ): TVector3F;
begin
  Result := Vec3F(
    A^[vecY]*B^[vecZ] - A^[vecZ]*B^[vecY],
    A^[vecZ]*B^[vecX] - A^[vecX]*B^[vecZ],
    A^[vecX]*B^[vecY] - A^[vecY]*B^[vecX]
  );
end;
 
// HERE IT IS :D
function CreateTorus( const MainCircleEdges, SecCircleEdges: Word;
  const MainCircleRadius, SecCircleRadius: Single): TTorus;
var
  Main, Sec: TVector3F;
  mTheta, sTheta: Single;
  i, j: Integer;
begin
  SetLength( Result, MainCircleEdges, SecCircleEdges );
  mTheta := 360/(MainCircleEdges);
  sTheta := 360/(SecCircleEdges);
  for i := 0 to MainCircleEdges-1 do
    for j := 0 to SecCircleEdges-1 do
      Result[i,j] := vec3F(
        (MainCircleRadius+SecCircleRadius*Cos((sTheta*j)*toRad))*cos((mTheta*i)*toRad),
        (MainCircleRadius+SecCircleRadius*Cos((sTheta*j)*toRad))*sin((mTheta*i)*toRad),
        SecCircleRadius*sin((sTheta*j)*toRad) );
end;
 
procedure RenderTorus( const Torus: TTorus );
var
  iH, jH: Integer;
  i, j: Integer;
  vec1, vec2,
  vec3, norm,
  tmp1, tmp2: TVector3F;
  procedure Draw();
  begin
    tmp1 := SubVec3F( @Vec2, @Vec1 );
    tmp2 := SubVec3F( @Vec3, @Vec1 );
    norm := CrossProduct3F( @tmp1, @tmp2 );
    norm := NormalizeVec3F( @norm );
    glNormal3FV( @norm );
    glVertex3FV( @vec1 );
    glVertex3FV( @vec2 );
    glVertex3FV( @vec3 );
  end;
begin
  iH := High(Torus)+1;
  jH := High(Torus[0])+1;
  glBegin( gl_Triangles );
    for i := 0 to iH-1 do
      for j := 0 to jH-1 do
      begin
        vec1 := vec3F( Torus[i,j,vecX], Torus[i,j,vecY], Torus[i,j,vecZ] );
        vec2 := vec3F( Torus[(i+1) mod iH,j,vecX], Torus[(i+1) mod iH,j,vecY], Torus[(i+1) mod iH,j,vecZ] );
        vec3 := vec3F( Torus[(i+1) mod iH,(j+1) mod jH,vecX], Torus[(i+1) mod iH,(j+1) mod jH,vecY], Torus[(i+1) mod iH,(j+1) mod jH,vecZ] );
        Draw();
        vec2 := vec3;
        vec3 := vec3F( Torus[i,(j+1) mod jH,vecX], Torus[i,(j+1) mod jH,vecY], Torus[i,(j+1) mod jH,vecZ] );
        Draw();
      end;
  glEnd();
end;
 

Edit:
Zu CreateTorus:
const MainCircleEdges = Anzahl der Ecken vom großen Kreis
const SecCircleEdges = Anzahl der Ecken vom kleinen Kreis;
const MainCircleRadius = Raidus vom großen Kreis
const SecCircleRadius = Radius vom kleinen Kreis

Du hast keine ausreichende Berechtigung, um die Dateianhänge dieses Beitrags anzusehen.

_________________
...GOD is wearing black...

Nach oben

Delphic

Betreff des Beitrags:

Verfasst: Do Jun 11, 2009 09:04

DGL Member

Registriert: Do Mai 30, 2002 18:48
Beiträge: 1617

Sind bereits enthalten, siehe Geometrie_durch_Kurven, man merkts nur nicht sofort, daß sie da sind :-)

Nach oben

Flash

Betreff des Beitrags:

Verfasst: Do Jun 11, 2009 14:09

Guitar Hero

Registriert: Do Sep 25, 2003 15:56
Beiträge: 7810
Wohnort: Sachsen - ERZ / C
Programmiersprache: Java (, Pascal)

Was soll das heißen? Sind die nicht verlinkt? Wenn nicht, dann bitte nachholen. Vielleicht auch mit sprechenderem Namen.

_________________
Blog: kevin-fleischer.de und fbaingermany.com

Nach oben

Seite 1 von 1

[ 3 Beiträge ]

Foren-Übersicht » Programmierung » OpenGL

Wer ist online?

Mitglieder in diesem Forum: 0 Mitglieder und 2 Gäste

Du darfst keine neuen Themen in diesem Forum erstellen.
Du darfst keine Antworten zu Themen in diesem Forum erstellen.
Du darfst deine Beiträge in diesem Forum nicht ändern.
Du darfst deine Beiträge in diesem Forum nicht löschen.
Du darfst keine Dateianhänge in diesem Forum erstellen.