DGL • Thema anzeigen - Partikel Performance verbessern

Partikel Performance verbessern

Moderator: DGL-Team

Seite 1 von 1

[ 4 Beiträge ]

Vorheriges Thema | Nächstes Thema

Autor

Nachricht

Gandalfus

Betreff des Beitrags: Partikel Performance verbessern

Verfasst: Fr Okt 26, 2007 13:22

DGL Member

Registriert: Mi Mai 30, 2007 15:15
Beiträge: 20

Ich habe ein kleines PartikelSystem programmiert wobei ich aber Probleme mit der Performance habe.
Liegt es jetzt an der Anzahl der Dreicke? Dann müsste doch die Performance besser werden wenn ich die Partikel Grösse erhöhe und die Anzahl verringere. Das trifft aber nicht zu. 10000 QUADS sollten doch kein Problem sein oder?

Code:

type
 
  TPartikel = class
  protected
    Color: TGLColor;
    LifeTime: int64;
    StartTime: int64;
    x,y,z: double;
    speedx, speedy, speedz: double;
    alpha: double;
    size: double;
  public
    procedure setSize(aSize: double);
    procedure setPositions(ax, ay, az: double);
    procedure paint(const Right,Up,View: TVektor);
    function move(vergangendeZeit: int64): boolean; //result=Kollision mit Rand
    constructor CreateParam(ax, ay, az, axspeed, ayspeed, azspeed: double; aLifetime: int64; aColor: TGLColor);
    destructor Destroy; override;
  end;
 
  TParticelControl = class
  protected
    x,y,z: double;
    Partikel: TObjectlist;
    Partikelspeed: integer;
    starttime: int64;
    Effektdauer: integer;
    nureinmal: boolean;
    gestartet: boolean;
    fTexture: TglBitmap2D;
  public
    procedure paint; virtual;
    function move(vergangendeZeit: int64): boolean; virtual; //result=Effekt fertig
    constructor Create(); virtual;
    procedure start(ax,ay,az: double); virtual;
    procedure stop; virtual;
    destructor Destroy; override;
  end;
 
implementation
 
constructor TParticelControl.Create;
begin
  Effektdauer := MAXINT;
  Partikel:= TObjectlist.Create(true);
  nureinmal:=true;
 
  fTexture := TglBitmap2D.Create(); // Instanz erstellen und Datei laden
  fTexture.LoadFromFile(ExtractFilePath(ParamStr(0))+'Texturen\point.bmp');
  //fTexture.AddAlphaFromColorKey(0,0,0,50) ;
  //fTexture.AddAlphaFromFile(ExtractFilePath(ParamStr(0))+'point.bmp');
  fTexture.GenTexture; // geladene Textur an OpenGL übergeben
 
 
  gestartet :=false;
end;
 
destructor TParticelControl.Destroy;
begin
  Partikel.Clear;
  Partikel.Free;
  fTexture.Free;
  inherited;
end;
 
procedure TParticelControl.paint;
var
  i: integer;
  Matrix: array [0.. 15] of single;
  Right,Up,View: TVektor;
begin
  if gestartet then
  begin
    glGetFloatv( GL_MODELVIEW_MATRIX, @Matrix );
    Right.x := Matrix[0]/sqrt(sqr(Matrix[0])+sqr(Matrix[4])+sqr(Matrix[8]));
    Right.y := Matrix[4]/sqrt(sqr(Matrix[0])+sqr(Matrix[4])+sqr(Matrix[8]));
    Right.z := Matrix[8]/sqrt(sqr(Matrix[0])+sqr(Matrix[4])+sqr(Matrix[8]));
    Up.x := Matrix[1]/sqrt(sqr(Matrix[1])+sqr(Matrix[5])+sqr(Matrix[9]));
    Up.y := Matrix[5]/sqrt(sqr(Matrix[1])+sqr(Matrix[5])+sqr(Matrix[9]));
    Up.z  := Matrix[9]/sqrt(sqr(Matrix[1])+sqr(Matrix[5])+sqr(Matrix[9]));
    View.x := Matrix[2];
    View.y := Matrix[6];
    View.z := Matrix[10];
 
    glDepthMask(false);
    glEnable(GL_BLEND);
    glBlendFunc(GL_SRC_ALPHA, GL_ONE);
    glEnable(GL_TEXTURE_2D);
    //glEnable(GL_ALPHA_TEST);
    //glAlphaFunc(GL_GREATER, 0.1);
    fTexture.Bind;
 
    glBegin(GL_QUADS);
    for i := 0 to Partikel.Count - 1 do
    begin
      TPartikel(Partikel.items[i]).paint(Right,Up,View);
    end;
    glEnd();
 
    fTexture.Unbind();
    glDisable(GL_TEXTURE_2D);
    glDepthMask(true);
    glDisable(GL_BLEND);
  end;
  //glDisable(GL_ALPHA_TEST);
 
end;
 
function TParticelControl.move(vergangendeZeit: int64): boolean;
var
  i: integer;
begin
  result:=false;
 
  if gestartet then
  begin
    for i := Partikel.Count - 1 downto 0 do
    begin
      if TPartikel(Partikel.items[i]).move(vergangendeZeit) then
        Partikel.Delete(i);
    end;
 
    if ((timegettime-starttime)>Effektdauer) then
    begin
      result := true;
      gestartet:=false;
      //Partikel.clear;
    end;
  end;
 
end;
 
procedure TParticelControl.start(ax,ay,az: double);
begin
  x:=ax;
  y:=ay;
  z:=az;
 
  Partikel.Clear;
 
  starttime:=timegettime;
  gestartet:=true;
end;
 
procedure TParticelControl.stop;
begin
  gestartet:=false;
end;
 
{ TPartikel }
 
constructor TPartikel.CreateParam(ax, ay, az, axspeed, ayspeed, azspeed: double; aLifetime: int64; aColor: TGLColor);
begin
  x:=ax;
  y:=ay;
  z:=az;
  color := aColor;
 
  speedx := axspeed;
  speedy := ayspeed;
  speedz := azspeed;
  StartTime := timegettime;
  LifeTime := aLifetime;
 
  size := 4.0
end;
 
destructor TPartikel.Destroy;
begin
 
  inherited;
end;
 
function TPartikel.move(vergangendeZeit: int64): boolean;
begin
  result := false;
  x := x+(speedx*vergangendeZeit/(1000));
  y := y+(speedy*vergangendeZeit/(1000));
  z := z+(speedz*vergangendeZeit/(1000));
  if (timegettime - StartTime)>LifeTime then result := true;
end;
 
procedure TPartikel.paint(const Right,Up,View: TVektor);
begin
 
  alpha := 1-(timegettime - StartTime)/LifeTime;
  if alpha>1.0 then alpha := 1.0;
 
 
  glColor4f(color[0], color[1],color[2], alpha);
  glNormal3f(View.x,View.y,View.z);
 
 
  glTexCoord2f(0,0);
  glVertex3f(x+Up.x*size,y+Up.y*size,z+Up.z*size);
  glTexCoord2f(0,1);
  glVertex3f(x+0,y+0,z+0);
  glTexCoord2f(1,1);
  glVertex3f(x+Right.x*size,y+Right.y*size,z+Right.z*size);
  glTexCoord2f(1,0);
  glVertex3f(x+(Right.x+Up.x)*size,y+(Right.y+Up.y)*size,z+(Right.z+Up.z)*size);
 
end;
 
procedure TPartikel.setSize(aSize: double);
begin
  size := asize;
end;
 

Code:

 
type
  TExplossionsEffekt = class(TParticelControl)
  protected
    spawnStartTime: int64;
    Color: TGLcolor;
    radius: double;
  public
    procedure setradius(aradius: double);
    function move(vergangendeZeit: int64): boolean; override; //result=Effekt fertig
    procedure start(ax,ay,az: double; aColor: TGLcolor; aradius: double; aEffektdauer: integer); reintroduce;
  end;
 
implementation
 
{ TExplossionsEffekt }
 
function TExplossionsEffekt.move(vergangendeZeit: int64): boolean;
var
  i,u: integer;
  PartikelCount: integer;
  PartikelLifeTime: integer;
  xspeed,yspeed,zspeed: double;
  theta1,theta2: double;
  colorTemp: TGlColor;
  tempPartikellifetime: integer;
begin
 
  PartikelCount := 15;
  Partikelspeed:=25;
  PartikelLifeTime := round(Partikelspeed*radius);
 
  if gestartet then
  begin
    if not ((timegettime-starttime)>(Effektdauer-tempPartikellifetime)) and  ((timegettime-spawnStartTime)>150) then
    begin
      for u:=0 to PartikelCount do
      begin
        theta1 := degtorad(random(360));
 
        for i:=0 to PartikelCount do
        begin
          theta2 := degtorad(random(360));
 
          xspeed := Partikelspeed*((90+random(20))/100)*cos(theta1) * cos(theta2);
          yspeed := Partikelspeed*((90+random(20))/100)*sin(theta1);
          zspeed := Partikelspeed*((90+random(20))/100)*cos(theta1) * sin(theta2);
 
          colorTemp[0] := color[0]*((80+random(20))/100);
          colorTemp[1] := color[1]*((80+random(20))/100);
          colorTemp[2] := color[2]*((80+random(20))/100);
        Partikel.Add(TPartikel.CreateParam(x-2+random(4),y-2+random(4),z-2+random(4),xspeed,yspeed,zspeed,PartikelLifeTime,colorTemp));
          TPartikel(Partikel.last).setSize(12);
        end;
      end;
 
      spawnStartTime := timegettime;
 
    end;
  end;
 
 
  result := inherited move(vergangendeZeit);
end;
 
procedure TExplossionsEffekt.start(ax, ay, az: double; aColor: TGLcolor; aradius: double; aEffektdauer: integer);
begin
  inherited start(ax, ay, az);
  spawnStartTime := timegettime;
  color := acolor;
  radius := aradius;
  Effektdauer := aEffektdauer;
end;
 

Das wichtigste dürfte in TExplossionsEffekt.move und in TParticelControl.paint sein.

Nach oben

Seth

Betreff des Beitrags:

Verfasst: Fr Okt 26, 2007 13:40

DGL Member

Registriert: Di Mai 24, 2005 16:43
Beiträge: 710

Ich bin mir nicht sicher, aber kann es nicht sein, dass hier die CPU ein wenig zu leiden hat ?
So wie ich das sehe ist bei dir jedes Partikel eine eigene Klasse mit vielen untertypen. ich habe versucht, meine partikel so minimalistisch wie möglich zu gestalten, also records mit wenigen informationen und so viel es geht in den emitter auslagern.
des weiteren solltest du schauen, ob du immer alle 10000 partikel zeichnen musst, oder ob du zB Frustrum culling einsetzen kannst.

mfg

Nach oben

Lossy eX

Betreff des Beitrags:

Verfasst: Fr Okt 26, 2007 14:20

DGL Member

Registriert: Do Dez 05, 2002 10:35
Beiträge: 4234
Wohnort: Dortmund

In jedem Falle solltest du die Zeiten messen die die einzelnen Funktionen benötigen. Dazu solltest du dir mal QueryPerformanceFrequency und QueryPerformanceCounter etwas näher anschauen. Denn dann kannst du erst richtig abschätzen was wie lange die einzelnen Teile benötigen.

Was ich persönlich ziemlich häftig finde ist das Paint des einzelnen Partikels. Dort musst du für jede kleine Koordinate extra eine Berechnung anwerfen. Ich würde versuchen das so einfach wie möglich zu gestalten. So viel wie möglich vorberechnen etc. Denn solche Berechnungen finden auf der FPU statt und eine zu starke vermischung zwischen FPU und CPU bringt Delphi etwas aus dem Tritt. Also so etwas sind stellen die immer gut Zeit benötigen.

Evtl könnte es auch einiges bringen zuvor die Punkte in ein VBO zu schreiben und dann dieses zu rendern. Evtl geht es schneller, da du derzeit bei jedem Quad warten musst bist die Grafikkarte fertig ist und so würdest du es in einen Speicher packen und anschließend nur sagen zeichnen. Wärend die Grafikkarte dann die Punkte zeichnet könntest du schon wieder andere Sachen machen, da das ganze ja asynchron abläuft.

Nach oben

elektrokrach

Betreff des Beitrags:

Verfasst: Fr Okt 26, 2007 16:05

DGL Member

Registriert: Di Okt 23, 2007 10:20
Beiträge: 84

unwichtig

Nach oben

Seite 1 von 1

[ 4 Beiträge ]

Foren-Übersicht » Programmierung » OpenGL

Wer ist online?

Mitglieder in diesem Forum: 0 Mitglieder und 20 Gäste

Du darfst keine neuen Themen in diesem Forum erstellen.
Du darfst keine Antworten zu Themen in diesem Forum erstellen.
Du darfst deine Beiträge in diesem Forum nicht ändern.
Du darfst deine Beiträge in diesem Forum nicht löschen.
Du darfst keine Dateianhänge in diesem Forum erstellen.