DGL • Thema anzeigen - Normalmapping - Fragmentshader kompiliert nicht

Normalmapping - Fragmentshader kompiliert nicht

Moderator: DGL-Team

Seite 1 von 1

[ 4 Beiträge ]

Druckansicht

Vorheriges Thema | Nächstes Thema

Autor

Nachricht

OpenglerF

Betreff des Beitrags: Normalmapping - Fragmentshader kompiliert nicht

Verfasst: Di Mai 15, 2012 21:16

DGL Member

Registriert: Do Dez 29, 2011 19:40
Beiträge: 421
Wohnort: Deutschland, Bayern
Programmiersprache: C++, C, D, C# VB.Net

Mein Normalmappingshader weigert sich momentan vehement, sich kompilieren zu lassen.
Das komische daran ist bloß, dass die ShaderInfo scheinbar leer ist.
Erst beim Linken kommt dann die Meldung: "fragmentinfo: fatal error C9999"

Der Quellcode:

Code:

#version 120
 
uniform sampler2D Texture;
uniform sampler2D NormalMap;
uniform float TexNormalScale;
 
varying vec3 Normal;
varying vec3 PixPos;
 
vec3 Mul(vec2 Vec, mat2x3 M)
{
    return vec3(Vec[0][0] * Vec.x + Vec[1][0] * Vec.y,
                Vec[0][1] * Vec.x + Vec[1][1] * Vec.y,
                Vec[0][2] * Vec.x + Vec[1][2] * Vec.y);
}
mat3 ComputeTBN(vec3 Normal, vec3 Position, vec2 TexCoords)
{
    vec3 EdgeFaceA = dFdx(Position);
    vec3 EdgeFaceB = dFdy(Position);
    vec2 UvEdgeA = dFdx(TexCoords);
    vec2 UvEdgeB = dFdy(TexCoords);
 
    mat2x3 M = mat2x3(EdgeFaceA, EdgeFaceB);
    vec3 Tangent = Mul(vec2(UvEdgeA.x, UvEdgeB.x), M);
    vec3 Bitangent = Mul(vec2(UvEdgeA.y, UvEdgeB.y), M);
 
    float MaxL = max(length(Tangent), length(Bitangent));
    return mat3(Tangent / MaxL, Bitangent / MaxL, Normal);
} 
 
void main()
{
    vec3 Shaded = vec3(gl_FrontMaterial.emission);
    vec3 EyeVector = normalize(-PixPos);
    vec3 Normal = normalize(Normal);
    mat3 TBN = ComputeTBN(Normal, PixPos, gl_TexCoord[0].st);
    
    Normal = TBN * vec3(texture2D(NormalMap, gl_TexCoord[0].st) - 0.5f);
 
    int i;
    for(i = 0; i < 2; i++)
    {
        vec3 LightDirection = normalize(vec3(gl_LightSource[i].position) - PixPos);
        vec3 ReflectVector = normalize(reflect(-LightDirection, Normal)); 
 
        //Ambient
        Shaded += vec3(gl_LightSource[i].ambient) * vec3(gl_FrontMaterial.ambient);
        //Diffuse
        Shaded += vec3(gl_LightSource[i].diffuse) * vec3(gl_FrontMaterial.diffuse) * max(dot(Normal, LightDirection), 0.0);
        //Specular
        Shaded += vec3(gl_LightSource[i].specular) * vec3(gl_FrontMaterial.specular) * pow(max(dot(ReflectVector, EyeVector), 0.0), gl_FrontMaterial.shininess);
    }
    gl_FragColor = vec4(Shaded, 1.0) * gl_Color * texture2D(Texture, gl_TexCoord[0].st);
}

Ich hoffe ihr wisst Rat.

Nach oben

Schläfer

Betreff des Beitrags: Re: Normalmapping - Fragmentshader kompiliert nicht

Verfasst: Mi Mai 16, 2012 15:51

DGL Member

Registriert: Fr Okt 03, 2008 13:32
Beiträge: 367

In Zeile 12 bis 14 benutzt du "Vec" als Matrix, sicherlich sollte das "M" gewesen sein.

Nach oben

OpenglerF

Betreff des Beitrags: Re: Normalmapping - Fragmentshader kompiliert nicht

Verfasst: Do Mai 17, 2012 11:07

DGL Member

Registriert: Do Dez 29, 2011 19:40
Beiträge: 421
Wohnort: Deutschland, Bayern
Programmiersprache: C++, C, D, C# VB.Net

Ahhhh!
Danke, da stand ich ja völlig auf dem Schlauch!

Kompiliert jetzt hervorragend, sieht allerdings eher mies aus.
Man sieht vor lauter grauem Geflimmer gar nichts.

Dateianhänge:

Dateikommentar: Bildfehler

Schach.png [ 217.57 KiB | 4760-mal betrachtet ]

Nach oben

Coolcat

Betreff des Beitrags: Re: Normalmapping - Fragmentshader kompiliert nicht

Verfasst: Do Mai 17, 2012 11:37

DGL Member

Registriert: Do Dez 29, 2005 12:28
Beiträge: 2249
Wohnort: Düsseldorf
Programmiersprache: C++, C#, Java

Ich vermute mal es liegt darin das du bei der Berechnung deiner TBN-Matrix nicht darauf achtest das alle Basisvektoren die Länge 1 haben und orthogonal zueinander liegen. Du willst schließlich die Normale nur rotieren, nicht skalieren oder scheren.

Des weiteren ist es eher schlecht das Tangente und Bitangente über die Ableitung der Texturkoordinaten zu berechnen. Damit hängt die Berechnung nämlich von der Kameraposition ab....je nach Kameraausrichtung bekommst du unterschiedliche Resultate. D.h. es könnte bei Kamerabewegungen flimmern.

Es empfiehlt sich die Tangente im voraus zu berechnen (etwa: http://www.terathon.com/code/tangent.html ) und pro Vertex zu speichern. Ggf. kann dein 3D-Modelingprogramm mit dem du deine Modelle erstellst sogar schon eine Tangente mit exportieren. Jedenfalls dann im Fragmentshader Normale und Tangente beide normalisieren und dann via Kreuzprodukt die Bitangente berechnen.

_________________
Yeah! :mrgreen:

Nach oben

Seite 1 von 1

[ 4 Beiträge ]

Foren-Übersicht » Programmierung » Shader

Wer ist online?

Mitglieder in diesem Forum: 0 Mitglieder und 6 Gäste

Du darfst keine neuen Themen in diesem Forum erstellen.
Du darfst keine Antworten zu Themen in diesem Forum erstellen.
Du darfst deine Beiträge in diesem Forum nicht ändern.
Du darfst deine Beiträge in diesem Forum nicht löschen.
Du darfst keine Dateianhänge in diesem Forum erstellen.