{$optimize-}

program VertexProgram1;

uses arb_vertex_program, arb_position_invariant;

 

// input:

// texture #0 = color map

// texture #1 = normal map

// texture #2 = offset map

// vertex.attrib[6] = tangent

 

// output:

// texcoord[0] offset in texture map

// texcoord[1] tangent space light0 vector

// texcoord[2] tangent space eye vector

 

// remarks

// binormal is computed on the fly

// light is taken from light source 0

// viewer position is taken from modelview.invtrans

 

var

  binormal, eyevec,

  light0pos, light0vec: vec4;

 

begin

  // compute binormal

  binormal := cross(vertex.attrib[6], vertex.normal);

 

  // vector pointing to light 0

  with state do

    light0pos := MatrixMult4(matrix.modelview.inverse, light[0].position);

  light0vec := vertex.position - light0pos;

 

  // transform light0 vector into tangent space

  with vertex do

    result.texcoord[1] := MatrixMult3(Matrix(attrib[6], binormal, normal), light0vec);

  result.texcoord[1].w := 1.0;

 

  // vector pointing to eye

  eyevec := vertex.position - state.matrix.modelview.invtrans.row[3];

 

  // transform eye vector into tangent space

  with vertex do

    result.texcoord[2] := MatrixMult3(Matrix(attrib[6], binormal, normal), eyevec);

  result.texcoord[2].w := 1.0;

 

  result.color:=vertex.color;

  result.texcoord[0]:=vertex.texcoord[0];

end;

 

{$optimize-}

program FragmentProgram1;

uses arb_fragment_program;

 

// input:

// texture #0 = color map

// texture #1 = normal map

// texture #2 = offset map

// texcoord[0] offset in texture map

// texcoord[1] tangent space light0 vector

// texcoord[2] tangent space eye vector

 

var

  eyevects,

  rgb, normal, height, bump, total,

  light0tsvec,

  newtexcoord: vec4;

 

begin

  // normalize tangent space eye vector

  eyevects := normalize(fragment.texcoord[2]);

 

  // calculate offset and new texture coordinate

  height := texture2d(2, fragment.texcoord[0]);

  newtexcoord := (height * 0.04 - 0.02) * eyevects + fragment.texcoord[0];

 

  // get texture data

  rgb := texture2d(0, newtexcoord);

  normal := normalize(texture2d(1, newtexcoord) * 2.0 - 1.0);

 

  // normalize light0 vector

  light0tsvec := normalize(fragment.texcoord[1]);

 

  // normal dot lightdir

  bump := dot3(normal, light0tsvec);

 

  // compute total effect

  total := sat(bump * state.light[0].diffuse + state.lightmodel.ambient);

 

  // and multiply by regular texture map color

  result.color := sat(rgb * total);

end;