DGL • Thema anzeigen - GL

GL_QUADS Problem

Moderator: DGL-Team

Seite 1 von 1

[ 3 Beiträge ]

Vorheriges Thema | Nächstes Thema

Autor

Nachricht

bluenavajo

Betreff des Beitrags: GL_QUADS Problem

Verfasst: Di Mai 09, 2006 14:00

DGL Member

Registriert: So Mai 07, 2006 20:20
Beiträge: 20

Hallo erstmal :wink:

Ich hab da so ein Problem mit GL_QUADS. Wenn ich ein Quadrat zeichnen will wird dieses nicht ausgegeben. Ersetze ich den Befehl hingegen durch GL_LINE_STRIP (es sind immernoch dieselben Koords, hab nur den Befehl geändert), werden die Linien
korrekt ausgegeben. Ich benutze dglOpenGL.pas, das Template (minimal verändert) aus den Einsteiger Tuts und Delphi7. Im Template hab ich nur den ErrorHandler als funktion deklariert, damit ich die Fehlermeldung gleich hinter der fps Anzeige ausgeben kann. Anbei der Code:

Code:

 
unit Unit1;
 
interface
 
uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, dglOpenGL;
 
type
  TForm1 = class(TForm)
    procedure FormCreate(Sender: TObject);
    procedure IdleHandler(Sender: TObject; var Done: Boolean);
    procedure FormResize(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
  private { Private declarations }
    StartTime, TimeCount, FrameCount  : Cardinal; //FrameCounter
    Frames, DrawTime                  : Cardinal; //& Timebased Movement
    procedure SetupGL;
    procedure Init;
    procedure Render;
    function ErrorHandler: string;
  public    { Public declarations }
    DC                                : HDC;  //Handle auf Zeichenfläche
    RC                                : HGLRC;//Rendering Context
  end;
 
var
  Form1: TForm1;
  NearClipping: integer;
  FarClipping: integer;
 
implementation
 
{$R *.dfm}
 
procedure TForm1.FormCreate(Sender: TObject);
begin
  DC:= GetDC(Handle);
  if not InitOpenGL then Application.Terminate;
  RC:= CreateRenderingContext( DC,
                               [opDoubleBuffered],
                               32,
                               24,
                               0,0,0,
                               0);
  ActivateRenderingContext(DC, RC);
  SetupGL;
  Init;
  Application.OnIdle := IdleHandler;
end;
 
procedure TForm1.Init;
begin
  NearClipping := 1;
  FarClipping  := 1000;
end;
 
procedure TForm1.SetupGL;
begin
  glClearColor(0.0, 0.0, 0.3, 0.0); //Hintergrundfarbe
  glEnable(GL_DEPTH_TEST);          //Tiefentest aktivieren
  glEnable(GL_CULL_FACE);           //Backface Culling aktivieren
end;
 
procedure TForm1.FormResize(Sender: TObject);
var tmpBool : Boolean;
begin
  glViewport(0, 0, ClientWidth, ClientHeight);
  glMatrixMode(GL_PROJECTION);
  glLoadIdentity;
  gluPerspective(45.0, ClientWidth/ClientHeight, NearClipping, FarClipping);
 
  glMatrixMode(GL_MODELVIEW);
  glLoadIdentity;
  IdleHandler(Sender, tmpBool);
end;
 
procedure TForm1.FormDestroy(Sender: TObject);
begin
  DeactivateRenderingContext;
  DestroyRenderingContext(RC);
  ReleaseDC(Handle, DC);
end;
 
procedure TForm1.Render;
begin
  glClear(GL_COLOR_BUFFER_BIT or GL_DEPTH_BUFFER_BIT);
 
  glMatrixMode(GL_PROJECTION);
  glLoadIdentity;
  gluPerspective(60, ClientWidth/ClientHeight, NearClipping, FarClipping);
 
  glTranslatef(0, 0, -5);
 
  glMatrixMode(GL_MODELVIEW);
  glLoadIdentity;
 
  glBegin(GL_LINE_STRIP);
   glColor3f(1,0,0); glVertex3f(-1, -1, 0);
   glColor3f(0,1,0); glVertex3f(-1, 1, 0);
   glColor3f(0,0,1); glVertex3f(1, 1, 0);
   glColor3f(1,1,0); glVertex3f(1, -1, 0);
  glEnd;
 
 { glBegin(GL_TRIANGLES);
    glVertex3f(-1, 0, 0);
    glVertex3f(0, 1, 0);
    glVertex3f(1, 0, 0);
  glEnd;
 }
 
  SwapBuffers(DC);
end;
 
function TForm1.ErrorHandler;
begin
  result := gluErrorString(glGetError);
end;
 
procedure TForm1.IdleHandler(Sender: TObject; var Done: Boolean);
begin
  StartTime:= GetTickCount;
  Render;
  DrawTime:= GetTickCount - StartTime;
  Inc(TimeCount, DrawTime);
  Inc(FrameCount);
 
  if TimeCount >= 1000 then begin
    Frames:= FrameCount;
    TimeCount:= TimeCount - 1000;
    FrameCount:= 0;
    Caption:= InttoStr(Frames) + 'FPS '+ErrorHandler;
    ErrorHandler;
  end;
 
  Done:= false;
end;
 
end.
 

Nach oben

Lossy eX

Betreff des Beitrags:

Verfasst: Di Mai 09, 2006 14:12

DGL Member

Registriert: Do Dez 05, 2002 10:35
Beiträge: 4234
Wohnort: Dortmund

Hallo.

Also für mich schreit es danach, dass du bei deinen Koordinaten eine falsche Reihenfolge benutzt hast. Üblich ist eine Reihenfolge gegen den Uhrzeigersinn. und wenn du dir deine Koordinaten mal im Kopf vorstellst. Na was passiert dann. Genau. Die sind mit dem Uhrzeigersinn. Somit siehst du in deinem Falle nur eine ausgeblendete Rückseite. Also nichts.

Du kannst ...
1: GL_CULL_FACE deaktivieren. Damit würden sowohl vorder als auch Rückseite gezeichnet werden. Nicht unbedingt optimal.

2: die Vorderseite zur Rückseite deklarieren was aber alle anderen externen Units und Entwickler verwirren könnte. Auch nicht so dolle.

3: die Reihenfolge der Punkte verändern. Und damit solltest du deine Fläche sehen. Wenn ich gerade nicht total verwirrt bin. Bin mir da heute absolut nicht sicher. ;-)

Code:

glBegin(GL_LINE_STRIP);
  glColor3f(1,0,0); glVertex3f(-1, -1, 0);
  glColor3f(1,1,0); glVertex3f(1, -1, 0);
  glColor3f(0,0,1); glVertex3f(1, 1, 0);
  glColor3f(0,1,0); glVertex3f(-1, 1, 0);
glEnd;

Das sollte es eigentlich gewesen sein.

PS: Herzlich Willkommen im Forum.

Nach oben

bluenavajo

Betreff des Beitrags: hui

Verfasst: Di Mai 09, 2006 14:53

DGL Member

Registriert: So Mai 07, 2006 20:20
Beiträge: 20

Tatsächlich, du hast Recht.
Jetz gehts es auch. Für die zukunft merke ich mir dann gegen den Uhrzeigersinn ^^
Ich hab mich grad eben noch mal Member Forum vorgestellt, da ich hier sicher noch sehr oft etwas posten werde:
Ausserdem find ich ein bisschen persönliches immer toll.

Nach oben

Seite 1 von 1

[ 3 Beiträge ]

Foren-Übersicht » Programmierung » Einsteiger-Fragen

Wer ist online?

Mitglieder in diesem Forum: 0 Mitglieder und 2 Gäste

Du darfst keine neuen Themen in diesem Forum erstellen.
Du darfst keine Antworten zu Themen in diesem Forum erstellen.
Du darfst deine Beiträge in diesem Forum nicht ändern.
Du darfst deine Beiträge in diesem Forum nicht löschen.
Du darfst keine Dateianhänge in diesem Forum erstellen.