DGL • Thema anzeigen - Polygon füllen

Polygon füllen

Moderator: DGL-Team

Seite 1 von 1

[ 4 Beiträge ]

Vorheriges Thema | Nächstes Thema

Autor

Nachricht

TAK2004

Betreff des Beitrags: Polygon füllen

Verfasst: Mo Sep 17, 2007 16:17

DGL Member

Registriert: Di Mai 18, 2004 16:45
Beiträge: 2623
Wohnort: Berlin
Programmiersprache: Go, C/C++

Ich habe folgendendes Szenario.
Eine Vertexliste mit Vertice, die miteinander verbunden, die Kontur einer Form ergeben.
Also über GL_LINES den Rahmen zeichnet.
Nun will ich aber die Form ausfüllen und dazu muss ich eine 2. Liste erstellen, wo ich dann über GL_TRIANGLES die Form füllen kann.
Das zauberwort ist Triangulieren und ich hab auch ein Artikel gefunden http://www-lehre.inf.uos.de/cg2/material/20021218/Tesselation.htm aber entweder ist da ein Fehler drin oder ned genau genug beschrieben( 1.4.1 ).

Kennt jemand ein Algo der Funktioniert(website/pdf) oder hat etwas Code?

_________________
"Wer die Freiheit aufgibt um Sicherheit zu gewinnen, der wird am Ende beides verlieren"
Benjamin Franklin

Projekte: https://github.com/tak2004

Nach oben

The-Winner

Betreff des Beitrags:

Verfasst: Mo Sep 17, 2007 16:20

DGL Member

Registriert: Di Jun 06, 2006 09:59
Beiträge: 474

Sind deine Vielecke konvex und planar?

_________________

Nach oben

TAK2004

Betreff des Beitrags:

Verfasst: Mo Sep 17, 2007 16:39

DGL Member

Registriert: Di Mai 18, 2004 16:45
Beiträge: 2623
Wohnort: Berlin
Programmiersprache: Go, C/C++

Dies sollte es besser veranschaulichen.

_________________
"Wer die Freiheit aufgibt um Sicherheit zu gewinnen, der wird am Ende beides verlieren"
Benjamin Franklin

Projekte: https://github.com/tak2004

Nach oben

TAK2004

Betreff des Beitrags:

Verfasst: Di Sep 18, 2007 03:40

DGL Member

Registriert: Di Mai 18, 2004 16:45
Beiträge: 2623
Wohnort: Berlin
Programmiersprache: Go, C/C++

Ich habe das Problem gelöst und werde noch den Code für die Lösung posten.
Die Lösung ist ein sogenanntes Ear Clipping, welches nur bei Polygonen funktioniert, die keine Löscher haben.
Man kann Polygone mit Löscher auch mit einen Ear Clipping Algo lösen, wenn man ein Punkt des Loches und ein Punkt auf der Convehülle als Kante definiert und somit die Reihenfolge neu berechnet. Mehr dazu findet man dann im Netzt.

Code:

 
      FCalculatedVertice:array of TGLVectori2;
      FTriangleIndices:array of cardinal;
...
function TKar_OGLShape.isconvex(prev,cur,next:TGLVectori2):boolean;
var
  v1,v2:TGLVectori2;
begin
  result:=false;
  v1[0]:=prev[0]-cur[0];
  v1[1]:=prev[1]-cur[1];
  v2[0]:=next[0]-cur[0];
  v2[1]:=next[1]-cur[1];
  if (v1[0]*v2[1]-v1[1]*v2[0])<=0 then
    result:=true;
end;
 
function TKar_OGLShape.SameSide(p1,p2,v1,v2:TGLVectori2):Boolean;
var
  cp1,cp2:TGLVectori3;
  d1,d2,d3:TGLVectori2;
begin
  d1[0]:=v2[0]-v1[0]; d1[1]:=v2[1]-v1[1];
  d2[0]:=p1[0]-v1[0]; d2[1]:=p1[1]-v1[1];
  d3[0]:=p2[0]-v1[0]; d3[1]:=p2[1]-v1[1];
 
  cp1[2]:=d1[0]*d2[1]-d1[1]*d2[0];
  cp2[2]:=d1[0]*d3[1]-d1[1]*d3[0];
 
  if (cp1[2]*cp2[2])>=0 then
    result:=true
  else
    result:=false;
end;
 
function TKar_OGLShape.PointInPolygon(a,b,c,p1:TGLVectori2):Boolean;
begin
  if SameSide(p1,a,b,c) and SameSide(p1,b,a,c) and SameSide(p1,c,a,b) then
    result:=true
  else
    result:=false;
end;
 
function TKar_OGLShape.isear(p1,p2,p3:cardinal;const list:array of TGLVectori2):Boolean;
var
  i:integer;
begin
  result:=false;
  for i:=0 to high(list) do
    if (i<>p1) and (i<>p2) and (i<>p3) then
      if PointInPolygon(list[p1],list[p2],list[p3],list[i]) then
        exit;
  result:=true;
end;
 
procedure TKar_OGLShape.Tesselieren;
var
  l:array of cardinal;
  prev,next,j,i:cardinal;
begin
  setlength(l,length(FCalculatedVertice));
  for i:=0 to high(FCalculatedVertice) do
    l[i]:=i;
 
  while length(l)>3 do
  begin
    i:=0;
    while i<=high(l) do
    begin
      if i=0 then prev:=high(l) else prev:=i-1;
      if i=high(l) then next:=0 else next:=i+1;
      if isconvex(FCalculatedVertice[l[prev]],FCalculatedVertice[l[i]],FCalculatedVertice[l[next]])
         and isear(prev,i,next,FCalculatedVertice) then
      begin
        //setindices
        setlength(FTriangleIndices,length(FTriangleIndices)+3);
        FTriangleIndices[high(FTriangleIndices)-2]:=l[prev];
        FTriangleIndices[high(FTriangleIndices)-1]:=l[i];
        FTriangleIndices[high(FTriangleIndices)]:=l[next];
        //remove from list
        for j:=i to high(l)-1 do
          l[j]:=l[j+1];
        setlength(l,high(l));
      end;
      inc(i);
    end;
  end;
  //setindices
  setlength(FTriangleIndices,length(FTriangleIndices)+3);
  FTriangleIndices[high(FTriangleIndices)-2]:=l[0];
  FTriangleIndices[high(FTriangleIndices)-1]:=l[1];
  FTriangleIndices[high(FTriangleIndices)]:=l[2];
end;

Ich habe meine neue GUI auf Shapes umgestellt und lasse im ersten Schritt den Rahmen errechnen(quadratische Bezierkurven).
Die neuen Punkte(FCalculatedVertice) werden dann zum Tesselieren übergeben und dann bekomme ich eine Indexliste zurück.
Die Border und Fill Klassen können dann noch auswirkungen auf die Abhandlung, der Zeichenroutine haben.
So kann z.B. Fill Bilder und Gardients(Farbliste wird in eine Textur mit Linearer interpolation gesteckt) oder Border kann die Rundungsstufen und die Größe des Rundungsbereiches festlegen. Keine rundungen sind auch möglich, man muss RoundSteps einfach auf 0 setzten.
So sieht aktuell meine Shape basierte GUI aus.
-TKar_Image mit einer DDS(DXT) Datei
-TKar_Button mit einen Gardient als Füller und zentrierten Text
-2TKar_Panel mit Default Theme Werten
-2TKar_Label mit Text
-TKar_TabPanel(noch beim coden)

_________________
"Wer die Freiheit aufgibt um Sicherheit zu gewinnen, der wird am Ende beides verlieren"
Benjamin Franklin

Projekte: https://github.com/tak2004

Nach oben

Seite 1 von 1

[ 4 Beiträge ]

Foren-Übersicht » Programmierung » OpenGL

Wer ist online?

Mitglieder in diesem Forum: 0 Mitglieder und 2 Gäste

Du darfst keine neuen Themen in diesem Forum erstellen.
Du darfst keine Antworten zu Themen in diesem Forum erstellen.
Du darfst deine Beiträge in diesem Forum nicht ändern.
Du darfst deine Beiträge in diesem Forum nicht löschen.
Du darfst keine Dateianhänge in diesem Forum erstellen.