DGL • Thema anzeigen - Objektselektion-Tutorial

Objektselektion-Tutorial

Moderator: DGL-Team

Seite 1 von 1

[ 3 Beiträge ]

Vorheriges Thema | Nächstes Thema

Autor

Nachricht

r4v3r

Betreff des Beitrags: Objektselektion-Tutorial

Verfasst: So Mär 23, 2008 18:32

DGL Member

Registriert: So Jan 07, 2007 19:22
Beiträge: 5

Guten Tag!

ich habe gerade das Objektselektion-Tutorial A durchgearbeitet, nur leider funktioniert mein Programm noch nicht richtig.
Ich habe 3 Quadrate in verschiedenen Farben gezeichnet, durch debuggen habe ich jetzt aber raus gefunden, dass immer alle 3 Quadrate getroffen werden, egal, ob ich auf eines der Quadrate klicke oder irgendwo auf den Hintergrund. Von der Selection-Funktion wird dadurch immer das Quadrat zurück gegeben, welches am nähsten an Kamera ist oder, wenn wenn alle denselben Z-Wert haben, das, was als erste gezeichnet wird. Woran könnte das liegen?
Hier noch mein Code:
Konstanten:

Code:

 
const
  NearClipping = 1;
  FarClipping = 1000;
  rot = 1;
  gruen = 2;
  blau = 3;
  namen : array[-1..3] of string = ('nichts', '', 'rot', 'grün', 'blau');
 

Rendern:

Code:

procedure TForm1.Render;
begin
  glClear(GL_COLOR_BUFFER_BIT or GL_DEPTH_BUFFER_BIT);
 
  glMatrixMode(GL_PROJECTION);
  glLoadIdentity;
  gluPerspective(45.0, ClientWidth/ClientHeight, Nearclipping, Farclipping);
 
  glMatrixMode(GL_MODELVIEW);
  glLoadIdentity;
 
  glTranslatef(0, 0, -20);
 
  glInitNames;
  glPushName(0);
 
  glColor3f(1, 0, 0);
  glLoadName(rot);
  glBegin(GL_QUADS);
    glVertex3f(-6, -6, 0);
    glVertex3f(-1, -6, 0);
    glVertex3f(-1, -1, 0);
    glVertex3f(-6, -1, 0);
  glEnd;
 
  glColor3f(0, 1, 0);
  glLoadName(gruen);
  glBegin(GL_QUADS);
    glVertex3f(1, -6, 0);
    glVertex3f(6, -6, 0);
    glVertex3f(6, -1, 0);
    glVertex3f(1, -1, 0);
  glEnd;
 
  glColor3f(0, 0, 1);
  glLoadName(blau);
  glBegin(GL_QUADS);
    glVertex3f(-2.5, 1, 0);
    glVertex3f(2.5, 1, 0);
    glVertex3f(2.5, 6, 0);
    glVertex3f(-2.5, 6, 0);
  glEnd;
 
  glPopName;
 
  SwapBuffers(DC);
end;
 

Selektion:

Code:

function TForm1.Selection(const x, y: integer): integer;
var
  Puffer       : array[0..256] of GLUInt;
  Viewport     : TGLVectori4;
  Treffer,i    : Integer;
  Z_Wert       : GLUInt;
  Getroffen    : GLUInt;
begin
  glGetIntegerv(GL_VIEWPORT, @viewport);      //Die Sicht speichern
  glSelectBuffer(256, @Puffer);               //Den Puffer zuordnen
 
  glMatrixMode(GL_PROJECTION);                //In den Projektionsmodus
  glRenderMode(GL_SELECT);                    //In den Selectionsmodus schalten
  glPushMatrix;                               //Um unsere Matrix zu sichern
  glLoadIdentity;                             //Und dieselbige wieder zurückzusetzen
 
  gluPickMatrix(x, viewport[3]-y, 0.1, 0.1, viewport);
  gluPerspective(45.0, ClientWidth/ClientHeight, Nearclipping, Farclipping);
 
  render;                                     //Die Szene zeichnen
  glMatrixMode(GL_PROJECTION);                //Wieder in den Projektionsmodus
  glPopMatrix;                                //und unsere alte Matrix wiederherzustellen
 
  treffer := glRenderMode(GL_RENDER);         //Anzahl der Treffer auslesen
 
  Getroffen := High(GLUInt);                  //Höchsten möglichen Wert annehmen
  Z_Wert := High(GLUInt);                     //Höchsten Z - Wert
  for i := 0 to Treffer-1 do
    if Puffer[(i*4)+1] < Z_Wert then
      begin
        getroffen       := Puffer[(i*4)+3];
        Z_Wert := Puffer[(i*4)+1];
      end;
 
  if getroffen=High(GLUInt) 
    then Result := -1
    else Result := getroffen;
end;

OnMouseDown:

Code:

procedure TForm1.FormMouseDown(Sender: TObject; Button: TMouseButton;
  Shift: TShiftState; X, Y: Integer);
begin
  ShowMessage('Die Farbe des Quadrats ist: '+ namen[selection(x, y)]);
end;

Vielen Dank schonmal und frohe Ostern,
r4v3r

Nach oben

Sascha Willems

Betreff des Beitrags:

Verfasst: So Mär 23, 2008 19:24

DGL Member

Registriert: Mo Sep 23, 2002 19:27
Beiträge: 5812
Programmiersprache: C++

In deiner Renderfunktion überschreibst du ja die Pickingmatrix, daher geht dann die Selektion logischerweise nichtmehr. Hier musst du im Rendervorgang prüfen ob du im Selektionsmodus bist, und dann die Matrix nicht überschreiben.

_________________
www.SaschaWillems.de | GitHub | Twitter | GPU Datenbanken (Vulkan, GL, GLES)

Nach oben

r4v3r

Betreff des Beitrags:

Verfasst: So Mär 23, 2008 22:19

DGL Member

Registriert: So Jan 07, 2007 19:22
Beiträge: 5

Kopf

Tisch

Klar, das ist einleuchtend, wenn man das so hört, dass ich da nicht selbst drauf gekommen bin :oops:

Dankeschön!

Falls jemand dasselbe Problem hat, ich hab das jetzt mit einem default-Parameter gemacht, der auf true gesetzt wird, falls die Render-Methode aus der Selection-Methode aufgerufen wird:

Code:

 
procedure TForm1.Render(const selection: boolean = false);
begin
  glClear(GL_COLOR_BUFFER_BIT or GL_DEPTH_BUFFER_BIT);
 
  if not selection then
    begin
      glMatrixMode(GL_PROJECTION);
      glLoadIdentity;
      gluPerspective(45.0, ClientWidth/ClientHeight, Nearclipping, Farclipping);
    end;
 
  // der restliche Quelltext ...
end;
 

MfG r4v3r

Nach oben

Seite 1 von 1

[ 3 Beiträge ]

Foren-Übersicht » Programmierung » Einsteiger-Fragen

Wer ist online?

Mitglieder in diesem Forum: 0 Mitglieder und 3 Gäste

Du darfst keine neuen Themen in diesem Forum erstellen.
Du darfst keine Antworten zu Themen in diesem Forum erstellen.
Du darfst deine Beiträge in diesem Forum nicht ändern.
Du darfst deine Beiträge in diesem Forum nicht löschen.
Du darfst keine Dateianhänge in diesem Forum erstellen.