DGL • Thema anzeigen - Text wird bei TextureFonts nicht dargestellt

Text wird bei TextureFonts nicht dargestellt

Moderator: DGL-Team

Seite 1 von 1

[ 4 Beiträge ]

Vorheriges Thema | Nächstes Thema

Autor

Nachricht

Kathmai

Betreff des Beitrags: Text wird bei TextureFonts nicht dargestellt

Verfasst: Di Mai 08, 2007 04:39

DGL Member

Registriert: Do Mai 27, 2004 15:22
Beiträge: 25
Wohnort: Stuttgart

Hallo Leute,

nach weiterem rumprobieren und ein paar Test's wagte ich mal an daran, Texte dar zu stellen.
Nach mehreren ausprobieren von Bitmap Fontbuilder und diversen anderen Programmen habe ich mich für das FontStudio von Nitrogen entschieden. Bei allen anderen entstehen hässliche Kanteneffekte und die zwischenräume werden einfach zu groß.

http://www.nitrogen.za.org/projectlist.asp?cat=dogl

Es wird dann in ein TGA-File gespeichert samt Daten (akkurate Zwischenräume bzw. tex-koordinaten).

Das Funktioniert soweit auch ganz gut. Aber sollte ich ein Hintergrundbild nehmen, funktioniert es nicht mehr - soll heissen nach dem Aufruf von "GenTexture" (über glbitmap2d) habe ich obwohl die Texture noch nicht gebunden wurde die Texture vom Hintergrundbild auf den Quads für die Buchstaben beim Text.

Hier mal der Quellcode...

Code:

unit Unit1;
 
interface
 
uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, DGLOpenGL, ExtCtrls, StdCtrls, glbitmap, font4;
 
Const
     NearClipping = 1;
     FarClipping  = 1000;
 
type
  TForm1 = class(TForm)
    procedure FormCreate(Sender: TObject);
    procedure FormResize(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
    procedure IdleHandler(Sender: TObject; var Done: Boolean);
    procedure FormShow(Sender: TObject);
  private
    { Private-Deklarationen }
 
 
    procedure SetupGL;
    procedure Render;
 
 
  public
    { Public-Deklarationen }
    DC                                : HDC;  //Handle auf Zeichenfläche
    RC                                : HGLRC;//Rendering Context
 
    StartTime, TimeCount, FrameCount  : Cardinal; //FrameCounter
    Frames, DrawTime                  : Cardinal; //& Timebased Movement
  end;
 
var
  Form1    : TForm1;
  fTexture : TglBitmap2D;
 
  fnt      : TFontObj; // Siehe Font4 Unit
 
implementation
 
{$R *.dfm}
 
procedure TForm1.Render;
begin
 glClear(GL_COLOR_BUFFER_BIT or GL_DEPTH_BUFFER_BIT);
 glMatrixMode(GL_PROJECTION);
 glLoadIdentity;
 glViewport(0,0,ClientWidth,ClientHeight);
 
 glOrtho(0,800,0,600, 0,128);
 
 glEnable(GL_TEXTURE_2D);
 
 glEnable(GL_Blend);
 glEnable(GL_ALPHA_TEST);
 glAlphaFunc(GL_GREATER, 0.1);
 
 
//glBlendFunc(GL_SRC_ALPHA, GL_ONE);
 fnt.Draw(10, 50, 'Hallo, dies ist ein Test...', 0);
 fnt.Draw(10, 580, inttostr(Frames) + ' FPS', 0);
 
 ftexture.Bind();
 
glBegin(GL_QUADS);
  glTexCoord2f(0,1); glVertex3f(1, 1, -1);
  glTexCoord2f(1,1); glVertex3f(1024, 0, -1);
  glTexCoord2f(1,0); glVertex3f(1024, 768, -1);
  glTexCoord2f(0,0); glVertex3f(0, 768, -1);
glEnd;
 
// glEnable(GL_BLEND);
//glBlendFunc(GL_SRC_ALPHA, GL_ONE_MINUS_SRC_ALPHA);
//gldisable(GL_BLEND);
 
 SwapBuffers(DC);
end;
 
// ----------------------------------------------------------------------------------
 
procedure TForm1.SetupGL;
 
begin
  fnt := TFontObj.Create;
  Fnt.LoadTGAComp('Font.tga');
  Fnt.LoadData('Font.tga', true); // Look inside Font.tga for the font data.
 
  glClearColor(0.6, 0.3, 1.0, 0); //Hintergrundfarbe:
  glEnable(GL_DEPTH_TEST);          //Tiefentest aktivieren
 
 
 
//  glFrontFace(GL_CW);
//  glEnable(GL_CULL_FACE);          //Backface Culling aktivieren
 
 
 
 fTexture := TglBitmap2D.Create;
 fTexture.LoadFromFile('space.jpg');
 
 ftexture.GenTexture;
 
// Wenn ich kein Hintergrundbild lade und an OGL per GenTexture übergebe
// dann zeigt er den Text richtig an...
 
end;
 
// ----------------------------------------------------------------------------------
 
procedure TForm1.FormCreate(Sender: TObject);
begin
 
DC:= GetDC(Handle);
  if not InitOpenGL then
  begin
   showmessage('OpenGL konnte nicht initialisiert werden...');
  end
  else
  begin
   RC:= CreateRenderingContext( DC,
                                [opDoubleBuffered],
                                32,
                                24,
                                0,0,0,
                                0);
   ActivateRenderingContext(DC, RC);
 
 
  SetupGL;
 
  Application.OnIdle := IdleHandler;
  end;
end;
 
// ----------------------------------------------------------------------------------
 
procedure TForm1.FormResize(Sender: TObject);
var tmpBool : Boolean;
begin
  glViewport(0, 0, ClientWidth, ClientHeight);
  glMatrixMode(GL_PROJECTION);
  glLoadIdentity;
  gluPerspective(45.0, ClientWidth/ClientHeight, NearClipping, FarClipping);
 
  glMatrixMode(GL_MODELVIEW);
  glLoadIdentity;
  IdleHandler(Sender, tmpBool);
end;
 
// ----------------------------------------------------------------------------------
 
procedure TForm1.FormDestroy(Sender: TObject);
begin
  ftexture.Free;
  fnt.Free;
 
  DeactivateRenderingContext;
  DestroyRenderingContext(RC);
  ReleaseDC(Handle, DC);
end;
 
// ----------------------------------------------------------------------------------
 
procedure TForm1.IdleHandler(Sender: TObject; var Done: Boolean);
begin
  StartTime:= GetTickCount;
  Render;
  DrawTime:= GetTickCount - StartTime;
  Inc(TimeCount, DrawTime);
  Inc(FrameCount);
 
  if TimeCount >= 1000 then begin
    Frames:= FrameCount;
    TimeCount:= TimeCount - 1000;
    FrameCount:= 0;
    Caption:= InttoStr(Frames) + ' FPS';
 
  end;
 
  Done:= false;
end;
 
 
procedure TForm1.FormShow(Sender: TObject);
begin
  form1.ClientHeight:=600;
  form1.ClientWidth:=800;
end;
 
end.

Wenn ich das erstellen von Texture := GlBitmap2d.Create ... und Texture.gentexture weglasse zeigt er den Text an.

Und hier die Unit (Font4.pas - auch auf der Seite zum Download).

Code:

// ---------------------
// Unit: Font4.pas
//
// FontObjs now load data and images separately
// Uses proper ABC font widths
// Supports Unicode Widestrings. (not Win 98 and earlier compatible?)
//
// Can Load JPG (separate RGB and Alpha) and 32bit TGAs
// Can Load Binary Fnt Data which has been combined with another file or separately.
//
// Author: Michael Pote
// Date: 30 April 2007
// -------------------
unit Font4;
 
interface
 
Uses dglOpenGL;
 
const
      MAX_CHARS = high(Word);
      USE_MIPMAP = true; //if you dont want mipmaps set this to false.
 
type  FontInfo = record
        A, C: integer;
        Wid, Hgt: cardinal;
        char: WideChar;
        x1,y1,x2,y2: double;
      end;
 
  TFontObj = class
                 private
                  CharLookup: array[0..MAX_CHARS] of integer;
                 public
 
                  F: array of FontInfo;
                  NumFonts: cardinal;
                  TexInd: glUInt;
 
                  SpaceWidth, MaxHeight: cardinal;
 
                  constructor Create; overload;
 
                  function LoadTGAComp(const Path: string): boolean;
                  function LoadJPEGs(const rgb, alpha: string): boolean;
                  function LoadData(const Filename: string; MergedFile: boolean): boolean;
 
                  function TextLen(const Txt: widestring): integer;
 
                  Procedure Draw(Const X,Y: single;Const Txt: widestring; Lev:single); Overload;
                end;
 
Procedure DrawQuadRT(X, Y, Wid, Hgt, Lev, Tu, Tu2, Tv,Tv2: single);
 
implementation
 
Uses Classes, Windows, JPEG, Graphics, SysUtils;
 
const
    MajorVersion: byte = 4;
    MinorVersion: byte = 0;
 
 
function LoadJPGs(Filename1, Filename2: String; var Texture: GLuint): Boolean; forward;
function LoadTGA( filename : string; var TexId: glUint; MipMap: boolean) : boolean; forward;        // Loads A TGA File Into Memory
 
////////////////////////////////////////////////////////////////////////////////
//  TFONTOBJ
///////////////////////////////////////////////////////////////////////////////
 
constructor TFontObj.Create;
begin
  inherited Create;
  NumFonts := 0;
end;
 
function TFontObj.TextLen(const Txt: widestring): integer;
var CurX: integer;
    Ch: Widechar;
    Chaar, I, Ind: integer;
begin
   CurX := 0;
 
   for I := 1 to length(Txt) do
   begin
       Ch := Txt[I];
       Chaar := integer(ch);
 
       if Chaar = 32 then
       begin
         Ind := -1;
         CurX := CurX + SpaceWidth;
       end
       else
       begin
         Ind := CharLookup[Chaar];
       end;
 
       if ind > -1 then
       begin
         CurX := CurX + F[Ind].A;
 
         //DrawQuadRT(CurX, Y, F[ind].Wid, F[ind].Hgt, 0, F[ind].x1,F[ind].x2,F[ind].y1,F[ind].y2);
 
         CurX := CurX + F[Ind].C;
       end;
   end;
 
   result := CurX;
 
end;
 
 
procedure TFontObj.Draw(const X, Y: single; const Txt: widestring; Lev: single);
var CurX: single;
    Ch: Widechar;
    Chaar, I, Ind: integer;
begin
   CurX := X;
 
   for I := 1 to length(Txt) do
   begin
       Ch := Txt[I];
       Chaar := integer(ch);
 
       if Chaar = 32 then
       begin
         Ind := -1;
         CurX := CurX + SpaceWidth;
       end
       else
       begin
         Ind := CharLookup[Chaar];
       end;
 
       if ind > -1 then
       begin
         CurX := CurX + F[Ind].A;
 
         DrawQuadRT(CurX, Y, F[ind].Wid, F[ind].Hgt, lev, F[ind].x1,F[ind].x2,F[ind].y1,F[ind].y2);
 
         CurX := CurX + F[Ind].C;
       end;
   end;
 
end;
 
//Loads the data part of the font.
//Use MergedFile if you saved the data into the graphic composite in Font Studio.
//Can only load binary font data (.Fnt filetype)
function TFontObj.LoadData(const Filename: string; MergedFile: boolean): boolean;
var Fs: TFileStream;
    Pos: int64;
    I: integer;
    Header: array[0..3] of char;
begin
   Fs := nil;
   try
      Fs := TFileStream.Create(filename, fmOpenRead);
 
      if MergedFile then
      begin
        Fs.Seek(-10, soFromEnd);
        Fs.Read(Header[0], 2);
        if (header[0] <> 'F') or (header[1] <> 'S') then
        begin
          Messagebox(0, 'TFontObj.LoadData: This is not a valid Merged file.', 'Error', MB_OK);
          result := false; //Not a valid merged file.
          exit;
        end;
 
        Fs.Read(Pos, sizeof(int64));
        Fs.Seek(Pos, soFromBeginning); //Move to the correct position.
      end;
 
    Fs.Read(Header[0], 4);
    if (header[0] <> 'F') or (header[1] <> 'S') then
    begin
          Messagebox(0, 'TFontObj.LoadData: This is not a valid font file (must be .fnt format).', 'Error', MB_OK);
          result := false; //Not a valid file.
          exit;
    end;
    if (byte(header[2]) <> MajorVersion) or (byte(header[3]) <> MinorVersion) then
    begin
       Messagebox(0, 'TFontObj.LoadData: Warning! Version Mismatch!', 'Error', MB_OK);
    end;
 
    Fs.Read(NumFonts, sizeof(Cardinal));
    Fs.Read(SpaceWidth, sizeof(Cardinal));
 
    setlength(F, NumFonts);
 
    for I := 0 to MAX_CHARS-1 do
       CharLookup[I] := -1;
 
 
    MaxHeight := 0;
    for I := 0 to NumFonts-1 do
    begin
       fs.Read(F[I].char, sizeof(WideChar));
       fs.Read(F[I].A, sizeof(integer));
       fs.Read(F[I].C, sizeof(integer));
       fs.Read(F[I].Wid, sizeof(cardinal));
       fs.Read(F[I].Hgt, sizeof(cardinal));
       fs.Read(F[I].X1, sizeof(double));
       fs.Read(F[I].Y1, sizeof(double));
       fs.Read(F[I].X2, sizeof(double));
       fs.Read(F[I].Y2, sizeof(double));
 
       if F[I].Hgt > MaxHeight Then MaxHeight := F[I].Hgt;
 
       if (integer(F[I].char) >= 0) and (integer(F[I].char) < MAX_CHARS) then
          CharLookup[integer(F[I].char)] := I;
    end;
 
    Result := true;
 
   finally
      if assigned(Fs) then Fs.Free;
   end;
end;
 
 
// Loads two jpeg images as the font texture.
function TFontObj.LoadJPEGs(const rgb, alpha: string): boolean;
begin
  LoadJpgs(rgb, alpha, TexInd);
end;
 
// Loads a 32bit TGA image as the font texture.
function TFontObj.LoadTGAComp(const Path: string): boolean;
begin
  LoadTGA(path, TexInd, USE_MIPMAP);
end;
 
 
 
////////////////////////////////////////////////////////////////////////////////
 
 
function CreateTexture(Width, Height, Format : Word; pData : Pointer; Mipmap: boolean) : Integer;
var
  Texture : GLuint;
begin
  glGenTextures(1, @Texture);
  glBindTexture(GL_TEXTURE_2D, Texture);
  glTexEnvi(GL_TEXTURE_ENV, GL_TEXTURE_ENV_MODE, GL_MODULATE);  {Texture blends with object background}
 
  { Select a filtering type. BiLinear filtering produces very good results with little performance impact
    GL_NEAREST               - Basic texture (grainy looking texture)
    GL_LINEAR                - BiLinear filtering
    GL_LINEAR_MIPMAP_NEAREST - Basic mipmapped texture
    GL_LINEAR_MIPMAP_LINEAR  - BiLinear Mipmapped texture
  }
 
  if Mipmap then
  begin
   glTexParameteri(GL_TEXTURE_2D, GL_TEXTURE_MAG_FILTER, GL_LINEAR); { only first two can be used }
   glTexParameteri(GL_TEXTURE_2D, GL_TEXTURE_MIN_FILTER, GL_LINEAR_MIPMAP_LINEAR); { all of the above can be used }
  end
  else
  begin
   glTexParameteri(GL_TEXTURE_2D, GL_TEXTURE_MAG_FILTER, GL_LINEAR); { only first two can be used }
   glTexParameteri(GL_TEXTURE_2D, GL_TEXTURE_MIN_FILTER, GL_LINEAR); { all of the above can be used }
  end;
 
  if Format = GL_RGBA then
    gluBuild2DMipmaps(GL_TEXTURE_2D, GL_RGBA, Width, Height, GL_RGBA, GL_UNSIGNED_BYTE, pData)
  else
    gluBuild2DMipmaps(GL_TEXTURE_2D, format, Width, Height, format, GL_UNSIGNED_BYTE, pData);
 
  result :=Texture;
end;
 
 
function LoadJPGs(Filename1, Filename2: String; var Texture: GLuint): Boolean;
var
  Data : Array of Byte;
  W, Width : Integer;
  H, Height : Integer;
  BMP : TBitmap;
  JPG: TJPEGImage;
  C : LongWord;
  Line : PByteArray;
 
  MaxSize: integer;
  TD: Array of LongWord;
  ScaleF: single;
  OldW, OldH, X, Y, I: integer;
 
begin
  result :=FALSE;
  JPG:=TJPEGImage.Create;
 
    try
      JPG.LoadFromFile(Filename1);
    except
      MessageBox(0, PChar('Couldn''t load JPG - "'+ Filename1 +'"'), PChar('BMP Unit'), MB_OK);
      Exit;
    end;
 
  // Create Bitmap
  BMP:=TBitmap.Create;
  BMP.pixelformat:=pf24bit;
  BMP.width:=JPG.width;
  BMP.height:=JPG.height;
  BMP.canvas.draw(0,0,JPG);        // Copy the JPEG onto the Bitmap
 
  Width :=BMP.Width;
  Height :=BMP.Height;
  SetLength(Data, Width*Height*4);
 
  For H:=0 to Height-1 do
  Begin
    Line :=BMP.scanline[Height-H-1];   // flip JPEG
    For W:=0 to Width-1 do
    Begin
 
      Data[(W*4)+(H*Width*4)] := Line[W*3+2];
      Data[(W*4)+1+(H*Width*4)] := Line[W*3+1];
      Data[(W*4)+2+(H*Width*4)] := Line[W*3];
 
    End;
  End;
 
    try
      JPG.LoadFromFile(Filename2);
    except
      MessageBox(0, PChar('Couldn''t load JPG - "'+ Filename2 +'"'), PChar('BMP Unit'), MB_OK);
      Exit;
    end;
  BMP.canvas.draw(0,0,JPG);        // Copy the JPEG onto the Bitmap
 
  For H:=0 to Height-1 do
  Begin
    Line :=BMP.scanline[Height-H-1];   // flip JPEG
    For W:=0 to Width-1 do
    Begin
 
      Data[(W*4)+3+(H*Width*4)] := Line[W*3];
    
 
    End;
  End;
 
  BMP.free;
  JPG.free;
 
 glGetIntegerv(GL_MAX_TEXTURE_SIZE, @MaxSize);
 
  OldW := -1;
 
  if width > Height then
  begin
   if width > Maxsize then
   begin
 
     ScaleF := MaxSize / width;
     OldW := width;
     OldH := Height;
     width := Maxsize;
     Height := round(Height*ScaleF);
   end;
  end
  else
  begin
   if height > Maxsize then
   begin
     ScaleF := MaxSize / height;
     OldW := width;
     OldH := Height;
     height := Maxsize;
     width := round(width*ScaleF);
   end;
  end;
 
  if OldW > -1 then
  begin
     ScaleF := 1/ScaleF;
     SetLength(TD, Width*Height);
     For X := 0 to Width-1 do
     For Y := 0 to Height-1 do
     begin
        TD[(Y*Width+X)] := data[
                        round(((Y*OldW)*ScaleF+(X*ScaleF)))
                        ];
     end;
     SetLength(Data, Width*Height);
     For Y := 0 to high(Td) do
      Data[Y] := Td[Y];
     SetLength(TD, 0);
 
  end;
 
 
 
 
  Texture :=CreateTexture(Width, Height, GL_RGBA, addr(Data[0]), USE_MIPMAP);
  result :=TRUE;
end;
 
 
Procedure DrawQuadRT(X, Y, Wid, Hgt, Lev, Tu, Tu2, Tv,Tv2: single);
begin
   Tv := 1-Tv;
  Tv2 := 1-Tv2;
  glBegin(GL_QUADS);
    glTexCoord2f(Tu,  Tv); glVertex3f(X,     Y, -lev);
    glTexCoord2f(Tu2, Tv); glVertex3f(X+Wid, Y, -lev);
    glTexCoord2f(Tu2,Tv2); glVertex3f(X+Wid, Y-Hgt, -lev);
    glTexCoord2f(Tu, Tv2); glVertex3f(X,     Y-Hgt, -lev);
  glEnd;
end;
 
 
function LoadTGA( filename : string; var TexId: glUint; MipMap: boolean) : boolean;         // Loads A TGA File Into Memory
const
  TGAheader : array [0..11] of GLubyte = (0,0,2,0,0,0,0,0,0,0,0,0); // Uncompressed TGA Header
TGAComheader : array [0..11] of GLubyte = (0,0,10,0,0,0,0,0,0,0,0,0);   // Compressed TGA Header
 
type TextureImage = record                                      // Structure Name
    imageData : PChar;                                      // Image Data (Up To 32 Bits)
    bpp : GLuint;                                           // Image Color Depth In Bits Per Pixel.
    width : GLuint;                                         // Image Width
    height : GLuint;                                            // Image Height
    texID : GLuint;
     end;
 
var
  TGAcompare : array [0..11] of GLubyte;                                // Used To Compare TGA Header
  header : array [0..5] of GLubyte;                                 // First 6 Useful Bytes From The Header
  bytesPerPixel : GLuint;                   // Holds Number Of Bytes Per Pixel Used In The TGA File
  imageSize : GLuint;                                   // Used To Store The Image Size When Setting Aside Ram
  i : GLuint;                                       // Temporary Variable
  gltype : GLuint;                              // Set The Default GL Mode To RBGA (32 BPP)
  Compressed:boolean;
 
  Tm: Char;
  Texture:  TextureImage;
  tgafile : integer;
  TD: pchar;
  ScaleF: single;
  OldW, OldH, X, Y: integer;
 
  PixelCount, CurrentPixel, CurrentByte: gluInt;
  ColorBuffer: Pchar;
  ChunkHeader: gluByte;
  Counter, Ret: integer;
begin
  tgafile := FileOpen(filename, fmOpenReadWrite);
 
  Ret := FileRead(tgafile, TGAcompare, sizeof(TGAcompare));
 
  if (
      (tgafile = -1) or                             // Does File Even Exist?
      (Ret <> sizeof(TGAcompare))   // Are There 12 Bytes To Read?
     )
  then
  begin
    //ShowError(10, 'TGATexture.LoadTGA', False);
    if (tgafile = -1) then                                  // Did The File Even Exist? *Added Jim Strong*
    begin
      result := false;                                  // Return False
      exit;
    end
    else
    begin
      fileclose(tgafile);                                   // If Anything Failed, Close The File
      result := false;                                  // Return False
      exit;
    end;
  end;
 
  if (CompareMem(@TGAheader, @TGAcompare, sizeof(TGAheader)) = false)                   // Does The Header Match What We Want?
  Then
  begin //File is not uncompressed...
 
   if (CompareMem(@TGAComheader, @TGAcompare, sizeof(TGAComheader)) = True)                 // Does The Header Match What We Want?
   Then
   Begin
      Compressed := True;
   end
   else
   Begin
     i := 0;
     //ShowError(17, 'TGATexture.LoadTGA', False);
     if (tgafile = -1) then                                 // Did The File Even Exist? *Added Jim Strong*
     begin
       result := false;                                 // Return False
       exit;
     end
     else
     begin
       fileclose(tgafile);                                  // If Anything Failed, Close The File
       result := false;                                 // Return False
       exit;
     end;
    end;
 
  end
  else
  begin
   Compressed := False;
  end;
 
   if (FileRead(tgafile, header, sizeof(header)) <> sizeof(header)) then
   begin
     //ShowError(10, 'TGATexture.LoadTGA', False);
     if (tgafile = -1) then                                 // Did The File Even Exist? *Added Jim Strong*
     begin
       result := false;                                 // Return False
       exit;
     end
     else
     begin
       fileclose(tgafile);                                  // If Anything Failed, Close The File
       result := false;                                 // Return False
       exit;
     end;
   end;
 
  texture.width  := header[1] * 256 + header[0];            // Determine The TGA Width  (highbyte*256+lowbyte)
  texture.height := header[3] * 256 + header[2];            // Determine The TGA Height (highbyte*256+lowbyte)
 
  if (texture.width <= 0)   or                              // Is The Width Less Than Or Equal To Zero
     (texture.height <= 0)  or                              // Is The Height Less Than Or Equal To Zero
     ((header[4] <> 24) and (header[4] <> 32)) then                 // Is The TGA 24 or 32 Bit?
  begin
    //ShowError(11, 'TGATexture.LoadTGA', False);
    fileclose(tgafile);                                     // If Anything Failed, Close The File
    result := false;                                        // Return False
    exit;
  end;
 
  texture.bpp   := header[4];                           // Grab The TGA's Bits Per Pixel (24 or 32)
  bytesPerPixel := texture.bpp div 8;                       // Divide By 8 To Get The Bytes Per Pixel
  imageSize := texture.width * texture.height * bytesPerPixel;  // Calculate The Memory Required For The TGA Data
  If BytesPerPixel = 4 then glType := GL_RGBA else
  glType := GL_RGB;
 
  GetMem(texture.imageData, imageSize);     // Reserve Memory To Hold The TGA Data
  //Setlength(texture.imagedata, imagesize);
  if Not Compressed then
  begin
   if (texture.imageData = nil) or         // Does The Storage Memory Exist?
      (fileread(tgafile, texture.imageData^, integer(imageSize)) <> imageSize)  // Does The Image Size Match The Memory Reserved?
      then
      begin
        if (texture.imageData <> nil)                       // Was Image Data Loaded
           then freemem(texture.imageData);                     // If So, Release The Image Data
 
        fileclose(tgafile);                                     // Close The File
        //ShowError(10, 'TGATexture.LoadTGA', False);
        result := false;                                        // Return False
        exit;
      end;
 
    i := 0;
    while i < imageSize do
    with texture do
    begin
     Tm := ImageData[I+2];
     imageData[i+2] := imageData[i];                    // Set The 3rd Byte To The Value In 'temp' (1st Byte Value)
     imageData[i] := Tm;                          // Set The 1st Byte To The Value Of The 3rd Byte
 
     i := i + bytesPerPixel;
    end;
 
 end
 else  //COMPRESSED TGA'S
 begin
   PixelCount := texture.width * Texture.Height;
   CurrentPixel := 0;
   CurrentByte := 0;
   GetMem(ColorBuffer, BytesPerPixel);
 
   Repeat
      ChunkHeader := 0;
      if FileRead(tgaFile, ChunkHeader, sizeof(gluByte)) = 0 then
      begin
        //ERROR reading Chunk!
        fileclose(tgafile);                                     // Close The File
        result := false;                                        // Return False
        exit;
      end;
 
 
      if ChunkHeader < 128 then
      begin
         ChunkHeader := ChunkHeader + 1;
         For Counter := 0 to ChunkHeader-1 do
         begin
            if fileRead(tgafile, ColorBuffer^, BytesPerPixel) <> BytesPerPixel then
            begin
             fileclose(tgafile);                                        // Close The File
             result := false;                                       // Return False
             exit;
            end;
 
            Texture.imageData[CurrentByte] := (ColorBuffer[2]);
            Texture.imageData[CurrentByte+1] := (ColorBuffer[1]);
            Texture.imageData[CurrentByte+2] := (ColorBuffer[0]);
            if BytesPerPixel = 4 then
            Texture.imageData[CurrentByte+3] := (ColorBuffer[3]);
 
            CurrentByte := CurrentByte + bytesPerPixel;
            inc(CurrentPixel);
            if CurrentPixel > PixelCount then
            begin
             fileclose(tgafile);                                        // Close The File
             result := false;                                       // Return False
             exit;
            end;
         end;
      end
      else //Chunkheader > 128
      begin
         ChunkHeader := ChunkHeader - 128;
         if fileRead(tgafile, ColorBuffer^, BytesPerPixel) <> BytesPerPixel then
         begin
          fileclose(tgafile);                                       // Close The File
          result := false;                                      // Return False
          exit;
         end;
         For Counter := 0 to ChunkHeader do
         begin
            Texture.imageData[CurrentByte] := ColorBuffer[2];
            Texture.imageData[CurrentByte+1] := ColorBuffer[1];
            Texture.imageData[CurrentByte+2] := ColorBuffer[0];
            if BytesPerPixel = 4 then
            Texture.imageData[CurrentByte+3] := ColorBuffer[3];
 
            CurrentByte := CurrentByte + bytesPerPixel;
            inc(CurrentPixel);
         end;
 
      end;
   Until CurrentPixel >= PixelCount;
   FreeMem(ColorBuffer);
 end;
 fileclose (tgafile);                                           // Close The File
 
 
 
  // Build A Texture From The Data
 Texture.texId := CreateTexture(Texture.Width, Texture.Height, glType, Texture.Imagedata, Mipmap);
 FreeMem(Texture.ImageData);
 
  TexId := Texture.texID;
  result := true;                                           // Texture Building Went Ok, Return True
end;
 
end.

Nach dem Durchschauen der Unit dachte ich es hängt einfach damit zusammen, daß einmal nur dur die Funktion "CreateTexture" eine Texture gebunden wurde und dann in der Zeichenroutine nicht wieder.

Ist da ein Fehler drin oder wie kann man Text richtig darstellen?

Bild

Funzt alles

Bild

Hier ohne Zeichnen des Bildes auf einem Quad - aber schon geladen und an OGL mit texture.Gentexture übergeben.

Bild

Und hier mit gezeichneten Quad und Texture drauf

Wäre echt dankbar wenn ihr mir dabei helfen könnt das Ding zum laufen zu bringen auch mittels meiner nicht gross vorhandenen Englischkenntnisse um mich bei Nitrogen im Forum über das Problem auszulassen...

Mfg
Thomas

Nach oben

i0n0s

Betreff des Beitrags:

Verfasst: Di Mai 08, 2007 05:50

Ernährungsberater

Registriert: Sa Jan 01, 2005 17:11
Beiträge: 2068
Programmiersprache: C++

Schonmal auf die Idee gekommen, dies:

Code:

 ftexture.Bind();

auch für die Fonttexture zu machen?
So bleibt natürlich nach dem ersten Rendern nur die Hintergrundtextur aktiv.

_________________
Steppity,✲steppity,✴step,❆step,✳step! :twisted:

❆ ❄ ❄ ❄ ❅ ❄ ❆ ❄ ❅ ❄ ❅ ❄ ❅ ❄ ❄
❅ ☃ ❄ ❄ ❄ ❅ ❄ ❄ ❄ ❅ ❄ ☃ ❄ ❆ ❄ ❄

Nach oben

Kathmai

Betreff des Beitrags:

Verfasst: Di Mai 08, 2007 07:15

DGL Member

Registriert: Do Mai 27, 2004 15:22
Beiträge: 25
Wohnort: Stuttgart

Hi,

war wohl meine Faulheit. Kaum zu glauben bei der Uhrzeit und das ich auf Arbeit bin :oops:

Nachdem ich die font4.pas nochmal durchforstet hab kam die Lösung (nach ner Tasse Kaffee).

Einfach wie Du sagtest "bind" aufrufen vorher... mit glBindTexture(GL_TEXTURE_2D, fnt.TexInd)

danke und gut n8

Nach oben

Lossy eX

Betreff des Beitrags:

Verfasst: Di Mai 08, 2007 07:41

DGL Member

Registriert: Do Dez 05, 2002 10:35
Beiträge: 4234
Wohnort: Dortmund

Ja also beim Erstellen muss eine Textur erst einmal gebunden werden. Und wenn ich mir so den Code der Fontklasse einmal anschaue, dann kann ich dort nirgends etwas entdecken was die Textur des Fonts bindet. Außer beim Erstellen.

Im Draw müsste er die entsprechende Textur erneut binden. Bzw denke ich, dass er es aus Optimierungsgründen so gemacht, dass er nur die TexturID rausreicht und du sie selber binden musst. Damit man bei richtig großen Texten nicht zu häufig ein und die selbe Textur binden muss. Ob das ein Fehler ist darüber kann man sich streiten. Ich finde es in jedem Fall unglück, dass ich da nirgends einen Hinweis gefunden habe.

Folgendes sollte ausreichen.

Code:

glBindTexture(GL_TEXTURE_2D, fnt.TexInd);
fnt.Draw(...);

PS: Ey. Das ist unfair selber auf die Lösung zu kommen wärend ich gerade am Schreiben bin. :twisted:

PPS: Aber schön, dass du es selber gefunden.

Nach oben

Seite 1 von 1

[ 4 Beiträge ]

Foren-Übersicht » Programmierung » Einsteiger-Fragen

Wer ist online?

Mitglieder in diesem Forum: 0 Mitglieder und 8 Gäste

Du darfst keine neuen Themen in diesem Forum erstellen.
Du darfst keine Antworten zu Themen in diesem Forum erstellen.
Du darfst deine Beiträge in diesem Forum nicht ändern.
Du darfst deine Beiträge in diesem Forum nicht löschen.
Du darfst keine Dateianhänge in diesem Forum erstellen.