DGL • Thema anzeigen - Probleme mit CallLists (beim Ausgeben von 3D Texten)

Probleme mit CallLists (beim Ausgeben von 3D Texten)

Moderator: DGL-Team

Seite 1 von 1

[ 5 Beiträge ]

Vorheriges Thema | Nächstes Thema

Autor

Nachricht

Andyh

Betreff des Beitrags: Probleme mit CallLists (beim Ausgeben von 3D Texten)

Verfasst: Mo Aug 22, 2005 13:50

DGL Member

Registriert: Do Jun 09, 2005 13:48
Beiträge: 117
Wohnort: Sankt Augustin

Ich habe (mit Hilfe von Vorlagen) eine Komponente zur Textausgabe geschrieben. Es klappt auch alles ganz toll bis auf eine Sache: wenn ich die Funktion glFont.Print (...) ausführe, verändert sich die Projektionsmatrix. Ich habe vorher alles schön perspektivisch dargestellt und habe es nach der Ausführung von CallLists im 2D Modus ohne tiefe etc. vor mir. Das habe ich ausprobiert, indem ich die Zeile mit CallLists auskommentiert habe. Ist sie auskommentiert sieht alles toll aus. Wenn nicht dann halt nicht. Ich habe mal den Code der Komponent eingefügt.

Wenn jemand das gleiche Problem schon mal hatte oder so weiß wodran es liegt, dann schreibt mir bitte.

Ich hjabe schon extra Prozeduren zum sichern und zurückspeichern aller Matrizen geschrieben (PushAll und PopAll) aber das bringt leider auch nichts.

Code:

 
unit glFont;
 
interface
 
uses
  Windows,
  Graphics,
  SysUtils,
  Classes,
  Controls,
  Dialogs,
  Forms,
  OpenGLUtil,
  DglOpenGL;
 
type
  TPglFont=^TglFont;
  TglFont=class(TComponent)
  private
    FFont: HFONT;                                    // Windows Font ID
    FFontList: GLUint;
    FFontgmf : array [0..255] of GLYPHMETRICSFLOAT;  // Address Buffer For Font Storage
    FEnabled: boolean;
    procedure PopAll;
    procedure PushAll;
  public
    constructor Create(AOwner:TComponent); override;
    destructor Destroy; override;
    procedure Print(text: pChar; V1: TGKvector);
    procedure BuildFont (FontName: string; glFontDC: HDC);
    procedure KillFont;
  published
    property Enabled: boolean read FEnabled write FEnabled;
  end; {TOpenGL}
 
procedure Register;
 
var
  OldFont: string;
 
implementation
 
constructor TglFont.Create(AOwner:TComponent);
begin
  inherited Create(AOwner);
  FFont := 0;
end;
 
destructor TglFont.Destroy;
begin
  inherited destroy;
end;
 
procedure TglFont.BuildFont (FontName: string; glFontDC: HDC); // Build Our Bitmap Font
begin
  if not FEnabled then
    exit;
  if FFont <> 0 then
    KillFont;
  PushAll;
 
  FFontList := glGenLists(256);             // Storage For 256 Characters
  glEnable(GL_POINT_SMOOTH);
 
  FFont := CreateFont(32,                   // Height Of Font
                      10,                   // Width Of Font
                      0,                    // Angle Of Escapement
                      0,                    // Orientation Angle
                      FW_BOLD,              // Font Weight
                      0,                    // Italic
                      0,                    // Underline
                      0,                    // Strikeout
                      ANSI_CHARSET,         // Character Set Identifier
                      OUT_TT_PRECIS,        // Output Precision
                      CLIP_DEFAULT_PRECIS,  // Clipping Precision
                      ANTIALIASED_QUALITY,  // Output Quality
                      FF_DONTCARE or DEFAULT_PITCH, // Family And Pitch
                      PCHAR(FontName));     // Font Name
 
  SelectObject(glFontDC, FFont);            // Selects The Font We Want
 
  wglUseFontOutlines(glFontDC,              // Select The wanted DC
                     0,                     // Starting Character
                     256,                   // Number Of Display Lists To Build
                     FFontList,             // Starting Display Lists
                     0.0,                   // Deviation From The True Outlines
                     0.5,                   // Font Thickness In The Z Direction
                     WGL_FONT_POLYGONS,     // Use Polygons, Not Lines
                     @FFontgmf);            // Address Of Buffer To Recieve Data
 
  PopAll;
end;
 
procedure TglFont.KillFont;
begin
  if not FEnabled then
    exit;
  if not glIsList (FFontList) then
    exit;
  PushAll;
  glDeleteLists(FFontList, 256);                   // Lösche alle 256 Zeichen
  FFont := 0;
  PopAll;
end;
 
procedure TglFont.Print(text: pChar; V1: TGKvector);
var
  laenge: glfloat;
  loop: integer;
  V2: TGLvector;
begin
  if not FEnabled then
    exit;
  if text = '' then
    exit;
  if not glIsList (FFontList) then
    exit;
 
  V2 := GK2GLvector (V1);  // vertauscht y und z
 
  // länge des texts ermitteln (für was auch immer...)
  laenge := 0;
  for loop:=1 to length(text)-1 do
    laenge := laenge + FFontgmf[loop].gmfCellIncX;
 
  PushAll;
  glPushAttrib(GL_LIST_BIT);
  glListBase(FFontList);
  glMatrixMode(GL_MODELVIEW);
  glTranslatef(V2.x, V2.y, V2.z);
  glCallLists(length(text),GL_UNSIGNED_BYTE,text);
  glPopAttrib;
  PopAll;
end;
 
procedure TglFont.PushAll;
begin
  glMatrixMode(GL_MODELVIEW);
  glPushMatrix;
  glMatrixMode(GL_PROJECTION);
  glPushMatrix;
  glMatrixMode(GL_TEXTURE);
  glPushMatrix;
end;
 
procedure TglFont.PopAll;
begin
  glMatrixMode(GL_TEXTURE);
  glPopMatrix;
  glMatrixMode(GL_PROJECTION);
  glPopMatrix;
  glMatrixMode(GL_MODELVIEW);
  glPopMatrix;
end;
 
procedure Register;
begin
  RegisterComponents('OpenGL',[TglFont]);
end;
 
end.
 

Zuletzt geändert von Andyh am Di Aug 23, 2005 11:02, insgesamt 2-mal geändert.

Nach oben

Flash

Betreff des Beitrags:

Verfasst: Mo Aug 22, 2005 14:51

Guitar Hero

Registriert: Do Sep 25, 2003 15:56
Beiträge: 7810
Wohnort: Sachsen - ERZ / C
Programmiersprache: Java (, Pascal)

Also...ich hatte das vor einiger Zeit auch mal benutzt. Der Code sah so ähnlich aus...ich kann jetzt nicht nachvollziehen, wieso deine Push&Pops net greifen....

_________________
Blog: kevin-fleischer.de und fbaingermany.com

Nach oben

Grizzly

Betreff des Beitrags:

Verfasst: Mo Aug 22, 2005 19:17

DGL Member

Registriert: Sa Nov 13, 2004 11:00
Beiträge: 229
Wohnort: Steinhude

die stacks haben nur ne begrenzte größe. ist es möglich dass noch irgendwo anders die matrix gepusht wird und nicht zu rechten zeit wieder gepopt? in dem fall würden push und pop nämlich wirkungslos bleiben.

Nach oben

Andyh

Betreff des Beitrags: hab ich schon überprüft

Verfasst: Di Aug 23, 2005 03:00

DGL Member

Registriert: Do Jun 09, 2005 13:48
Beiträge: 117
Wohnort: Sankt Augustin

An die Stacks hatte ich auch schon gedacht und habe versucht das nachzuvollziehen. Das scheint in Ordnung zu sein. Das komische ist, dass ich den Projektionsmodus nicht mehr auf Perspektive umschalten kann. Wenn ich einmal den Befehl CallLists aufgerufen habe, bleibt mein System immer im Ortho-Modus.

Nach oben

Andyh

Betreff des Beitrags: funktioniert jetzt

Verfasst: Di Aug 23, 2005 03:32

DGL Member

Registriert: Do Jun 09, 2005 13:48
Beiträge: 117
Wohnort: Sankt Augustin

Ich habe mal ein bisschen rumprobiert und herausgefunden, dass der Befehl "glPushAttrib (GL_LIST_BIT) " nicht richtig war. man muss stattdessen "glPushAttrib (GL_ALL_ATTRIB_BITS)" ausführen. Hier wird bestimmt einiges weggesichert was man nicht sichern braucht aber ich habe keine Lust jetzt jedes einzelne Attribut zu testen.

Hier der Funktionierende Code un eine kurze Anleitung zum Gebrauch (funktioniert jetzt einwandfrei):

Code:

unit glFont;
 
interface
 
uses
  Windows,
  Graphics,
  SysUtils,
  Classes,
  Controls,
  Dialogs,
  Forms,
  OpenGLUtil,
  DglOpenGL;
 
type
  TPglFont=^TglFont;
  TglFont=class(TComponent)
  private
    FFont: HFONT;                                    // Windows Font ID
    FFontList: TGLUint;
    FFontSize: integer;
    FFontThickness: integer;
    FFontWidth: integer;
    FFontgmf : array [0..255] of GLYPHMETRICSFLOAT;  // Address Buffer For Font Storage
    FEnabled: boolean;
  public
    constructor Create(AOwner:TComponent); override;
    destructor Destroy; override;
    procedure Print(text: pChar; V1: TGKvector);
    procedure BuildFont (FontName: string; glFontDC: HDC);
    procedure KillFont;
  published
    property Enabled: boolean read FEnabled write FEnabled;
    property FontSize: integer read FFontSize write FFontSize;
    property FontThickness: integer read FFontThickness write FFontThickness;
    property FontWidth: integer read FFontWidth write FFontWidth;
  end; {TOpenGL}
 
procedure Register;
 
var
  OldFont: string;
 
implementation
 
constructor TglFont.Create(AOwner:TComponent);
begin
  inherited Create(AOwner);
  FFont := 0;
  FFontSize := 12;
  FFontWidth := 10;
  FFontThickness := 1;
end;
 
destructor TglFont.Destroy;
begin
  inherited destroy;
end;
 
procedure TglFont.BuildFont (FontName: string; glFontDC: HDC); // Build Our Bitmap Font
begin
  if not FEnabled then
    exit;
  if FFont <> 0 then
    KillFont;
 
  FFontList := glGenLists(256);             // Storage For 256 Characters
  glEnable(GL_POINT_SMOOTH);
 
  FFont := CreateFont(FFontSize,            // Height Of Font
                      FFontWidth,           // Width Of Font
                      0,                    // Angle Of Escapement
                      0,                    // Orientation Angle
                      FW_NORMAL,            // Font Weight
                      0,                    // Italic
                      0,                    // Underline
                      0,                    // Strikeout
                      ANSI_CHARSET,         // Character Set Identifier
                      OUT_TT_PRECIS,        // Output Precision
                      CLIP_DEFAULT_PRECIS,  // Clipping Precision
                      ANTIALIASED_QUALITY,  // Output Quality
                      FF_DONTCARE or DEFAULT_PITCH, // Family And Pitch
                      PCHAR(FontName));     // Font Name
 
  SelectObject(glFontDC, FFont);            // Selects The Font We Want
 
  wglUseFontOutlines(glFontDC,              // Select The wanted DC
                     0,                     // Starting Character
                     256,                   // Number Of Display Lists To Build
                     FFontList,             // Starting Display Lists
                     0.0,                   // Deviation From The True Outlines
                     FFontThickness/10,     // Font Thickness In The Z Direction
                     WGL_FONT_POLYGONS,     // Use Polygons, Not Lines
                     @FFontgmf);            // Address Of Buffer To Recieve Data
end;
 
procedure TglFont.KillFont;
begin
  if not FEnabled then
    exit;
  if not glIsList (FFontList) then
    exit;
  glDeleteLists(FFontList, 256);                   // Lösche alle 256 Zeichen
  FFont := 0;
end;
 
procedure TglFont.Print(text: pChar; V1: TGKvector);
var
  laenge: glfloat;
  loop: integer;
  V2: TGLvector;
begin
  if not FEnabled then
    exit;
  if text = '' then
    exit;
  if not glIsList (FFontList) then
    exit;
 
  V2 := GK2GLvector (V1);
 
  // länge des texts ermitteln (für was auch immer...)
  laenge := 0;
  for loop:=1 to length(text)-1 do
    laenge := laenge + FFontgmf[loop].gmfCellIncX;
 
  //glPushAttrib(GL_LIST_BIT);
  glPushAttrib (GL_ALL_ATTRIB_BITS);
  glListBase(FFontList);
  glMatrixMode(GL_MODELVIEW);
  glTranslatef(V2.x, V2.y, V2.z);
  glCallLists(length(text),GL_UNSIGNED_BYTE,text);
  glPopAttrib;
end;
 
procedure Register;
begin
  RegisterComponents('OpenGL',[TglFont]);
end;
 
end.
 

Beispiel zur Benutzung. Hierbei wird davon ausgegangen, dass die Komponente aus der Komponentenleiste auf das aktuelle Formular gezogen wurde.

Code:

unit Main;
 
interface
 
uses
  ..., glFont;
 
type
  TGLVector = packed record
    x,y,z: GLfloat;
  end;
 
type
  TFMain = class(TForm)
    .
    .
    .
    glFont1: TglFont;
    .
    .
    .
    procedure FormCreate(Sender: TObject);
    procedure FormClose(Sender: TObject; var Action: TCloseAction);
    procedure FormPaint(Sender: TObject);
  private
  public
  end;
 
var
  FMain: TFMain;
 
implementation
 
procedure TFMain.FormCreate(Sender: TObject);
begin
  glFont1.Enabled := true;
  glFont1.FontSize := 12;
  glFont1.FontWidth := 10;
  glFont1.FontThickness := 1;
  glFont1.BuildFont('Arial Black', getDC(handle));
end;
 
procedure TFMain.FormPaint(Sender: TObject);
var
  pVec: TGLvector;
begin
  pVec.x := 0;
  pVec.y := 0;
  pVec.z := 0;
 
  glColor3f (1, 0.7, 0);
  glFont1.Print('Dies ist ein 3D Text', pVec);
end;
 
procedure TFMain.FormClose(Sender: TObject; var Action: TCloseAction);
begin
  glFont1.KillFont;
end;
 

Nach oben

Seite 1 von 1

[ 5 Beiträge ]

Foren-Übersicht » Programmierung » OpenGL

Wer ist online?

Mitglieder in diesem Forum: 0 Mitglieder und 13 Gäste

Du darfst keine neuen Themen in diesem Forum erstellen.
Du darfst keine Antworten zu Themen in diesem Forum erstellen.
Du darfst deine Beiträge in diesem Forum nicht ändern.
Du darfst deine Beiträge in diesem Forum nicht löschen.
Du darfst keine Dateianhänge in diesem Forum erstellen.