DGL • Thema anzeigen - Picture from the scene

Picture from the scene

Moderator: DGL-Team

Seite 1 von 1

[ 2 Beiträge ]

Druckansicht

Vorheriges Thema | Nächstes Thema

Autor

Nachricht

graverko

Betreff des Beitrags: Picture from the scene

Verfasst: Di Mai 22, 2007 13:18

DGL Member

Registriert: Do Feb 01, 2007 12:24
Beiträge: 5

Do anybody know how to make a picture from the scene I have created in OprnGL?
(Something like screnshot)
I am drawing the scene in to the Panel.

Nach oben

MatReno

Betreff des Beitrags:

Verfasst: Di Mai 22, 2007 15:09

DGL Member

Registriert: Mo Jan 31, 2005 11:02
Beiträge: 432
Wohnort: Rheinlandpfalz

Hi,
works for me with something like this:

Code:

unit PrtScr;
 
INTERFACE
 
Uses SysUtils, windows, dglOpenGL;
 
Type
  BITMAPFILEHEADER = packed record
    bfType: Word;
    bfSize: DWORD;
    bfReserved1: Word;
    bfReserved2: Word;
    bfOffBits: DWORD;
  end;
 
  BITMAPINFOHEADER = packed record
    biSize: DWORD;
    biWidth: Longint;
    biHeight: Longint;
    biPlanes: Word;
    biBitCount: Word;
    biCompression: DWORD;
    biSizeImage: DWORD;
    biXPelsPerMeter: Longint;
    biYPelsPerMeter: Longint;
    biClrUsed: DWORD;
    biClrImportant: DWORD;
  end;
 
  Procedure ScreenShot(const FileName: string; NumChar: Char);
 
 
IMPLEMENTATION
 
 
Procedure ScreenShot(const FileName: string; NumChar: Char);
var F          : file;
    FileInfo   : BITMAPINFOHEADER;
    FileHeader : BITMAPFILEHEADER;
    pPicData   : Pointer;
    Viewport   : array[0..3] of integer;
    FileNameNr : string;
    i          : word;
Begin
  // Nummerierung (Falls es DateiNamen schon gibt)
  i := 0;
  Repeat
    inc(i);
    FileNameNr := FileName;
    Insert(NumChar + inttostr(i), FileNameNr, Length(FileNameNr)-3);
  Until (not FileExists(FileNameNr));
 
  // Speicher für die Speicherung der Header-Informationen vorbereiten
  ZeroMemory(@FileHeader, SizeOf(BITMAPFILEHEADER));
  ZeroMemory(@FileInfo, SizeOf(BITMAPINFOHEADER));
 
  // Größe des Viewports abfragen
  glGetIntegerv(GL_VIEWPORT, @Viewport);
 
  // Initialisieren der Daten des Headers
  FileHeader.bfType := 19778; //$4D42 = 'BM'
  FileHeader.bfOffBits := SizeOf(BITMAPINFOHEADER)+SizeOf(BITMAPFILEHEADER);
 
  // Schreiben der Bitmap-Informationen
  FileInfo.biSize      := SizeOf(BITMAPINFOHEADER);
  FileInfo.biWidth     := Viewport[2];
  FileInfo.biHeight    := Viewport[3];
  FileInfo.biPlanes    := 1;
  FileInfo.biBitCount  := 32;
  FileInfo.biSizeImage := FileInfo.biWidth*FileInfo.biHeight*(FileInfo.biBitCount div <!-- s8) --><img src=\"{SMILIES_PATH}/icon_cool.gif\" alt=\"8)\" title=\"Cool\" /><!-- s8) -->;
 
  // Größenangabe auch in den Header übernehmen
  FileHeader.bfSize := FileHeader.bfOffBits + FileInfo.biSizeImage;
 
  // Speicher für die Bilddaten reservieren
  GetMem(pPicData, FileInfo.biSizeImage);
  try
    // Bilddaten von OpenGL anfordern
    glReadPixels(0, 0, Viewport[2], Viewport[3], GL_BGRA, GL_UNSIGNED_BYTE, pPicData);
 
    // Bilddaten in die Datei schreiben
    AssignFile(f, FileNameNr);
    Rewrite(f, 1);
    try
      BlockWrite(F, FileHeader, SizeOf(BITMAPFILEHEADER));
      BlockWrite(F, FileInfo, SizeOf(BITMAPINFOHEADER));
      BlockWrite(F, pPicData^, FileInfo.biSizeImage );
    finally
      CloseFile(f);
    end;
 
  finally
    // Angeforderten Speicher wieder freigeben ...
    FreeMem(pPicData, FileInfo.biSizeImage);
  end;
End;
 
end.

Sorry for German Comments :wink:

_________________
http://texelviews.delphigl.com

Nach oben

Seite 1 von 1

[ 2 Beiträge ]

Foren-Übersicht » English » English Programming Forum

Wer ist online?

Mitglieder in diesem Forum: 0 Mitglieder und 10 Gäste

Du darfst keine neuen Themen in diesem Forum erstellen.
Du darfst keine Antworten zu Themen in diesem Forum erstellen.
Du darfst deine Beiträge in diesem Forum nicht ändern.
Du darfst deine Beiträge in diesem Forum nicht löschen.
Du darfst keine Dateianhänge in diesem Forum erstellen.