DGL • Thema anzeigen - Schaffe es nicht Texturen darzustellen

Schaffe es nicht Texturen darzustellen

Moderator: DGL-Team

Seite 1 von 1

[ 7 Beiträge ]

Vorheriges Thema | Nächstes Thema

Autor

Nachricht

yellow

Betreff des Beitrags: Schaffe es nicht Texturen darzustellen

Verfasst: Sa Feb 18, 2006 18:07

DGL Member

Registriert: Sa Feb 18, 2006 17:51
Beiträge: 3

Hallo Leute,

erstmal Danke dass ihr euch die Mühe gemacht habt die tollen Tutorials zu schreiben.
Allerdings ist es etwas mühsam ohne Beispiel-Quellcode klarzukommen. So ist es mir leider nicht gelungen anhand des 4. Tuts eine Textur auf ein Quad zu zeichnen (es wird nur lediglich ein weißes Quad angezeigt) und ich finde den Fehler einfach nicht. Wäre nett, wenn ihr mal den Code überfliegen könntet und einem verzweifelten Noob seinen Fehler aufzeigt. Danke!

Achja: Die Textur is 256x256, am Format kann es also nicht liegen.

Code:

unit Unit1;
 
interface
 
uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms,
  Dialogs, dglOpenGL, SDL, SDL_Image;
 
type
  TForm1 = class(TForm)
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
    procedure Render;
    procedure OnIdle(Sender: TObject; var Done: Boolean);
  private
    { Private declarations }
 
  public
    { Public declarations }
  end;
 
var
  Form1: TForm1;
  DC, RC :HDC;
  rotation : integer;
 
implementation
 
{$R *.dfm}
 
procedure TexturLaden();
var
  handle : gluint;
  tex : PSDL_Surface;
begin
  tex := IMG_Load('./brick01.jpg');
  if assigned(tex) then
  begin
    glGenTextures(1, addr(handle));
    glBindTexture(GL_TEXTURE_2D, handle);
 
    glTexParameteri(GL_TEXTURE_2D, GL_TEXTURE_MIN_FILTER, GL_LINEAR);
    glTexParameteri(GL_TEXTURE_2D, GL_TEXTURE_MAG_FILTER, GL_LINEAR);
 
    glTexImage2D(GL_TEXTURE_2D, 0, 3, tex^.w, tex^.h,0, GL_RGB, GL_UNSIGNED_BYTE, tex^.pixels);
 
    SDL_FreeSurface(tex);
  end
  else
    MessageBox(0,'Texturenpfad oder Dateiname falsch!',
                        'Fehler beim Laden der Textur!',MB_OK or MB_ICONERROR);
end;
 
procedure TForm1.FormCreate(Sender: TObject);
begin
  InitOpenGL;
 
  TexturLaden();
 
  DC:=GetDC(Handle);
  //GoToFullscreen(1024, 768, 32, 75);
  RC:=CreateRenderingContext(DC, [opDoubleBuffered], 32, 24, 0, 0, 0, 0);
  ActivateRenderingContext(DC, RC);
  glClearColor(0.0, 0.0, 0.0, 0.0);
  Application.OnIdle:=Onidle;
 
  rotation:=0;
end;
 
procedure TForm1.FormDestroy(Sender: TObject);
begin
  DeactivateRenderingContext;
  DestroyRenderingContext(RC);
  ReleaseDC(Handle,DC);
  ChangeDisplaySettings(devmode(nil^), 0);
end;
 
procedure TForm1.Render;
begin
  glMatrixMode(GL_PROJECTION);
  glLoadIdentity;
  glViewport(0, 0, ClientWidth, ClientHeight);
  gluPerspective(60, ClientWidth/ClientHeight,1, 128);
  glMatrixMode(GL_Modelview);
  glLoadIdentity;
  glClear(GL_COLOR_BUFFER_BIT or GL_DEPTH_BUFFER_BIT);
  glTranslatef(0, 0,-6);
  glrotatef(rotation,0,1,0);
 
  //Zeichnen
  glEnable(GL_TEXTURE_2D);
  glBindTexture(GL_TEXTURE_2D, handle);
  glBegin(GL_QUADS);
    glTexCoord2f(0,0); glVertex3f(-1,-1,0);
    glTexCoord2f(0,1); glVertex3f(-1,1,0);
    glTexCoord2f(1,1); glVertex3f(1,1,0);
    glTexCoord2f(1,0); glVertex3f(1,-1,0);
  glEnd;
 
  SwapBuffers(DC);
  rotation:=rotation+1;
end;
 
procedure TForm1.Onidle(Sender: TObject; var Done: Boolean);
begin
  Render;
  Done:= false;
end;
end.

Nach oben

Flash

Betreff des Beitrags:

Verfasst: Sa Feb 18, 2006 18:55

Guitar Hero

Registriert: Do Sep 25, 2003 15:56
Beiträge: 7810
Wohnort: Sachsen - ERZ / C
Programmiersprache: Java (, Pascal)

Sieht eigentlich alles ganz gut aus. Was du mal versuchen solltest ist, das Texturladen am ende der FormCreate auszuführen, da dein Rednercontext zu dem Zeitpunkt noch nicht aktiv ist, und Texturen an selbigem hängen.

_________________
Blog: kevin-fleischer.de und fbaingermany.com

Nach oben

yellow

Betreff des Beitrags:

Verfasst: Sa Feb 18, 2006 19:01

DGL Member

Registriert: Sa Feb 18, 2006 17:51
Beiträge: 3

Danke für die Antwort, aber daran liegt es leider auch nicht

Nach oben

i0n0s

Betreff des Beitrags:

Verfasst: Sa Feb 18, 2006 19:53

Ernährungsberater

Registriert: Sa Jan 01, 2005 17:11
Beiträge: 2068
Programmiersprache: C++

glBindTexture(GL_TEXTURE_2D, handle);
Das Handle ist nicht als Texture bekannt, da du es in der Texturladen-Procedure nur als lokale Variable hast.
Wenn du den Namen änderst (Namenkonflikt) und es zu einer globalen Variablen machst geht es.

Nach oben

yellow

Betreff des Beitrags:

Verfasst: Sa Feb 18, 2006 21:20

DGL Member

Registriert: Sa Feb 18, 2006 17:51
Beiträge: 3

Ah jetzt gehts, danke!

Nach oben

Flash

Betreff des Beitrags:

Verfasst: So Feb 19, 2006 01:55

Guitar Hero

Registriert: Do Sep 25, 2003 15:56
Beiträge: 7810
Wohnort: Sachsen - ERZ / C
Programmiersprache: Java (, Pascal)

Kannst du nochmal folgendes ausprobieren (nur der neugier halber):
Den Code von oben nehmen, und das BindTexture in der renderprocedur rauswerfen.

_________________
Blog: kevin-fleischer.de und fbaingermany.com

Nach oben

ShadowOfSky

Betreff des Beitrags:

Verfasst: So Mär 05, 2006 11:57

DGL Member

Registriert: Sa Mär 04, 2006 22:54
Beiträge: 32

Ich habe das ganze nun auch mal so probiert wie es hier steht und kam erst nicht zu recht :-(

Habe das Handle angepaßt (neuer Name - wegen dem Konflikt mit dem anderem Handle) und mich dann gewundert warum es immer noch nicht ging. Bis ich mir dann den Beitrag von Flash nochmal angeschaut habe und dann die procedure Texturladen an das Ende der Create procedure angehängt habe. Und dann ging alles.

@Flash: ja man kann die Zeile in der Render Procedure weglassen, es geht trotzdem.

_________________
Schönen Gruß, Sky.

Nach oben

Seite 1 von 1

[ 7 Beiträge ]

Foren-Übersicht » Programmierung » Einsteiger-Fragen

Wer ist online?

Mitglieder in diesem Forum: 0 Mitglieder und 3 Gäste

Du darfst keine neuen Themen in diesem Forum erstellen.
Du darfst keine Antworten zu Themen in diesem Forum erstellen.
Du darfst deine Beiträge in diesem Forum nicht ändern.
Du darfst deine Beiträge in diesem Forum nicht löschen.
Du darfst keine Dateianhänge in diesem Forum erstellen.