DGL • Thema anzeigen

ParticleTut

Moderator: DGL-Team

Seite 1 von 1

[ 2 Beiträge ]

Vorheriges Thema | Nächstes Thema

Autor

Nachricht

Shaddow

Betreff des Beitrags: ParticleTut

Verfasst: Sa Aug 26, 2006 13:05

DGL Member

Registriert: So Aug 20, 2006 23:19
Beiträge: 564

Habe da mal ein Prob, das Tut hab ich durchgearbeitet und entstanden ist folgendes:

Engine.pas:

Code:

unit Engine;
 
interface
 
uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, glBitmap, Particle, DGLOpenGL;
 
type
  TForm1 = class(TForm)
  private
    { Private-Deklarationen }
  public
    { Public-Deklarationen }
  end;
 
TFire = class (TObject)
  protected
    Container : TContainer;
    Particle : TParticle;
    EmissionTime : Integer;
    FireTex : TglBitmap2D;
  public
    constructor Create;
    procedure Render;
    procedure Advance(aTime : Integer);
    destructor Destroy; override;
end;
 
var
  Form1: TForm1;
 
implementation
============================>{$R *.dfm} <==================== HIER, DER HAT GEFEHLT!!
const
  START_LIVESPAN = 1000;
  EMISSION_RATE = 20;
  PARTICLES_PER_EMISSION = 10;
 
constructor TFire.Create();
begin
  inherited;
  FireTex := TglBitmap2d.Create('Fire.bmp');
  FireTex.GenTexture();
  Container := TContainer.Create(600);
end;
 
procedure TFire.Advance(aTime : Integer);
var i: Integer;
begin
  INC(EmissionTime, aTime);
  while EmissionTime > EMISSION_RATE do
  begin
    with Particle do
    begin
      Position.X        := Random(20)/100-0.1;
      Position.Y        := Random(5) /100;
      Position.Z        := Random(5) /100;
      Geschwindigkeit.X := Random(60)/100-0.3;
      Geschwindigkeit.Y := Random(80)/100+0.2;
      Geschwindigkeit.Z := Random(40)/100-0.2;
      Farbe.R           := 1;
      Farbe.G           := Random * 0.7;
      Farbe.B           := Random * 0.25;
      LebensZeit        := START_LIVESPAN;
 
      for i:=0 to PARTICLES_PER_EMISSION do
      begin
        Position.X        := Position.X        + Random(10)/100-0.05;
        Position.Y        := Position.Y        + Random(5) /100;
        Geschwindigkeit.X := Geschwindigkeit.X + Random(4)/100-0.02;
        Geschwindigkeit.Y := Geschwindigkeit.Y + Random(6)/100+0.03;
        Container.Add(Particle);
      end;
      DEC(EmissionTime, EMISSION_RATE);
    end;
  end;
  Container.Advance(aTime);
end;
 
procedure TFire.Render();
var i: Integer;
    Saettigung: Single;
begin
  for i:=0 to Container.NumParticles do
  begin
    with Container.Particles[i] do
    begin
      if Lebenszeit > 0 then
      begin
        if Alter > 100 then Saettigung := 1 - Alter/START_LIVESPAN
        else Saettigung := Alter/100;
        glPushMatrix();
        glColor4f  (Farbe.R   , Farbe.G   , Farbe.B   , Saettigung/2);
        glTranslatef(Position.X, Position.Y, Position.Z);
        FXBillBoardBegin;
 
        glBegin(GL_QUADS);
          glTexCoord2f(1,0);
          glVertex3f( 0.05,-0.05,0);
          glTexCoord2f(0,0);
          glVertex3f(-0.05,-0.05,0);
          glTexCoord2f(0,1);
          glVertex3f(-0.05, 0.05,0);
          glTexCoord2f(1,1);
          glVertex3f( 0.05, 0.05,0);
        glEnd();
        FXBillBoardEnd;
        glPopMatrix();
      end;
    end;
  end;
end;
 
destructor TFire.Destroy();
begin
  Container.Free;
  inherited;
end;
 
end.
 

und die Particle.pas:

Code:

unit Particle;
 
interface
 
type
TVektor = record
  X : Single;
  Y : Single;
  Z : Single;
end;
 
TFarbe = record
  R : Single;
  G : Single;
  B : Single;
end;
 
TParticle = record
  Position        : TVektor;
  Geschwindigkeit : TVektor;
  Dichte          : Single;
  Masse           : Single;
  Groesse         : Single;
  Farbe           : TFarbe;
  Lebenszeit      : Integer;
  Alter           : Integer;
end;
 
TContainer = class (TObject)
  protected
    FNumParticles : Word; // Anzahl d. Particel
    function GetSize : Word; // Auslesen der Größe
  public
    Particles : Array of TParticle; // Array aller Particel
    property NumParticles                 : Word read FNumParticles;
    property Size                         : Word read GetSize;
 
    constructor Create (aSize : Integer); overload;
    function Add (aParticle : TParticle)  : Integer;
    procedure Delete (aIndex : Integer);
    procedure Advance (aTime : Integer);
    function Clean                        : Word;
    procedure Clear;
end;
 
procedure FXBillBoardBegin;
procedure FXBillBoardEnd;
 
implementation
 
uses Windows, DGLOpenGL;
 
procedure FXBillBoardBegin;
var x, y : Byte;
    Matrix : Array[0..15] of Single;
begin
  // Sichern der Matrix
  glPushMatrix();
  // Speichern der Matrix in der Variable
  glGetFloatv(GL_MODELVIEW_MATRIX, @Matrix);
  for x:=0 to 2 do
    for y:=0 to 2 do
      if x=y then Matrix[x*4+y] := 1
      else Matrix[x*4+y]:=0;
  glLoadMatrixF(@Matrix);
end;
 
procedure FXBillBoardEnd;
begin
  glPopMatrix();
end;
 
function TContainer.GetSize : Word;
begin
  Result := Length(Particles);
end;
 
constructor TContainer.Create(aSize : Integer);
begin
  SetLength(Particles, aSize);
  FNumParticles:=0;
end;
 
function TContainer.Add(aParticle : TParticle) : Integer;
begin
  // Wenn Array voll, Aufräumen
  if FNumParticles = Size-1 then Clean;
  Particles[FNumParticles] := aParticle;
 
  if FNumParticles < Size-1 then INC(FNumParticles);
 
  result := FNumParticles;
end;
 
procedure TContainer.Delete(aIndex : Integer);
begin
  Particles[aIndex].Lebenszeit := 0;
end;
 
procedure TContainer.Advance(aTime : Integer);
var i : Integer;
begin
  for i:=0 to FNumParticles-1 do
  begin
    with Particles[i] do
    begin
      Position.X := Position.X + Geschwindigkeit.X * aTime/1000;
      Position.Y := Position.Y + Geschwindigkeit.Y * aTime/1000;
      Position.Z := Position.Z + Geschwindigkeit.Z * aTime/1000;
      Lebenszeit := Lebenszeit - aTime;
      Alter      := Alter + aTime;
    end;
  end;
end;
 
function TContainer.Clean : Word;
var i, pos: Integer;
begin
  pos := 0;
  for i:=0 to FNumParticles-1 do
  begin
    // Standartmäßig übertragen des Datensatzes
    Particles[pos]:=Particles[i];
 
    // Nur wenn übertragenes Particle noch Lebenszeit hat,
    // wird das Particel nicht vom nächsten überschrieben
    if Particles[pos].Lebenszeit > 0 then INC(pos);
  end;
  // Anzahl gelöschter Particle
  Result := FNumParticles - Pos;
  // FNum (alte Anzahl Particle) wird mit Pos (neue Anzahl) überschrieben
  FNumParticles :=  Pos;
end;
 
procedure TContainer.Clear;
begin
  FNumParticles := 0;
end;
 
end.
 

Nun kommt allerdings das Problem:
"Im Projekt Feuer.exe ist eine Exeption der Klasse EResNotFound aufgetreten. Meldung 'Ressource TForm wurde nicht gefunden' Prozess wurde angehalten. Mit einzelner Anwendung oder Start fortsetzen."

Das Formular existiert und ich weiß nich, warums nich läuft. Dass am ende OpenGl noch nich initalisiert ist etc. weiss ich, aber erstmal sollte das Prog ja auch so laufen

Nach oben

Shaddow

Betreff des Beitrags:

Verfasst: Sa Aug 26, 2006 14:34

DGL Member

Registriert: So Aug 20, 2006 23:19
Beiträge: 564

Vielen Dank an Jonas!!
Fehler ist oben eingefügt :oops:

Nach oben

Seite 1 von 1

[ 2 Beiträge ]

Foren-Übersicht » Programmierung » Einsteiger-Fragen

Wer ist online?

Mitglieder in diesem Forum: 0 Mitglieder und 8 Gäste

Du darfst keine neuen Themen in diesem Forum erstellen.
Du darfst keine Antworten zu Themen in diesem Forum erstellen.
Du darfst deine Beiträge in diesem Forum nicht ändern.
Du darfst deine Beiträge in diesem Forum nicht löschen.
Du darfst keine Dateianhänge in diesem Forum erstellen.