DGL • Thema anzeigen - Terrain und IBO

Terrain und IBO

Moderator: DGL-Team

Seite 1 von 1

[ 13 Beiträge ]

Vorheriges Thema | Nächstes Thema

Autor

Nachricht

Dropye

Betreff des Beitrags: Terrain und IBO

Verfasst: Mo Aug 13, 2012 19:54

DGL Member

Registriert: Do Jan 07, 2010 21:58
Beiträge: 240

Hallo mal wieder

heute aber ich versucht mein Terrain mit einem IBO zu verbinden aber irgendwie sieht das ganze bisschen putzig aus *siehe bild*

erstellt wird das ganze in dieser form

Code:

 
const
  DATASize = 4096;
  VBOSize = 64;
 
procedure TMap.InitVBO;
var
  Data : array[0..DATASize] of TVertex2V;
  iData : array[0..DATASize] of GLShort;
  mverts, datasize, pos, x, y : Integer;
begin
 
  pos := 0;
  glGenBuffers(1, @VBO);
  glBindBuffer(GL_ARRAY_BUFFER, VBO);
  mverts := VBOSize+1;
  datasize := mverts*mverts*2*sizeof(GLFLOAT);
 
 
  for y := 0 to mverts do
    for x := 0 to mverts do begin
      data[pos].x := x;
      data[pos].z := y;
      inc(pos);
    end;
  glBufferData(GL_ARRAY_BUFFER, datasize, @data, GL_STATIC_DRAW);
 
  glGenBuffers(1, @IBO);
  glBindBuffer(GL_ELEMENT_ARRAY_BUFFER, IBO);
  datasize := mverts*mverts*2*sizeof(GLshort);
  pos := 0;
  for y := 0 to VBOSize do
    for x := 0 to VBOSize do begin
      idata[pos] := (x+0) + (y+0) * mverts;
      idata[pos] := (x+0) + (y+1) * mverts;
      idata[pos] := (x+1) + (y+1) * mverts;
      idata[pos] := (x+1) + (y+1) * mverts;
      idata[pos] := (x+1) + (y+0) * mverts;
      idata[pos] := (x+0) + (y+0) * mverts;
    end;
  glBufferData(GL_ELEMENT_ARRAY_BUFFER, datasize, @idata, GL_STATIC_DRAW);
end;

gerendert wird mit hilfe des Terrain shaders von coolcat wobei ich nur den Vertex teil übernommen habe und mit dem Fragment shader was anderes vor habe

der rendercode sieht ganz normal aus

Code:

procedure TMap.Render;
var x, y : Integer;
begin
  for x := 0 to 15 do
    for y := 0 to 15 do begin
      glUniform2i(leafmin, x*64,y*64);
      glInterleavedArrays(GL_V2F, SizeOf(TVertex2V), nil);
      glDrawArrays(GL_TRIANGLES, 0, 4096*SizeOf(TVertex2V));
    end;
    
  glUseProgram(0);
end;

Du hast keine ausreichende Berechtigung, um die Dateianhänge dieses Beitrags anzusehen.

Nach oben

Coolcat

Betreff des Beitrags: Re: Terrain und IBO

Verfasst: Mo Aug 13, 2012 20:18

DGL Member

Registriert: Do Dez 29, 2005 12:28
Beiträge: 2249
Wohnort: Düsseldorf
Programmiersprache: C++, C#, Java

Könnte möglicherweise am Backface-Culling liegen. Dreh das mal testweise rum bzw. schalte es ab.

_________________
Yeah! :mrgreen:

Nach oben

Lord Horazont

Betreff des Beitrags: Re: Terrain und IBO

Verfasst: Mo Aug 13, 2012 20:25

DGL Member

Registriert: Do Sep 02, 2004 19:42
Beiträge: 4158
Programmiersprache: FreePascal, C++

Da sind indicies kaputt würde ich sagen. Kannst du bitte mal näher ran gehen und vorallem eine PNG und keine JPEG hochladen? JPEG ist für screenshots hochgradig ungeeignet wegen verlustbehafteter und nicht für harte kanten ausgelegter Kompression.

grüße

_________________
If you find any deadlinks, please send me a notification – Wenn du tote Links findest, sende mir eine Benachrichtigung.
current projects: ManiacLab; aioxmpp
zombofant network • my photostream
„Writing code is like writing poetry“ - source unknown

„Give a man a fish, and you feed him for a day. Teach a man to fish and you feed him for a lifetime. “ ~ A Chinese Proverb

Nach oben

Dropye

Betreff des Beitrags: Re: Terrain und IBO

Verfasst: Mo Aug 13, 2012 20:52

DGL Member

Registriert: Do Jan 07, 2010 21:58
Beiträge: 240

das culling ist bereits ausgeschaltet

hier ist das neue bild

Du hast keine ausreichende Berechtigung, um die Dateianhänge dieses Beitrags anzusehen.

Nach oben

Coolcat

Betreff des Beitrags: Re: Terrain und IBO

Verfasst: Mo Aug 13, 2012 21:00

DGL Member

Registriert: Do Dez 29, 2005 12:28
Beiträge: 2249
Wohnort: Düsseldorf
Programmiersprache: C++, C#, Java

Kannst du mal einen Screenshot von genau oben machen? Sind die X/Z-Koordinaten richtig? Der Shader sollte ja nur die Höhe ändern.
Irgendwie sieht es für mich aus als wären die Dreiecke skaliert (vielleicht um die Hälfte) und irgendwie gespiegelt?

TVertex2V hat nur x und z, richtig? Nicht das der noch ein y dazwischen hat, weil du den ja als GL_V2F benutzt.

_________________
Yeah! :mrgreen:

Nach oben

Dropye

Betreff des Beitrags: Re: Terrain und IBO

Verfasst: Mo Aug 13, 2012 21:17

DGL Member

Registriert: Do Jan 07, 2010 21:58
Beiträge: 240

das stimmt TVertex2V heißt nicht umsonst so :p

hier ist nochmal ein neues bild von soweit oben wie ich es nur hin bekommen konnte da noch was mit meinem Winkelberechnungen nicht stimmt

Du hast keine ausreichende Berechtigung, um die Dateianhänge dieses Beitrags anzusehen.

Nach oben

Schläfer

Betreff des Beitrags: Re: Terrain und IBO

Verfasst: Mo Aug 13, 2012 22:26

DGL Member

Registriert: Fr Okt 03, 2008 13:32
Beiträge: 367

Zum Zeichnen mit Indices verwendet man doch glDrawElements, oder ist das bei den Interleaved-Arrays anders?

Nach oben

TAK2004

Betreff des Beitrags: Re: Terrain und IBO

Verfasst: Di Aug 14, 2012 09:19

DGL Member

Registriert: Di Mai 18, 2004 16:45
Beiträge: 2622
Wohnort: Berlin
Programmiersprache: Go, C/C++

Deine Magic Numbers sind auf jedenfall nicht korrekt, was zu falschen darstellungen führen wird, da du die Koordinaten falsch setzt und noch einige out of bound fehler im gl context generierst.

Zitat:

mverts := VBOSize+1;

Statt 32768Bytes hantierst du mit 33800Bytes und die for-Schleifen sind entsprechend auch 1 zu weit.
Wieso du keine "out of bound" exception schon befüllen bekommst wundert mich.
Ich vermisse das pos im indice for-Schleifen block, wenn du kein copy/paste fehler gemacht hast schreibst du die ganze zeit immer den gleichen index und dann ist dort auch noch der Schleifenbereich um 2 zu groß.
Da du x+1 und y+1 verwendest und noch

Code:

mverts := VBOSize+1;

hast.
Das sollte eventuell schon helfen, wenn da nicht noch woanders ein Problem lauert.

Code:

mverts := VBOSize;
...
  for y := 0 to VBOSize-1 do
    for x := 0 to VBOSize-1 do begin
      idata[pos] := (x+0) + (y+0) * mverts;
      idata[pos+1] := (x+0) + (y+1) * mverts;
      idata[pos+2] := (x+1) + (y+1) * mverts;
      idata[pos+3] := (x+1) + (y+1) * mverts;
      idata[pos+4] := (x+1) + (y+0) * mverts;
      idata[pos+5] := (x+0) + (y+0) * mverts;
      pos+=6;
    end;

_________________
"Wer die Freiheit aufgibt um Sicherheit zu gewinnen, der wird am Ende beides verlieren"
Benjamin Franklin

Projekte: https://github.com/tak2004

Nach oben

Dropye

Betreff des Beitrags: Re: Terrain und IBO

Verfasst: Di Aug 14, 2012 11:10

DGL Member

Registriert: Do Jan 07, 2010 21:58
Beiträge: 240

also nach dem was du mir da gerade aufgeschrieben hast würde ich ~24000 Indices benötigen :shock:

und das für nur 4096 Vertices.

Wobei mir auch 4000 Vertices etwas viel vorkommt, rauskommen soll ein Block von 64x64 Quadraten wobei jedes Quadrat aus 2 Dreiecken besteht.

Die Vertices scheinen so zu stimmen der Shader arbeitet anscheinend auch gut nur die Indices wollen nicht so wie ich will.
Auch der Ansatz von TAK2004 bringt leider kein wirkliches Ergebnis, wenn ich das so mache habe ich auf einmal ganz viele lange schnipsel als ob einer meine Landschaft durch den Schredder gejagt hätte

Nach oben

TAK2004

Betreff des Beitrags: Re: Terrain und IBO

Verfasst: Di Aug 14, 2012 12:55

DGL Member

Registriert: Di Mai 18, 2004 16:45
Beiträge: 2622
Wohnort: Berlin
Programmiersprache: Go, C/C++

Ups, darauf hab ich nicht geachtet, die index Daten sind noch murks.

Code:

iData : array[0..DATASize] of GLShort;

Code:

iData : array[0..DATASize*6] of GLShort;

und

Code:

datasize := mverts*mverts*2*sizeof(GLshort);

Code:

datasize := mverts*mverts*6*sizeof(GLshort);

So renderst du dann 2 Triangle pro feld und pro Triangle brauchst du 3 indices=>6 indices pro Feld.
Dann der Renderbefehl:

Code:

glDrawArrays(GL_TRIANGLES, 0, 4096*SizeOf(TVertex2V));

Code:

glDrawArrays(GL_TRIANGLES, 0, DATASize*6);

Der 3. Parameter gibt an, wieviele Indices verwendet werden sollen und durch Triangle weiß er, dass er durch 3 teilen muss und dann die Anzahl an Triangle hat, die er rendert.

Edit: Um die Indices zu reduzieren, kannst du auf GL_TRIANGLE_STRIP umstellen.
Um das Caching zu erhöhen macht es sinn das Triangle Strip von innen nach aussen, wie ein Schneckenpanzer zu generieren.
Das ist aber dann keine triviale Schleife und im aktuellem Stadium wohl ein bisschen overdose.

_________________
"Wer die Freiheit aufgibt um Sicherheit zu gewinnen, der wird am Ende beides verlieren"
Benjamin Franklin

Projekte: https://github.com/tak2004

Nach oben

Skeptiker

Betreff des Beitrags: Re: Terrain und IBO

Verfasst: Di Aug 14, 2012 15:08

DGL Member

Registriert: Sa Mär 14, 2009 17:48
Beiträge: 99
Programmiersprache: D, Java, C++

Schläfer hat geschrieben:

Zum Zeichnen mit Indices verwendet man doch glDrawElements, oder ist das bei den Interleaved-Arrays anders?

Davon ging ich auch immer aus. Kann's sein das du einfach nur deinen Vertexbuffer zeichnest und deshalb nur einen Teil der Triangles siehst?

Nach oben

TAK2004

Betreff des Beitrags: Re: Terrain und IBO

Verfasst: Di Aug 14, 2012 15:40

DGL Member

Registriert: Di Mai 18, 2004 16:45
Beiträge: 2622
Wohnort: Berlin
Programmiersprache: Go, C/C++

Mh, ich hab mal in mein Code geguckt, weil ich schon gut 1-2Jahre kein OpenGL mehr angerührt hab und in opengl2 und 3 wrapper code hab ich glDrawArrays ohne indices und glDrawRangeElements mit.
Damit ist das also auch ein Fehler.

Code:

glDrawRangeElements(GL_TRIANGLES,0,DATASize,DATASize*2,GL_UNSIGNED_SHORT,0);

_________________
"Wer die Freiheit aufgibt um Sicherheit zu gewinnen, der wird am Ende beides verlieren"
Benjamin Franklin

Projekte: https://github.com/tak2004

Nach oben

Dropye

Betreff des Beitrags: Re: Terrain und IBO

Verfasst: Di Aug 14, 2012 17:22

DGL Member

Registriert: Do Jan 07, 2010 21:58
Beiträge: 240

okay ja jetzt hab ich es

die lösung sieht nun genau so aus

Code:

 
const
  DATASize = 4096;
  VBOSize = 64;
 
procedure TMap.InitVBO;
var
  Data : array[0..DATASize] of TVertex2V;
  iData : array[0..DATASize*6] of GLuShort;
  mverts, data_size, pos, x, y : Integer;
begin
 
  pos := 0;
  glGenBuffers(1, @VBO);
  glBindBuffer(GL_ARRAY_BUFFER, VBO);
  mverts := VBOSize+1;
  data_size := mverts*mverts*2*sizeof(GLFLOAT);
 
 
  for y := 0 to mverts do
    for x := 0 to mverts do begin
      data[pos].x := x;
      data[pos].z := y;
      inc(pos);
    end;
  glBufferData(GL_ARRAY_BUFFER, data_size, @data, GL_STATIC_DRAW);
 
  glGenBuffers(1, @IBO);
  glBindBuffer(GL_ELEMENT_ARRAY_BUFFER, IBO);
  data_size := mverts*mverts*6*sizeof(GLushort);
  pos := 0;
  for y := 0 to VBOSize-1 do
    for x := 0 to VBOSize-1 do begin
      idata[pos] := (x+0) + (y+0) * mverts;
      idata[pos+1] := (x+0) + (y+1) * mverts;
      idata[pos+2] := (x+1) + (y+1) * mverts;
      idata[pos+3] := (x+1) + (y+1) * mverts;
      idata[pos+4] := (x+1) + (y+0) * mverts;
      idata[pos+5] := (x+0) + (y+0) * mverts;
      inc(pos,6);
    end;
  glBufferData(GL_ELEMENT_ARRAY_BUFFER, data_size, @idata, GL_STATIC_DRAW);
end;
 
 
procedure TMap.Render;
var x, y : Integer;
begin
  glUseProgram(Shader.ProgramObject);
 
  for x := 0 to 15 do
    for y := 0 to 15 do begin
      glUniform2i(leafmin, x*63,y*63);
      glInterleavedArrays(GL_V2F, SizeOf(TVertex2V), nil);
      glDrawRangeElements(GL_TRIANGLES,0,DATASize,DATASize*6,GL_UNSIGNED_SHORT,0);
    end;
 
  glUseProgram(0);
end;
 

danke für eure Hilfe ich werde mich sicher wieder melden

Nach oben

Seite 1 von 1

[ 13 Beiträge ]

Foren-Übersicht » Programmierung » Einsteiger-Fragen

Wer ist online?

Mitglieder in diesem Forum: 0 Mitglieder und 29 Gäste

Du darfst keine neuen Themen in diesem Forum erstellen.
Du darfst keine Antworten zu Themen in diesem Forum erstellen.
Du darfst deine Beiträge in diesem Forum nicht ändern.
Du darfst deine Beiträge in diesem Forum nicht löschen.
Du darfst keine Dateianhänge in diesem Forum erstellen.