DGL • Thema anzeigen - SetupPixelFormat!??? und andere Wehwehchen

SetupPixelFormat!??? und andere Wehwehchen

Moderator: DGL-Team

Seite 1 von 1

[ 9 Beiträge ]

Vorheriges Thema | Nächstes Thema

Autor

Nachricht

der-cain

Betreff des Beitrags: SetupPixelFormat!??? und andere Wehwehchen

Verfasst: Mo Nov 21, 2005 17:14

DGL Member

Registriert: Mo Nov 21, 2005 16:59
Beiträge: 3

Hallo zusammen!

Hab vor einigen Tagen angefangen mit mit Opengl zu beschäftigen und habe mir jetzt erstmal vorgenommen eine kleine 2D Demo zu basteln. Allerdings gibt es jetzt schon probleme beim einfachen zeichnen. Ich habe mir eure VCL-Template runtergeladen und die ist auch super, allerdings will er nichts zeichnen

Die Frames werden wie gewünscht ausgegeben, aber von Polygonen keine Spur... Jetzt habe ich in den Soucre Dateien von euch ein paar mal gesehen, dass es immer eine MEthode SetupPixelFormat gibt, habe aber im Online-Wiki keine Infos dazu gefunden. Wozu ist das gut und braucht man diese Methode?
Ich habe auch schon versucht, die Methode zu kopieren und dann aufzurufen, aber das Fenster blieb nach wie vor schwarz...

[edit] achso hab ganz vergessen: Es soll erstmal nur zu Testzwecken ein Dreieck gemalt werden, aber ich denke darauf wärt ihr auch noch gekommen

[/edit]

Ich habe allerdings auch das Gefühl, dass ihr warscheinlich noch andere Fehler finden werdet, aber ich kann mir nicht erklären, warum nichts gezeichnet wird....

Hier der Code:

Code:

 
unit Main;
 
interface
 
uses
  Windows,
  Messages,
  SysUtils,
  Classes,
  Graphics,
  Controls,
  Forms,
  Dialogs,
  Textures,
  dglOpenGL;
 
type
  TGLForm = class(TForm)
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
    procedure ApplicationEventsIdle(Sender: TObject; var Done: Boolean);
    procedure FormKeyPress(Sender: TObject; var Key: Char);
  private
    { Private-Deklarationen }
  public
    RC        : HGLRC;
    DC        : HDC;
    ShowFPS   : Boolean;
    FontBase  : GLUInt;
    StartTick : Cardinal;
    Frames    : Integer;
    FPS       : Single;
    procedure GoToFullScreen(pWidth, pHeight, pBPP, pFrequency : Word);
    procedure BuildFont(pFontName : String);
    procedure PrintText(pX,pY : Integer; const pText : String);
    procedure ShowText;
    procedure DrawDot();
  end;
 
var
  GLForm: TGLForm;
  MyTex : Array[0..5] of glUInt;
 
implementation
 
{$R *.dfm}
 
// =============================================================================
//  TForm1.GoToFullScreen
// =============================================================================
//  Wechselt in den mit den Parametern angegebenen Vollbildmodus
// =============================================================================
procedure TGLForm.GoToFullScreen(pWidth, pHeight, pBPP, pFrequency : Word);
var
 dmScreenSettings : DevMode;
begin
end;
 
// =============================================================================
//  TForm1.BuildFont
// =============================================================================
//  Displaylisten für Bitmapfont erstellen
// =============================================================================
procedure TGLForm.BuildFont(pFontName : String);
var
 Font : HFONT;
begin
// Displaylisten für 256 Zeichen erstellen
FontBase := glGenLists(96);
// Fontobjekt erstellen
Font     := CreateFont(16, 0, 0, 0, FW_MEDIUM, 0, 0, 0, ANSI_CHARSET, OUT_TT_PRECIS, CLIP_DEFAULT_PRECIS,
                       ANTIALIASED_QUALITY, FF_DONTCARE or DEFAULT_PITCH, PChar(pFontName));
// Fontobjekt als aktuell setzen
SelectObject(DC, Font);
// Displaylisten erstellen
wglUseFontBitmaps(DC, 0, 256, FontBase);
// Fontobjekt wieder freigeben
DeleteObject(Font)
end;
 
// =============================================================================
//  TForm1.PrintText
// =============================================================================
//  Gibt einen Text an Position x/y aus
// =============================================================================
procedure TGLForm.PrintText(pX,pY : Integer; const pText : String);
begin
if (pText = '') then
 exit;
glPushAttrib(GL_LIST_BIT);
 glRasterPos2i(pX, pY);
 glListBase(FontBase);
 glCallLists(Length(pText), GL_UNSIGNED_BYTE, PChar(pText));
glPopAttrib;
end;
 
// =============================================================================
//  TForm1.ShowText
// =============================================================================
//  FPS, Hilfstext usw. ausgeben
// =============================================================================
procedure TGLForm.ShowText;
begin
// Tiefentest und Texturierung für Textanzeige deaktivieren
glDisable(GL_DEPTH_TEST);
glDisable(GL_TEXTURE_2D);
// In orthagonale (2D) Ansicht wechseln
glMatrixMode(GL_PROJECTION);
glLoadIdentity;
glOrtho(0,640,480,0, -1,1);
glMatrixMode(GL_MODELVIEW);
glLoadIdentity;
PrintText(5,15, FloatToStr(FPS)+' fps');
glEnable(GL_DEPTH_TEST);
glEnable(GL_TEXTURE_2D);
end;
 
// =============================================================================
//  TForm1.FormCreate
// =============================================================================
//  OpenGL-Initialisierungen kommen hier rein
// =============================================================================
procedure TGLForm.FormCreate(Sender: TObject);
begin
// Wenn gewollt, dann hier in den Vollbildmodus wechseln
// Muss vorm Erstellen des Kontextes geschehen, da durch den Wechsel der
// Gerätekontext ungültig wird!
// GoToFullscreen(1024, 768, 32, 75);
                     
// OpenGL-Funtionen initialisieren
InitOpenGL;
// Gerätekontext holen
DC := GetDC(Handle);
// Renderkontext erstellen (32 Bit Farbtiefe, 24 Bit Tiefenpuffer, Doublebuffering)
RC := CreateRenderingContext(DC, [opDoubleBuffered], 32, 24, 0, 0, 0, 0);
// Erstellten Renderkontext aktivieren
ActivateRenderingContext(DC, RC);
// Tiefenpuffer aktivieren
glEnable(GL_DEPTH_TEST);
// Nur Fragmente mit niedrigerem Z-Wert (näher an Betrachter) \"durchlassen\"
glDepthFunc(GL_LESS);
// 2D Texturen
glEnable(GL_TEXTURE_2D);
// Löschfarbe für Farbpuffer setzen
glClearColor(0,0,0,0);
// Displayfont erstellen
BuildFont('MS Sans Serif');
// Idleevent für Rendervorgang zuweisen
Application.OnIdle := ApplicationEventsIdle;
// Zeitpunkt des Programmstarts für FPS-Messung speichern
StartTick := GetTickCount;
// Textur namens 'dot.tga' laden
LoadTexture('images\dot.tga', MyTex[0], False); // <--- den Befehl könnt ihr löschen, soweit bin ich noch nich <!-- s:P --><img src=\"{SMILIES_PATH}/icon_razz.gif\" alt=\":P\" title=\"Razz\" /><!-- s:P -->
end;
 
// =============================================================================
//  TForm1.DrawDot
// =============================================================================
//  Hier wird ein Rechteck gemalt und mit der Textur belegt
// =============================================================================
procedure TGLForm.DrawDot(); // Warum wird hier nix gezeichnet???
begin
glTranslatef(-1.5, 0,-6);
glBegin(GL_TRIANGLES);
  glVertex3f(-1,-1, 0);  
  glVertex3f( 1,-1, 0);
  glVertex3f( 0, 1, 0);
glEnd;
end;
 
// =============================================================================
//  TForm1.FormDestroy
// =============================================================================
//  Hier sollte man wieder alles freigeben was man so im Speicher belegt hat
// =============================================================================
procedure TGLForm.FormDestroy(Sender: TObject);
begin
// Renderkontext deaktiveren
DeactivateRenderingContext;
// Renderkontext \"befreien\"
wglDeleteContext(RC);
// Erhaltenen Gerätekontext auch wieder freigeben
ReleaseDC(Handle, DC);
// Falls wir im Vollbild sind, Bildschirmmodus wieder zurücksetzen
ChangeDisplaySettings(devmode(nil^), 0);
end;
 
// =============================================================================
//  TForm1.ApplicationEventsIdle
// =============================================================================
//  Hier wird gerendert. Der Idle-Event wird bei Done=False permanent aufgerufen
// =============================================================================
procedure TGLForm.ApplicationEventsIdle(Sender: TObject; var Done: Boolean);
begin
// In die Projektionsmatrix wechseln
glMatrixMode(GL_PROJECTION);
// Identitätsmatrix laden
glLoadIdentity;
// Viewport an Clientareal des Fensters anpassen
glViewPort(0, 0, ClientWidth, ClientHeight);
// 2D Perspektive definieren
glOrtho(0,640,480,0, 0,128);
 
// In die Modelansichtsmatrix wechseln
glMatrixMode(GL_MODELVIEW);
// Identitätsmatrix laden
glLoadIdentity;
// Farb- und Tiefenpuffer löschen
glClear(GL_COLOR_BUFFER_BIT or GL_DEPTH_BUFFER_BIT);
 
DrawDot();
ShowText;
 
// Hinteren Puffer nach vorne bringen
SwapBuffers(DC);
 
// Windows denken lassen, das wir noch nicht fertig wären
Done := False;
 
// Nummer des gezeichneten Frames erhöhen
inc(Frames);
// FPS aktualisieren
if GetTickCount - StartTick >= 500 then
 begin
 FPS       := Frames/(GetTickCount-StartTick)*1000;
 Frames    := 0;
 StartTick := GetTickCount
 end;
end;
 
// =============================================================================
//  TForm1.FormKeyPress
// =============================================================================
 
procedure TGLForm.FormKeyPress(Sender: TObject; var Key: Char);
begin
case Key of
 #27 : Close;
end;
end;
 
end.
 

Ich bedanke mich im Vorraus

MfG Marius

Nach oben

Axalus

Betreff des Beitrags:

Verfasst: Mo Nov 21, 2005 17:56

DGL Member

Registriert: Mo Nov 21, 2005 17:11
Beiträge: 10
Wohnort: Siegburg

kann mir mal endlich bitte bitte sagen was ihr für lektüre benutzt???
ich hab über all gesucht aber nix für delphi opengl oder delphigl gefunden ausser euren tutorials!
bitte antwortet mir!
*verzweifel*

Nach oben

der-cain

Betreff des Beitrags:

Verfasst: Mo Nov 21, 2005 18:08

DGL Member

Registriert: Mo Nov 21, 2005 16:59
Beiträge: 3

was meinst du denn überhaupt?

mit den tutorials im dgl wiki kann man doch schon einiges anfangen...

http://wiki.delphigl.com/index.php/Tutorial

Nach oben

Lossy eX

Betreff des Beitrags:

Verfasst: Mo Nov 21, 2005 18:11

DGL Member

Registriert: Do Dez 05, 2002 10:35
Beiträge: 4234
Wohnort: Dortmund

Axalus. So läuft das hier nicht ab! Es kann nicht angehen, dass du ständig in anderen Themen deine völlig Themenfremden Fragen postest. Erstelle ein eigenes Thema oder bleib bei dem Thema was ich aus deinem ersten Beitrag erstellt habe. Wenn du konkrete Problem hast, dann kannst du diese im Forum auch stellen und dir wird geholfen. In einem eigenen Thema versteht sich. Für alles andere gibt es noch das Wiki was für genau solche Probleme auch gemacht wurde.

Nach oben

La Boda

Betreff des Beitrags:

Verfasst: Mo Nov 21, 2005 18:12

DGL Member

Registriert: Mi Jul 17, 2002 12:07
Beiträge: 976
Wohnort: Tübingen

@der-cain:
Verschieb mal die Zeile "glClear(GL_COLOR_BUFFER_BIT or GL_DEPTH_BUFFER_BIT);" an den Anfang der Prozedur.
Außerdem füg mal, nur zu Testzwecken (Ich weiss, dass du 2d brauchst), statt glOrtho diese Zeile ein:

Code:

gluPerspective(90, GLForm.ClientWidth/GLForm.ClientHeight, 1, 128);

Schreib mir dann mal, obs geht.

_________________
"Du musst ein Schwein sein in dieser Welt, sangen die Prinzen, das ist so 1.0. Du musst auf YouTube zeigen, dass dir dein Schweinsein gefällt, das ist leuchtendes, echtes Web 2.0."
- Hal Faber
Meine Homepage: http://laboda.delphigl.com

Nach oben

i0n0s

Betreff des Beitrags:

Verfasst: Mo Nov 21, 2005 18:15

Ernährungsberater

Registriert: Sa Jan 01, 2005 17:11
Beiträge: 2068
Programmiersprache: C++

Im Orthomodus bewegst du dich mit - aus dem sichtbaren Bereich.
Probier es mal mit:

Code:

procedure TGLForm.DrawDot(); // Warum wird hier nix gezeichnet???
begin
  glTranslatef(150, 150,-6);
  glBegin(GL_TRIANGLES);
    glVertex3f(-10,-10, 0);
    glVertex3f( 10,-10, 0);
    glVertex3f( 0, 10, 0);
  glEnd;
end;

Oder das was La Boda geschrieben hat.

Übrigens versuch mal ein 1 Pixel grosses Dreieck auf einem 640*480 grossen Fenster zu sehen

Im Orthomodus definierst du die Grösse der "Weltkoordinaten"

Nach oben

La Boda

Betreff des Beitrags:

Verfasst: Mo Nov 21, 2005 18:19

DGL Member

Registriert: Mi Jul 17, 2002 12:07
Beiträge: 976
Wohnort: Tübingen

Jetzt wos i0n0s schreibt, fällts mir auch auf.

Code:

glOrtho(0,640,480,0, 0,128);

Hier musst du nicht die \"Auflösung\" eingeben, das machst du mit glViewport.
Hier gibst du praktisch die Weltkoordinaten an mit denen du einen Obejkte später verschiebst. Und in der Tat ist ein ein Pixel großes Dreieck ziemlich verloren in so ner großen, schwarzen Fläche $\";)\"$

Recht angenehme Werte wären also

Code:

glOrtho(-10, 10, -10, 10, 0,128);

Nach oben

der-cain

Betreff des Beitrags:

Verfasst: Mo Nov 21, 2005 18:23

DGL Member

Registriert: Mo Nov 21, 2005 16:59
Beiträge: 3

juhu danke ionos und boda das war die lösung.... scheint ale müsste ich mir die sache mit der kamera nochmal ansehen *g*

also erstmal vielen Dank, ich meld mich dann wieder

Nach oben

Lossy eX

Betreff des Beitrags:

Verfasst: Mo Nov 21, 2005 18:25

DGL Member

Registriert: Do Dez 05, 2002 10:35
Beiträge: 4234
Wohnort: Dortmund

Cain: Habe bei dir mal die Pascaltags hinzugefügt. Das ist für Delphicode besser als die Codetags.

Zu deiner Frage. Wenn die Methode kein GL oder WGL voranstehen hat oder sonst von OpenGL Handelt, dann ist die Wahrscheinlichkeit groß, dass diese Methode von Windows stammt oder eine eigene ist. Für den Fall, dass diese von Windows stammt gibt es die MSDNs und da findet man auch eine Beschreibung zu SetPixelFormat. Aber in deinem Fall brauchst du dich darum nicht zu kümmern, da der Aufruf von SetupPixelFormat bereits in der Methode CreateRenderContext statt findet. Diese Methode stammt aus dem OpenGL Header und erstellt ohne Umwege einen gültigen Context.

Zu dem warum du nichts siehst.

In dem ShowText setzt du noch einmal den 2D Modus. Den setzt du aber bereits in ApplicationOnIdle. Den ViewPort und das glOrtho solltest du eigentlich auch nur setzen, wenn sich die Größe des Fenster ändert. Also würde es bei einem fixen Fenster genügen, wenn du dies direkt nach dem Initialisieren deines RCs setzt.

Sonst Hat i0n0s recht. Das Greieck verschiebst du in den unsichtbaren bereich. Du könntest das Translate auch erst mal komplett weg lassen.

Angaben bei glOrtho: Das kommt immer darauf an was man vor hat. Ich verwende bei glOtho IMMER die Auflösung des Viewports. Ich will aber auch IMMER Pixelgenau zeichnen. Wenn du das nicht vorhättest würden auch andere Werte funktionieren. Kommt da auch drauf an wie du es gerne am liebsten hast.

Nach oben

Seite 1 von 1

[ 9 Beiträge ]

Foren-Übersicht » Programmierung » Einsteiger-Fragen

Wer ist online?

Mitglieder in diesem Forum: 0 Mitglieder und 3 Gäste

Du darfst keine neuen Themen in diesem Forum erstellen.
Du darfst keine Antworten zu Themen in diesem Forum erstellen.
Du darfst deine Beiträge in diesem Forum nicht ändern.
Du darfst deine Beiträge in diesem Forum nicht löschen.
Du darfst keine Dateianhänge in diesem Forum erstellen.