DGL • Thema anzeigen - Kapier Transparent Frabe mit glBitmap nicht

Kapier Transparent Frabe mit glBitmap nicht

Moderator: DGL-Team

Seite 1 von 1

[ 5 Beiträge ]

Vorheriges Thema | Nächstes Thema

Autor

Nachricht

Ferby

Betreff des Beitrags: Kapier Transparent Frabe mit glBitmap nicht

Verfasst: Mi Mär 14, 2007 20:37

DGL Member

Registriert: Do Nov 23, 2006 20:44
Beiträge: 21
Wohnort: Wien

Hallo,

Ich habe mehrere Texturen geladen, und möchte das eine bestimmte Farbe immer Transparent ist.

Ich verwende glBitmap als Texturloader.

Ich lade meine Textur
LoadTexture('ferby.tga', Textur[1], false);

und habe diese funktion gefunden AddAlphaFromValue(100);

Allerdings kommt die Meldung [Fehler] MainUnit.pas(47): Undefinierter Bezeichner: 'AddAlphaFromValue'

Warum? Was mach ich falsch?

Nach oben

Lossy eX

Betreff des Beitrags:

Verfasst: Mi Mär 14, 2007 21:33

DGL Member

Registriert: Do Dez 05, 2002 10:35
Beiträge: 4234
Wohnort: Dortmund

Also als erstes. Du hast mit der glBitmap 2 Wege um Texturen zu laden. 1. den Proceduralen. Das ist dann nur die Methode LoadTexture. Und NICHTS weiter und dann den Objektorientierten bei dem du die Bilder noch verändern, beeinflussen kannst. Ich empfehle grundsätzlich den über die Objekte. Dann würde das ganze in etwa so aussehen.

Code:

var
  Tex: TglBitmap2D;
begin
  Tex := TglBitmap2D.Create;  // Klasse erstellen
  Tex.LoadFromFile('Blahhhh');  // Datei laden
  Tex.AddAlphaFromValue(100);  // fixen Alpha von 100 setzen
 
  Tex.GenTexture;  // Wenn alles Fertig ist dann Textur Erzeugen
end;

Wenn du die Textur nicht mehr brauchst dann einfach die Textur freigeben. Binden kannst du die Textur dann mit Tex.Bind. Dabei wird auch (ohne zusatzparameter bei bind) auch gleich GL_TEXTURE_2D mit aktiviert.

PS: Wenn du lieber mit der ID der Texture arbeiten möchtest dann kannst du wie folgt die Textureklasse freigeben ohne, dass die Textur gelöscht wird.

Code:

Textur[1] := Tex.ID;  // ID Holen
Tex.DeleteTextureOnFree := False;  // Texturfreigabe verhindern
Tex.Free;  // Instanz frei geben

PPS: Ein fixer Alphawert von 100 macht nur sehr selten Sinn. Besser und resourceschonender wäre es wohl, wenn du den Alphawert über glColor4f einstellst.

[edit] Was mir gerade noch auffällt. Wenn du eine Farbe transparent haben möchtest musst du wohl eher ColorKeys verwenden. Dabei wird bei einer bestimmten Farbe der Alphakanal gesetzt oder nicht.

Code:

Tex.AddAlphaFromColorKey(0, $FF, 0); // Exaktes grün wird zu Alpha.

Nach oben

Ferby

Betreff des Beitrags:

Verfasst: Mi Mär 14, 2007 22:03

DGL Member

Registriert: Do Nov 23, 2006 20:44
Beiträge: 21
Wohnort: Wien

Hallo,

Das man die Texturen Objektorientiert laden kann, hab ich nicht gewußt.
Das ist sicher die besser Möglichkeit.

Leider funktioniert die Transparenz noch immer nicht....

Im Anhang ist mein kleinens Project. Das einizge, was ich will, ist, das das Schwarz in der Grafik Ferby.tga Transparent ist.......

Hier der Quellcode

Code:

 
unit MainUnit;
 
interface
 
uses
  Windows, Forms, dglOpenGL, glBitmap, Classes, ExtCtrls, SysUtils, SimpleOpenGL;
 
type
  TMainForm = class(TForm)
    FrameTimer: TTimer;
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
    procedure Render(Sender: TOBject);
    procedure FormResize(Sender: TObject);
  end;
 
var
  MainForm: TMainForm;
 
  // OpenGL Ini
  DC : HDC;
  RC : HGLRC;
 
  // Test
  Textur1: TglBitmap2D;
 
implementation
 
{$R *.dfm}
                                                                                ////////////
                                                                                // CREATE //
                                                                                ////////////
procedure TMainForm.FormCreate(Sender: TObject);
begin
  DC:= GetDC(Handle);
  RC:= CreateRenderingContext( DC,[opDoubleBuffered],32,24,0,0,0,0);
  ActivateRenderingContext(DC, RC);
  glEnable(GL_DEPTH_TEST);  // Tiefentest
  glEnable(GL_CULL_FACE);   // nur vorderseite zeichnen (gegen urzeigersinn)
  glEnable(GL_TEXTURE_2D);
  glClearColor(0.2, 1, 1, 1);
 
  // Lade Textur
  Textur1 := TglBitmap2D.Create; // Klasse erstellen
  Textur1.LoadFromFile('Ferby.tga'); // Datei laden
  Textur1.AddAlphaFromColorKey(0, 0, 0); // fixen Alpha  setzen
  Textur1.GenTexture; // Wenn alles Fertig ist dann Textur Erzeugen
 
  Render(NIL);
end;
 
                                                                                ////////////
                                                                                // RENDER //
                                                                                ////////////
procedure TMainForm.Render(Sender: TOBject);
begin
  // Lösche Altes Bild
  glClear(GL_COLOR_BUFFER_BIT or GL_DEPTH_BUFFER_BIT);
 
  glMatrixMode(GL_PROJECTION);
  glLoadIdentity;
  glViewport(0,0,ClientWidth,ClientHeight);
  glOrtho(0,800,600,0,0,128);
 
  // Ferby Schriftzug
  Textur1.Bind;
  glSimpleQuad(50,50,700,500,0);
 
  SwapBuffers(DC);
end;
                                                                                ////////////
                                                                                // RESIZE //
                                                                                ////////////
procedure TMainForm.FormResize(Sender: TObject);
begin
  glViewport(0, 0, ClientWidth, ClientHeight);
  glMatrixMode(GL_PROJECTION);
  glLoadIdentity;
  gluPerspective(50, ClientWidth/ClientHeight, 1, 1000);
 
  glMatrixMode(GL_MODELVIEW);
  glLoadIdentity;
end;                                                                            /////////////
                                                                                // DESTROY //
                                                                                /////////////
procedure TMainForm.FormDestroy(Sender: TObject);
begin
  DeactivateRenderingContext;
  DestroyRenderingContext(RC);
  ReleaseDC(Handle, DC);
end;
 
 
 
end.
 

Du hast keine ausreichende Berechtigung, um die Dateianhänge dieses Beitrags anzusehen.

Nach oben

Lossy eX

Betreff des Beitrags:

Verfasst: Mi Mär 14, 2007 23:01

DGL Member

Registriert: Do Dez 05, 2002 10:35
Beiträge: 4234
Wohnort: Dortmund

Ja der Alphakanal in der Textur ist Eines aber du musst OpenGL natürlich auch noch sagen was er damit anstellen soll. Bei einem ColorKey genügt ein simpler Alphatest. Bei Semipranzparenzen sollte es dann schon Blending sein.

Das ist ein Alphatest. Das musst du setzen bevor du deine Fläche zeichnest und wenn du es nicht mehr benötigst musst du GL_ALPHA_TEST wieder deaktivieren.

Code:

 glEnable(GL_ALPHA_TEST);
 glAlphaFunc(GL_GREATER, 0.1); 

Nach oben

Ferby

Betreff des Beitrags:

Verfasst: Do Mär 15, 2007 11:39

DGL Member

Registriert: Do Nov 23, 2006 20:44
Beiträge: 21
Wohnort: Wien

Hallo,

danke jetzt geht's

Nach oben

Seite 1 von 1

[ 5 Beiträge ]

Foren-Übersicht » Programmierung » Einsteiger-Fragen

Wer ist online?

Mitglieder in diesem Forum: 0 Mitglieder und 8 Gäste

Du darfst keine neuen Themen in diesem Forum erstellen.
Du darfst keine Antworten zu Themen in diesem Forum erstellen.
Du darfst deine Beiträge in diesem Forum nicht ändern.
Du darfst deine Beiträge in diesem Forum nicht löschen.
Du darfst keine Dateianhänge in diesem Forum erstellen.