DGL • Thema anzeigen - Brauche Hilfe bei erstellung eines GC für OpenGL3.2

Brauche Hilfe bei erstellung eines GC für OpenGL3.2

Moderator: DGL-Team

Seite 1 von 1

[ 7 Beiträge ]

Vorheriges Thema | Nächstes Thema

Autor

Nachricht

Kami-Oni

Betreff des Beitrags: Brauche Hilfe bei erstellung eines GC für OpenGL3.2

Verfasst: Sa Okt 31, 2009 19:32

DGL Member

Registriert: Fr Mai 29, 2009 19:44
Beiträge: 12
Wohnort: Saarland

Hallo,
ich versuche schon seit ein paar Stunden einen OpenGl3.2 GC zu erstellen, aber irgendwie kriege ich es nicht ganz gebacken ^^
Ich habe mir schon das Tutorial zu OpenGL 3 durchgelesen, aber ich kenne mich in C nicht aus.
Auch google liefert keine nützlichen Tipps/Codes. Würde das ganze halt gern in Delphi machen, aber zur Zeit beisse ich mir die Zähne an der erstellung des GCs aus

Wenn jemand schon einen CG für OpenGL 3.2 erstellt hat, köne er/sie dann den Code hier vill. reinposten, oder mir erklären wie ich einen erstellen kann?

Danke

Nach oben

Joni

Betreff des Beitrags: Re: Brauche Hilfe bei erstellung eines GC für OpenGL3.2

Verfasst: Do Nov 05, 2009 19:41

DGL Member

Registriert: So Okt 21, 2007 14:16
Beiträge: 123
Programmiersprache: Delphi

Hallo,

ich habe den Code auf Delphi umgeschrieben, kann jedoch nicht garantieren, dass dieser richtig ist, da ich keine OpenGL 3.0-fähige Grafikkarte habe.

Code:

type
  TWGLCreateContextAttribsARB = function(DC: HDC; hShareContext: HGLRC; const attriblist: array of Integer): HGLRC; stdcall;
const
    WGL_CONTEXT_MAJOR_VERSION_ARB = $2091;
    WGL_CONTEXT_MINOR_VERSION_ARB=  $2092;
    WGL_CONTEXT_LAYER_PLANE_ARB   = $2093;
    WGL_CONTEXT_FLAGS_ARB           = $2094;
    WGL_CONTEXT_PROFILE_MASK_ARB  = $9126;
  WGL_CONTEXT_DEBUG_BIT_ARB     =   $0001;
    WGL_CONTEXT_FORWARD_COMPATIBLE_BIT_ARB  =   $0002;
 
procedure CreateOpenGL3Context(hwindow: hwnd);
var
  DeviceContext: HDC;
  Tempcontext, Context: HGLRC;
  attribs: array[0..6] of Integer;
  wglCreateContextAttribsARB: TWGLCreateContextAttribsARB;
begin
  deviceContext := GetDC(hwindow);
  tempcontext := CreateRenderingContext(deviceContext, [opDoubleBuffered],
                               32, 24, 0, 0, 0, 0);
  if tempcontext = 0 then
  begin
    ShowMessage('Error: Could not create an OpenGL rendering context');
    exit;
  end;
  ActivateRenderingContext(deviceContext, tempcontext);
  wglCreateContextAttribsARB := nil;
  wglCreateContextAttribsARB := wglGetProcAddress('wglCreateContextAttribsARB');
  if not Assigned(wglCreateContextAttribsARB) then
  begin
    wglDeleteContext(TempContext);
    ShowMessage('Error: There is no OpenGL3 context support.');
    exit;
  end;
  attribs[0] := WGL_CONTEXT_MAJOR_VERSION_ARB;
  attribs[1] := 3;
  attribs[2] := WGL_CONTEXT_MINOR_VERSION_ARB;
  attribs[3] := 1;  //Für OpenGL 3.2 muss man das hier (wahrscheinlich) auf 2 setzen
  attribs[4] := WGL_CONTEXT_FLAGS_ARB;
  attribs[5] := WGL_CONTEXT_FORWARD_COMPATIBLE_BIT_ARB;
  attribs[6] := 0;
  Context := wglCreateContextAttribsARB(DeviceContext,0, attribs);//versuche ein OpenGL3.1 fähigen Context zu erstellen
  if context = 0 then
  begin
    //Entweder hat der Treiber noch keinen OpenGL3.1 support oder die Grafikkarte beherrscht kein OpenGL3.1.
    ShowMessage('Error: Couldnt create OpenGL3.1 context. Try now OpenGL3.0 context');
    attribs[3] := 0;//Setze minor version auf 0 um ein OpenGL3.0 context zu erstellen.
    Context := wglCreateContextAttribsARB(DeviceContext,0, attribs);
    if context = 0 then
    begin
      //Die -->Grafikkarte<-- beherrscht kein OpenGL3.
      wglDeleteContext(TempContext);//aufräumen und beenden
      ShowMessage('Error: Couldnt create OpenGL3 context.');
      exit;
    end;
  end;
  wglMakeCurrent(DeviceContext,Context);//wechsel auf den OpenGL3.x context
  wglDeleteContext(TempContext);//Zerstöre den temporären Context, denn er wird nicht länger benötigt.
end;

Ich verwende den DGL Header, also vorher InitOpenGL aufrufen

Gruß Joni.

Zuletzt geändert von Joni am Do Dez 03, 2009 15:57, insgesamt 1-mal geändert.

Nach oben

Kami-Oni

Betreff des Beitrags: Re: Brauche Hilfe bei erstellung eines GC für OpenGL3.2

Verfasst: Fr Nov 06, 2009 16:49

DGL Member

Registriert: Fr Mai 29, 2009 19:44
Beiträge: 12
Wohnort: Saarland

Vielen Dank

Ich denke von deinem Code aus komme ich weiter

Ich vergleiche einfach mal C++ und Delphi Code und dann klappt das schon

Danke nochmal :mrgreen:

Nach oben

Joni

Betreff des Beitrags: Re: Brauche Hilfe bei erstellung eines GC für OpenGL3.2

Verfasst: Di Dez 01, 2009 19:11

DGL Member

Registriert: So Okt 21, 2007 14:16
Beiträge: 123
Programmiersprache: Delphi

Hallo,

das ist mir jetzt etwas peinlich, aber ich habe einen neuen Rechner mit OpenGL 3.2 fähiger Grafikkarte und stehe jetzt vor dem selben Problem -.- mit meinem Code klappts auf jeden Fall bei mir nicht. Ein Treiberproblem schließe ich aus, da http://www.dhpoware.com/demos/gl3HelloWorld.html bei mir funktioniert. Falls du - oder jemand anderes - das mittlerweile in Delphi geschafft hat, wäre es sehr nett, wenn das hier jemand posten würde

Gruß Joni.

Nach oben

Lossy eX

Betreff des Beitrags: Re: Brauche Hilfe bei erstellung eines GC für OpenGL3.2

Verfasst: Mi Dez 02, 2009 09:55

DGL Member

Registriert: Do Dez 05, 2002 10:35
Beiträge: 4234
Wohnort: Dortmund

Ich habe nur 3.1er Hardware. Entsprechend kann ich nicht sagen ob das mit 3.2 funktionieren würde oder nicht. Für die dglOpenGL hatte ich eine Testanwendung geschrieben wo ich den 3.0 Kontext getestet hatte. Ich habe das gerade mal auf ein Delphi Formular übertragen.

Ob der Code so richtig schön ist lasse ich mal dahin gestellt. Auch weiß ich nicht ob er richtig sicher ist. Also ich weiß nicht was was passiert, wenn GL 3.0 nicht unterstützt wird. Bzw muss der natürlich auch an die jeweiligen Gegebenheiten angepasst werden.

Code:

procedure TMainForm.FormShow(Sender: TObject);
var
  // gl2
  PixelFormatDescriptor: TPixelFormatDescriptor;
  PixelFormat: Integer;
  gl2Context: HGLRC;
 
  // gl3
  Attribs: array of GLint;
begin
  // init OpenGL
  if not InitOpenGL then
    raise Exception.Create('OpenGL seems to be unsupported.');
 
  // create dc
  fDC := GetDC(Handle);
 
  // initiale pixelformat structure
  FillChar(PixelFormatDescriptor, SizeOf(PixelFormatDescriptor), 0);
  with PixelFormatDescriptor do begin
    nSize := SizeOf(PixelFormatDescriptor);
    nVersion := 1;
    dwFlags := PFD_SUPPORT_OPENGL or PFD_DRAW_TO_WINDOW or PFD_DOUBLEBUFFER;
    iPixelType := PFD_TYPE_RGBA;
    cColorBits := 32;
    cDepthBits := 24;
    iLayerType := PFD_MAIN_PLANE
  end;
 
  // choose pixelformat
  PixelFormat := ChoosePixelFormat(fDC, @PixelFormatDescriptor);
  if PixelFormat = 0 then
    RaiseLastOSError;
 
  // set pixelformat
  if not SetPixelFormat(fDC, PixelFormat, @PixelFormatDescriptor) then
    RaiseLastOSError;
 
  // create gl 2.0 context
  gl2Context := wglCreateContext(fDC);
 
  // activate gl 2.0 context
  wglMakeCurrent(fDC, gl2Context);
 
  // check for extension and load wglCreateContextAttribsARB inside of dglOpenGL
  WGL_ARB_create_context := dglCheckExtension('WGL_ARB_create_context');
  wglCreateContextAttribsARB := dglGetProcAddress('wglCreateContextAttribsARB');
 
  if not (WGL_ARB_create_context and Assigned(@wglCreateContextAttribsARB)) then
    raise Exception.Create('OpenGL 3.0 seems to be unsupported.');
 
  // setup attribs for gl 3.0
  SetLength(Attribs, 5);
  Attribs[0] := WGL_CONTEXT_MAJOR_VERSION_ARB;
  Attribs[1] := 3;
  Attribs[2] := WGL_CONTEXT_MINOR_VERSION_ARB;
  Attribs[3] := 2;
  Attribs[4] := 0;
 
  // try create 3.2 context
  fRC := wglCreateContextAttribsARB(fDC, 0, @Attribs[0]);
 
  // fallback to 3.1
  if fRC = 0 then begin
    Attribs[3] := 1;
    fRC := wglCreateContextAttribsARB(fDC, 0, @Attribs[0]);
  end;
 
  // fallback to 3.0
  if fRC = 0 then begin
    Attribs[3] := 0;
    fRC := wglCreateContextAttribsARB(fDC, 0, @Attribs[0]);
  end;
 
  // 3.0 context creation failed
  if fRC = 0 then
    raise Exception.Create('Creation of OpenGL 3.0 context failed');
 
  // deactivate and destroy gl 2.0 context
  wglMakeCurrent(fDC, 0);
  wglDeleteContext(gl2Context);
 
  // activate context and load all functionpointer
  ActivateRenderingContext(fDC, fRC);
 
  // Initialization of opengl
  glClearColor(1, 0.5, 0.5, 0);
end;

Hier aber ein bisschen was zu Erklärung des Codes. Ich mache nichts weiter als einen 2.0 Kontext zu erstellen. Dazu gehört das Pixelformat zu definieren (PixelFormatDescriptor) und dann ein passendes Format zu suchen (ChoosePixelFormat) und zu setzen (SetPixelFormat). Anschließend werden die Funktionen zum Erstellen des Kontexts geladen und die Attribute vorbereitet. Wenn das geschafft ist wird versucht einen Kontext zu erstellen. Hat das nicht geklappt wird die Versionsnummer verkleinert.

Vom Prinzip her ziemlich genau das was du (joni) auch machst. Nur mit dem Unterschied, dass ich die in unserem OpenGL Header eingebauten Konstanten/Funktionen benutzen bzw. den 2.0 Kontext nur über wglMakeCurrent aktiviere. ActivateRenderingContext geht her und lädt alle Funktionspointer. Was aber quatsch/nicht nötig ist.

Wobei ich auch gerade sehe, dass dein Fehler wahrscheinlich schon darin liegt, dass du bei der Defintion von TWGLCreateContextAttribsARB vergessen hast ein stdcall mit anzugeben. Ohne Typenkonvention kann es natürlich nicht klappen. Bzw bei dem letzten Parameter tendiere ich eher dazu mich peinlich genau an das zu halten wie es im C/C++ Header definiert ist.

Nach oben

Joni

Betreff des Beitrags: Re: Brauche Hilfe bei erstellung eines GC für OpenGL3.2

Verfasst: Do Dez 03, 2009 16:11

DGL Member

Registriert: So Okt 21, 2007 14:16
Beiträge: 123
Programmiersprache: Delphi

Hallo,

vielen Dank, es lag wirklich am stdcall. Meine Grafikkarte (HD 5770) sollte eigentlich OpenGL 3.2 können, wenn es denn die Treiber schon gäbe :twisted:

(um Missverständnissen vorzubeugen: OpenGL 3.1 kann der Treiber schon).

[Edit]
So, mittlerweile gibts jetzt auch die Treiber für OpenGL 3.2

[/Edit]

Gruß Joni.

Zuletzt geändert von Joni am Mo Feb 01, 2010 10:25, insgesamt 2-mal geändert.

Nach oben

NerdIII

Betreff des Beitrags: Re: Brauche Hilfe bei erstellung eines GC für OpenGL3.2

Verfasst: Do Dez 10, 2009 14:36

DGL Member

Registriert: Mo Nov 06, 2006 19:15
Beiträge: 172

Ja nVidia war diesmal unglaublich schnell mit den ersten Betatreibern. Hab mich auch schon bedankt.

Die Kinnlade ist mir aber dann runtergeklappt als ich feststellen musste, dass die Matrizen nicht mehr vorhanden sind. An sonsten sehr positiv, dass es erstmal keine Extensions für 3.2 gibt und alle redundanten Möglichkeiten das selbe zu tun weggefallen sind. Für den Moment hat man also ohne Extensions prüfen zu müssen in einem 3.2er Kontext alles was Spaß macht bereits zur Verfügung.
Für C gibt es auf OpenGL.org eine Header-Datei die sich so einstellen lässt, dass Immediate Mode Befehle und andere gar nicht mehr bekannt sind. Dann kann man auch keine falschen Funktionen mehr aufrufen oder versehentlich Texturformate wählen die es nicht mehr gibt.

Nach oben

Seite 1 von 1

[ 7 Beiträge ]

Foren-Übersicht » Programmierung » Einsteiger-Fragen

Wer ist online?

Mitglieder in diesem Forum: 0 Mitglieder und 7 Gäste

Du darfst keine neuen Themen in diesem Forum erstellen.
Du darfst keine Antworten zu Themen in diesem Forum erstellen.
Du darfst deine Beiträge in diesem Forum nicht ändern.
Du darfst deine Beiträge in diesem Forum nicht löschen.
Du darfst keine Dateianhänge in diesem Forum erstellen.