DGL • Thema anzeigen - Question on picking...

Question on picking...

Moderator: DGL-Team

Seite 1 von 1

[ 9 Beiträge ]

Druckansicht

Vorheriges Thema | Nächstes Thema

Autor

Nachricht

dpm_dpmartin

Betreff des Beitrags: Question on picking...

Verfasst: So Jan 28, 2007 01:13

DGL Member

Registriert: Mi Jan 24, 2007 00:44
Beiträge: 144

Hello,

My question is as simple as "Why can't I seem to pick the red rotating squares in my program?" which will become more apparent as I provide more detail. I am setting myself up to do some good things with OpenGL but I need my users to be able to interface with the scene - so I looked into some tutorials on picking and have made good progress, only one thing confuses me. I have several spinning squares stacked on top of each other - I have two columns of these - I can successfully pick any square but the bottom square on each column - try as I might, I can't pick the bottom square (in both cases, the red square) and I haven't got a clue why.

Here's what my OpenGL program window looks like, my annotations are trying to illustrate my problem:

Bild

My code is relatively simple... the picking stuff is more or less lifted from some Internet tutorials - with some slight modications made by me - although I'm not sure how I could have broken it though. Any help would be greatly appreciated... I can provide the .pas, .dfm and .dpr in a .zip if anyone has the heart to see see what's really happening (3K only).

Code:

unit Main;
 
interface
 
uses
  OpenGL, Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
  StdCtrls, ExtCtrls, ComCtrls;
 
type
  TForm1 = class(TForm)
    Timer1: TTimer;
    procedure FormCreate (Sender : TObject);
    procedure Timer1Timer(Sender : TObject);
    procedure FormMouseDown (Sender : TObject; Button : TMouseButton; Shift : TShiftState; X, Y : Integer);
  private
    procedure Draw;
    procedure DSquare (Select : Integer; X, Y, Z, Angle : GLFloat);
  public
  end;
 
var
  Form1 : TForm1;
  Flipper1 : GLFloat;
  Selecting : Boolean;
  LastName : Integer;
 
 
implementation
 
procedure glBindTexture ( Target : GLEnum;
                          Texture : GLUInt
                        ); stdcall; external OpenGL32;
 
{$R *.DFM}
 
 
procedure TForm1.DSquare ( Select : Integer;
                           X, Y, Z, Angle : GLFloat
                         );
begin
  glLoadIdentity;
  glTranslatef (X,Y,Z);
  glRotatef (-80,1,0,0);
  glRotatef (Angle,0,0,1);
  glRotatef (Sin (GetTickCount / 900) * 5,0,1,0);
 
  if (Selecting) then
  begin
    Inc (LastName);
    glLoadName (LastName);
  end;
 
  case Select of
    1 : glColor3f (1,0,0);
    2 : glColor3f (0,1,0);
    3 : glColor3f (0,0,1);
    4 : glColor3f (1,1,0);
    5 : glColor3f (0,1,1);
    6 : glColor3f (1,0,1);
  end;
 
  glBegin (GL_QUADS);
    glTexCoord2f (0,0);
    glVertex3f (-1,-1,0);
 
    glTexCoord2f (1,0);
    glVertex3f (1,-1,0);
 
    glTexCoord2f (1,1);
    glVertex3f (1,1,0);
 
    glTexCoord2f (0,1);
    glVertex3f (-1,1,0);
  glEnd;
end;
 
 
procedure setupPixelFormat ( DC :HDC
                           );
const
   pfd : TPIXELFORMATDESCRIPTOR = (nSize : SizeOf (TPIXELFORMATDESCRIPTOR);
         nVersion : 1;
         dwFlags : PFD_SUPPORT_OPENGL or PFD_DRAW_TO_WINDOW or PFD_DOUBLEBUFFER;
         iPixelType : PFD_TYPE_RGBA;
         cColorBits : 24;
         cRedBits : 0; cRedShift : 0; cGreenBits : 0;  cGreenShift : 0; cBlueBits : 0; cBlueShift : 0;
         cAlphaBits : 0; cAlphaShift : 0; cAccumBits : 0; cAccumRedBits : 0; cAccumGreenBits : 0;
         cAccumBlueBits : 0; cAccumAlphaBits : 0; cDepthBits : 16; cStencilBits : 0; cAuxBuffers : 0;
         iLayerType : PFD_MAIN_PLANE; bReserved : 0; dwLayerMask : 0; dwVisibleMask : 0; dwDamageMask : 0);
var
  PixelFormat : Integer;
begin
  PixelFormat := ChoosePixelFormat (DC,@pfd);
  if (PixelFormat = 0) then
  begin
    Exit;
  end;
 
  if (SetPixelFormat (DC,PixelFormat,@pfd) <> True) then
  begin
    Exit;
  end;
end;
 
 
procedure TForm1.FormCreate ( Sender : TObject
                            );
var
  DC : HDC;
  RC : HGLRC;
begin
  DC := GetDC (Handle);
  SetupPixelFormat (DC);
  RC := wglCreateContext (DC);
  wglMakeCurrent (DC,RC);
 
  glMatrixMode (GL_PROJECTION);
  glFrustum (-0.1,0.1,-0.1,0.1,0.3,25.0);
  glMatrixMode (GL_MODELVIEW);
  glEnable (GL_DEPTH_TEST);
  glDepthFunc (GL_LESS);
  glHint (GL_PERSPECTIVE_CORRECTION_HINT,GL_NICEST);
  glEnable (GL_TEXTURE_2D);
 
  Flipper1 := 0;
  Selecting := False;
end;
 
 
procedure TForm1.Draw;
begin
  { Reset this each time around; in case Draw is called while selecting. }
  LastName := 0;
 
  glClear (GL_COLOR_BUFFER_BIT or GL_DEPTH_BUFFER_BIT);
  glClearColor (0,0,0.5,1);
 
  DSquare (1,1.5,-2,-10,-Flipper1);
  DSquare (2,1.5,-1.5,-10,-Flipper1 + 10);
  DSquare (3,1.5,-1,-10,-Flipper1 + 20);
  DSquare (4,1.5,-0.5,-10,-Flipper1 + 30);
 
  DSquare (1,-1.5,-2,-10,-Flipper1);
  DSquare (2,-1.5,-1.5,-10,-Flipper1 + 10);
  DSquare (3,-1.5,-1,-10,-Flipper1 + 20);
  DSquare (4,-1.5,-0.5,-10,-Flipper1 + 30);
  DSquare (5,-1.5,0,-10,-Flipper1 + 40);
  DSquare (6,-1.5,0.5,-10,-Flipper1 + 50);
 
  if (Flipper1 = 360) then
  begin
    Flipper1 := 0;
  end;
 
  SwapBuffers (wglGetCurrentDC);
end;
 
 
procedure TForm1.Timer1Timer ( Sender : TObject
                             );
begin
  Flipper1 := Flipper1 + 0.5;
  Draw;
end;
 
 
procedure TForm1.FormMouseDown ( Sender : TObject;
                                 Button : TMouseButton;
                                 Shift : TShiftState;
                                 X, Y : Integer
                               );
var
  selectBuff : array [0..23] of GLUint;
  viewport : array [0..3] of GLUint;
begin
  { Stop the timer doing any screen updates... }
  Timer1.Enabled := False;
 
  { Select buffer parameters; viewport = 0, 0, width, height... }
  glGetIntegerv (GL_VIEWPORT,@viewport);
  glSelectBuffer (23,@selectBuff);
 
  { Enter selection mode... }
  glMatrixMode (GL_PROJECTION);
  glPushMatrix;
    glRenderMode (GL_SELECT);
    Selecting := True;
 
    { Clear Select Buffer... }
    glInitNames;
    glPushName (0);
    glLoadIdentity;
 
    { Set a viewing volume; (x, y, width, height, viewport); pick matrix... }
    gluPickMatrix (X,viewport[3]-Y-27,1,1,@viewport);
    { Do the perspective calculations... last value = maximum clipping depth... }
    gluPerspective (45.0,viewport[2] / viewport[3],0.0,100.0);
    glMatrixMode (GL_MODELVIEW);
    Draw;
 
    if (glRenderMode (GL_RENDER) > 0) then
    begin
      ShowMessage ('Object picked: ' + IntToStr (SelectBuff[3]));
    end;
 
    glMatrixMode (GL_PROJECTION);
  glPopMatrix;
  glMatrixMode (GL_MODELVIEW);
 
  Selecting := False;
  Timer1.Enabled := True;
end;
 
 
end.

My guess is that this is something someone will be able to point to immediately and it's a lesson I'll never forget. :lol:

_________________
Cheers, DpM
http://www.hmusiccentre.org.uk

Nach oben

i0n0s

Betreff des Beitrags:

Verfasst: So Jan 28, 2007 01:49

Ernährungsberater

Registriert: Sa Jan 01, 2005 17:11
Beiträge: 2068
Programmiersprache: C++

At that point, the only "fault" I could find, is that you're not using dglOpenGL.pas

But that is just for comfort and won't resolve that problem.

The only differnce I can see between your program and our selection sample in the wiki is the way you're taking the picked object:

Code:

ShowMessage ('Object picked: ' + IntToStr (SelectBuff[3]));

Code:

  treffer := glRenderMode(GL_RENDER);         //Anzahl der Treffer auslesen
 
  Getroffen := High(GLUInt);                  //Höchsten möglichen Wert annehmen
  Z_Wert := High(GLUInt);                     //Höchsten Z - Wert
  for i := 0 to Treffer-1 do
    if Puffer[(i*4)+1] < Z_Wert then
    begin
      getroffen       := Puffer[(i*4)+3];
      Z_Wert := Puffer[(i*4)+1];
    end;
 
  if getroffen=High(GLUInt) 
    then Result := -1
    else Result := getroffen;

but that is not a reason why you're are not able to hit glName(1);

_________________
Steppity,✲steppity,✴step,❆step,✳step! :twisted:

❆ ❄ ❄ ❄ ❅ ❄ ❆ ❄ ❅ ❄ ❅ ❄ ❅ ❄ ❄
❅ ☃ ❄ ❄ ❄ ❅ ❄ ❄ ❄ ❅ ❄ ☃ ❄ ❆ ❄ ❄

Nach oben

dpm_dpmartin

Betreff des Beitrags: Been digging a little more...

Verfasst: So Jan 28, 2007 02:54

DGL Member

Registriert: Mi Jan 24, 2007 00:44
Beiträge: 144

OK,

Maybe this will help highlight the problem... the issue is not that I can't pick glName(1) - it seems I can - but that it was the green square, as opposed to the red one at the bottom. At first I thought it was like the red squares hadn't been assigned a name at all, but then I started picking all over the place on the screen... and I got the following surprising results:

Bild

...and now I'm starting to think there is something fundamentally wrong with my coordinates somewhere - in fact, it seems pretty obvious that this is true. I'll keep on looking at this, but if anyone can spot it straight away or have a run of the program (which can be found here http://www.hmusiccentre.org.uk/HMCImages/Picking.zip if wanted) and alter the code to fix it it would be really helpful.

_________________
Cheers, DpM
http://www.hmusiccentre.org.uk

Nach oben

i0n0s

Betreff des Beitrags:

Verfasst: So Jan 28, 2007 12:02

Ernährungsberater

Registriert: Sa Jan 01, 2005 17:11
Beiträge: 2068
Programmiersprache: C++

Ok, I found the problem at line 197:

But first another fault I found:

Code:

gluPickMatrix (X,viewport[3]-Y-27,1,1,@viewport);

You don't need to subtract 27 from Y, the titlebar has been subtracted before.

So, the real problem:

Code:

gluPerspective (45.0,viewport[2] / viewport[3],0.0,100.0);

You only run this code if you're selecting, if you're just rendering you're using

Code:

glFrustum (-0.1,0.1,-0.1,0.1,0.3,25.0);

instead. If you're replacing gluPerspective with glFrustum it works nearly correct. Now you can select the red square, but you will select it too if the green square is in front of it. To resolve this you have to use the code I postet on post ago.

_________________
Steppity,✲steppity,✴step,❆step,✳step! :twisted:

❆ ❄ ❄ ❄ ❅ ❄ ❆ ❄ ❅ ❄ ❅ ❄ ❅ ❄ ❄
❅ ☃ ❄ ❄ ❄ ❅ ❄ ❄ ❄ ❅ ❄ ☃ ❄ ❆ ❄ ❄

Nach oben

Phobeus

Betreff des Beitrags:

Verfasst: So Jan 28, 2007 13:03

Fels i.d. Brandung

Registriert: Sa Mai 04, 2002 19:48
Beiträge: 3830
Wohnort: Tespe (nahe Hamburg)

Don't want to interrupt, but did you thought about implementing some sort of color picking? After working with different methods, I think it is pretty easy to implement. If the user clicks, you are rendering the scene a second time offscreen. Every object is getting a unique color value and (of course) you have to disable everything that might influenece the color (texture, lighting, dithering etc. disable everything) Now you just need to read one pixel from the color buffer, trying to indentify it from some kind of color list. Because a modern graphic card should not having any troubles with one small offscreen rendering... especially because it's not needed every render pass, but only if the user clicks. If you having a true color envroiment you also have the Alpha channel additionally and should be able to handle lot's of objects, without any mathematic stuff.

_________________
"Light travels faster than sound. This is why some people appear bright, before you can hear them speak..."

Nach oben

LarsMiddendorf

Betreff des Beitrags:

Verfasst: So Jan 28, 2007 16:14

DGL Member

Registriert: Sa Dez 28, 2002 11:13
Beiträge: 2244

You don't even need offscreen rendering. You can simply render the frame again with colors after SwapBuffers(), so they stay in the backbuffer.

Nach oben

dpm_dpmartin

Betreff des Beitrags:

Verfasst: So Jan 28, 2007 17:49

DGL Member

Registriert: Mi Jan 24, 2007 00:44
Beiträge: 144

OK - I've finally arrived at where I want to be and have two ways of identifying my picked objects now - the extremely simple way I started with (which works quite well, unless other objects get in the way of the one you want to pick) and the more complicated way which will cycle through multiple picked objects and ascertain which is closest to you - based on Depth - I got confused here for a while, as all my objects are on the same Z - but Depth must mean something else! The second method appears to work perfectly for my requirements, i.e. it will allow me to 'pick' the bottom square from the tower. Thanks for all of the hints and tips!

1) Simplest...

Code:

procedure TForm1.FormMouseDown ( Sender : TObject;
                                 Button : TMouseButton;
                                 Shift : TShiftState;
                                 X, Y : Integer
                               );
var
  SelectBuffer : array [0..23] of GLUInt;
  Viewport : array [0..3] of GLUInt;
begin
  { Stop the timer doing any screen updates... }
  Timer1.Enabled := False;
  Selecting := True;
 
  { Select buffer parameters; viewport = 0, 0, width, height... }
  glGetIntegerv (GL_VIEWPORT,@Viewport);
  glSelectBuffer (23,@SelectBuffer);
 
  { Enter selection mode... }
  glMatrixMode (GL_PROJECTION);
  glPushMatrix;
    glRenderMode (GL_SELECT);
 
    { Clear Select Buffer... }
    glInitNames;
    glPushName (0);
    glLoadIdentity;
 
    { Set a viewing volume; (x, y, width, height, viewport); pick matrix... }
    gluPickMatrix (X,Viewport[3] - Y,1,1,@Viewport);
    glFrustum (-0.1,0.1,-0.1,0.1,0.3,25);
    glMatrixMode (GL_MODELVIEW);
    Draw;
 
    if (glRenderMode (GL_RENDER) > 0) then
    begin
      ShowMessage ('glName: ' + IntToStr (SelectBuffer[3]));
    end;
 
    glMatrixMode (GL_PROJECTION);
  glPopMatrix;
  glMatrixMode (GL_MODELVIEW);
 
  Selecting := False;
  Timer1.Enabled := True;
end;

2) Discerning between multiple hits...

Code:

procedure TForm1.SecondFormMouseDown ( Sender : TObject;
                                       Button : TMouseButton;
                                       Shift : TShiftState;
                                       X, Y : Integer
                                     );
var
  ViewportCoords : array [0..3] of Integer;
  SelectBuffer : array [0..31] of Cardinal;
  SelectedObject, Loop, NumberOfHits : Integer;
  { It is very important that LowestDepth is a Cardinal, not an Integer. }
  LowestDepth : Cardinal;
begin
  { Stop the timer doing any screen updates... }
  Timer1.Enabled := False;
  Selecting := True;
 
  glSelectBuffer (32,@SelectBuffer);
  glGetIntegerv (GL_VIEWPORT,@ViewportCoords);
  glMatrixMode (GL_PROJECTION);
 
  glPushMatrix;
    glRenderMode (GL_SELECT);
    { Clear Select Buffer... }
    glInitNames;
    glPushName (0);
    glLoadIdentity;
    gluPickMatrix (X,ViewportCoords[3] - Y,1,1,@ViewportCoords);
    glFrustum (-0.1,0.1,-0.1,0.1,0.3,25);
    glMatrixMode (GL_MODELVIEW);
    Draw;
    NumberOfHits := glRenderMode (GL_RENDER);
    glMatrixMode (GL_PROJECTION);
  glPopMatrix;
 
  glMatrixMode (GL_MODELVIEW);
 
  if (NumberOfHits > 0) then
  begin
    LowestDepth := SelectBuffer[1];
    SelectedObject := SelectBuffer[3];
 
    if (NumberOfHits > 1) then
    begin
      for Loop := 0 to NumberOfHits - 1 do
      begin
        if (SelectBuffer[(Loop * 4) + 1] < LowestDepth) then
        begin
          LowestDepth := SelectBuffer[(Loop * 4) + 1];
          SelectedObject := SelectBuffer[(Loop * 4) + 3];
        end;
      end;
    end;
    ShowMessage ('glName: ' + IntToStr (SelectedObject));
  end;
 
  Selecting := False;
  Timer1.Enabled := True;
end;

To answer the question posed by Phobeus, as best as I can anyway... I believe that I can't use colour picking for my requirements as I intend these spinning squares to have texures and represent Album covers - I limited the program that I posted on this forum to just be coloured squares so that I would not confuse the issue of anyone helping with textures etc.. If I can get everything working as expected, what I am looking for is a new way of HMusicCentre users being able to pick Albums by certain Artists - via some eye-candy selection screen where an Artist has a 'tower' of Albums and users can click on the one they want to play... i.e. just like below...

Bild

As for the comment by LarsMiddendorf, I'm sorry - but I didn't understand it - maybe I will later.

_________________
Cheers, DpM
http://www.hmusiccentre.org.uk

Nach oben

Phobeus

Betreff des Beitrags:

Verfasst: So Jan 28, 2007 21:18

Fels i.d. Brandung

Registriert: Sa Mai 04, 2002 19:48
Beiträge: 3830
Wohnort: Tespe (nahe Hamburg)

Have a look at:
http://gpwiki.org/index.php/OpenGL_Selection_Using_Unique_Color_IDs

_________________
"Light travels faster than sound. This is why some people appear bright, before you can hear them speak..."

Nach oben

dpm_dpmartin

Betreff des Beitrags: Very interesting...

Verfasst: Mo Jan 29, 2007 00:20

DGL Member

Registriert: Mi Jan 24, 2007 00:44
Beiträge: 144

I have had a good read of that and it was really interesting. There'd be some work for me to do to translate the bits of C++ to Delphi though so, unless there's some incredible performance boost or the way I have implemented it is going to get really difficult when I have hundreds of items on the screen, I think I shall stick with the way that I have working, via Picking, illustrated above.

_________________
Cheers, DpM
http://www.hmusiccentre.org.uk

Nach oben

Seite 1 von 1

[ 9 Beiträge ]

Foren-Übersicht » English » English Programming Forum

Wer ist online?

Mitglieder in diesem Forum: 0 Mitglieder und 1 Gast

Du darfst keine neuen Themen in diesem Forum erstellen.
Du darfst keine Antworten zu Themen in diesem Forum erstellen.
Du darfst deine Beiträge in diesem Forum nicht ändern.
Du darfst deine Beiträge in diesem Forum nicht löschen.
Du darfst keine Dateianhänge in diesem Forum erstellen.