DGL • Thema anzeigen - Fullscreen mit dglOpenGL

Fullscreen mit dglOpenGL

Moderator: DGL-Team

Seite 1 von 1

[ 9 Beiträge ]

Vorheriges Thema | Nächstes Thema

Autor

Nachricht

SamStone

Betreff des Beitrags: Fullscreen mit dglOpenGL

Verfasst: Mo Okt 04, 2004 13:42

DGL Member

Registriert: So Okt 12, 2003 14:53
Beiträge: 74

Hi

Erstmal Sorry für die blöde Frage, aber ich finde leider nirgends infos darüber, wie man mit der dglOpenGL (die neuste) ein Fullscreen Mode einstellt.
Ich initialisiere das ganze Fenster zeugs so:

Code:

InitOpenGL;
// Gerätekontext holen
DC := GetDC(Form1.Handle);
// Renderkontext erstellen (32 Bit Farbtiefe, 24 Bit Tiefenpuffer, Doublebuffering)
RC := CreateRenderingContext(DC, [opDoubleBuffered], 32, 24, 0, 0, 0, 0);
// Erstellten Renderkontext aktivieren
ActivateRenderingContext(DC, RC);

Das Tutorial hier auf der Seite bezieht sich ja auf eine andere OpenGL Unit.

Nach oben

Flash

Betreff des Beitrags:

Verfasst: Mo Okt 04, 2004 13:47

Guitar Hero

Registriert: Do Sep 25, 2003 15:56
Beiträge: 7810
Wohnort: Sachsen - ERZ / C
Programmiersprache: Java (, Pascal)

Im DGL-SDK gabs ne Unit namens Fullscreen.pas. Die wird unter anderem in den Templates verwendet. Kannst dir ja einfach so ein Template ziehen und dann die Unit daraus nehmen.

Die Unit wurde von jemanden hier ausm Forum geschrieben. (Weiß jetzt nicht wers war :oops:

)

_________________
Blog: kevin-fleischer.de und fbaingermany.com

Nach oben

LarsMiddendorf

Betreff des Beitrags:

Verfasst: Mo Okt 04, 2004 14:23

DGL Member

Registriert: Sa Dez 28, 2002 11:13
Beiträge: 2244

Im Wesentlichen muß man einfach den Rahmen des Fensters entfernen (BorderStyle:=bsNone) und das Fenster genau an die Bildschirmgröße anpassen. Wenn man eine anderer Auflösung haben möchte, kann man die vorher mit ChangeDisplaySettings umstellen.

Nach oben

rswm

Betreff des Beitrags:

Verfasst: Mo Okt 04, 2004 19:27

DGL Member

Registriert: Mi Aug 28, 2002 19:27
Beiträge: 568
Wohnort: Chemnitz / Sachsen

@flash, naja wer wirds denn gewesen sein?? der große meister natürlich !!!!!!!

SOS !!!!!

_________________
Aktuelles Projekt :
www.PicPlace.de

Nach oben

Stucuk

Betreff des Beitrags:

Verfasst: Mo Okt 04, 2004 19:53

DGL Member

Registriert: Mi Jul 21, 2004 22:39
Beiträge: 360
Wohnort: UK, Scotland

Helios_GL.pas

Note: Opengl15 is dglOpenGL v1.4 renamed to OpenGL15
Note2: LaunchHelios is called after glcreatewnd, launchhelios shows the window and makes it fullscreen(if the user wants it to) when u have everything setup

Code:

 
unit Helios_GL;
 
interface
 
function glCreateWnd : Boolean;
procedure glKillWnd(Fullscreen : Boolean);
Procedure LaunchHelios;
Procedure ChangeToFullScreen;
 
implementation
 
Uses Windows,Messages,Sysutils,OpenGL15, Helios_Global, Helios_Engine, Helios_CvarSystem,
  Helios_Types;
 
Procedure CheckExtensions;
begin
ChangeCVar('Cg_MultiTexture',BoolToStr(GL_ARB_multitexture));
end;
 
function WndProc(hWnd: HWND; Msg: UINT;  wParam: WPARAM;  lParam: LPARAM): LRESULT; stdcall;
begin
  result := 0;
  if not Loaded then begin
    Result := DefWindowProc(hWnd, Msg, wParam, lParam);    // Default result if nothing happens
    exit;
  end;
 
  case (Msg) of
    WM_CREATE:
      begin
        // Insert stuff you want executed when the program starts
      end;
    WM_CLOSE:
      begin
        PostQuitMessage(0);
        Result := 0
      end;
    WM_KEYDOWN:       // Set the pressed key (wparam) to equal true so we can check if its pressed
      begin
//      cons.AddMsg(inttostr(wParam));
        keys[wParam] := True;
        lastKeyPress := GetTickCount;
        Result := 0;
      end;
    WM_KEYUP:         // Set the released key (wparam) to equal false so we can check if its pressed
      begin
        keys[wParam] := False;
        Result := 0;
      end;
    WM_SIZE:          // Resize the window with the new width and height
      begin
        glResizeWnd(LOWORD(lParam),HIWORD(lParam));
        Result := 0;
      end;
    WM_TIMER :                     // Add code here for all timers to be used.
      begin
//
      end;
    WM_RBUTTONDOWN :                                                    // If we hit the right mouse button
      begin
//
      end;
    WM_LBUTTONDOWN:                             // If we hit the left mouse button
      begin
//
      end;
    else
      Result := DefWindowProc(hWnd, Msg, wParam, lParam);    // Default result if nothing happens
  end;
end;
 
procedure glKillWnd(Fullscreen : Boolean);
begin
OpenGLRunning := False;
  if Fullscreen then begin            // Change back to non fullscreen
    Q3levelLoaded := false;
    ChangeDisplaySettings(devmode(nil^), 0);
    ShowCursor(True);
  end;
 
  // Makes current rendering context not current, and releases the device
  // context that is used by the rendering context.
  if (not wglMakeCurrent(h_DC, 0)) then
    MessageBox(0, 'Release of DC and RC failed!', 'Error', MB_OK or MB_ICONERROR);
 
  // Attempts to delete the rendering context
  if (not wglDeleteContext(h_RC)) then begin
    MessageBox(0, 'Release of rendering context failed!', 'Error', MB_OK or MB_ICONERROR);
    h_RC := 0;
  end;
 
  // Attemps to release the device context
  if ((h_DC > 0) and (ReleaseDC(h_Wnd, h_DC) = 0)) then begin
    MessageBox(0, 'Release of device context failed!', 'Error', MB_OK or MB_ICONERROR);
    h_DC := 0;
  end;
 
  // Attempts to destroy the window
  if ((h_Wnd <> 0) and (not DestroyWindow(h_Wnd))) then begin
    MessageBox(0, 'Unable to destroy window!', 'Error', MB_OK or MB_ICONERROR);
    h_Wnd := 0;
  end;
 
  // Attempts to unregister the window class
  if (not UnRegisterClass('OpenGL', hInstance)) then begin
    MessageBox(0, 'Unable to unregister window class!', 'Error', MB_OK or MB_ICONERROR);
    hInstance := 0;
  end;
end;
 
function glCreateWnd : Boolean;
var
  wndClass : TWndClass;         // Window class
  dwStyle : DWORD;              // Window styles
  dwExStyle : DWORD;            // Extended window styles
  PixelFormat : GLuint;         // Settings for the OpenGL rendering
  h_Instance : HINST;           // Current instance
  pfd : TPIXELFORMATDESCRIPTOR;  // Settings for the OpenGL window
begin
  InitOpenGL;
  SCREEN_WIDTH := HeliosSettings.Width;
  SCREEN_HEIGHT := HeliosSettings.Height;
 
  AddToConsole('--- Creating Window ---');
 
  h_Instance := GetModuleHandle(nil);       //Grab An Instance For Our Window
  ZeroMemory(@wndClass, SizeOf(wndClass));  // Clear the window class structure
 
  with wndClass do  begin                  // Set up the window class
    style         := CS_HREDRAW or    // Redraws entire window if length changes
                     CS_VREDRAW or    // Redraws entire window if height changes
                     CS_OWNDC;        // Unique device context for the window
    lpfnWndProc   := @WndProc;        // Set the window procedure to our func WndProc
    hInstance     := h_Instance;
    hCursor       := LoadCursor(0, IDC_ARROW);
    hIcon         := LoadIcon(hInstance, 'MAINICON');
    lpszClassName := 'OpenGL';
  end;
 
  if (RegisterClass(wndClass) = 0) then  begin// Attemp to register the window class
    AddToConsole('Failed to register the window class!');
    Result := False;
    Exit
  end;
 
  AddToConsole('Registered Class...');
 
  //ChangeToFullScreen;
 
  // If we are still in fullscreen then
  if (HeliosSettings.Fullscreen) then begin
    dwStyle := WS_POPUP or                // Creates a popup window
               WS_CLIPCHILDREN            // Doesn't draw within child windows
               or WS_CLIPSIBLINGS;        // Doesn't draw within sibling windows
    dwExStyle := 0;         // Top level window
    //ShowCursor(false);                    // Turn of the cursor (gets in the way)
  end
  else begin
       dwStyle := WS_OVERLAPPEDWINDOW or     // Creates an overlapping window
               WS_CLIPCHILDREN or         // Doesn't draw within child windows
               WS_CLIPSIBLINGS;           // Doesn't draw within sibling windows
 
    dwExStyle := WS_EX_APPWINDOW or       // Top level window
                 WS_EX_WINDOWEDGE;        // Border with a raised edge
    //ShowCursor(false);                    // Turn of the cursor (gets in the way)
  end;
 
  // Attempt to create the actual window
  h_Wnd := CreateWindowEx(dwExStyle,      // Extended window styles
                          'OpenGL',       // Class name
                          WND_TITLE,      // Window title (caption)
                          dwStyle,        // Window styles
                          0, 0,           // Window position
                          HeliosSettings.Width, HeliosSettings.Height,  // Size of window
                          0,              // No parent window
                          0,              // No menu
                          h_Instance,     // Instance
                          nil);           // Pass nothing to WM_CREATE
  if h_Wnd = 0 then begin
    AddToConsole('Unable to create window!');
    glKillWnd(False);                // Undo all the settings we've changed
    Result := False;
    Exit;
  end;
 
  Loaded := True;
 
  AddToConsole('Window Created...');
  AddToConsole('');
  AddToConsole('--- Initalizing OpenGL ---');
  // Try to get a device context
  h_DC := GetDC(h_Wnd);
  if (h_DC = 0) then begin
    AddToConsole('Unable to get a device context!');
    glKillWnd(False);
    Result := False;
    Exit;
  end;
 
  AddToConsole('Got DC...');
 
  // Settings for the OpenGL window
  with pfd do begin
    nSize           := SizeOf(TPIXELFORMATDESCRIPTOR); // Size Of This Pixel Format Descriptor
    nVersion        := 1;                    // The version of this data structure
    dwFlags         := PFD_DRAW_TO_WINDOW    // Buffer supports drawing to window
                       or PFD_SUPPORT_OPENGL // Buffer supports OpenGL drawing
                       or PFD_DOUBLEBUFFER;  // Supports double buffering
    iPixelType      := PFD_TYPE_RGBA;        // RGBA color format
    cColorBits      := HeliosSettings.PixelDepth;           // OpenGL color depth
//    cRedBits        := 0;                    // Number of red bitplanes
//    cRedShift       := 0;                    // Shift count for red bitplanes
//    cGreenBits      := 0;                    // Number of green bitplanes
//    cGreenShift     := 0;                    // Shift count for green bitplanes
//    cBlueBits       := 0;                    // Number of blue bitplanes
//    cBlueShift      := 0;                    // Shift count for blue bitplanes
//    cAlphaBits      := 0;                    // Not supported
//    cAlphaShift     := 0;                    // Not supported
//    cAccumBits      := 0;                    // No accumulation buffer
//    cAccumRedBits   := 0;                    // Number of red bits in a-buffer
//    cAccumGreenBits := 0;                    // Number of green bits in a-buffer
//    cAccumBlueBits  := 0;                    // Number of blue bits in a-buffer
//    cAccumAlphaBits := 0;                    // Number of alpha bits in a-buffer
    cDepthBits      := HeliosSettings.TextureDepth;           // Specifies the depth of the depth buffer
    cStencilBits    := HeliosSettings.StencilDepth ;                    // Turn off stencil buffer
//    cAuxBuffers     := 0;                    // Not supported
    iLayerType      := PFD_MAIN_PLANE;       // Ignored
//    bReserved       := 0;                    // Number of overlay and underlay planes
//    dwLayerMask     := 0;                    // Ignored
//    dwVisibleMask   := 0;                    // Transparent color of underlay plane
//    dwDamageMask    := 0;                     // Ignored
  end;
 
  // Attempts to find the pixel format supported by a device context that is the best match to a given pixel format specification.
  PixelFormat := ChoosePixelFormat(h_DC, @pfd);
  if (PixelFormat = 0) then begin
    AddToConsole('Unable to find a suitable pixel format');
    glKillWnd(False);
    Result := False;
    Exit;
  end;
 
  AddToConsole('Pixel Format ' + inttostr(PixelFormat) + ' Chosen');
 
  // Sets the specified device context's pixel format to the format specified by the PixelFormat.
  if (not SetPixelFormat(h_DC, PixelFormat, @pfd)) then begin
    AddToConsole('Unable to set the pixel format');
    glKillWnd(False);
    Result := False;
    Exit;
  end;
 
  AddToConsole('Pixel Format Set...');
 
  // Create a OpenGL rendering context
  h_RC := wglCreateContext(h_DC);
  if (h_RC = 0) then begin
    AddToConsole('Unable to create an OpenGL rendering context');
    glKillWnd(False);
    Result := False;
    Exit;
  end;
 
  AddToConsole('OpenGL Rendering Context Created...');
 
  // Makes the specified OpenGL rendering context the calling thread's current rendering context
  if (not wglMakeCurrent(h_DC, h_RC)) then begin
    AddToConsole('Unable to activate OpenGL rendering context');
    glKillWnd(False);
    Result := False;
    Exit;
  end;
  ActivateRenderingContext(h_DC, h_RC);
 
  AddToConsole('OpenGL Rendering Context Activated...');
 
  ReadExtensions;
  ReadImplementationProperties;
  CheckExtensions;
  if GL_EXT_compiled_vertex_array then begin
    LockingAvailable := true;
 //   LockArrays := true;
  end
  else
  LockArrays := False;
 
  // Ensure the OpenGL window is resized properly
  glResizeWnd(HeliosSettings.Width, HeliosSettings.Height); // DOV !!!!!
 
  AddToConsole('Finished');
  AddToConsole('');
 
  Result := True;
end;
 
Procedure ChangeToFullScreen;
var
dmScreenSettings : DEVMODE;   // Screen settings (fullscreen, etc...)
begin
 
// Change to fullscreen if so desired
  if HeliosSettings.Fullscreen then begin
    ZeroMemory(@dmScreenSettings, SizeOf(dmScreenSettings));
    with dmScreenSettings do begin              // Set parameters for the screen setting
      dmSize       := SizeOf(dmScreenSettings);
      dmPelsWidth  := SCREEN_WIDTH;                    // Window width
      dmPelsHeight := SCREEN_HEIGHT;                   // Window height
      dmBitsPerPel := HeliosSettings.PixelDepth;               // Window color depth
      dmFields     := DM_PELSWIDTH or DM_PELSHEIGHT or DM_BITSPERPEL;
    end;
 
    // Try to change screen mode to fullscreen
    if (ChangeDisplaySettings(dmScreenSettings, CDS_FULLSCREEN) = DISP_CHANGE_FAILED) then begin
      AddToConsole('Unable to switch to fullscreen!');
      HeliosSettings.Fullscreen := False;
    end;
  end;
 
end;
 
Procedure LaunchHelios;
begin
 
AddToConsole('');
AddToConsole('Launching Helios...');
 
ShowCursor(false);
ChangeToFullScreen;
ShowWindow(h_Wnd, SW_SHOW);
glClear(GL_COLOR_BUFFER_BIT or GL_DEPTH_BUFFER_BIT or GL_STENCIL_BUFFER_BIT);    // Clear The Screen And The Depth Buffer
glClearColor(BGColor.X, BGColor.Y, BGColor.Z, 1.0);
SwapBuffers(h_dc);
SetForegroundWindow(h_Wnd);
SetFocus(h_Wnd);
SwapBuffers(h_dc);
 
SetCursorPos(SCREEN_WIDTH SHR 1, SCREEN_HEIGHT SHR 1); // Set the cursor to the middle, so it doesn't alter the view on the first frame!
 
 
OpenGLRunning := True;
 
end;
 
end.
 

_________________
Free Map Editor - Game Requirements - Stucuk.Net
-Stu

Nach oben

Phobeus

Betreff des Beitrags:

Verfasst: Mo Okt 04, 2004 21:53

Fels i.d. Brandung

Registriert: Sa Mai 04, 2002 19:48
Beiträge: 3830
Wohnort: Tespe (nahe Hamburg)

Wie bereits indirekt gesagt wurde. OpenGL bietet keine Möglichkeit eines Fullscreens. Man muss auf eine entsprechende API des Systems zurückgreifen und das Fenster entsprechend präperieren. ChangeDisplaySettings für die WinAPI oder dem entsprechenden Flags (z.B. bei SDL). Bei Delphic VCL-Tutorials solltest Du entsprechende Beispiele für die WinAPI finden.

_________________
"Light travels faster than sound. This is why some people appear bright, before you can hear them speak..."

Nach oben

Flash

Betreff des Beitrags:

Verfasst: Di Okt 05, 2004 13:35

Guitar Hero

Registriert: Do Sep 25, 2003 15:56
Beiträge: 7810
Wohnort: Sachsen - ERZ / C
Programmiersprache: Java (, Pascal)

Soll die UFullscreen nicht benutzt werden oder wieso sagt von euch niemand was dazu?

Oder war meine Ausführungen so vollständig und doll?

_________________
Blog: kevin-fleischer.de und fbaingermany.com

Nach oben

SamStone

Betreff des Beitrags:

Verfasst: Mi Okt 06, 2004 14:55

DGL Member

Registriert: So Okt 12, 2003 14:53
Beiträge: 74

THX für die Antwort. Sorry das ich so lange nicht geantwortet habe. Ich habs jetzt mit der Fullscreen Unit gemacht.

Ich dachte ehrlich gesagt bis jetzt immer das diese Fullscreen Methode von OpenGL, bzw DirectX kommt :oops:

Nach oben

luketheduke

Betreff des Beitrags:

Verfasst: Mi Okt 06, 2004 15:14

DGL Member

Registriert: Fr Mai 14, 2004 18:56
Beiträge: 804
Wohnort: GER/OBB/TÖL-WOR/Greiling

Ganz einfach gehts auch mit dem opengl1.5-template, das es hier zum donwnloaden gibt.

DArin ist unter anderem die prozedur

Code:

 
procedure TGLForm.GoToFullScreen(pWidth, pHeight, pBPP, pFrequency : Word);
var
 dmScreenSettings : DevMode;
begin
// Fenster vor Vollbild vorbereiten
WindowState := wsMaximized;
BorderStyle := bsNone;
ZeroMemory(@dmScreenSettings, SizeOf(dmScreenSettings));
with dmScreenSettings do
 begin
 dmSize              := SizeOf(dmScreenSettings);
 dmPelsWidth         := pWidth;                    // Breite
 dmPelsHeight        := pHeight;                   // Höhe
 dmBitsPerPel        := pBPP;                      // Farbtiefe
 dmDisplayFrequency  := pFrequency;                // Bildwiederholfrequenz
 dmFields            := DM_PELSWIDTH or DM_PELSHEIGHT or DM_BITSPERPEL or DM_DISPLAYFREQUENCY;
 end;
if (ChangeDisplaySettings(dmScreenSettings, CDS_FULLSCREEN) = DISP_CHANGE_FAILED) then
 begin
 MessageBox(0, 'Konnte Vollbildmodus nicht aktivieren!', 'Error', MB_OK or MB_ICONERROR);
 exit
 end;
 
FullScreenConsequences(pWidth,pHeight);
end;
 

die fullscreenconsequences sind von mir, kannst du rauslöschen.[/quote]

_________________

"User Error. Replace User and hit Continue."

Nach oben

Seite 1 von 1

[ 9 Beiträge ]

Foren-Übersicht » Programmierung » OpenGL

Wer ist online?

Mitglieder in diesem Forum: 0 Mitglieder und 5 Gäste

Du darfst keine neuen Themen in diesem Forum erstellen.
Du darfst keine Antworten zu Themen in diesem Forum erstellen.
Du darfst deine Beiträge in diesem Forum nicht ändern.
Du darfst deine Beiträge in diesem Forum nicht löschen.
Du darfst keine Dateianhänge in diesem Forum erstellen.