DGL • Thema anzeigen - Screenshot mittels glReadPixels

Screenshot mittels glReadPixels

Moderator: DGL-Team

Seite 2 von 4

[ 60 Beiträge ]

Gehe zu Seite Vorherige 1, 2, 3, 4 Nächste

Vorheriges Thema | Nächstes Thema

Autor

Nachricht

Flash

Betreff des Beitrags:

Verfasst: Mo Apr 18, 2005 13:53

Guitar Hero

Registriert: Do Sep 25, 2003 15:56
Beiträge: 7810
Wohnort: Sachsen - ERZ / C
Programmiersprache: Java (, Pascal)

So...also so richtig gehn tuts net. Eigentlich gehts noch überhaupt gar net.

So sieht der Code aus:

Code:

procedure OutputToBitmap(FileName : string);
var Bitmap     : TBitmap;
    Dummi      : Boolean;
    i,j        : integer;
    h          : byte;
    PixelData  : PRGBQuad;
    Header     : PBitmapInfo;
begin
     Bitmap := TBitmap.Create;
     Bitmap.PixelFormat := pf32Bit;
     Bitmap.Width  := RenderForm.ClientWidth;
     Bitmap.Height := RenderForm.ClientHeight;
 
     GetMem( PixelData, Bitmap.Width*Bitmap.Height*4 ); //Speicher für die Pixeldaten reservieren
 
     HptFenster.IdleHandler(HptFenster,Dummi);          //Ausgabe Zeichnen
 
     glReadPixels(0, 0, Bitmap.Width, Bitmap.Height, GL_RGBA, GL_UNSIGNED_BYTE, PixelData);
 
 
     for i := 0 to Bitmap.Height * Bitmap.Width -1 do
         begin // RGB -> BGR (Bitmaps speichern BGR!)
              h := PixelData^.rgbBlue;
              PixelData^.rgbBlue := PixelData^.rgbRed;
              PixelData^.rgbRed := h;
              inc(PixelData);
         end;
 
     GetMem( Header, SizeOf( TBitmapInfoHeader ) );
     with Header^.bmiHeader do
     begin
          biSize            := SizeOf( TBitmapInfoHeader );
          biWidth           := Bitmap.Width;
          biHeight          := Bitmap.Height;
          biPlanes          := 1;
          biBitCount        := 32;
          biCompression     := BI_RGB;
          biSizeImage       := Bitmap.Width*Bitmap.Height*4;
     end;
 
     SetDIBits( Bitmap.Canvas.Handle, Bitmap.Handle, 0, Bitmap.Height, PixelData, TBitmapInfo( Header^ ), DIB_RGB_COLORS );
 
     Bitmap.SaveToFile(FileName);
     
     Bitmap.Free;
     FreeMem( PixelData );
     FreeMem( Header );
end;

2 Fehler kommen:

1.: Das Bild ist komplett weiß.
2.: Bei FreeMem(PixelData) kommt eine "ungültige Zeigeroperation".

Bin gerade im 14.00Uhr Loch und weiß absolut net was hier net stimmt. :oops:

_________________
Blog: kevin-fleischer.de und fbaingermany.com

Nach oben

sniper

Betreff des Beitrags:

Verfasst: Mo Apr 18, 2005 16:07

DGL Member

Registriert: Mi Dez 15, 2004 20:36
Beiträge: 454
Wohnort: Wien, Österreich

Code:

 
type TTGAHEADER = packed record
    tfType : Byte;
    tfColorMapType : Byte;
    tfImageType : Byte;
    tfColorMapSpec : Array[0..4] of Byte;
    tfOrigX : Array [0..1] of Byte;
    tfOrigY : Array [0..1] of Byte;
    tfWidth : Array [0..1] of Byte;
    tfHeight : Array [0..1] of Byte;
    tfBpp : Byte;
    tfImageDes : Byte;
  end;
 
procedure GLScreenShot(name : string);
const MaxSize_ = 1024 * 768 * 4 + 1;
 
var Buffer : array of Byte;//[0..MaxSize_] of Byte;
    picname : string[80];
    c,i,j,temp : integer;
    f : file;
    tgaHeader : TTGAHEADER;
    ffwidth, ffheight : integer;
    viewport : Array[0..3] of integer;
begin
 picname := name;
 
 glGetIntegerv(GL_VIEWPORT, @viewport);
 ffwidth := viewport[2];
 ffheight:= viewport[3];
 
 c:= ffWidth * ffHeight * 4;
 
 if c>maxsize_ then Exit;
 
 SetLength(buffer,c);
 
 ZeroMemory(@tgaHeader, SizeOf(tgaHeader));
 
    // Fill the structure with info for the image to be saved
    tgaHeader.tfImageType := 2; // TGA_RGB = 2
    tgaHeader.tfWidth[0] := ffWidth and 255;
    tgaHeader.tfWidth[1] := ffWidth shr 8;
    tgaHeader.tfHeight[0] := ffHeight and 255;
    tgaHeader.tfHeight[1] := ffHeight shr 8;
    tgaHeader.tfBpp := 24;
 
 glReadPixels(0,0,ffWidth, ffHeight, GL_RGBA, GL_UNSIGNED_BYTE, @Buffer[0]);   // get image as 32-bit format
 
    // swap rgb to bgr
     i := 0;
     while ( i < c) do
     begin
        temp := buffer[i];
        buffer[i] := buffer[i+2];
        buffer[i+2] := temp;
      inc(i,4);
     end;
 
 c := ffwidth * ffheight * 3;
 i := 0;
 j := 0;
 
    while ( i < c) do        // convert from 32-bit to 24 bitformat
    begin
      Buffer[i] := Buffer[j];
      Buffer[i+1] := Buffer[j+1];
      Buffer[i+2] := Buffer[j+2];
 
      Inc(i,3);
      Inc(j,4);
    end;
 
 AssignFile(f, picname);
 Rewrite( f,1 );
 
 BlockWrite(F, tgaHeader, SizeOf(tgaHeader));
 BlockWrite(f, buffer[0], c );
 
 CloseFile(f);
 SetLength(buffer, 0 );
 
end;
 

Damit bekommst du eine *.tga Datei...Besser als nichts.

_________________
"Meine Mutter sagt : 'Dumm ist der, der Dummes tut'." - Forrest Gump

Nach oben

Flash

Betreff des Beitrags:

Verfasst: Mo Apr 18, 2005 16:11

Guitar Hero

Registriert: Do Sep 25, 2003 15:56
Beiträge: 7810
Wohnort: Sachsen - ERZ / C
Programmiersprache: Java (, Pascal)

Danke. Später vielleicht ganz gut. Aber Bitmaps machen sich für die Weiterverarbeitung ganz gut. Außerdem kann selbst Paint die Dinger lesen.

_________________
Blog: kevin-fleischer.de und fbaingermany.com

Nach oben

Flo

Betreff des Beitrags:

Verfasst: Mo Apr 18, 2005 16:35

DGL Member

Registriert: Do Jun 19, 2003 10:44
Beiträge: 991
Wohnort: Karlsfeld (nahe München)

Zitat:

tfOrigX : Array [0..1] of Byte;
tfOrigY : Array [0..1] of Byte;
tfWidth : Array [0..1] of Byte;
tfHeight : Array [0..1] of Byte;

Statt dem Typ Array[0..1] of Byte sollte hier ein Word(0..2^16-1) genutzt werden.
Das erstpart die Rechnung :wink:

Theoretisch wäre das ein super Artikel für das Wiki("Erstellen von Screenshots"), nur habe ich noch nicht die Zeit gefunden ihn zu schreiben.

MfG
Flo

_________________
Danke an alle, die mir (und anderen) geholfen haben.
So weit... ...so gut

Nach oben

Flash

Betreff des Beitrags:

Verfasst: Mo Apr 18, 2005 17:15

Guitar Hero

Registriert: Do Sep 25, 2003 15:56
Beiträge: 7810
Wohnort: Sachsen - ERZ / C
Programmiersprache: Java (, Pascal)

Stimmt. Ich hoffe einer Macht das mal. (Ich hab gerade Stress). Sogar mit verschiedenen Codes (TGA/Bitmap) würde bestimmt toll werden.

_________________
Blog: kevin-fleischer.de und fbaingermany.com

Nach oben

sniper

Betreff des Beitrags:

Verfasst: Mo Apr 18, 2005 18:05

DGL Member

Registriert: Mi Dez 15, 2004 20:36
Beiträge: 454
Wohnort: Wien, Österreich

Zitat:

Statt dem Typ Array[0..1] of Byte sollte hier ein Word(0..2^16-1) genutzt werden.
Das erstpart die Rechnung Wink

Interesant. Kannst du das praktisch zeigen?
Auf gezeigte Art ist es sicherer und klarer zu lesen oder ?

_________________
"Meine Mutter sagt : 'Dumm ist der, der Dummes tut'." - Forrest Gump

Nach oben

Flo

Betreff des Beitrags:

Verfasst: Mo Apr 18, 2005 20:03

DGL Member

Registriert: Do Jun 19, 2003 10:44
Beiträge: 991
Wohnort: Karlsfeld (nahe München)

Hier die abgeänderte Version:

Code:

 
type TTGAHEADER = packed record
    tfType : Byte;
    tfColorMapType : Byte;
    tfImageType : Byte;
    tfColorMapSpec : Array[0..4] of Byte;
    tfOrigX : Word; //Array [0..1] of Byte;
    tfOrigY : Word;
    tfWidth : Word;
    tfHeight : Word;
    tfBpp : Byte;
    tfImageDes : Byte;
  end;
 
procedure GLScreenShot(name : string);
const MaxSize_ = 1024 * 768 * 4 + 1;
 
var Buffer : array of Byte;//[0..MaxSize_] of Byte;
    picname : string[80];
    c,i,j,temp : integer;
    f : file;
    tgaHeader : TTGAHEADER;
    ffwidth, ffheight : integer;
    viewport : Array[0..3] of integer;
begin
 picname := name;
 
 glGetIntegerv(GL_VIEWPORT, @viewport);
 ffwidth := viewport[2];
 ffheight:= viewport[3];
 
 c:= ffWidth * ffHeight * 4;
 
 if c>maxsize_ then Exit;
 
 SetLength(buffer,c);
 
    // Fill the structure with info for the image to be saved
    ZeroMemory(@tgaHeader, SizeOf(tgaHeader));
    tgaHeader.tfImageType := 2; // TGA_RGB = 2
    tgaHeader.tfWidth := ffWidth // <<-----------------hier wird es weniger und einfacher
    tgaHeader.tfHeight := ffHeight;
    tgaHeader.tfBpp := 24;
 
 glReadPixels(0,0,ffWidth, ffHeight, GL_RGBA, GL_UNSIGNED_BYTE, @Buffer[0]);   // get image as 32-bit format
 
    // swap rgb to bgr
     i := 0;
     while ( i < c) do
     begin
        temp := buffer[i];
        buffer[i] := buffer[i+2];
        buffer[i+2] := temp;
      inc(i,4);
     end;
 
 c := ffwidth * ffheight * 3;
 i := 0;
 j := 0;
 
    while ( i < c) do        // convert from 32-bit to 24 bitformat
    begin
      Buffer[i] := Buffer[j];
      Buffer[i+1] := Buffer[j+1];
      Buffer[i+2] := Buffer[j+2];
 
      Inc(i,3);
      Inc(j,4);
    end;
 
 AssignFile(f, picname);
 Rewrite( f,1 );
 
 BlockWrite(F, tgaHeader, SizeOf(tgaHeader));
 BlockWrite(f, buffer[0], c );
 
 CloseFile(f);
 SetLength(buffer, 0 );
 
end;
 

Ich habe es fast auf die gleiche Art gelöst nur das ich bei dem Vertauschen der Rot und Blau Komponeten folgende Typen verwende:

Code:

 
 Tbgr_Format = packed record
    blue : Byte;
    green : Byte;
    red : Byte;
  end;
 Pbgr_Format = ^Tbgr_Format;
 Trgb_Format = packed record
    red : Byte;
    green : Byte;
    blue : Byte;
  end;
 Prgb_Format = ^Trgb_Format;
 

MfG
Flo

_________________
Danke an alle, die mir (und anderen) geholfen haben.
So weit... ...so gut

Zuletzt geändert von Flo am Mo Mai 23, 2005 14:54, insgesamt 2-mal geändert.

Nach oben

Grizzly

Betreff des Beitrags:

Verfasst: Mo Apr 18, 2005 21:08

DGL Member

Registriert: Sa Nov 13, 2004 11:00
Beiträge: 229
Wohnort: Steinhude

sniper_w hat geschrieben:

Interesant. Kannst du das praktisch zeigen?
Auf gezeigte Art ist es sicherer und klarer zu lesen oder ?

Also ich würde es ja ansich einfacher zu lesen, wenn der Wert direkt in eine Variable geschrieben wird, anstatt auf 2 aufgesplittet zu werden.
Und wo das sicherer sein soll ist mir auch noch nicht ganz klar.

Nach oben

Betreff des Beitrags:

Verfasst: Mo Apr 18, 2005 21:25

DGL Member

Registriert: Sa Jan 22, 2005 21:10
Beiträge: 225

Um noch mal auf den ursprünglichen Code zurückzukommen:

Hier inkrementierst du Pixeldata

Code:

 
  for i := 0 to Bitmap.Height * Bitmap.Width -1 do
         begin // RGB -> BGR (Bitmaps speichern BGR!)
              h := PixelData^.rgbBlue;
              PixelData^.rgbBlue := PixelData^.rgbRed;
              PixelData^.rgbRed := h;
              inc(PixelData);
         end; 
 

Jetzt zeigt Pixeldata auf das ende deines Datenblocks..

Code:

 
 SetDIBits( Bitmap.Canvas.Handle, Bitmap.Handle, 0, Bitmap.Height, PixelData, TBitmapInfo( Header^ ), DIB_RGB_COLORS );
 

und nun sagst du ihm, dass er die Daten von da an (also vom Ende an) lesen soll. Dass da weiß rauskommt ist Zufall.

Code:

 
     Bitmap.SaveToFile(FileName);
     
     Bitmap.Free;
     FreeMem( PixelData );

Ah ja, und jetzt versuchst du, den Speicher am ende deines Datenblocks freizugeben. Nur den haste nie Reserviert...

Ich denke, du solltest bei der For-Schleife nen 2. Pointer verwenden. Das müsste die Probleme beheben - glaube ich...

Nach oben

sniper

Betreff des Beitrags:

Verfasst: Mo Apr 18, 2005 22:04

DGL Member

Registriert: Mi Dez 15, 2004 20:36
Beiträge: 454
Wohnort: Wien, Österreich

@Flo : Hast recht.

_________________
"Meine Mutter sagt : 'Dumm ist der, der Dummes tut'." - Forrest Gump

Nach oben

Flash

Betreff des Beitrags:

Verfasst: Mo Apr 18, 2005 22:22

Guitar Hero

Registriert: Do Sep 25, 2003 15:56
Beiträge: 7810
Wohnort: Sachsen - ERZ / C
Programmiersprache: Java (, Pascal)

@Al: Danke. Werds mit mal angucken.

_________________
Blog: kevin-fleischer.de und fbaingermany.com

Nach oben

Blechwolf

Betreff des Beitrags:

Verfasst: Di Apr 19, 2005 08:35

DGL Member

Registriert: Fr Nov 12, 2004 14:58
Beiträge: 76
Wohnort: Aachen

Ähm ja.
Also mir sind da ein paar Sachen aufgefallen.

Code:

PixelData : PRGBQuad;

Eigentlich reicht hier folgendes:

Code:

PixelData : PByte;

Ich weiss allerdings nicht wie Dein PRGBQuad aussieht oder ob es später Probleme mit dem SetDIBits gibt wenn Du ein einfaches PByte verwendest. Da Du nur einen Screenshot machen willst, musst Du ja nicht mehr auf die einzelnen Farben zugreifen. (Siehe nächster Absatz)

Code:

 
     glReadPixels(0, 0, Bitmap.Width, Bitmap.Height, GL_RGBA, GL_UNSIGNED_BYTE, PixelData);
 

Wenn Du OpenGL >= 1.2 benutzt (was eigentlich bei allen halbwegs modernen Grafikkarten der Fall sein sollte) kannst Du auch die Konstante GL_BGRA verwenden.

Code:

 
     glReadPixels(0, 0, Bitmap.Width, Bitmap.Height, GL_BGRA, GL_UNSIGNED_BYTE, PixelData);
 

Das spart die nämlich den Teil

Code:

 
     for i := 0 to Bitmap.Height * Bitmap.Width -1 do
         begin // RGB -> BGR (Bitmaps speichern BGR!)
              h := PixelData^.rgbBlue;
              PixelData^.rgbBlue := PixelData^.rgbRed;
              PixelData^.rgbRed := h;
              inc(PixelData);
         end;
 

Sollte das aus irgendeinem Grund nicht gehen, brauchst Du einen Laufzeiger weil Du sonst die Start-Adresse von PixelData verlierst.

Ansonsten speichere ich die Daten immer anders in das Bitmap ab. Bin mir nicht sicher ob das schneller oder langsamer ist, funktioniert aber auf jeden Fall:

Code:

 
  temp := PixelData;
  for j := Bitmap.Height-1 downto 0 do begin
    Move(temp^,Bitmap.Scanline[j]^,Bitmap.Width*4);
    inc(PChar(temp),Bitmap.Width*4);
  end;
 

Wobei temp auch wieder ein PByte ist (der "Laufzeiger").

Grüße

Wolf

_________________
Ein Schiff im Hafen ist sicher. Aber dafür werden Schiffe nicht gebaut. (Engl. Sprichwort)

Nach oben

sniper

Betreff des Beitrags:

Verfasst: Di Apr 19, 2005 12:16

DGL Member

Registriert: Mi Dez 15, 2004 20:36
Beiträge: 454
Wohnort: Wien, Österreich

So geht auch *.bmp:

Code:

 
procedure GLScreenShot_BMP(name : string);
var viewport : Array[0..3] of integer;
    BMP : Graphics.TBitmap;
 
    Row, Size, RowSize: Integer;
    pSource, pData,pAnfang: Pointer;
begin
 BMP := Graphics.TBitmap.Create();
 BMP.PixelFormat := pf32bit;
 
 glGetIntegerv(GL_VIEWPORT, @viewport);
 BMP.Width := viewport[2];
 BMP.Height:= viewport[3];
 
 Size := 4;
 RowSize := Size * BMP.Width;
 GetMem(pSource, RowSize * BMP.Height);
 pAnfang := pSource;
 glReadPixels(0,0,BMP.Width, BMP.Height, GL_BGRA, GL_UNSIGNED_BYTE, pSource);   // get image as 32-bit format
 
      for Row := BMP.Height -1 downto 0 do
      begin
       pData := BMP.Scanline[Row];
       if Assigned(pData) then
        begin
          Move(pSource^, pData^, RowSize);
          Inc(PChar(pSource), RowSize);
        end;
      end;
 
 FreeMem(pAnfang, RowSize * BMP.Height);
 BMP.PixelFormat := pf24bit; // optional
 BMP.SaveToFile(name);
 BMP.Free();
end;
 

//verbesserte Version

_________________
"Meine Mutter sagt : 'Dumm ist der, der Dummes tut'." - Forrest Gump

Zuletzt geändert von sniper am Di Apr 19, 2005 13:12, insgesamt 1-mal geändert.

Nach oben

Blechwolf

Betreff des Beitrags:

Verfasst: Di Apr 19, 2005 12:38

DGL Member

Registriert: Fr Nov 12, 2004 14:58
Beiträge: 76
Wohnort: Aachen

sniper_w hat geschrieben:

So geht auch *.bmp:

Was so ziemlich dem entspricht was ich oben gepostet habe bzw. schon mehrfach hier gepostet wurde.
Was ich bei Dir allerdings nicht verstehe ist das folgende:

Code:

 
BMP := Graphics.TBitmap.Create(); 
BMP.PixelFormat := pf32bit;
[...]
// FreeMem(pSource); 
BMP.PixelFormat := pf24bit; // optional
 

Warum setzt Du PixelFormat 2x ? Einmal auf 32bit und einmal auf 24bit.
Du verwendest keinen Laufzeiger und hast damit das Problem, das Dir Deine originale Speicheradresse verloren geht. Deswegen funktioniert das FreeMem nicht. Hat aber den Nachteil das Du je nach Bitmap-Größe eine ziemliche Speicherleicher produzierst. Nicht gut... :roll:

Grüße

Wolf

_________________
Ein Schiff im Hafen ist sicher. Aber dafür werden Schiffe nicht gebaut. (Engl. Sprichwort)

Nach oben

sniper

Betreff des Beitrags:

Verfasst: Di Apr 19, 2005 12:53

DGL Member

Registriert: Mi Dez 15, 2004 20:36
Beiträge: 454
Wohnort: Wien, Österreich

Zitat:

BMP.PixelFormat := pf24bit; // optional

Das hst du übersehen. Und danke für den FreeMem Hinwies.

_________________
"Meine Mutter sagt : 'Dumm ist der, der Dummes tut'." - Forrest Gump

Nach oben

Seite 2 von 4

[ 60 Beiträge ]

Gehe zu Seite Vorherige 1, 2, 3, 4 Nächste

Foren-Übersicht » Programmierung » OpenGL

Wer ist online?

Mitglieder in diesem Forum: 0 Mitglieder und 8 Gäste

Du darfst keine neuen Themen in diesem Forum erstellen.
Du darfst keine Antworten zu Themen in diesem Forum erstellen.
Du darfst deine Beiträge in diesem Forum nicht ändern.
Du darfst deine Beiträge in diesem Forum nicht löschen.
Du darfst keine Dateianhänge in diesem Forum erstellen.