DGL • Thema anzeigen - Ogg and OpenAL

Ogg and OpenAL

Moderator: DGL-Team

Seite 1 von 1

[ 6 Beiträge ]

Druckansicht

Vorheriges Thema | Nächstes Thema

Autor

Nachricht

BTierens

Betreff des Beitrags: Ogg and OpenAL

Verfasst: Sa Nov 27, 2004 10:36

DGL Member

Registriert: Fr Aug 13, 2004 17:43
Beiträge: 60
Wohnort: Belgien

Hello,

I've a procedure that loads ogg audio files with the ogg vorbis audio library. It works with some audio files, but it doesn't work always. I think there is something wrong with setLength(buffer,...) functions but I don't know exactely what. I don't want to stream the oggs, I want to load them completely in one time. Is there somebody who knows what's wrong?

Code:

 
type
  TALSource = record
    source: Taluint;
    position: Array[0..2] of TALFloat;
    buffer : TALuint;
  end;
 
 
procedure LoadOGG(fileName: String;var buffer: TByteArray;var format: TALEnum;var freq: TALSizei);
var
  Res : Integer;
  oggFile: TFileStream;
  OGGStream: OGGVorbis_File;
  VorbisInfo    : Vorbis_Info;
  Source        : TALUInt;
  bbyte: byte;
  bitStream: integer = 0;
  bytes: integer;
  counter: integer;
begin
  // Load the OGG-File into a Filestream
    setLength(buffer,32768);
  OggFile := TFileStream.Create(FileName, fmOpenRead);
  Res := ov_open_callbacks(OggFile, OggStream, nil, 0, ops_callbacks);
  if Res <> 0 then
  begin
    writeLn('Failed');
    exit;
  end;
  //Get some infos out of the OGG-file
  VorbisInfo    := ov_info(OggStream,-1)^;
  if VorbisInfo.channels = 1 then
    Format := AL_FORMAT_MONO16
  else
    Format := AL_FORMAT_STEREO16;
  counter := 0;
  freq := VorbisInfo.rate;
  repeat
    //Keep reading until all is read
    //Read up to a buffer's worth of decoded sound data
    bytes := ov_read(OGGStream, buffer[counter], 32768, 0, 2, 1, @bitStream);
  if bytes > 0 then
  begin
    inc(counter,bytes);
    setLength(buffer,length(buffer)+32768);
  end;
 
  // Append to end of buffer
  until(bytes <= 0);
 
  //Clean up!
  ov_clear(OGGStream);
end;
 
 
//************************************************************************************************
//Load audio
//************************************************************************************************
procedure loadAudio();
var
  format: TALenum;                          // The sound data format
  freq: TALsizei;                           // The frequency of the sound data
  bufferData: TByteArray;                // The sound buffer data from file
  state: TALint;                            // The state of the sound source
begin
  loadOgg(localDir + 'audio/rain.ogg',bufferData, format, freq);
  alGenBuffers(1, @alSource[0].buffer);
  alBufferData(alSource[0].buffer, format, @bufferData[0], length(bufferData), freq);
 
  alGenSources(1,@alSource[0].source);
 
  alSourcef(alSource[0].source, AL_PITCH, 1.0);
  alSourcef(alSource[0].source, AL_GAIN, 1.0);
  alSourcei(alSource[0].source, AL_BUFFER, alSource[0].buffer);
  alSourcei(alSource[0].source, AL_LOOPING, AL_TRUE);
  alSourcei(alSource[0].source, AL_BUFFER, alSource[0].buffer);
  alSourcef(alSource[0].source, AL_POSITION, alSource[0].position[0]);
  alSourcePlay(alSource[0].source);
 
end;
 

Nach oben

noeska

Betreff des Beitrags:

Verfasst: Sa Nov 27, 2004 11:55

DGL Member

Registriert: Di Jul 01, 2003 18:59
Beiträge: 887
Wohnort: (The Netherlands)
Programmiersprache: fpc/delphi/java/c#

did you take a look at: http://www.noeska.com/doal/lesson9.aspx. it is much easier that way.

_________________
http://3das.noeska.com - create adventure games without programming

Nach oben

BTierens

Betreff des Beitrags:

Verfasst: Sa Nov 27, 2004 12:38

DGL Member

Registriert: Fr Aug 13, 2004 17:43
Beiträge: 60
Wohnort: Belgien

noeska hat geschrieben:

did you take a look at: http://www.noeska.com/doal/lesson9.aspx. it is much easier that way.

I know. But this extension is only available in the OpenAL beta version. I prefer a stable version that is available on more systems.

Nach oben

BTierens

Betreff des Beitrags:

Verfasst: So Nov 28, 2004 14:56

DGL Member

Registriert: Fr Aug 13, 2004 17:43
Beiträge: 60
Wohnort: Belgien

I've already found a solution. Thanks anyway.

Nach oben

noeska

Betreff des Beitrags:

Verfasst: So Nov 28, 2004 15:27

DGL Member

Registriert: Di Jul 01, 2003 18:59
Beiträge: 887
Wohnort: (The Netherlands)
Programmiersprache: fpc/delphi/java/c#

Care about sharing it with the rest of us? Please post your solution below...

PS rumour has it that March 2005 ogg will be in the release version of openal

_________________
http://3das.noeska.com - create adventure games without programming

Nach oben

BTierens

Betreff des Beitrags:

Verfasst: So Nov 28, 2004 15:48

DGL Member

Registriert: Fr Aug 13, 2004 17:43
Beiträge: 60
Wohnort: Belgien

Here it is:

Code:

 
procedure AppendBytes(var ADest: TByteArray; const AAppend: Array of Byte; ALength: integer);
var
  iStart:     Integer;
 
begin
  if High(AAppend) < 0 then
    exit;
 
  // Make room for the extra bytes
  iStart  := Length(ADest);
  SetLength(ADest, iStart + ALength);
 
  // Copy the data
  Move(AAppend[0], ADest[iStart], ALength);
end;
 
 
procedure LoadOGG(fileName: String;var buffer: TByteArray;var format: TALEnum;var freq: TALSizei);
var
  Res : Integer;
  oggFile: TFileStream;
  OGGStream: OGGVorbis_File;
  VorbisInfo    : Vorbis_Info;
  Source        : TALUInt;
  bbyte: byte;
  bitStream: integer = 0;
  bytes: integer;
  counter: integer;
  byteArray: Array[0..32768] of byte;
begin
  // Load the OGG-File into a Filestream
  OggFile := TFileStream.Create(FileName, fmOpenRead);
  Res := ov_open_callbacks(OggFile, OggStream, nil, 0, ops_callbacks);
  if Res <> 0 then
  begin
    writeLn('Failed');
    exit;
  end;
  //Get some infos out of the OGG-file
  VorbisInfo    := ov_info(OggStream,-1)^;
  if VorbisInfo.channels = 1 then
    Format := AL_FORMAT_MONO16
  else
    Format := AL_FORMAT_STEREO16;
  counter := 0;
  freq := VorbisInfo.rate;
  repeat
    //Keep reading until all is read
    //Read up to a buffer's worth of decoded sound data
    bytes := ov_read(OGGStream, byteArray[0], 32768, 0, 2, 1, @bitStream);
  if bytes > 0 then
  begin
    inc(counter,bytes);
    appendBytes(buffer,byteArray,bytes);
  end;
 
  // Append to end of buffer
  until(bytes <= 0);
 
  //Clean up!
  ov_clear(OGGStream);
end;
 

Nach oben

Seite 1 von 1

[ 6 Beiträge ]

Foren-Übersicht » English » English Programming Forum

Wer ist online?

Mitglieder in diesem Forum: 0 Mitglieder und 4 Gäste

Du darfst keine neuen Themen in diesem Forum erstellen.
Du darfst keine Antworten zu Themen in diesem Forum erstellen.
Du darfst deine Beiträge in diesem Forum nicht ändern.
Du darfst deine Beiträge in diesem Forum nicht löschen.
Du darfst keine Dateianhänge in diesem Forum erstellen.