DGL • Thema anzeigen - Mehrere Device-Contexte in einer Applikation

Mehrere Device-Contexte in einer Applikation

Moderator: DGL-Team

Seite 1 von 1

[ 7 Beiträge ]

Vorheriges Thema | Nächstes Thema

Autor

Nachricht

BigAl

Betreff des Beitrags: Mehrere Device-Contexte in einer Applikation

Verfasst: Di Jun 10, 2014 20:59

DGL Member

Registriert: Di Jun 10, 2014 06:59
Beiträge: 17
Programmiersprache: Delphi XE6

Hallo zusammen,

bin hier neu und beschäftige mich erst seit ein paar Tagen mit OpenGL. Grundsätzlich funktioniert alles wie ich mir es vorstelle (wenn auch manchmal etwas umständlich). Da ich OpenGL zur Visualisierung von Berechnungsergebnissen einsetze spielen für mich so Dinge wie Beleuchtung, Texturen etc. eine untergeordnete bis gar keine Rolle. Macht alles sehr viel einfacher :-)

. Ach ja: Ich nutze Delphi XE6 auf einer Win7 64 und einer Win 8 64 Maschine.

Zu meinem Problem(chen):

Ich habe eine Komponente auf Basis von TCustomControl erstellt. Die Initialisierung des DC/RC mache ich in CreateWnd bzw. die Freigabe der Handles in DestroyWnd bzw. am Schluss dann in "Destroy". Den DC kann ich in Destroy aber nicht mit ReleaseDC freigeben, da wohl der Handle der Komponente bereits nicht mehr gültig ist. Gibt Fehler... Die Ausgabe findet klassisch in "Paint" statt. Die Initialisierung von OpenGL (InitOpenGL) mache ich in der "initialization"-Sektion der Unit. Funktioniert soweit alles super und stabil. Leider kann ich die Komponente nur einmal auf einem Formular verwenden. Ein zweites mal wird da nichts ausgegeben (schwarz). Ist das eine Restriktion von OpenGL? Ich hätte halt gerne zwei unabhängige Grafiken - auf Basis der gleichen Komponente - nebeneinander gehabt...

Wäre klasse, wenn mir da jemand einen Tipp geben könnte.

Vielen Dank im Voraus

Alex

Nach oben

OpenglerF

Betreff des Beitrags: Re: Mehrere Device-Contexte in einer Applikation

Verfasst: Di Jun 10, 2014 22:37

DGL Member

Registriert: Do Dez 29, 2011 19:40
Beiträge: 421
Wohnort: Deutschland, Bayern
Programmiersprache: C++, C, D, C# VB.Net

Mehrere Kontexte sollten auf jeden Fall möglich sein.
Leider kann ich dir im Speziellen wenig weiterhelfen, weil ich bisher immer auf etwas fertiges gesetzt habe, das diesen Schritt für meine Bedürfnisse übernimmt (GLFW3). Kannst du vielleicht mal ein bisschen auf das Problem reduzierten Code bereitstellen?

Ausßerdem ist dir hoffentlich schon bewusst, dass du natürlich beide Grafikbereiche rendern musst und dazwischen mit "wglMakeCurrent"(Windows) oder "glXMakeCurrent"(X also Linux, *BSD, ...) wechseln musst? Der aktuelle Kontext ist übrigens Thread lokal.

Nach oben

BigAl

Betreff des Beitrags: Re: Mehrere Device-Contexte in einer Applikation

Verfasst: Mi Jun 11, 2014 07:44

DGL Member

Registriert: Di Jun 10, 2014 06:59
Beiträge: 17
Programmiersprache: Delphi XE6

Hallo OpenglerF,

vielen Dank für Deine Antwort. Das mit wglMakeCurrent kannte ich noch nicht.

ES FUNKTIONIERT!

Nichts desto trotz hier mal ein paar Code-Fragmente, die ich auf das Wesentliche verkürzt habe:

Die komplette Definition der Komponente sieht momentan so aus:

Code:

 
type
  // Projekt Canvas OpenGL
  TfemCustomOpenGLCanvas = class(TCustomControl)
  private
    // Device Context
    FDC: HWND;
    // Rendering Context
    FRC: HGLRC;
    // Schriftspeicher
    FFontLists: Cardinal;
    // OpenGL bereit
    FOpenGLReady: Boolean;
    // Sichtfeld Winkel
    FFieldOfViewAngle: Double;
    // Clipping
    FClippingNear, FClippingFar: Double;
    // Kameraverschiebung
    FMoveX, FMoveY, FMoveZ: Single;
    // Objektdrehung
    FRotateX, FRotateY, FRotateZ: Single;
    // Schrift setzen
    procedure SetFontList;
    // Sichtfeld Winkel
    procedure SetFieldOfViewAngle(const Value: Double);
    function GetFieldOfViewAngleStored: Boolean;
    // Clipping
    procedure SetClipping(Index: Integer; const Value: Double);
    function GetClippingStored(Index: Integer): Boolean;
    // Kameraverschiebung
    procedure SetMove(Index: Integer; const Value: Single);
    function GetMoveStored(Index: Integer): Boolean;
    // Objektdrehung
    procedure SetRotate(Index: Integer; const Value: Single);
    function GetRotateStored(Index: Integer): Boolean;
  protected
    procedure CreateWnd; override;
    procedure DestroyWnd; override;
    procedure WMSize(var Msg: TWMSize); message WM_SIZE;
    procedure WMEraseBkgnd(var Msg: TWmEraseBkgnd); message WM_ERASEBKGND;
    procedure CMFontChanged(var Msg: TMessage); message CM_FONTCHANGED;
    procedure Paint; override;
    // Text an Position X, Y ausgeben (Bildschirmkoordinaten)
    procedure ShowTextAt(X, Y: Integer; const S: string);
    // Sichtfeld Winkel
    property FieldOfViewAngle: Double read FFieldOfViewAngle write SetFieldOfViewAngle stored GetFieldOfViewAngleStored;
    // Clipping
    property ClippingNear: Double index 1 read FClippingNear write SetClipping stored GetClippingStored;
    property ClippingFar: Double index 2 read FClippingFar write SetClipping stored GetClippingStored;
    // Kameraverschiebung
    property MoveX: Single index 1 read FMoveX write SetMove stored GetMoveStored;
    property MoveY: Single index 2 read FMoveY write SetMove stored GetMoveStored;
    property MoveZ: Single index 3 read FMoveZ write SetMove stored GetMoveStored;
    // Objektdrehung
    property RotateX: Single index 1 read FRotateX write SetRotate stored GetRotateStored;
    property RotateY: Single index 2 read FRotateY write SetRotate stored GetRotateStored;
    property RotateZ: Single index 3 read FRotateZ write SetRotate stored GetRotateStored;
  public
    // Initialisierung
    constructor Create(AOwner: TComponent); override;
    // Freigabe
    destructor Destroy; override;
  published
  end;
 

Hier wird der Geräte- und der Renderkontext erstellt:

Code:

 
procedure TfemCustomOpenGLCanvas.CreateWnd;
// Fenster erstellen
begin
  inherited;
  // Gerätekontext
  FDC := GetDC(Handle);
  // Renderkontext
  FRC := CreateRenderingContext(FDC, [opDoubleBuffered], 32, 24, 0, 0, 0, 0);
  ActivateRenderingContext(FDC, FRC);
  // Schrift setzen
  SetFontList;
  // OpenGL ist bereit
  FOpenGLReady := True;
end;
 

Falls der Context sich zwischendurch ändert:

Code:

 
procedure TfemCustomOpenGLCanvas.DestroyWnd;
// Fenster freigeben
begin
  DeactivateRenderingContext;
  DestroyRenderingContext(FRC);
  ReleaseDC(Handle, FDC);
  inherited;
end;
 

Größenänderung:

Code:

 
procedure TfemCustomOpenGLCanvas.WMSize(var Msg: TWMSize);
// Panelgröße wurde geändert
begin
  inherited;
  if FOpenGLReady then
    glViewport(0, 0, Msg.Width, Msg.Height);
end;
 

Die eigentliche Zeichenroutine (hier verkürzt):

Code:

 
procedure TfemCustomOpenGLCanvas.Paint;
// Ausgabe
var
  ScreenRatio: Single;
begin
  if FOpenGLReady then
  begin
    // Tiefentest aktivieren
    glEnable(GL_DEPTH_TEST);
    // Backface Culling deaktivieren
    glDisable(GL_CULL_FACE);
    // Hintergrund löschen
    glClearColor(1.0, 1.0, 1.0, 0.0);
    glClear(GL_COLOR_BUFFER_BIT or GL_DEPTH_BUFFER_BIT);
 
    // Kamera *******************************************************************
    glMatrixMode(GL_PROJECTION);
    // Identitätsmatrix laden
    glLoadIdentity;
    // Perspektive einstellen (Blickwinkel, Verhältnis Breit / Höhe, Clipping vorne, Clipping hinten)
    ScreenRatio := ClientWidth / ClientHeight;
    gluPerspective(FFieldOfViewAngle, ScreenRatio, FClippingNear, FClippingFar);
    // Kameraverschiebung X/Y/Z
    glTranslatef(FMoveX, FMoveY, FMoveZ);
 
    // Modell *******************************************************************
    glMatrixMode(GL_MODELVIEW);
    // Identitätsmatrix laden
    glLoadIdentity;
 
    // skallieren
    glScalef(1.0, 1.0, 1.0);
    // rotieren des Modells
    glRotatef(FRotateX, 1.0, 0.0, 0.0);
    glRotatef(FRotateY, 0.0, 1.0, 0.0);
    glRotatef(FRotateZ, 0.0, 0.0, 1.0);
 
    // hier wird gezeichnet
    // ...
 
    // Ausgabe
    SwapBuffers(FDC);
  end;
end;
 

Wie gesagt: Initialisiert wird im "initialization"_abschnitt:

Code:

 
initialization
 
InitOpenGL;
 
end.

Bin natürlich für alle Tipps empfänglich

Alex

Nach oben

mathias

Betreff des Beitrags: Re: Mehrere Device-Contexte in einer Applikation

Verfasst: Mi Jun 11, 2014 16:48

DGL Member

Registriert: Fr Mai 31, 2002 19:41
Beiträge: 1278
Wohnort: Bäretswil (Schweiz)
Programmiersprache: Pascal

Ich hatte mal eine kleine Demo geschrieben, dort wird gezeigt, wie man 2 OpenGL-Grafiken unabhägig zeichen kann.

Code:

unit Unit1;
 
interface
 
uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, OpenGL, ExtCtrls, StdCtrls;
 
type
  TForm1 = class(TForm)
    Panel1: TPanel;
    Panel2: TPanel;
    PaintBox1: TPaintBox;
    PaintBox2: TPaintBox;
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
    procedure DrawScene1;
    procedure DrawScene2;
    procedure PaintBox1Paint(Sender: TObject);
    procedure PaintBox2Paint(Sender: TObject);
  private
    { Private-Deklarationen }
    hrc1, hrc2 : HGLRC;
    dc1, dc2 : hdc;
    procedure SetDCPixelFormat(Handle : HDC);
  public
    { Public-Deklarationen }
  end;
 
var
  Form1: TForm1;
 
implementation
 
procedure TForm1.SetDCPixelFormat(Handle: HDC);
var
  pfd: TPixelFormatDescriptor;
  nPixelFormat: Integer;
 
begin
  FillChar(pfd, SizeOf(pfd), 0);
  with pfd do begin
    nSize     := sizeof(pfd);                               // Size of this structure
    nVersion  := 1;                                         // Version number
    dwFlags   := PFD_DRAW_TO_WINDOW or PFD_SUPPORT_OPENGL; //or PFD_DOUBLEBUFFER;  // Flags
    iPixelType:= PFD_TYPE_RGBA;                             // RGBA pixel values
    cColorBits:= 24;                                        // 24-bit color
    cDepthBits:= 32;                                        // 32-bit depth buffer
    iLayerType:= PFD_MAIN_PLANE;                            // Layer type
  end;
  nPixelFormat := ChoosePixelFormat(Handle, @pfd);
  SetPixelFormat(Handle, nPixelFormat, @pfd);
end;
 
{$R *.dfm}
 
procedure TForm1.FormCreate(Sender: TObject);
var
  fdc : hdc;
  base : Integer;
begin
  dc1 := GetDC(Panel1.Handle);
  SetDCPixelFormat(dc1);
  hrc1 := wglCreateContext(dc1);
  dc2 := GetDC(Panel2.Handle);
  SetDCPixelFormat(dc2);
  hrc2 := wglCreateContext(dc2);
end;
 
procedure TForm1.FormDestroy(Sender: TObject);
begin
  wglDeleteContext(hrc1);
  wglDeleteContext(hrc2);
end;
 
procedure TForm1.DrawScene1;
var
  fdc : hdc;
  base : Integer;
const
  s : PChar = 'opengl 2';
 
begin
  glClearColor(0.0, 0.5, 0.5, 0);
  glClear(GL_COLOR_BUFFER_BIT or GL_DEPTH_BUFFER_BIT);
  glBegin(GL_TRIANGLES);
    glColor3f(1.0, 0, 0);
    glVerTex2f(-0.5, -0.5);
    glColor3f(0, 1.0, 0);
    glVerTex2f(0.5, -0.5);
    glColor3f(0, 0, 1.0);
    glVerTex2f(-0, 0.5);
  glEnd;
  glColor3f(1.0, 1.0, 1.0);
  wglUseFontBitmaps(dc1, 0, 255, 0);
  glListBase(0);
  glRasterPos2f(0.2, 0);
  glCallLists(Length(s), GL_BYTE, s);
  glFlush;
end;
 
procedure TForm1.DrawScene2;
var
  fdc : hdc;
  base : Integer;
const
  s : PChar = 'opengl 1';
 
begin
  glClearColor(0.5, 0.5, 0, 0);
  glClear(GL_COLOR_BUFFER_BIT or GL_DEPTH_BUFFER_BIT);
  glBegin(GL_TRIANGLES);
    glColor3f(1.0, 0, 0);
    glVerTex2f(-0.5, -0.5);
    glColor3f(0, 1.0, 0);
    glVerTex2f(-0, 0.5);
    glColor3f(0, 0, 1.0);
    glVerTex2f(0.5, -0.5);
  glEnd;
  wglUseFontBitmaps(dc1, 0, 255, 0);
  glListBase(0);
  glRasterPos2f(0.2, 0);
  glCallLists(Length(s), GL_BYTE, s);
  glFlush;
end;
 
procedure TForm1.PaintBox1Paint(Sender: TObject);
begin
  wglMakeCurrent(dc1, hrc1);
  DrawScene1;
  wglMakeCurrent(0, 0);
end;
 
procedure TForm1.PaintBox2Paint(Sender: TObject);
begin
  wglMakeCurrent(dc2, hrc2);
  DrawScene2;
  wglMakeCurrent(0, 0);
end;
 
end.

_________________
OpenGL

Nach oben

BigAl

Betreff des Beitrags: Re: Mehrere Device-Contexte in einer Applikation

Verfasst: Mi Jun 11, 2014 19:07

DGL Member

Registriert: Di Jun 10, 2014 06:59
Beiträge: 17
Programmiersprache: Delphi XE6

Hallo Mathias,

ist im Wesentlichen so wie bei mir jetzt auch

. Hättest ja theoretisch jedesmal die gleiche Zeichenroutine starten können, nachdem du vorher den DC umgeschaltet hast. Ich mache das in meiner Komponente halt jetzt am Eingang der "Paint"-Methode. Läuft ja alles im Vordergrund...

Eine Frage habe ich aber dazu noch:

Hat es einen bestimmten Grund, warum Du nach DrawScene wglMakeCurrent(0, 0) setzt? Da Du jeweils vor dem Zeichnen explizit DC/RC angibst wäre das ja eigentlich nicht nötig. Oder?

Alex

Nach oben

Jens01

Betreff des Beitrags: Re: Mehrere Device-Contexte in einer Applikation

Verfasst: Mi Jun 11, 2014 19:59

DGL Member

Registriert: Mo Nov 09, 2009 12:01
Beiträge: 200

@BigAl
Dasselbe Problem hatte ich anfangs auch. Du mußt halt bei jeder Aktion des Fensters zuvor den Context binden, wie Du es wohl auch schon gemacht hast. Aufpassen muss man auch beim Destroyen, da muß zuvor auch der Context gebunden werden, sonst vernichtet man ggf ein ganz anderes Fenster.

Aufpassen muß man zusätzlich bei gedockten Fenstern mit diesen Dockingsystem. Beim Docken bzw. Entdocken ändert sich de Handle des Fensters und entsprechend muß der Context auch neu gebunden werden.

Nach oben

mathias

Betreff des Beitrags: Re: Mehrere Device-Contexte in einer Applikation

Verfasst: Mi Jun 11, 2014 21:14

DGL Member

Registriert: Fr Mai 31, 2002 19:41
Beiträge: 1278
Wohnort: Bäretswil (Schweiz)
Programmiersprache: Pascal

Zitat:

Hat es einen bestimmten Grund, warum Du nach DrawScene wglMakeCurrent(0, 0) setzt? Da Du jeweils vor dem Zeichnen explizit DC/RC angibst wäre das ja eigentlich nicht nötig. Oder?

Ich habe jetzt 0,0 gelöscht und es läuft auch. Ich weis nicht mehr, warum ich das geschrieben habe, der Code ist schon sehr alt.

_________________
OpenGL

Nach oben

Seite 1 von 1

[ 7 Beiträge ]

Foren-Übersicht » Programmierung » OpenGL

Wer ist online?

Mitglieder in diesem Forum: 0 Mitglieder und 62 Gäste

Du darfst keine neuen Themen in diesem Forum erstellen.
Du darfst keine Antworten zu Themen in diesem Forum erstellen.
Du darfst deine Beiträge in diesem Forum nicht ändern.
Du darfst deine Beiträge in diesem Forum nicht löschen.
Du darfst keine Dateianhänge in diesem Forum erstellen.