DGL • Thema anzeigen

Antialias

Moderator: DGL-Team

Seite 1 von 1

[ 5 Beiträge ]

Vorheriges Thema | Nächstes Thema

Autor

Nachricht

sirrk

Betreff des Beitrags: Re: Antialias

Verfasst: Do Mai 31, 2012 11:42

DGL Member

Registriert: Mi Jul 15, 2009 20:48
Beiträge: 111
Wohnort: Berlin
Programmiersprache: Delphi,JS,PHP,AS3,C#

leider kann ich zu deiner spezifischen frage nichts sagen, aber vill hilft dir dieses ati-aliasing verfahren, dass sogar ich implementieren konnte

_________________
thanks to the internet we have rule 34, wich states that if something exists, theres a pornographic version of it,

Nach oben

Bergmann89

Betreff des Beitrags: Re: Antialias

Verfasst: Do Mai 31, 2012 11:59

DGL Member

Registriert: Di Apr 29, 2008 18:56
Beiträge: 1213
Programmiersprache: Delphi/FPC

Hey,

das Pixelformat setzt man für die Zeichenfläche, also in deinem Fall für das Fenster (nehm ich an). Mit dem COntext hat das erstmal nix zu tun. Das Pixelformat kann man nur einmal festlegen. Wenn du es danach noch einmal ändern willst, dann musst du ein neues Fenster anlegen und auch den Context neu auf dieses Fenster initialisieren.
Normalerweiße macht man das Ganze aber anders rum. Man erstellt sich zum auslesen des AntiAliasing ein extra Fenster + Context, holt sich die Werte, wertet die aus und setzt dementsprechend das Pixelformat. Ich hatte damit auch schonmal paar Probleme. Damals ist folgende Funktion entstanden. Sie ist nicht perfekt, aber sie macht das was sie soll:

Code:

////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
//ermittelt alle Pixelformate, die MultiSampling unterstützen
//@aFormatSettings: Settings des Pixelformats;
//@PFList: Liste in die die Pixelformate geschieben werden;
//@SampleList: Liste in die die SampleRate passend zum Pixelformat geschrieben wird;
//@MaxCount: Maximale Länge der übergebenen Listen;
//@Count: Anzahl der gefundenen Pixelformate in der Liste;
//@result: TRUE wenn erfolgreich, sonst FALSE;
function  gluGetAntiAliasingPixelFormats(const aFormatSettings: TgluPixelFormatSettings; PFList, SampleList: PglInt; const MaxCount: Integer; var Count: Integer): Boolean;
var
  //temporäres Fenster zum erzeugen des RC
  Form: TForm;
  //ARB_Erweiterung vorhanden
  //|          EXT_Erweiterung vorhanden
  MultiARBSup, MultiEXTSup: Boolean;
  //Liste der Integer Attribute
  IAttrib: array[0..22] of Integer;
  //Liste der Float Attribute (nur 0, da kein Wert)
  FAttrib: GLFloat;
  //temp. PixelFormat
  //| Schleifenvariable
  //| |  AttributName
  PF, i, QueryAtrib: Integer;
  //Zeiger auf zum hochzählen ni der Liste
  PPosiblePF, PSample: PglInt;
  //temp. RenderKontext
  //| RenderContext, der zurvor aktiviert war
  RC, OldRC: TgluRenderContext;
begin
  result       := false;
  OldRC.DC     := wglGetCurrentDC;
  OldRC.RC     := wglGetCurrentContext;
 
  Form := TForm.Create(nil);
  PF := gluGetPixelFormat(Form.Handle, aFormatSettings);
  RC := gluCreateRenderContext(Form.Handle, PF);
  if RC.RC = 0 then begin
    Form.Free;
    if (OldRC.DC <> 0) and (OldRC.RC <> 0) then
      gluActivateRenderContext(OldRC);
    gluLastError := GLU_ERROR_INVALID_RC;
    exit;
  end;
  if not gluActivateRenderContext(RC) then begin
    Form.Free;
    gluDestroyRenderContext(RC);
    if (OldRC.DC <> 0) and (OldRC.RC <> 0) then
      gluActivateRenderContext(OldRC);
    gluLastError := GLU_ERROR_ACTIVATE_RC;
    exit;
  end;
 
  //Pixelformate mit AA auslesen
  MultiARBSup := false;
  MultiEXTSup := false;
  if WGL_ARB_extensions_string and
     WGL_ARB_pixel_format and
     (WGL_ARB_MULTISAMPLE or GL_ARB_MULTISAMPLE) then
    multiARBSup := true;
  if WGL_EXT_extensions_string and
     WGL_EXT_pixel_format and
     (WGL_EXT_MULTISAMPLE or GL_EXT_MULTISAMPLE) then
    multiEXTSup := true;
 
  if multiARBSup then
    Read_WGL_ARB_pixel_format
  else if multiEXTSup then
    Read_WGL_EXT_pixel_format;
 
  if not (MultiARBSup or MultiEXTSup) then begin
    Form.Free;
    gluDestroyRenderContext(RC);
    if (OldRC.DC <> 0) and (OldRC.RC <> 0) then
      gluActivateRenderContext(OldRC);
    gluLastError := GLU_ERROR_AA_NOT_SUPPORTED;
  end;
 
  IAttrib[00] := WGL_DRAW_TO_WINDOW_ARB;
  IAttrib[01] := 1;
 
  IAttrib[02] := WGL_SUPPORT_OPENGL_ARB;
  IAttrib[03] := 1;
 
  IAttrib[04] := WGL_DOUBLE_BUFFER_ARB;
  if (opDoubleBuffered in aFormatSettings.Options) then
    IAttrib[05] := 1
  else
    IAttrib[05] := 0;
 
  IAttrib[06] := WGL_PIXEL_TYPE_ARB;
  IAttrib[07] := WGL_TYPE_RGBA_ARB;
 
  IAttrib[08] := WGL_COLOR_BITS_ARB;
  IAttrib[09] := aFormatSettings.ColorBits;
 
  IAttrib[10] := WGL_ALPHA_BITS_ARB;
  IAttrib[11] := aFormatSettings.AlphaBits;
 
  IAttrib[12] := WGL_DEPTH_BITS_ARB;
  IAttrib[13] := aFormatSettings.DepthBits;
 
  IAttrib[14] := WGL_STENCIL_BITS_ARB;
  IAttrib[15] := aFormatSettings.StencilBits;
 
  IAttrib[16] := WGL_ACCUM_BITS_ARB;
  IAttrib[17] := aFormatSettings.AccumBits;
 
  IAttrib[18] := WGL_AUX_BUFFERS_ARB;
  IAttrib[19] := aFormatSettings.AuxBuffers;
 
  IAttrib[20] := WGL_SAMPLE_BUFFERS_ARB;
  IAttrib[21] := 1;
 
  IAttrib[22] := 0;
  FAttrib     := 0;
 
  if multiARBSup then
    wglChoosePixelFormatARB(RC.DC, @IAttrib, @FAttrib, MaxCount, PFList, @Count)
  else if multiEXTSup then
    wglChoosePixelFormatEXT(RC.DC, @IAttrib, @FAttrib, MaxCount, PFList, @Count);
 
  if Count > MaxCount then
    Count := MaxCount;
 
  QueryAtrib := WGL_SAMPLES_ARB;
  PSample    := SampleList;
  PPosiblePF := PFList;
  for i := 0 to Count-1 do begin
    if multiARBSup then
      wglGetPixelFormatAttribivARB(RC.DC, PPosiblePF^, 0, 1, @QueryAtrib, PSample)
    else if multiEXTSup then
      wglGetPixelFormatAttribivEXT(RC.DC, PPosiblePF^, 0, 1, @QueryAtrib, PSample);
    inc(PSample);
    inc(PPosiblePF);
  end;
 
  if not gluDestroyRenderContext(RC) then begin
    Form.Free;
    exit;
  end;
  Form.Free;
 
  if (OldRC.DC <> 0) and (OldRC.RC <> 0) then
    if not gluActivateRenderContext(OldRC) then
      exit;
 
  result := True;
end;   

MfG Bergmann

_________________
Aktuelle Projekte: BumpMapGenerator, Massive Universe Online
Auf meiner Homepage gibt auch noch paar Projekte und Infos von mir.

Nach oben

Bergmann89

Betreff des Beitrags: Re: Antialias

Verfasst: Do Mai 31, 2012 12:15

DGL Member

Registriert: Di Apr 29, 2008 18:56
Beiträge: 1213
Programmiersprache: Delphi/FPC

Welche Unit meinst du? Die für TForm? Du musst keine TForm nehmen, wenn du willst kannst du dir auch ein Fenster direkt von Windows erstellen lassen. Dann musst du nur die entsprechenden Funktionen dafür laden. Nur mit dglOpenGL geht das nicht, weil die keine Routinen zur Verfügung stellt, um ein Fenster zu erzeugen.
Meine CreateRenderContext bekommt von mir das Handle der Zeichenfläche und ein Pixelformat. Den Rest macht die Funktion selbst. Dort ist auch das entsprechende ErrorHandling eingebaut. So Unsinnig find ich das nicht.

_________________
Aktuelle Projekte: BumpMapGenerator, Massive Universe Online
Auf meiner Homepage gibt auch noch paar Projekte und Infos von mir.

Nach oben

Bergmann89

Betreff des Beitrags: Re: Antialias

Verfasst: Do Mai 31, 2012 12:49

DGL Member

Registriert: Di Apr 29, 2008 18:56
Beiträge: 1213
Programmiersprache: Delphi/FPC

Die dglOpenGL brauchst du immer. Meine Funktion ist da nur zwischengelagert, um die Initialisierung bisl zu vereinfachen. Im Grund macht die nix anderes als die Funktionen aus der dglOpenGL aufzurufen. Irgendwann kommt immer der Aufruf von wglCreateContext. Das ist die eigentliche Funktion die einen Context erstellt, und die kommt aus der dglOpenGL, oder besser gesagt aus der GLU32.dll
Wenn du die Anwendung so klein wie möglich halten willst, dann würde ich eh nicht den dgl-Header verwenden, sondern die Funktionen die du benötigst selbst aus der DLL laden. Dann hast du nur genau das im Code, was du auch wirklich brauchst.

_________________
Aktuelle Projekte: BumpMapGenerator, Massive Universe Online
Auf meiner Homepage gibt auch noch paar Projekte und Infos von mir.

Nach oben

Bergmann89

Betreff des Beitrags: Re: Antialias

Verfasst: Do Mai 31, 2012 13:10

DGL Member

Registriert: Di Apr 29, 2008 18:56
Beiträge: 1213
Programmiersprache: Delphi/FPC

Ja da sind noch viele Funktionen und Typen von mir mit drin. Ich hab dir die Sachen die du dafür brauchst mal zusammen gepackt. Ich hoffe ich hab nix vergessen...
der Aufruf der Funktionen sieht dann ungefähr so aus:

Code:

////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
function TglContext.GetPF: Integer;
var
  PFList, SampleList: array[0..31] of glInt;
  c, i: Integer;
begin
  result := 0;
  c := 0;
  if fAASampleRate > 0 then begin
    if not gluGetAntiAliasingPixelFormats(fPFSettings, PFList, SampleList, Length(PFList), c) then
      raise EglContext.Create('can''t read anti aliasing pixel formats. error code: 0x'+IntToHex(gluGetLastError(), 8))
    else begin
      for i := 0 to c-1 do begin
        if SampleList[i] = fAASampleRate then begin
          result := PFList[i];
          exit;
        end;
      end;
    end;
  end else if Assigned(fCanvas) then begin
    result := gluGetPixelFormat(fRenderContext.Handle, fPFSettings);
  end;
end;  
 
////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
procedure TglContext.CreateContext;
var
  PF: Integer;
begin
  if not Assigned(fCanvas) then
    raise EglContext.Create('no valid canvas assigned');
 
  PF := GetPF;
  if PF = 0 then
    raise EglContext.Create('can''t find matching pixel format');
 
  gluGetLastError;
  fRenderContext := gluCreateRenderContext(fCanvas.GetHandle, PF);
  case gluGetLastError of
    GLU_ERROR_INIT_OPENGL:
      raise EglContext.Create('can''t initialize OpenGL');
    GLU_ERROR_INVALID_PIXELFORMAT:
      raise EglContext.Create('invalid pixel format');
    GLU_ERROR_CREATE_DC:
      raise EglContext.Create('invalid devide handle');
    GLU_ERROR_SET_PIXELFORMAT:
      raise EglContext.Create('can''t activate pixelformat for canvas');
    GLU_ERROR_CREATE_RC: begin
      fPixelFormatActivated := true;
      raise EglContext.Create('can''t create render context');
    end;
  end;
  fPixelFormatActivated := true;
  UpdateVieport;
end;  

Du hast keine ausreichende Berechtigung, um die Dateianhänge dieses Beitrags anzusehen.

_________________
Aktuelle Projekte: BumpMapGenerator, Massive Universe Online
Auf meiner Homepage gibt auch noch paar Projekte und Infos von mir.

Nach oben

Seite 1 von 1

[ 5 Beiträge ]

Foren-Übersicht » Programmierung » OpenGL

Wer ist online?

Mitglieder in diesem Forum: 0 Mitglieder und 9 Gäste

Du darfst keine neuen Themen in diesem Forum erstellen.
Du darfst keine Antworten zu Themen in diesem Forum erstellen.
Du darfst deine Beiträge in diesem Forum nicht ändern.
Du darfst deine Beiträge in diesem Forum nicht löschen.
Du darfst keine Dateianhänge in diesem Forum erstellen.