DGL • Thema anzeigen - Text wird nicht angezeigt

Text wird nicht angezeigt

Moderator: DGL-Team

Seite 1 von 1

[ 7 Beiträge ]

Vorheriges Thema | Nächstes Thema

Autor

Nachricht

SunBlack

Betreff des Beitrags: Text wird nicht angezeigt

Verfasst: Sa Mär 31, 2007 19:29

DGL Member

Registriert: Di Jan 24, 2006 18:46
Beiträge: 97

Hallo,

in Englisch sollen wir irgendeine kreative Arbeit vollbringen zum Theman Globalisierung. Sie hatte zum Beispiel vorgeschlagen, dass wir uns ein Gedicht bzw. Lied ausdenken. Da ich dazu keine Luste habe, will ich ne OGL-Animation machen (damit ich OpenGl nicht verlerne :mrgreen:

).
Nun ja: Ich scheitere gerade am Text. IMHO sollte der ausgegeben werden, aber leider tut er das nicht. Ich bekomme auch kein OGL-Fehler zurückgeliefert

Code:

unit Unit1;
 
interface
 
uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, dglOpengl, Math;
 
type
  TForm1 = class(TForm)
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
    procedure FormResize(Sender: TObject);
    procedure FormPaint(Sender: TObject);
    procedure FormKeyDown(Sender: TObject; var Key: Word; Shift: TShiftState);
    procedure FormClose(Sender: TObject; var Action: TCloseAction);
    procedure FormActivate(Sender: TObject);
  private
    { Private-Deklarationen }
    procedure SetOpenGLSettings;
    procedure DrawDefaultWorld;
  public
    { Public-Deklarationen }
  end;
 
var
  Form1: TForm1;
  DC   : HDC  ;
  RC   : HGLRC;
  Break: Boolean = false;
  FontLists: Cardinal;
 
implementation
 
{$R *.dfm}
 
procedure TForm1.FormActivate(Sender: TObject);
begin
 { BorderStyle:=bsNone;
  WindowState:=wsMaximized;
  ShowCursor(false) }
end;
 
procedure TForm1.FormClose(Sender: TObject; var Action: TCloseAction);
begin
  Break:=true;
end;
 
procedure TForm1.FormCreate(Sender: TObject);
const
  MemoryDCs = [OBJ_MEMDC, OBJ_METADC, OBJ_ENHMETADC];
var
  pfd  : TPixelFormatDescriptor;
  pf   : Integer;
  AType: DWORD;
  Error: Boolean;
begin
  Error:=true;
 
  DC   := GetDC(Handle);
  RC   := 0;
  if DC<>0 then
  begin
    if InitOpenGL then
    begin
      AType:= GetObjectType(DC);
      if AType<>0 then
      begin
        ZeroMemory(@pfd, SizeOf(TPixelFormatDescriptor));
        with pfd do
        begin
          nSize   := SizeOf(TPixelFormatDescriptor);
          nVersion:= 1;
          dwFlags := PFD_SUPPORT_OPENGL;
          if AType in MemoryDCs then dwFlags:= dwFlags or PFD_DRAW_TO_BITMAP
                                else dwFlags := dwFlags or PFD_DRAW_TO_WINDOW;
          dwFlags := dwFlags or PFD_DOUBLEBUFFER;
          iPixelType   := PFD_TYPE_RGBA;
          cColorBits   := 32;
          cDepthBits   := 24;
          cStencilBits := 0;
          cAccumBits   := 0;
          cAuxBuffers  := 0;
          iLayerType := PFD_MAIN_PLANE;
        end;
        pf := ChoosePixelFormat(DC, @pfd);
        if pf<>0 then
        begin
          if GetPixelFormat(DC) <> pf then
          begin
             if SetPixelFormat(DC, pf, @pfd) then
             begin
               DescribePixelFormat(DC, pf, SizeOf(TPixelFormatDescriptor), pfd);
               RC := wglCreateContext(DC);
             end;
          end
          else
          begin
            DescribePixelFormat(DC, pf, SizeOf(TPixelFormatDescriptor), pfd);
            RC := wglCreateContext(DC);
          end;
          if RC<>0 then
          begin
            if wglMakeCurrent(DC, RC) then
            begin
              ReadExtensions;
              ReadImplementationProperties;
 
              SetOpenGLSettings;
              Font.Style:=[fsBold];
              Font.Size:=25;
              SelectObject(DC, Canvas.Font.Handle);
              wglUseFontBitmaps (DC, 0, 255, FontLists);
              glListBase(FontLists);
 
              Error:=false;
            end
            else wglMakeCurrent(DC, 0);
          end
        end
      end
    end
  end;
  if error then
  begin
    Application.MessageBox('Der Rendercontext konnte nicht erstellt werden!',
                           'Fehler', 16);
    halt;
  end;
end;
 
procedure TForm1.FormDestroy(Sender: TObject);
begin
  wglMakeCurrent(DC, 0);
  wglDeleteContext(RC);
  ReleaseDC(Handle, DC);
end;
 
procedure TForm1.FormKeyDown(Sender: TObject; var Key: Word;
  Shift: TShiftState);
begin
  if Key=VK_F10 then
  begin
    if BorderStyle = bsNone then
    begin
      BorderStyle:=bsSizeable;
      WindowState:=wsNormal;
    end
    else
    begin
      BorderStyle:=bsNone;
      WindowState:=wsMaximized;
    end;
  end;
end;
 
procedure TForm1.SetOpenGLSettings;
begin
  glHint(GL_PERSPECTIVE_CORRECTION_HINT, GL_FASTEST);
  glDepthFunc(GL_LEQUAL);
  glEnable(GL_DEPTH_TEST);
  glEnable(GL_CULL_FACE);
  glDepthMask(True);
  glClearDepth(1);
  glDisable(GL_BLEND);
  glDisable(GL_ALPHA_TEST);
  glEnable(GL_COLOR_MATERIAL);
 
  glClearColor(0.66, 0.84, 1, 0);
end;
 
procedure TForm1.FormPaint(Sender: TObject);
var
  t, tb, tbc: Cardinal;
begin
  OnPaint:=nil;
  t:=GetTickCount;
  tb:=0;
  tbc:=0;
  while (not Break) and (tb<5000) do
  begin
    glClear(GL_DEPTH_BUFFER_BIT or GL_COLOR_BUFFER_BIT );
    glCallLists(13, GL_UNSIGNED_BYTE, PChar('Globalization'));
    Form1.Caption:=gluErrorString(glGetError);
    SwapBuffers(DC);
    
    tbc:=GetTickCount-t-tb;
    inc(tb, tbc);
    Application.ProcessMessages;
  end;
 
  tb:=0;
  tbc:=0;  
{  while (not Break) and (tb<5000) do
  begin
 
    glTranslatef(-tbc/5000, 0, 0);
    DrawDefaultWorld;
    SwapBuffers(DC);
 
    tbc:=GetTickCount-t-tb;
    inc(tb, tbc);
    Application.ProcessMessages;
  end; }
end;
 
procedure TForm1.FormResize(Sender: TObject);
var
  CS: array[0..1] of Integer;
  DWidth, DHeight: Integer;
begin
  glGetIntegerv(GL_MAX_VIEWPORT_DIMS, @CS);
  DWidth :=  Min(CS[0], Width);
  DHeight := Min(CS[1], Height);
 
  glViewport(0, 0, DWidth, DHeight);
 
  glMatrixMode(GL_PROJECTION);
  glLoadIdentity();
 
  glOrtho(0, 1, 0, Width/Height, -1, 1);
 
  glMatrixMode(GL_MODELVIEW);
  glLoadIdentity();
end;
 
procedure TForm1.DrawDefaultWorld;
var
  i: integer;
begin
  glColor3ub(0, 196, 0);
  glBegin(GL_QUADS);
    glVertex2f(0, 0);
    glVertex2f(5, 0);
    glVertex2f(5, 0.25);
    glVertex2f(0, 0.25);
  glEnd;
  glColor3ub(196, 196, 196);
  glBegin(GL_QUADS);
    glVertex2f(0, 0.0625);
    glVertex2f(5, 0.0625);
    glVertex2f(5, 0.1875);
    glVertex2f(0, 0.1875);
  glEnd;
  glColor3ub(255, 255, 255);
  glBegin(GL_QUADS);
  for i := 0 to 127 do
  begin
    glVertex2f(i*0.02      , 0.1225);
    glVertex2f(i*0.02+0.01 , 0.1225);
    glVertex2f(i*0.02+0.012, 0.1275);
    glVertex2f(i*0.02+0.002, 0.1275);
  end;
  glEnd;
end;
 
end.

Sieht einer von euch den Fehler? Ach so, wo ich gerade bei TExt bin: Gibts die Möglichkeit ihn zentriert anzufassen, so wie es mitm Canvas möglich ist (durch die OGL-Listen wird das ja bestimmt nicht gehen)?

Nach oben

SunBlack

Betreff des Beitrags:

Verfasst: So Apr 01, 2007 10:10

DGL Member

Registriert: Di Jan 24, 2006 18:46
Beiträge: 97

glPushAttrib(GL_ALL_ATTRIB_BITS); und glPopAttrib hat gefehlt

. Habe ich gerade mitbekommen, nachdme ich mir von einem anderem die Unit angeguckt hatte. Schade, dass es im wiki nicht dazustand

Nach oben

SunBlack

Betreff des Beitrags:

Verfasst: So Apr 01, 2007 11:29

DGL Member

Registriert: Di Jan 24, 2006 18:46
Beiträge: 97

Gibt es eigentlich die Möglichkeit, die Position zu reseten? Denn glRasterPos ist bei mir leider teilweise ungeeignet, da es scheinbar ein bissl Bildschirmgrößenabhängig ist (oder Schriftgrößenabhängig...)

Nach oben

Lossy eX

Betreff des Beitrags:

Verfasst: So Apr 01, 2007 12:44

DGL Member

Registriert: Do Dez 05, 2002 10:35
Beiträge: 4234
Wohnort: Dortmund

Wie meinst du das mit glRasterPos? Das was du dort übergibst richtet sich danach was du bei glOrtho übergeben hast. Und du übergibst dort Werte zwischen 0 und 1. Wenn du jetzt das Fenster vergrößerst ist es vollkommen logisch, dass sich die Abstände zwischen dem Text verändern, da 0.1 vorher irgendwas an die 64 Pixel war und jetzt auf einmal 80 Pixel sind.

Bei glOrtho finde ich es am Besten, wenn man die genau Höhe des Fensters abgibt. In wenigen Fällen mag das auch Sinn machen aber bei Text etc arbeite ich immer mit den genauen Fenstergrößen. Das ist zu mindest meine Meinung.

Nach oben

SunBlack

Betreff des Beitrags:

Verfasst: So Apr 01, 2007 12:54

DGL Member

Registriert: Di Jan 24, 2006 18:46
Beiträge: 97

Wenns nur text wäre, wäre es sicherlich besser. Nur habe ich später dann noch Bilder, die somit automatisch an die Größe des Fensters skaliert werden sollten (was auch passiert)

.

Gibts da irgendeine Variante, den Text zu zentrieren (also zu 0,5)?

Nach oben

SunBlack

Betreff des Beitrags:

Verfasst: So Apr 01, 2007 13:14

DGL Member

Registriert: Di Jan 24, 2006 18:46
Beiträge: 97

Mhm, das Problem gefunden

. Durch diese beiden zeile hier

Code:

wglUseFontBitmaps (DC, 0, 255, FontLists);
glListBase(FontLists);

Hat sich das ganze schon verschoben. Und da diese beiden Zeilen beim verändern der Fenstergröße aufgerufen wurden, gabs dem entsprechend verschiebungen, die ich nicht wollte...

Nach oben

SunBlack

Betreff des Beitrags:

Verfasst: Mo Apr 02, 2007 18:23

DGL Member

Registriert: Di Jan 24, 2006 18:46
Beiträge: 97

So langsam verzweifle ich an der Schrift. Sie funktioniert jetzte so, wie ich es will, aber über Wege, di9e nicht gerade schön sind

Code:

procedure SetFontSize(FontSize: Integer);
begin
  glPushAttrib(GL_ALL_ATTRIB_BITS);
    CurFontSize:=FontSize;
    Form1.Canvas.Font.Height:=round(FontSize*Form1.ClientWidth/500);
    SelectObject(DC, Form1.Canvas.Font.Handle);
    wglUseFontBitmaps (DC, 0, 255, FontLists);
    glListBase(FontLists);
  glPopAttrib;
end;
 
procedure TForm1.FormPaint(Sender: TObject);
var
  t, tb, tbc: Cardinal;
begin
  OnPaint:=nil;
  FormResize(Sender);
  SetFontSize(75);
  t:=GetTickCount;
  tb:=0;
  tbc:=0;
  while (not Break) and (tb<2500) do
  begin
    glClear(GL_DEPTH_BUFFER_BIT or GL_COLOR_BUFFER_BIT );
    glColor3ub(tb*196 div 2500, tb*196 div 2500, tb*255 div 2500);
    glPushAttrib(GL_ALL_ATTRIB_BITS);
      glRasterPos2f(0.12, 0.5);
      glCallLists(13, GL_UNSIGNED_BYTE, PChar('...'));
    glPopAttrib;
 
    SwapBuffers(DC);
 
    tbc:=GetTickCount-t-tb;
    inc(tb, tbc);
    Application.ProcessMessages;
  end;
...
end;
 
procedure TForm1.FormResize(Sender: TObject);
var
  CS: array[0..1] of Integer;
  DWidth, DHeight: Integer;
begin
  glGetIntegerv(GL_MAX_VIEWPORT_DIMS, @CS);
  DWidth :=  Min(CS[0], ClientWidth);
  DHeight := Min(CS[1], ClientHeight);
 
  glViewport(0, 0, DWidth, DHeight);
 
  glMatrixMode(GL_PROJECTION);
  glLoadIdentity();
 
  glOrtho(0, 1, 0, DHeight/DWidth, -1, 1);
 
  glMatrixMode(GL_MODELVIEW);
  glLoadIdentity();
  SetFontSize(CurFontSize);
  if Assigned(OnPaint) then OnPaint(Sender);
end;

Was daran komisch ist, dürfte eigentlich auffallen. Ich brauche 2x SetSizeFont, damit er die größe auch wirklich verändert. Sobald ich eins der beiden Wegnehme, funktionietr es nicht mehr...

Nach oben

Seite 1 von 1

[ 7 Beiträge ]

Foren-Übersicht » Programmierung » OpenGL

Wer ist online?

Mitglieder in diesem Forum: 0 Mitglieder und 2 Gäste

Du darfst keine neuen Themen in diesem Forum erstellen.
Du darfst keine Antworten zu Themen in diesem Forum erstellen.
Du darfst deine Beiträge in diesem Forum nicht ändern.
Du darfst deine Beiträge in diesem Forum nicht löschen.
Du darfst keine Dateianhänge in diesem Forum erstellen.