DGL • Thema anzeigen - Textur gespiegelt

Textur gespiegelt

Moderator: DGL-Team

Seite 1 von 1

[ 3 Beiträge ]

Vorheriges Thema | Nächstes Thema

Autor

Nachricht

Nils

Betreff des Beitrags: Textur gespiegelt

Verfasst: Mo Apr 02, 2012 20:10

DGL Member

Registriert: Mi Okt 03, 2007 14:22
Beiträge: 388

Moin,

bevor ich mich weiter damit beschäftigen kann, wie man prüft ob eine Kugel eine Ebene trifft, muss ich erstmal aufräumen. Meine Projekte sind einfach zu unaufgeräumt und ein klares und vor allem logisches Denken ist kaum noch möglich, eine einzelne Codezeile hat meist eine andere Wirkung als man es erwartet und so kann ich einfach nicht mehr weiterarbeiten. Effektiv bedeutet das, dass ich Units auf Funktion prüfe.

Um die Units wirklich zu testen nehme ich offensichtlich funktionierende Projekte und ersetze deren Units durch eigene um zu schauen, ob meine Units in der Funktion und Bedienung her einigermaßen einem Standard entsprechen, sodass ich endlich weniger Ärger habe. Da mich das Terrain-Tutorial eh interessierte, nahm ich den Code vom ersten und begann auch direkt zu experimentieren damit, sodass jetzt eine Mischung aus Tutorial1 und 2 vorhanden ist. Nachdem ich mich da ausgetobt hatte, habe ich endlich doch mal was sinnvolleres getan und die mitgelieferte Textures.pas durch meine uTexture.pas ersetzt, sowie mein SDL-Gerüst eingebaut etc., da ja auch die uTexture SDL verwendet. Und siehe da: Die Skybox ist vertikal gespiegelt. Da wegen unvollständigen SDL-Gerüst-Einbau keine Drehung möglich, kann ich nur sagen dass die zunächst sichtbare Skybox-Seite vertikal gespiegelt ist. Kurz: Ich habe die mitgelieferte Textures.pas durch meine ersetzt und es läuft nicht mehr.
Ich habe das eben geschildert, weil sonst würde der Verdacht direkt auf irgendetwas programminternes fallen, denn Ihr müsst bedenken, dass meine Unit seit Jahren erfolgreich eingesetzt wird und es erstmal komisch erscheint, dass in ihr ein Fehler sein soll - in meinen Augen ist der Fehler sehr wahrscheinlich in ihr, denn es ist so auffällig, dass der Fehler direkt auftritt, wenn ich die Textur-Units austausche.

Im Folgenden die Unit, sämtliche Funktionen die ich bei der Skybox weder direkt noch indirekt nutze, sind nicht aufgeführt. Ich wünschte ich könnte den Fehler einschränken, jedoch habe ich keine Ahnung was hier schiefgeht.
Zur Funktion: Ich rufe LoadTexture('...', irgendeineId) auf und lade so die Texturen, Id ist eine Ganzzahl, jeder Textur ist eine eindeutige Ganzzahl zugeordnet. Mit Bind binde ich die Textur, wobei zu beachten ist, dass Bind(Id) erwartet, dass nicht Id sondern Id-1 angegeben wird - das ist verwirrender Mist, den ich noch verbessern werde.
Die Skybox wird recht weit oben im Terrain-Tutorial behandelt und der Code zum Laden und zeichnen ist genau dieser, eben bis auf den Einsatz meiner Unit, deren Aufruf-Funktionsweise ich eben ja schon kurz erklärt habe.

Das sind die wesentlichen Stellen die Ihr wissen solltet, mehr einschränken kann ich leider nicht. Sieht hier irgendjemand einen Fehler ?

Code:

unit uTexture;                                                   
 
interface
 
uses SDL, SDLUtils, SDLImage, dglOpenGL, SysUtils, uBase;
 
type
  TTextur = record
    Id     : Integer;
    Textur : GluInt;
  end;
  TDynTexArr = Array of TTextur;
 
function LoadTexture(Filename : String; aId : Integer) : Boolean; // Textur aus Datei laden und mit definierten Index in Texturarray schreiben
procedure SwapBGR(SDLSurface : PSDL_Surface);                                           // Farben vertauschen
procedure Bind(Id : Integer);                                                           // Textur binden
 
implementation
 
uses
  uVars;
 
// OpenGL-Textur erstellen
function CreateTexture(SDL_Surface : PSDL_Surface) : Integer;
var tmpInitial : PSDL_Surface;
      Texture    : GluInt;
    MaxAni     : Real;
begin
  // Es ist nicht klar, ob die Funktion erfolgreich durchläuft.
  Result := -1;
  if Assigned(SDL_Surface) then
  begin
    // Für Alphakanal
    tmpInitial := SDL_DisplayFormatAlpha(SDL_Surface);
    SDL_FreeSurface(SDL_Surface);
    // Da der Alphakanal die Farben vertauscht, muss dies über SwapRGB gerade gebogen werden.
    SwapBGR(tmpInitial);
 
    glGenTextures(1, @Texture);
    glBindTexture(GL_TEXTURE_2D, Texture);
    // Die Größen werden automatisch berechnet. Sonst wären nur Potenzen von 2 möglich (16x16, 32x32, usw.).
    if tmpInitial.format.BytesPerPixel > 3 then
      glTexImage2D(GL_TEXTURE_2D, 0, GL_RGBA, tmpInitial^.w, tmpInitial^.h, 0, GL_RGBA, GL_UNSIGNED_BYTE, tmpInitial^.pixels)
    else
      glTexImage2D(GL_TEXTURE_2D, 0, GL_RGB, tmpInitial^.w, tmpInitial^.h, 0, GL_RGB, GL_UNSIGNED_BYTE, tmpInitial^.pixels);
    // Textureigenschaften setzen
    glTexParameteri(GL_TEXTURE_2D, GL_TEXTURE_MIN_FILTER, GL_LINEAR_MIPMAP_NEAREST);
    glTexParameteri(GL_TEXTURE_2D, GL_TEXTURE_MAG_FILTER, GL_LINEAR_MIPMAP_LINEAR);
    if IsExtensionSupported('GL_EXT_texture_filter_anisotropic') then
    begin
      glGetFloatv(GL_MAX_TEXTURE_MAX_ANISOTROPY_EXT, @MaxAni);
      glTexParameterf(GL_TEXTURE_2D, GL_TEXTURE_MAX_ANISOTROPY_EXT, MaxAni/2);
    end;
    glTexParameteri(GL_TEXTURE_2D, GL_GENERATE_MIPMAP, GL_TRUE);
    glGenerateMipmap(GL_TEXTURE_2D);
    // Mipmaps generieren
    if tmpInitial.format.BytesPerPixel > 3 then
      gluBuild2DMipmaps(GL_TEXTURE_2D, GL_RGBA, tmpInitial^.w, tmpInitial^.h, GL_RGBA, GL_UNSIGNED_BYTE, tmpInitial^.pixels)
    else
      gluBuild2DMipmaps(GL_TEXTURE_2D, GL_RGB, tmpInitial^.w, tmpInitial^.h, GL_RGB, GL_UNSIGNED_BYTE, tmpInitial^.pixels);
    // Freigabe
    SDL_FreeSurface(tmpInitial);
    // Rückgabe
    Result := Texture;
  end;
end;
 
// Textur aus Datei laden und mit definierten Index in Texturarray schreiben
function LoadTexture(Filename : String; aId : Integer) : Boolean;
begin
  Result := False;
  if FileExists(Filename) then
  begin
    SetLength(Tex, High(Tex)+2);
    with Tex[High(Tex)] do
    begin
      Id     := Succ(aId);
      Textur := CreateTexture(IMG_Load(PChar(Filename)));
    end;
    Result := True;
  end;
end;
 
// Farben vertauschen
procedure SwapBGR(SDLSurface : PSDL_Surface);
var x, y           : Integer;
    p              : UInt32;
    pR, pG, pB, pA : PUInt8;
    r, g, b, a     : UInt8;
begin
  for y := 0 to Pred(SDLSurface.h) do
    for x := 0 to Pred(SDLSurface.w) do
    begin
      p := SDL_GetPixel(SDLSurface, x, y);
 
      pR := @r;
      pG := @g;
      pB := @b;
      pA := @a;
 
      SDL_GetRGBA(p, SDLSurface.format, pR, pG, pB, pA);
      p := SDL_MapRGBA(SDLSurface.format, b, g, r, a);
 
      SDL_PutPixel(SDLSurface, x, y, p);
    end;
end;
 
// Textur binden
procedure Bind(Id : Integer);
var i : Integer;
begin
  for i := 0 to High(Tex) do
    if Tex[i].Id = Id then
    begin
      glBindTexture(GL_TEXTURE_2D, Tex[i].Textur);
      Break;
    end;
end;
 
end.

Nachtrag: Habe mich eben mal schnell an die SDL-Mouse-Events gesetzt um mal freie Sicht zu kriegen. Im Anhang sieht man wie Die Skybox "unten" aussieht, recht katastrophal irgendwie. Es ist irgendetwas verdreht. Außerdem kam mir die Idee, ich könnte folgende Codeabschnitte hier mal schnell posten, hoffe das macht es noch etwas leichter:

Code:

 
procedure LoadTextures;
const SkyTexturesName : Array[0..5] of String = ('north.jpg', 'east.jpg', 'south.jpg', 'west.jpg', 'top.jpg', 'bottom.jpg');
var i : Integer;
begin
  //Bilder für SkyBox laden
  for i := 0 to 5 do
    LoadTexture(SkyTexturesName[i], 20+i); // Startwert 20 ist rein nach belieben gewählt, aber funktionieren muss es trotzdem, denn 20 aufwärts ist garantiert frei. 
end;
 
procedure PaintSkyBox;
const QuadPosition : Array[0..5] of Array[0..3] of Array[0..2] of Single = 
  ((( 2.005,  2.005, -1.995), ( 2.005, -2.005, -1.995), (-2.005, -2.005, -1.995), (-2.005,  2.005, -1.995)), //Nordseite
   (( 1.995,  2.005,  2    ), ( 1.995, -2.005,  2    ), ( 1.995, -2.005, -2    ), ( 1.995,  2.005, -2    )), //Ostseite
   ((-2.005,  2.005,  1.995), (-2.005, -2.005,  1.995), ( 2.005, -2.005,  1.995), ( 2.005,  2.005,  1.995)), //Südseite
   ((-1.995,  2.005, -2    ), (-1.995, -2.005, -2    ), (-1.995, -2.005,  2    ), (-1.995,  2.005,  2    )), //Westseite
   ((-2    ,  2    , -2    ), (-2    ,  2    ,  2    ), ( 2    ,  2    ,  2    ), ( 2    ,  2    , -2    )),
   (( 2    , -2    , -2    ), ( 2    , -2    ,  2    ), (-2    , -2    ,  2    ), (-2    , -2    , -2    )));
      TexturePos : Array[0..3] of Array[0..1] of Single = ((1,1), (1,0), (0, 0), (0, 1));                       
var Side, Vertex : Integer;
begin
  for Side := 0 to 5 do
  begin
    //Textur aktivieren
    Bind(19+Side); // Hier wie oben erläutert nicht 20 sondern 19 als Startwert, das ist der Designfehler meiner Textur-Unit, welcher noch beseitigt werden muss. 
    //!glBindTexture(GL_TEXTURE_2D, SkyBoxTexturen[Side]); -- Originalcode
    glBegin(GL_QUADS);
    //Vertieces und Tex Coords übergeben
    for Vertex := 3 downto 0 do
    begin
      glTexCoord2fv(@TexturePos[Vertex][0]);
      glVertex3fv(@QuadPosition[Side][Vertex][0])
    end;
    glEnd;
  end;
end;

Gruß,
Nils

Du hast keine ausreichende Berechtigung, um die Dateianhänge dieses Beitrags anzusehen.

_________________
Meine Musik: spiker-music.net

Nach oben

Markus

Betreff des Beitrags: Re: Textur gespiegelt

Verfasst: Di Apr 03, 2012 10:20

DGL Member

Registriert: Fr Mär 30, 2007 18:35
Beiträge: 331

So wie ich das sehe, liegt der Fehler in der Textures.pas aus dem Tutorial. In der wird eine Bitmap geladen in dem einfach die Daten aus der Datei in den Speicher geladen werden. Bei einer Bitmap sind aber die unteren Zeilen des Bilds zuerst im Speicher (und die erste Zeile als letztes). Beim Laden des JPGs werden die Zeilen in einer Schleife vertauscht. Die Bilder werden also alle "falsch" geladen.

Ich gehe davon aus, dass die SDL Methode das "richtig" macht. Deswegen sind alle deine Texturen gespiegelt. Ich würde einfach die Texturkoordinaten der Skybox anpassen.

Nach oben

Nils

Betreff des Beitrags: Re: Textur gespiegelt

Verfasst: Di Apr 03, 2012 22:06

DGL Member

Registriert: Mi Okt 03, 2007 14:22
Beiträge: 388

Ah stimmt. Vielen Dank für die Hilfe!

_________________
Meine Musik: spiker-music.net

Nach oben

Seite 1 von 1

[ 3 Beiträge ]

Foren-Übersicht » Programmierung » OpenGL

Wer ist online?

Mitglieder in diesem Forum: 0 Mitglieder und 16 Gäste

Du darfst keine neuen Themen in diesem Forum erstellen.
Du darfst keine Antworten zu Themen in diesem Forum erstellen.
Du darfst deine Beiträge in diesem Forum nicht ändern.
Du darfst deine Beiträge in diesem Forum nicht löschen.
Du darfst keine Dateianhänge in diesem Forum erstellen.