DGL • Thema anzeigen - Bekomme keine realistische Ansicht hin

Bekomme keine realistische Ansicht hin

Moderator: DGL-Team

Seite 1 von 2

[ 17 Beiträge ]

Gehe zu Seite 1, 2 Nächste

Vorheriges Thema | Nächstes Thema

Autor

Nachricht

Coolman1974

Betreff des Beitrags: Bekomme keine realistische Ansicht hin

Verfasst: Mo Dez 11, 2006 19:45

DGL Member

Registriert: Do Jun 22, 2006 19:13
Beiträge: 52
Wohnort: Lübeck

Hallo zusammen,

ich beschäftige mich seit dem Wochenende mit OpenGL und hab auch schon ein wenig hinbekommen können. Aber was mir absolut nicht gelingen will, ist eine realistische Ansicht der Tennisbälle.

Ich habe ein ganz normal Textur über die Spheren gelegt. Wenn ich mit Licht arbeiten muss, dann frage ich mich wie. Ich habe alle parameter verstellt und nichts ändert sich.

Kann mir jemand ein wenig helfen ?

hier ein Screenshot und ein wenig Source:

Bild

Code:

 
var
  Form1: TForm1;
  Palette: HPALETTE;
  rot:           array[0..3] of GLFloat = (1, 0, 0, 1);
  Gruen:         array[0..3] of GLFloat = (0, 1, 0, 1);
  Weiss:         array[0..3] of GLFloat = (1, 1, 1, 1);
  Schwarz:       array[0..3] of GLFloat = (0, 0, 0, 1);
  Grau:          array[0..3] of GLFloat = (0.5 , 0.5, 0.5, 1);
  LichtPosition: array[0..3] of GLFloat = (-10, 10, 30, 1);
  LichtRichtung: array[0..3] of GLFloat = (-10, 10, 30, 0);
  Viewport: TVector4i;
  Treffer: Boolean;
  Ball: TBall;
  ModellMatrix: TMatrix4d;
  ProjectionMatrix: TMatrix4d;
  mZ: Single;
  myTex: Cardinal;
  TexturNamen:    array [1..2] of GLuint;
  PBitmap: Pointer;
  Quadric : PGLUQuadric;
 
const
  BufSize = 512;
 
implementation
 
{$R *.dfm}
 
{ TForm1 }
 
procedure TForm1.FormCreate(Sender: TObject);
var
  Breite: Integer;
  Hoehe: Integer;
  Tiefe: Integer;
begin
  mZ := 0;
  BallListe := TBallListe.Create;
 
  InitOpenGL;
  DC := GetDC(Panel1.Handle);
  RC := CreateRenderingContext(DC, [opDoubleBuffered], 32, 0, 0, 0, 0, Palette);
  wglMakeCurrent(DC, RC);
 
  glEnable(GL_DEPTH_TEST);
 
  glEnable(GL_LIGHT0);
  glEnable(GL_LIGHTING);
 
  glLightfv(GL_LIGHT1, GL_AMBIENT, @Rot);
  glLightfv(GL_LIGHT1, GL_DIFFUSE, @Rot);
  glLightfv(GL_LIGHT1, GL_SPECULAR, @Rot);
  glLightfv(GL_LIGHT1, GL_POSITION, @LichtPosition);
 
  glLightfv(GL_LIGHT2, GL_AMBIENT, @Rot);
  glLightfv(GL_LIGHT2, GL_DIFFUSE, @Rot);
  glLightfv(GL_LIGHT2, GL_SPECULAR, @Rot);
  glLightfv(GL_LIGHT2, GL_POSITION, @LichtRichtung);
 
  glLightModelf(GL_LIGHT_MODEL_TWO_SIDE, 1);
 
  glGenTextures(2,@TexturNamen);
 
  CreateImageBMP('C:\BallNeu.bmp',Breite,Hoehe,PBitmap);
  glBindTexture(GL_TEXTURE_2D,TexturNamen[2]);
  glTexImage2D(GL_TEXTURE_2D,0,GL_RGB,Breite,Hoehe,0,
               GL_RGB,GL_UNSIGNED_BYTE ,PBitmap);
  glTexParameterf(GL_TEXTURE_2D,GL_TEXTURE_MAG_FILTER,GL_NEAREST);
  glTexParameterf(GL_TEXTURE_2D,GL_TEXTURE_MIN_FILTER,GL_NEAREST);
  glTexEnvf(GL_TEXTURE_ENV,GL_TEXTURE_ENV_MODE,GL_REPLACE);
  gluBuild2DMipmaps(GL_TEXTURE_2D,GL_RGB,Breite,Hoehe,GL_RGB,GL_UNSIGNED_BYTE,PBitmap);
end;
 
procedure TForm1.DrawScene;
var
  i: Integer;
begin
  glPushAttrib(GL_ALL_ATTRIB_BITS);
  glEnable(GL_DEPTH_TEST);
  glEnable(GL_Normalize);
 
  gluPerspective(45, Panel1.Width/Panel1.Height, 1, 2000);
 
  Quadric:=gluNewQuadric;
  gluQuadricDrawStyle(Quadric, GLU_FILL);
  gluQuadricTexture(Quadric, GL_TRUE);
  glEnable(GL_TEXTURE_2D);
  glMatrixMode(GL_TEXTURE);
  glLoadIdentity;
 
  glEnable(GL_BLEND);
  glBlendFunc(GL_DST_COLOR, GL_SRC_COLOR);
 
  glBindTexture(GL_TEXTURE_2D,TexturNamen[2]);
 
  glMatrixMode(GL_MODELVIEW);
  glLoadIdentity;
 
  gluLookAt(0, 0, 0, 0, 0, -100, 0, 1, 0);
 
  for i := 0 to BallListe.Liste.Count - 1 do
  begin
    TBall(BallListe.Liste.Items[i]).DrawBall;
  end;
end;
 
{ TBall }
 
procedure TBall.DrawBall;
begin
  glDisable(GL_LIGHT0);
  glEnable(GL_LIGHT1);
  glDisable(GL_LIGHTING);
 
  glLoadName(Nummer);
 
  glMaterialfv(GL_FRONT_AND_BACK, GL_DIFFUSE, @Weiss);
  glMaterialfv(GL_FRONT_AND_BACK, GL_AMBIENT, @Schwarz);
  glMaterialf(GL_FRONT_AND_BACK, GL_SHININESS, 20);
 
  glPushMatrix;
 
  glTranslatef(Position[0], Position[1], Position[2]);
 
  GLUSphere(Quadric, 5, 40, 40);
 
  glPopMatrix;
end;
 

Nach oben

i0n0s

Betreff des Beitrags:

Verfasst: Mo Dez 11, 2006 22:13

Ernährungsberater

Registriert: Sa Jan 01, 2005 17:11
Beiträge: 2068
Programmiersprache: C++

Wenn du den Ball renderst deaktivierst du mit glDisable(GL_LIGHTING) das Licht. Somit kann sich nichts mehr an dem Licht verändern

_________________
Steppity,✲steppity,✴step,❆step,✳step! :twisted:

❆ ❄ ❄ ❄ ❅ ❄ ❆ ❄ ❅ ❄ ❅ ❄ ❅ ❄ ❄
❅ ☃ ❄ ❄ ❄ ❅ ❄ ❄ ❄ ❅ ❄ ☃ ❄ ❆ ❄ ❄

Nach oben

Coolman1974

Betreff des Beitrags:

Verfasst: Mo Dez 11, 2006 23:05

DGL Member

Registriert: Do Jun 22, 2006 19:13
Beiträge: 52
Wohnort: Lübeck

Selbst wenn ich das Licht anschalte verändert sich nichts

Code:

 
procedure TBall.DrawBall;
begin
  glEnable(GL_LIGHT0);
  glEnable(GL_LIGHT1);
  glEnable(GL_LIGHTING);
 
  glLoadName(Nummer);
 
  glMaterialfv(GL_FRONT_AND_BACK, GL_DIFFUSE, @Weiss);
  glMaterialfv(GL_FRONT_AND_BACK, GL_AMBIENT, @Schwarz);
  glMaterialf(GL_FRONT_AND_BACK, GL_SHININESS, 20);
 
  glPushMatrix;
 
  glTranslatef(Position[0], Position[1], Position[2]);
  glRotatef(Angle, 10, 5, 0);
 
  GLUSphere(Quadric, 5, 40, 40);
 
  glPopMatrix;
end;
 

Wenn sich doch wenigstens ein wenig was verändern würde, dann wüsste ich ja in welche Richtung ich weiter nachdenken muss. Ich weiß nicht mehr weiter. Hab so viele Sachen ausprobiert.

Nach oben

Coolman1974

Betreff des Beitrags:

Verfasst: Mo Dez 11, 2006 23:30

DGL Member

Registriert: Do Jun 22, 2006 19:13
Beiträge: 52
Wohnort: Lübeck

Mir ist augefallen, sobald ich glEnable(GL_TEXTURE_2D) ausführe werden anscheinend keine Lichtberechnungen mehr berücksichtigt.

Kommentier ich die Zeile aus sehe ich rote Bälle mit Lichtberechnung. Schalte ich das Licht aus sind die Bälle weiß. Aberdas ist ja auch richtig so und ich versteh auch warum. Aber warum die Bälle bei glEnable(GL_TEXTURE_2D) und enable(GL_LIGHTING) nur wie 2D-Bilder aussehen versteh ich nicht.

Hier die Bälle mit auskommentierter glEnable(GL_TEXTURE_2D) Zeile:

Bild

Code:

 
procedure TBall.DrawBall;
begin
  glDisable(GL_LIGHT0);
  glEnable(GL_LIGHT1);
  glEnable(GL_LIGHTING);
 
  glLoadName(Nummer);
 
  glMaterialfv(GL_FRONT_AND_BACK, GL_DIFFUSE, @Weiss);
  glMaterialfv(GL_FRONT_AND_BACK, GL_AMBIENT, @Schwarz);
  glMaterialf(GL_FRONT_AND_BACK, GL_SHININESS, 1);
 
  glPushMatrix;
 
  glTranslatef(Position[0], Position[1], Position[2]);
  glRotatef(Angle, 10, 5, 0);
 
  glutSolidSphere(5, 40, 40);
 
  glPopMatrix;
end;
 

Nach oben

yonibear

Betreff des Beitrags:

Verfasst: Di Dez 12, 2006 07:09

DGL Member

Registriert: So Feb 19, 2006 23:46
Beiträge: 55

Versuch mal glEnable(GL_COLOR_MATERIAL), das ist eine der Möglichkeiten Texturen mit Licht darzustellen.

Nach oben

dj3hut1

Betreff des Beitrags:

Verfasst: Di Dez 12, 2006 09:31

DGL Member

Registriert: Di Dez 27, 2005 12:44
Beiträge: 393
Wohnort: Berlin
Programmiersprache: Java, C++, Groovy

Hallo,

die Normalen sind bei Quadrics nicht standardmässig aktiviert.

Versuchs mal mit

Code:

gluQuadricNormals(Quadric, GLU_SMOOTH);

Viele Grüße
dj3hut1

Nach oben

Coolman1974

Betreff des Beitrags:

Verfasst: Di Dez 12, 2006 12:25

DGL Member

Registriert: Do Jun 22, 2006 19:13
Beiträge: 52
Wohnort: Lübeck

Vielen Dank schon mal für eure Antworten.

Da ich noch auf Arbeit bin kann ich eure Ideen erst ab 19.00 Uhr ausprobieren.

Nach oben

Coolman1974

Betreff des Beitrags:

Verfasst: Di Dez 12, 2006 18:14

DGL Member

Registriert: Do Jun 22, 2006 19:13
Beiträge: 52
Wohnort: Lübeck

Hallo!

Also, ich habe eure Ideen ausprobiert und keine von beiden sorgt für die kleinste Veränderung in der Scene.

Ich habe mal die pas und die dfm und alle erforderlichen Dateien hochgeladen.

Währe super, wenn sich die mal jemand anschauen kann.

Besten Dank schon einmal.

Hier der Link

Nach oben

Seth

Betreff des Beitrags:

Verfasst: Di Dez 12, 2006 19:25

DGL Member

Registriert: Di Mai 24, 2005 16:43
Beiträge: 710

schön dass du die glut32.dll reingepackt hast, aber die dpr hast du vergessen

ist aber kein problem, diese hier geht:

Code:

 
program Ball;
 
uses
  Forms,
  Unit1 in 'Unit1.pas' {Form1};
 
{$R *.res}
 
begin
  Application.Initialize;
  Application.CreateForm(TForm1, Form1);
  Application.Run;
end.
 

der header ist auch net mehr so aktuell, lade dir mal bitte die dglopengl.pas findest du im wiki und ob glut noch so aktuell und gebräuchlich ist, weiß ich auch net $\";)\"$

was mich stutzig macht an deine, code ist das hier:

Code:

  glEnable(GL_LIGHT0);
  glEnable(GL_LIGHTING);
 
  glLightfv(GL_LIGHT1, GL_AMBIENT, @Rot);
  glLightfv(GL_LIGHT1, GL_DIFFUSE, @Rot);
  glLightfv(GL_LIGHT1, GL_SPECULAR, @Rot);
  glLightfv(GL_LIGHT1, GL_POSITION, @LichtPosition);
 
  glLightfv(GL_LIGHT2, GL_AMBIENT, @Rot);
  glLightfv(GL_LIGHT2, GL_DIFFUSE, @Rot);
  glLightfv(GL_LIGHT2, GL_SPECULAR, @Rot);
  glLightfv(GL_LIGHT2, GL_POSITION, @LichtRichtung);
 

du aktivierst light0 und setzt werte für light1 und light2, das kann garnet klappen und wozu hast du einmal licht position und einmal licht richtung ? bei zwei verschiedenen lichtern die du garnet aktivierst ?

ebenso, dass du alles auf rot setzt, ich glaube dadurch wirst du kein richtiges licht erhalten.

mfg

Zuletzt geändert von Seth am Di Dez 12, 2006 19:30, insgesamt 2-mal geändert.

Nach oben

Coolman1974

Betreff des Beitrags:

Verfasst: Di Dez 12, 2006 19:27

DGL Member

Registriert: Do Jun 22, 2006 19:13
Beiträge: 52
Wohnort: Lübeck

Die brauch man doch nun wirklich nicht.

Der Source kann doch in ein von dir neu erstelltes Projekt kopiert werden. --- Aber ich kann auch alles komplett hochladen.

mom....

Nach oben

Seth

Betreff des Beitrags:

Verfasst: Di Dez 12, 2006 19:31

DGL Member

Registriert: Di Mai 24, 2005 16:43
Beiträge: 710

guck dir nochmal an was ich oben editiert habe, vielleicht sticht dir dann dein fehler schon ins auge

Nach oben

Coolman1974

Betreff des Beitrags:

Verfasst: Di Dez 12, 2006 19:34

DGL Member

Registriert: Do Jun 22, 2006 19:13
Beiträge: 52
Wohnort: Lübeck

Hier der Link zum komletten Projekt.

Nach oben

Seth

Betreff des Beitrags:

Verfasst: Di Dez 12, 2006 19:38

DGL Member

Registriert: Di Mai 24, 2005 16:43
Beiträge: 710

der eigentliche fehler liegt in dieser zeile:

Code:

// glTexEnvf(GL_TEXTURE_ENV,GL_TEXTURE_ENV_MODE,GL_REPLACE);

die musst du auskommentieren, sonst hast du nicht viel vom licht $\";)\"$

so sieht das bei mir momentan aus und es geht:

Code:

 
unit Unit1;
 
interface
 
uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ExtCtrls, OpenGL12, GLUT, ComCtrls, Math, GLToolsDelphi;
 
type
  TPosition = array[0..2] of GLFloat;
 
type
  TBall = Class
  private
    FNummer: Integer;
    FPosition: TPosition;
    FFarbe: Pointer;
  public
    procedure DrawBall;
    property Nummer: Integer read FNummer write FNummer;
    property Position: TPosition read FPosition write FPosition;
    property Farbe: Pointer read FFarbe write FFarbe;
  End;
 
type
  TBallListe = class
  private
    FListe: TList;
  public
    procedure DrawBaelle;
    constructor Create;
    destructor Destroy; override;
    property Liste: TList read FListe write FListe;
  end;
 
type
  TForm1 = class(TForm)
    Panel1: TPanel;
    Button1: TButton;
    Timer1: TTimer;
    TrackBar1: TTrackBar;
    TrackBar2: TTrackBar;
    TrackBar3: TTrackBar;
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
    procedure Timer1Timer(Sender: TObject);
    procedure Button1Click(Sender: TObject);
    procedure Panel1MouseDown(Sender: TObject; Button: TMouseButton;
      Shift: TShiftState; X, Y: Integer);
    procedure Panel1MouseUp(Sender: TObject; Button: TMouseButton;
      Shift: TShiftState; X, Y: Integer);
    procedure Panel1MouseMove(Sender: TObject; Shift: TShiftState; X,
      Y: Integer);
  private
    RC: HGLRC;
    DC: HDC;
    BallListe: TBallListe;
    function GetBallByNummer(aNummer: Integer): TBall;
    function GetOpenGLPos(aX, aY: Integer): TVector3d;
  public
    procedure DrawScene;
  end;
 
var
  Form1: TForm1;
  Palette: HPALETTE;
 
    mat_specular   : Array[0..3] of GlFloat = (1.0, 1.0, 1.0, 1.0);
    mat_shininess  : Array[0..0] of GlFloat = (50.0);
    mat_ambient    : Array[0..3] of GlFloat = (0.4, 0.4, 0.4, 1.0);
    mat_diffuse    : Array[0..3] of GlFloat = (0.4, 0.8, 0.4, 1.0);
 
    light_position : Array[0..3] of GlFloat = (0.0, 10.0, 0.0, 1.0);
    light_ambient  : Array[0..3] of GlFloat = (0.8, 0.8, 0.8, 1.0);
    light_diffuse  : Array[0..3] of GlFloat = (0.8, 0.8, 0.8, 1.0);
 
  rot:           array[0..3] of GLFloat = (1, 0, 0, 1);
  Gruen:         array[0..3] of GLFloat = (0, 1, 0, 1);
  Weiss:         array[0..3] of GLFloat = (1, 1, 1, 1);
  Schwarz:       array[0..3] of GLFloat = (0, 0, 0, 1);
  Grau:          array[0..3] of GLFloat = (0.5 , 0.5, 0.5, 1);
  LichtPosition: array[0..3] of GLFloat = (-10, 10, 30, 1);
  LichtRichtung: array[0..3] of GLFloat = (-10, 10, 30, 0);
  Viewport: TVector4i;
  Treffer: Boolean;
  Ball: TBall;
  ModellMatrix: TMatrix4d;
  ProjectionMatrix: TMatrix4d;
  mZ: Single;
  myTex: Cardinal;
  TexturNamen:    array [1..2] of GLuint;
  PBitmap: Pointer;
  PBitmap1: Pointer;
  Quadric : PGLUQuadric;
  Angle: GLFloat;
const
  BufSize = 512;
 
implementation
 
{$R *.dfm}
 
{ TForm1 }
 
procedure TForm1.FormCreate(Sender: TObject);
var
  Breite: Integer;
  Hoehe: Integer;
  Tiefe: Integer;
begin
  Angle := 0;
  mZ := 0;
  BallListe := TBallListe.Create;
 
  InitOpenGL;
  DC := GetDC(Panel1.Handle);
  RC := CreateRenderingContext(DC, [opDoubleBuffered], 32, 0, 0, 0, 0, Palette);
  wglMakeCurrent(DC, RC);
 
  glEnable(GL_DEPTH_TEST);
  glEnable(GL_CULL_FACE);
 
    glMaterialfv(GL_FRONT, GL_SPECULAR,  @mat_specular[0]);
    glMaterialfv(GL_FRONT, GL_SHININESS, @mat_shininess[0]);
    glMaterialfv(GL_FRONT, GL_AMBIENT,   @mat_ambient[0]);
    glMaterialfv(GL_FRONT, GL_DIFFUSE,   @mat_diffuse[0]);
 
    glLightfv(GL_LIGHT0, GL_AMBIENT,  @light_ambient[0]);
    glLightfv(GL_LIGHT0, GL_DIFFUSE,  @light_diffuse[0]);
    glLightfv(GL_LIGHT0, GL_POSITION, @light_position[0]);
 
  glEnable(GL_LIGHT0);
  glEnable(GL_LIGHTING);
 
//  glLightModelf(GL_LIGHT_MODEL_TWO_SIDE, 1);
 
  glGenTextures(2,@TexturNamen);
 
  glEnable(GL_TEXTURE_2D);
//  glEnable(GL_COLOR_MATERIAL);
 
  CreateImageBMP('BallNeu.bmp',Breite,Hoehe, PBitmap);
  glBindTexture(GL_TEXTURE_2D,TexturNamen[2]);
  glTexImage2D(GL_TEXTURE_2D,0,GL_RGB,Breite,Hoehe, 0,
               GL_RGB,GL_UNSIGNED_BYTE ,PBitmap);
  glTexParameterf(GL_TEXTURE_2D,GL_TEXTURE_MAG_FILTER,GL_NEAREST);
  glTexParameterf(GL_TEXTURE_2D,GL_TEXTURE_MIN_FILTER,GL_NEAREST);
//  glTexEnvf(GL_TEXTURE_ENV,GL_TEXTURE_ENV_MODE,GL_REPLACE);
  gluBuild2DMipmaps(GL_TEXTURE_2D,GL_RGB,Breite,Hoehe,GL_RGB,GL_UNSIGNED_BYTE, PBitmap);
end;
 
procedure TForm1.FormDestroy(Sender: TObject);
begin
  DestroyRenderingContext(RC);
end;
 
function TForm1.GetBallByNummer(aNummer: Integer): TBall;
var
  i: Integer;
begin
  Result := nil;
  for i := 0 to BallListe.Liste.Count - 1 do
  begin
    if TBall(BallListe.Liste.Items[i]).Nummer = aNummer then
    begin
      Result := TBall(BallListe.Liste.Items[i]);
      Exit;
    end;
  end;
end;
 
function TForm1.GetOpenGLPos(aX, aY: Integer): TVector3d;
var
    modelview:  TMatrix4d;
    projection: TMatrix4d;
    winZ,winY:  Single;
begin
    glGetDoublev(GL_MODELVIEW_MATRIX, @modelview );
    glGetDoublev(GL_PROJECTION_MATRIX, @projection );
 
  winY := viewport[3] - ay;
 
  if mZ = 0 then
  begin
    glReadPixels(aX, Round(winY), 1, 1, GL_DEPTH_COMPONENT, GL_FLOAT, @winZ );
    mz := winz;
  end;
    gluUnProject(aX, winY, mZ,
              modelview, projection, viewport,
                    @Result[0], @Result[1], @Result[2]);
  caption := FloatToStr(winZ);
end;
 
procedure TForm1.Panel1MouseDown(Sender: TObject; Button: TMouseButton;
  Shift: TShiftState; X, Y: Integer);
var
  SelectBuf: Array[0..BufSize - 1] of GLuInt;
  Hits: GLInt;
  i: GLInt;
  j: GLInt;
  k: GLInt;
  Names: GLInt;
  n: extended;
  msg: String;
begin
  ShowCursor(False);
 
  n := IntPower(2, 32) - 1;
 
  glSelectBuffer(BufSize, @SelectBuf);
 
  glRenderMode(GL_SELECT);
 
  glInitNames;
  glPushName(0);
 
  glMatrixMode(GL_PROJECTION);
  glPushMatrix;
  glLoadIdentity;
  gluPickMatrix(X, Viewport[3] - Y, 4, 4, Viewport);
  DrawScene;
  glPopMatrix;
 
  glPopName;
 
  Hits := glRenderMode(GL_RENDER);
 
  for i := 0 to Hits - 1 do
  begin
    Names := SelectBuf[0];
    Caption := IntToStr(SelectBuf[3]);
    Ball := GetBallByNummer(SelectBuf[3]);
    Treffer := True;
    //showmessage(FloatToStr(SelectBuf[2]));
  end;  
end;
 
procedure TForm1.Panel1MouseMove(Sender: TObject; Shift: TShiftState; X,
  Y: Integer);
var
  Pos: TPosition;
  mouse : TPoint;
  mouse3D: TVector3d;
begin
  if Treffer then
  begin
    // Get the 3D Projected Vector from our 2D mouse position
    mouse3D := GetOpenGLPos(X, Y);
    //Caption := FloatToStr(Mouse3D[0]) + '/' + FloatToStr(Mouse3D[1]);
    Pos[0] := Mouse3D[0];
    Pos[1] := Mouse3D[1];
    Pos[2] := Ball.Position[2];
    Ball.Position := Pos;
  end;
end;
 
procedure TForm1.Panel1MouseUp(Sender: TObject; Button: TMouseButton;
  Shift: TShiftState; X, Y: Integer);
begin
  Treffer := False;
  mZ := 0;
  ShowCursor(True);
end;
 
procedure TForm1.Timer1Timer(Sender: TObject);
begin
  if Angle >= 360 then
    Angle := 0
  else
    Angle := Angle + 5;
 
  glClearColor(0, 0, 0.05, 1);
 
  glClear(GL_COLOR_BUFFER_BIT or GL_DEPTH_BUFFER_BIT);
 
  glViewport(0, 0, Panel1.Width, Panel1.Height);
  glGetIntegerv(GL_VIEWPORT, @Viewport);
 
  glMatrixMode(GL_PROJECTION);
  glLoadIdentity;
 
  glEnable(GL_AUTO_NORMAL);
  glEnable(GL_Normalize);
 
  DrawScene;
 
  SwapBuffers(DC);
end;
 
procedure TForm1.Button1Click(Sender: TObject);
var
  i: Integer;
  Ball: TBall;
  Pos: TPosition;
  Wert: GLFloat;
  Erster: Boolean;
begin
  Randomize;
  Wert := -40;
  Erster := False;
  for i := 1 to 100 do
  begin
    Ball := TBall.Create;
    Ball.Farbe := @Gruen;
    Pos[0] := Wert;//Random(100) * -1;
    Pos[1] := 0;
    Pos[2] := 10 * i * -1;//Random(100) * -1;
    Ball.Position := Pos;
    Ball.Nummer := i;
    BallListe.Liste.Add(Ball);
    if Erster then
    begin
      Wert := Wert -80;
      Erster := False;
    end
    else
    begin
      Wert := Wert +80;
      Erster := True;
    end;
  end;
end;
 
procedure TForm1.DrawScene;
var
  i: Integer;
begin
  glPushAttrib(GL_ALL_ATTRIB_BITS);
  glEnable(GL_DEPTH_TEST);
  glEnable(GL_Normalize);
 
  gluPerspective(45, Panel1.Width/Panel1.Height, 1, 2000);
 
  Quadric:=gluNewQuadric;
  gluQuadricDrawStyle(Quadric, GLU_FILL);
  gluQuadricTexture(Quadric, GL_TRUE);
  gluQuadricNormals(Quadric, GLU_SMOOTH);
  glMatrixMode(GL_TEXTURE);
  glLoadIdentity;
 
  glBindTexture(GL_TEXTURE_2D, TexturNamen[2]);
 
  glMatrixMode(GL_MODELVIEW);
  glLoadIdentity;
 
  gluLookAt(0, 0, 0, 0, 0, -100, 0, 1, 0);
 
  for i := 0 to BallListe.Liste.Count - 1 do
  begin
    TBall(BallListe.Liste.Items[i]).DrawBall;
  end;
end;
 
{ TBall }
 
procedure TBall.DrawBall;
begin
  glEnable(GL_LIGHT0);
  glEnable(GL_LIGHTING);
 
  glLoadName(Nummer);
 
  glPushMatrix;
 
  glTranslatef(Position[0], Position[1], Position[2]);
  glRotatef(Angle, 10, 5, 0);
  
  gluQuadricNormals(Quadric, GLU_SMOOTH);
 
  GLUSphere(Quadric, 5, 40, 40);
 
  glPopMatrix;
end;
 
{ TBallListe }
 
constructor TBallListe.Create;
begin
  Liste := TList.Create;
end;
 
destructor TBallListe.Destroy;
var
  i: Integer;
begin
  for i := 0 to Liste.Count - 1 do
  begin
    TBall(Liste.Items[i]).Free;
  end;
  Liste.Free;  
  inherited;
end;
 
procedure TBallListe.DrawBaelle;
var
  i: Integer;
begin
  for i := 0 to Liste.Count - 1 do
  begin
    TBall(Liste.Items[i]).DrawBall;
  end;  
end;
 
end.
 

mfg

Nach oben

Coolman1974

Betreff des Beitrags:

Verfasst: Di Dez 12, 2006 20:10

DGL Member

Registriert: Do Jun 22, 2006 19:13
Beiträge: 52
Wohnort: Lübeck

Vielen vielen Dank !!!!!

Super, nun funktioniert es !!!

Ich habe für den Tennisball noch eine Textur die für die Struktur des Balls sein soll.

Wie bekomme ich nun diese noch dazu ??

Stichwort Bumpmapping. Lieg ich richtig ?

Nach oben

The-Winner

Betreff des Beitrags:

Verfasst: Di Dez 12, 2006 20:38

DGL Member

Registriert: Di Jun 06, 2006 09:59
Beiträge: 474

Mit Bump bzw Normalmaps liegst du zwar richtig, das ist aber deultlich komplexer und wird meist mit shadern statt gllicht gelöst.

Nach oben

Seite 1 von 2

[ 17 Beiträge ]

Gehe zu Seite 1, 2 Nächste

Foren-Übersicht » Programmierung » OpenGL

Wer ist online?

Mitglieder in diesem Forum: 0 Mitglieder und 3 Gäste

Du darfst keine neuen Themen in diesem Forum erstellen.
Du darfst keine Antworten zu Themen in diesem Forum erstellen.
Du darfst deine Beiträge in diesem Forum nicht ändern.
Du darfst deine Beiträge in diesem Forum nicht löschen.
Du darfst keine Dateianhänge in diesem Forum erstellen.