DGL • Thema anzeigen - Exception bei Textausgabe

Exception bei Textausgabe

Moderator: DGL-Team

Seite 1 von 1

[ 14 Beiträge ]

Vorheriges Thema | Nächstes Thema

Autor

Nachricht

Boogi

Betreff des Beitrags: Exception bei Textausgabe

Verfasst: Do Okt 06, 2005 23:01

DGL Member

Registriert: Di Mär 16, 2004 22:25
Beiträge: 17

Hi,

hab das Bombermantut als Basis fürn eigenes Spiel genommen. Jetzt hab ich folgendes Problem:

Im OnIdle wird mein Menü gezeichnet und es funktioniert alles gut, wenn ich aber denselben Code in ne Procedure meines GameObjects auslagere krieg ich ne Exception beim Zeichnen des Textes (texturemanager.Print2d bei FontTexture.Bind).
Im OnIdle steht sonst nichts oglmässiges drin.

Code:

 
glMatrixMode(GL_PROJECTION);
  glLoadIdentity;
  glOrtho(0,640,480,0,-2,2);
  glMatrixMode(GL_MODELVIEW);
  glLoadIdentity;
  glEnable(GL_Texture_2d);
  TextureManager.BindTexture('inevitable_1024.jpg');
  glDisable(gl_Depth_test);
  glClear(GL_DEPTH_BUFFER_BIT or GL_COLOR_BUFFER_BIT);
  glColor3f(1,1,1);
  glBegin(GL_QUADS);
   glTexCoord2f(0,1); glVertex3f(0, 0, 0);
   glTexCoord2f(0,0); glVertex3f(0, 480, 0);
   glTexCoord2f(1,0); glVertex3f(640, 480, 0);
   glTexCoord2f(1,1); glVertex3f(640, 0, 0);
  glEnd;
  for i := Low(EntryName) to High(EntryName) do
    if i = Game.MenueSelected then
      TextureFont.Print2D(EntryName[i], [230,EntryPos[i],0],[1,0.3,0.3],1,1)
    else
      TextureFont.Print2D(EntryName[i], [230,EntryPos[i],0],[1,1,1],1,1);
  swapBuffers(DC);
 

Gruß Steffen

Nach oben

Flash

Betreff des Beitrags:

Verfasst: Do Okt 06, 2005 23:16

Guitar Hero

Registriert: Do Sep 25, 2003 15:56
Beiträge: 7810
Wohnort: Sachsen - ERZ / C
Programmiersprache: Java (, Pascal)

Hmmmm eventuell hast du einen anderen GL Header eingebunden. In deinem gesamten Quellcode muss überall der selbe Header verwendet werden. (z.B. kracht es wenn du in der Hauptdatei die DGLopenGL.pas benutzt und in ner anderen Datei dann die OpenGL.pas einbindest.)

Allerdings kann man aus dem Code net viel erkennen.... Ich jedenfalls net...

_________________
Blog: kevin-fleischer.de und fbaingermany.com

Nach oben

Boogi

Betreff des Beitrags:

Verfasst: Do Okt 06, 2005 23:33

DGL Member

Registriert: Di Mär 16, 2004 22:25
Beiträge: 17

hab überall den gleichen header.
hab grad in meiner formularunit n testobject gemacht und den Code da reingepackt. Da gehts.
Nur nich wenn der Code in ner anderen unit steht.

Nach oben

Lossy eX

Betreff des Beitrags:

Verfasst: Fr Okt 07, 2005 07:28

DGL Member

Registriert: Do Dez 05, 2002 10:35
Beiträge: 4234
Wohnort: Dortmund

Kann mich Flash nur anschließen. Das was du an Code gepostet hast lässt nicht viel erkennen.
Mich würde aber auch mal interessieren was für eine Exception auftritt. Normal haben die auch nen Text und nen Exceptiontypen. Wenn du uns das sagen kannst, dann können wir schon viel mehr vermuten.

Außerdem kann ich deinen Ausführungen mit dem Manager und der Textur nicht ganz folgen. Zu mindest decken die sich überhaupt nicht mit dem Code den du gepostet hast. Wenn ich da mal was aufführen dürfte.

Code:

texturemanager.Print2d
TextureManager.BindTexture('inevitable_1024.jpg');
FontTexture.Bind
TextureFont.Print2D(EntryName[i], [230,EntryPos[i],0],[1,0.3,0.3],1,1)

Was gehört denn jetzt wohin? ;-)

Zitat:

hab überall den gleichen header.

Nur um sicher zu gehen. Benutzt du Fremdunits? Wenn ja müssen die natürlich auch den selben Header benutzen. Aber ob es an so etwas liegen würde könnte man anhand einer detailierten Fehlerbeschreibung schon erkennen. ;-)

Zitat:

Im OnIdle steht sonst nichts oglmässiges drin.

Exceptions können überall auftreten. Das hat nicht unbedingt was mit OpenGL zu tun. Normal liefert OpenGL nämlich keine Exceptions sondern man muss einen Fehlercode abfragen.

Nach oben

Boogi

Betreff des Beitrags:

Verfasst: Fr Okt 07, 2005 12:03

DGL Member

Registriert: Di Mär 16, 2004 22:25
Beiträge: 17

Sorry für die etwas unpräzisen Angaben.

Ich benutz den Texturemanager aus dem Bombermantut für die "normalen" Texturen.
Und die Texturefonts aus demselben Tut fürs Textzeichnen.

Hab grad den texturemanager und alles andere überflüssige komplett entfernt.
hab jetzt nur noch die texturefonts aus dem tut drin. ändert trotzdem nichts.

Als Exception kommt:

Benachrichtigung über Debugger-Exception
Im Projekt EarthDefender.exe ist eine Exception der Klasse EAcessViolation mit der Meldung 'Zugriffsverletzung bei Adresse 00490FA5 in Modul 'EarthDefender.exe'. Lesen von Adresse 00000008' aufgetreten.

Danach springt er zur Zeile "FontTexture.Bind" der "TTexFont.Print2d" aus "BombermanFont.pas"

Das merkwürdige ist ja, dass es funzt, wenn der zeichencode im mainform drinsteht, aber sobald er in ne andere unit ausgelagert wird gehts nimmer.

Wenns hilft hier der Code:

Mainform:

Code:

 
unit Main;
 
interface
 
uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs,
 
  jpeg,
  dglOpenGL,
 
  EDGame,
  EDFonts,
  StdCtrls;
 
type
  TMainForm = class(TForm)
    procedure FormResize(Sender: TObject);
    procedure FormPaint(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
    procedure ApplicationEventsIdle(Sender: TObject; var Done: Boolean);
    procedure FormCreate(Sender: TObject);
  private
    { Private-Deklarationen }
  public
    { Public-Deklarationen }
    procedure GoToFullScreen(pWidth, pHeight, pBPP, pFrequency : Word);
  end;
 
var
  MainForm: TMainForm;
 
implementation
 
{$R *.dfm}
 
 
// =============================================================================
//  TMainForm.GoToFullScreen
// =============================================================================
//  Wechselt in den mit den Parametern angegebenen Vollbildmodus
// =============================================================================
procedure TMainForm.GoToFullScreen(pWidth, pHeight, pBPP, pFrequency : Word);
var
  dmScreenSettings : DevMode;
begin
  // Fenster vor Vollbild vorbereiten
  WindowState := wsMaximized;
  BorderStyle := bsNone;
  ZeroMemory(@dmScreenSettings, SizeOf(dmScreenSettings));
  with dmScreenSettings do begin
    dmSize              := SizeOf(dmScreenSettings);
    dmPelsWidth         := pWidth;                    // Breite
    dmPelsHeight        := pHeight;                   // Höhe
    dmBitsPerPel        := pBPP;                      // Farbtiefe
    dmDisplayFrequency  := pFrequency;                // Bildwiederholfrequenz
    dmFields            := DM_PELSWIDTH or DM_PELSHEIGHT or DM_BITSPERPEL or DM_DISPLAYFREQUENCY;
  end;
  if (ChangeDisplaySettings(dmScreenSettings, CDS_FULLSCREEN) = DISP_CHANGE_FAILED) then begin
    MessageBox(0, 'Konnte Vollbildmodus nicht aktivieren!', 'Error', MB_OK or MB_ICONERROR);
    exit
  end;
end;
 
// =============================================================================
//  TMainForm.FormCreate
// =============================================================================
//  Initialisiert das Hauptfenster MainForm
// =============================================================================
procedure TMainForm.FormCreate(Sender: TObject);
begin
  ChDir(ExtractFilePath(Application.ExeName));
  Game:=TedGame.Create;
  //MainForm.BorderStyle := bsNone;
  //MainForm.FormStyle := fsStayOnTop;
  MainForm.Width   := 640;
  MainForm.Height  := 480;
  MainForm.Position:= poDesktopcenter;
  Game.Firststart  :=true;
  Game.CurrentState:=GSGameStart;
end;
 
// =============================================================================
//  TMainForm.FormPaint
// =============================================================================
//  Sobald das Fenster sichtbar ist => Splashscreen + weitere Initialisierung
// =============================================================================
procedure TMainForm.FormPaint(Sender: TObject);
Var
  jpg : TjpegImage;
begin
  If Game.firststart then Begin
    jpg:=TJpegImage.Create;
    jpg.LoadFromFile(ExtractFilePath(Application.ExeName)+'\Textures\Special\Splashscreen.jpg');
    canvas.Draw(0,0,jpg);
    jpg.Free;
 
    { Soundengine initialisieren }
 
    { Texturemanager erstellen }
   // Texturemanager:=TTextureManager.create;
 
    // Wenn gewollt, dann hier in den Vollbildmodus wechseln
    // Muss vorm Erstellen des Kontextes geschehen, da durch den Wechsel der
    // Gerätekontext ungültig wird!
    // GoToFullscreen(1600, 1200, 32, 75);
    // OpenGL-Funtionen initialisieren
    InitOpenGL;
    // Gerätekontext holen
    DC := GetDC(Handle);
    // Renderkontext erstellen (32 Bit Farbtiefe, 24 Bit Tiefenpuffer, Doublebuffering)
    RC := CreateRenderingContext(DC, [opDoubleBuffered], 32, 24, 0, 0, 0, 0);
    // Erstellten Renderkontext aktivieren
    ActivateRenderingContext(DC, RC);
    // Tiefenpuffer aktivieren
    glEnable(GL_DEPTH_TEST);
    // Nur Fragmente mit niedrigerem Z-Wert (näher an Betrachter) "durchlassen"
    glDepthFunc(GL_LESS);
    // Löschfarbe für Farbpuffer setzen
    glClearColor(0,0,0,0);
    // Displayfont erstellen
   // BuildFont('MS Sans Serif');
    // Idleevent für Rendervorgang zuweisen
    Application.OnIdle := ApplicationEventsIdle;
    // Frequenz des Hochpräzisionstimers ermitteln
    QueryPerformanceFrequency(PerfCounterFreq);
    // ================================
 
    // texturen einlesen ( braucht ogl)
  //  TextureManager.AddTexturesInDir(ExtractFilePath(Application.ExeName)+'\Textures','*');
    TextureFont := TTexFont.Create(ExtractFilePath(Application.ExeName)+'\Textures\Special\Arial-256x256.bmp');
 
    with Game do begin
      OwnerForm := @MainForm;
      CurrentState:=GSMainMenue;
      Firststart:=false;
      OwnerForm^.windowState:=wsmaximized;
    end;
  End;
end;
 
// =============================================================================
//  TMainForm.FormDestroy
// =============================================================================
//  Alles wieder deactivieren + freigeben
// =============================================================================
procedure TMainForm.FormDestroy(Sender: TObject);
begin
  // TextureManager freeen
//  Texturemanager.free;
  Texturefont.free;
  Game.free;
  // Renderkontext deaktiveren
  DeactivateRenderingContext;
  // Renderkontext "befreien"
  wglDeleteContext(RC);
  // Erhaltenen Gerätekontext auch wieder freigeben
  ReleaseDC(Handle, DC);
  // Falls wir im Vollbild sind, Bildschirmmodus wieder zurücksetzen
  ChangeDisplaySettings(devmode(nil^), 0);   
end;
 
// =============================================================================
//  TMainForm.resize
// =============================================================================
//  GL anneues Fenster anpassen
// =============================================================================
procedure TMainForm.FormResize(Sender: TObject);
begin
  If Game.CurrentState<>GSGameStart Then Begin
    glViewport(0, 0, mainform.ClientWidth, Mainform.ClientHeight);
    //Projektionsmatrix resetten
    glMatrixMode(GL_PROJECTION);
    glLoadIdentity();
    //Perspektivische Darstellung
    gluPerspective(45.0,ClientWidth/ClientHeight,NearClipping,FarClipping);// Calculate The Aspect Ratio Of The Window
    glMatrixMode(GL_MODELVIEW);
    glLoadIdentity;
  End;
end;
 
// =============================================================================
//  TMainForm.ApplicationEventsIdle
// =============================================================================
//  Hier wird gerendert. Der Idle-Event wird bei Done=False permanent aufgerufen
// =============================================================================
procedure TMainForm.ApplicationEventsIdle(Sender: TObject; var Done: Boolean);
Var
  dt    : double;
  twait : integer;
 
Const
  EntryName : array[0..4] of String = ('Neues Spiel', 'Mitspielen', 'Readme', 'Credits', 'Spiel beenden');
  EntryPos  : array[0..4] of Single = (160,190,220,250,320);
Var
  i                      : integer;
 
Begin
  Queryperformancecounter(PerfCounterStart);
  // Windows denken lassen, das wir noch nicht fertig wären
  Done := False;
  Case Game.CurrentState of
    GSMainMenue: Begin
       Game.DrawMainMenue;
 
 
// Code fürs menüzeichnen (grad ohne hintergrund)
  // In den orthognalen Modus wechseln und Menü zeichnen
  glMatrixMode(GL_PROJECTION);
  glLoadIdentity;
  glOrtho(0,640,480,0,-2,2);
  glMatrixMode(GL_MODELVIEW);
  glLoadIdentity;
  glEnable(GL_Texture_2d);
//  TextureManager.BindTexture('inevitable_1024.jpg');
  glDisable(gl_Depth_test);
  glClear(GL_DEPTH_BUFFER_BIT or GL_COLOR_BUFFER_BIT);
  glColor3f(1,1,1);
 { glBegin(GL_QUADS);
   glTexCoord2f(0,1); glVertex3f(0, 0, 0);
   glTexCoord2f(0,0); glVertex3f(0, 480, 0);
   glTexCoord2f(1,0); glVertex3f(640, 480, 0);
   glTexCoord2f(1,1); glVertex3f(640, 0, 0);
  glEnd;}
  for i := Low(EntryName) to High(EntryName) do
    if i = Game.MenueSelected then
      TextureFont.Print2D(EntryName[i], [230,EntryPos[i],0],[1,0.3,0.3],1,1)
    else
      TextureFont.Print2D(EntryName[i], [230,EntryPos[i],0],[1,1,1],1,1);
  swapBuffers(DC);
 
 
    End;
    GSStartMenue: Begin
      Game.DrawStartMenue
    End;
    GSJoinMenue: Begin
      Game.DrawJoinMenue
    End;
    GSReadmeMenue: Begin
      Game.DrawReadmeMenue
    End;
    GSCreditsMenue: Begin
      Game.DrawCreditsMenue
    End;
    GSInGame: Begin
   
      //=== Grafik zeichnen ===
      Game.DrawInGame
    End;
    GSEndGame: Begin
      Game.DrawEndGame
    End;
  End;
  Queryperformancecounter(PerfCounterEnd);
  dt:=(PerfCounterEnd-PerfCounterstart)/PerfCounterFreq;
  If dt<1/60 then Begin
    twait:=trunc((1/60-dt)*1000);
    sleep(twait);
    QueryPerformanceCounter(PerfCounterEnd);
  End;
  Game.TimeFactor:=(PerfCounterEnd-PerfCounterstart)/PerfCounterFreq;
  If Game.TimeFactor>0 Then FPS:=1/Game.TimeFactor;
End;
 
end.
 

und hier meine Gameunit mit der Alternativpos für den zeichencode:

Code:

 
unit EDGame;
 
interface
 
uses
  Windows,
  Classes,
  IniFiles,
  SysUtils,
  Forms,
  Math,
 
  dglOpenGL,
  glBMP,
  EDFonts;
 
Const GSGameStart   = 0;
      GSMainMenue   = 1;
      GSStartMenue  = 2;
      GSJoinMenue   = 3;
      GSReadmeMenue = 4;
      GSCreditsMenue= 5;
      GSInGame      = 6;
      GSEndGame     = 7;
      nearclipping  = 1;
      farclipping   = 1e5;
 
 
Type
 
//=== TEDGame ==================================================================
TEDGame = class(Tobject)
  Public
    TimeFactor          : Single;              // Berechneter Zeitfaktor um Bewegungen geschwindigkeitsunabhängig zu machen
    OwnerForm           : ^TForm;
    CurrentState        : Word;                // Die Szene in der unsere Statemachine sich gerade befindet
    Firststart          : boolean;
    MenueSelected       :integer;
    Procedure DrawMainMenue;
    Procedure DrawStartMenue;
    Procedure DrawJoinMenue;
    Procedure DrawReadmeMenue;
    Procedure DrawCreditsMenue;
    Procedure DrawInGame;
    procedure DrawEndGame;
end;
 
//...
 
 
var
  Game                                    : TEDGame; // Unsere Spielinstanz
  Player                                  : array of TPlayer;
  KIPlayer                                : array of TKIPlayer;
  NWPlayer                                : array of TNWPlayer;
  PerfCounterFreq,PerfCounterStart,
  PerfCounterEnd                          : Int64;   // Frequenz des Hochpräzisionstimers
  RC                                      : HGLRC;   // Der OpenGL-Renderkontext
  DC                                      : HDC;     // Der GeräteKontext dem der OpenGL-Renderkontext zugewiesen wird
 // TextureManager                          : TTextureManager;
  TextureFont                             : TTexFont;
  FPS                                     : Single;
 
implementation
 
 
// =============================================================================
// =============================================================================
//  TEDGame
// =============================================================================
// =============================================================================
 
// =============================================================================
//  TEDGame.DrawMainMenue
// =============================================================================
Procedure TEDGame.DrawMainMenue;
 
Begin
 
 // ALTERNATIVPOSITION für den ZeichenCode
 
  If high(getasynckeystate(VK_up))=$128 then begin
    dec(MenueSelected);
    If (MenueSelected<=0) Then MenueSelected:=1;
  End;
  If High(getasynckeystate(VK_down))=$128 then begin
    inc(MenueSelected);
    If (MenueSelected>5) Then MenueSelected:=5;
  End;
  Game.OwnerForm^.Caption:='MainMenue '+FloatToStr(fps);
End;
 
 
//...
 
end.
 

[/code]

Nach oben

Lossy eX

Betreff des Beitrags:

Verfasst: Fr Okt 07, 2005 12:57

DGL Member

Registriert: Do Dez 05, 2002 10:35
Beiträge: 4234
Wohnort: Dortmund

Also der Fehler ist ein nicht initialisierter Pointer. Da wird versuchst auf etwas zu zugreifen was noch nicht initialisiert oder erstellt worden ist. Was das genau ist, kann ich jetzt so auf anhieb nicht finden. Du solltest deine Anwendung mal debuggen. Bzw stück für Stück durchgehen und dir mal anschauen ob die Klassen alle schön erstellt werden und wo genau der Fehler auftritt.

Ich gehe mal davon aus, dass der OpenGL Code der sich in OnIdle in dem Case befindet ist der den du in Game.DrawMainMenue; eingefügt hattest und dann kracht es? Wobei ich zusagen muss, dass ich da so jetzt nichts offensichtlich falsches gefunden habe. Einige gewöhnungsbedürftige Konstrukte aber das dürfte am Originalcode liegen.

Die glBMP ist bei dem TutorialCode dabei gewesen, oder? Und das zu ladende Bild existiert auch?

Sonst kann ich dir jetzt so spontan nur empfehlen mal zu versuchen den Code zu debuggen. Evtl findest du den übeltäter ja selber. Wenn das nicht der Fall sein sollte musst du wohl mal den kompletten Code rausrücken. Also dann per mail so, dass sich einer von uns mal den Code ansehen kann. Im Forum anhängen dürfte nicht, da es wohl zu groß ist. Wobei ich auch nicht weiß wie groß das Projekt insgesammt so ist.

Um noch etwas anderes was nicht zum Thema passt. Ich weiß nicht ob es so praktisch ist, wenn du große Teile aus dem Tutorial übernimmst. Klar es ist jetzt das einfachste. Aber ich glaube der Lerneffekt ist nicht sonderlich groß und das Bomberman ist mit Sicherheit auch nicht auf dein Programm zugeschnitten.

Nach oben

Flash

Betreff des Beitrags:

Verfasst: Fr Okt 07, 2005 13:53

Guitar Hero

Registriert: Do Sep 25, 2003 15:56
Beiträge: 7810
Wohnort: Sachsen - ERZ / C
Programmiersprache: Java (, Pascal)

Das Bomberman Tut wurde von Sascha ja hauptsächlich dazu geschrieben (jedenfalls denke ich das), damit Anfänger mal sehen, wie man ein größeres Projekt gliedern/strukturieren sollte. Es war nicht als CopyPaste Vorlage gedacht. Das würde auch gar nicht zu Sascha passen....der wollte eh lieber, dass man selber was probiert und weniger kopiert.

_________________
Blog: kevin-fleischer.de und fbaingermany.com

Nach oben

Boogi

Betreff des Beitrags:

Verfasst: Sa Okt 08, 2005 10:10

DGL Member

Registriert: Di Mär 16, 2004 22:25
Beiträge: 17

Au Mann!!!

hab die Variable meines TextureFont-Objekts 2mal in unterschiedlichen units deklariert.
Harrr...
aber wieso schluckt das delphi einfach so?

Gruß Steffen

Nach oben

Lossy eX

Betreff des Beitrags:

Verfasst: Sa Okt 08, 2005 10:30

DGL Member

Registriert: Do Dez 05, 2002 10:35
Beiträge: 4234
Wohnort: Dortmund

Das ist halt so. Finde ich persönlcih auch nicht schlimm. Du kannst auch Klassen doppelt definieren. Dann musst du entsprechend nur angeben welche Klasse du haben willst. Also Windows.TBitmap oder Graphics.TBitmap.

Nach oben

Flash

Betreff des Beitrags:

Verfasst: So Okt 09, 2005 00:17

Guitar Hero

Registriert: Do Sep 25, 2003 15:56
Beiträge: 7810
Wohnort: Sachsen - ERZ / C
Programmiersprache: Java (, Pascal)

Immer noch besser als das IFDEF gewurschtel unter C

_________________
Blog: kevin-fleischer.de und fbaingermany.com

Nach oben

LarsMiddendorf

Betreff des Beitrags:

Verfasst: So Okt 09, 2005 00:20

DGL Member

Registriert: Sa Dez 28, 2002 11:13
Beiträge: 2244

Es kommt auch auf die Reihenfolge der Units bei der Uses Anweisung an. Es werden zuerst die Klassen in den zuletzt eingebundenen Units genommen.

Zitat:

Immer noch besser als das IFDEF gewurschtel unter C

In C ist das ja totales Gefrickel mit den Headern.

Nach oben

Flash

Betreff des Beitrags:

Verfasst: So Okt 09, 2005 00:24

Guitar Hero

Registriert: Do Sep 25, 2003 15:56
Beiträge: 7810
Wohnort: Sachsen - ERZ / C
Programmiersprache: Java (, Pascal)

LarsMiddendorf hat geschrieben:

Es kommt auch auf die Reihenfolge der Units bei der Uses Anweisung an. Es werden zuerst die Klassen in den zuletzt eingebundenen Units genommen.

Wobei sowas echt mies gelöst ist. Da sollte ein Compiler schon nen Fehler melden, oder zumindest ne Warnung "Klasse X in Unit Y überdeckt deklaration aus Unit Z".

LarsMiddendorf hat geschrieben:

In C ist das ja totales Gefrickel mit den Headern.

Wem sagst du das... wenn plötzlich der Compiler einen unbedarften Delphientwickler anschreit wegen einer "doppelt deklarierten" Konstante, und die Konstante existiert nur in einem Header, dann guckt man schon ganz schön in die Röhre... :wink:

_________________
Blog: kevin-fleischer.de und fbaingermany.com

Nach oben

Sunny

Betreff des Beitrags:

Verfasst: So Okt 09, 2005 02:10

DGL Member

Registriert: Do Feb 24, 2005 22:44
Beiträge: 29

Zitat:

In C ist das ja totales Gefrickel mit den Headern.

Zitat:

Immer noch besser als das IFDEF gewurschtel unter C

Na na, denkt bloß nicht, dass ihr hier unbeobachtet seit. :lol:

Es soll auch User hier geben die sich für OpenGL interessieren aber C verwenden und nicht Delphi. :lol:

Nach oben

Lossy eX

Betreff des Beitrags:

Verfasst: So Okt 09, 2005 08:47

DGL Member

Registriert: Do Dez 05, 2002 10:35
Beiträge: 4234
Wohnort: Dortmund

Sunny hat geschrieben:

Na na, denkt bloß nicht, dass ihr hier unbeobachtet seit. :lol:

Es soll auch User hier geben die sich für OpenGL interessieren aber C verwenden und nicht Delphi. :lol:

Wie? Sag bloß du benutzt C? Phob: Wir hätten hier mal nen Account der gesperrt werden müsste. ;-)

Kleiner Scherz. Es ist ja jedem selbst überlassen was er macht. Habe auch ne Zeit lang C/C++ programmiert finde Pascal was das angeht aber einfach logischer und schicker.

@Flash: Doppelte Klassen per Compilerfehler zu sperren halte für gar keine gute Idee. Klar ist es verwirrend und idiotisch, wenn man zwei Klassen hat aber stell dir mal vor du benutzt 2 externe Bibliotheken die du kompiliert (dcu) einbinden musst, weil die Quellen nicht offen sind. Wenn die rein zufällig gleich heißen hast du ein echtes Problem. Da kannste dann nix gegen tun. Und dann sind mir doppelte Klassen wesentlich lieber. ;-)

Nach oben

Seite 1 von 1

[ 14 Beiträge ]

Foren-Übersicht » Programmierung » OpenGL

Wer ist online?

Mitglieder in diesem Forum: 0 Mitglieder und 6 Gäste

Du darfst keine neuen Themen in diesem Forum erstellen.
Du darfst keine Antworten zu Themen in diesem Forum erstellen.
Du darfst deine Beiträge in diesem Forum nicht ändern.
Du darfst deine Beiträge in diesem Forum nicht löschen.
Du darfst keine Dateianhänge in diesem Forum erstellen.