DGL • Thema anzeigen

DDS

Moderator: DGL-Team

Seite 1 von 1

[ 5 Beiträge ]

Druckansicht

Vorheriges Thema | Nächstes Thema

Autor

Nachricht

Stucuk

Betreff des Beitrags: DDS

Verfasst: Fr Okt 22, 2004 19:32

DGL Member

Registriert: Mi Jul 21, 2004 22:39
Beiträge: 360
Wohnort: UK, Scotland

Below is a modifyed version of Jan Horn's Textures.pas and Martin Waldegger's DDS.

My question is how can the pByte be modifyed so its's Y coords are reversed(so 0,0 is bottom left not top left)?

Dateianhänge:

Dateikommentar: Textures.pas And DDS.pas

textures_and_dds.zip [7.18 KiB]
282-mal heruntergeladen

_________________
Free Map Editor - Game Requirements - Stucuk.Net
-Stu

Nach oben

Mars

Betreff des Beitrags:

Verfasst: Fr Okt 22, 2004 21:22

DGL Member

Registriert: Fr Dez 13, 2002 12:18
Beiträge: 1063

A PByte is just a pointer to a byte (respective a byte array), referring to DDS you cant easily turn or mirror the texture image while loading, since the decompression is done by OpenGL itself. However, you can retrieve the texture image via glGetTexImage after uploading it and do what you want with the uncompressed picture data (and send it to OpenGL afterwards).

_________________
Viel Spaß beim Programmieren,
Mars
http://www.basegraph.com/

Nach oben

Stucuk

Betreff des Beitrags:

Verfasst: Fr Okt 22, 2004 22:24

DGL Member

Registriert: Mi Jul 21, 2004 22:39
Beiträge: 360
Wohnort: UK, Scotland

I can't get it to work

Code:

 
Procedure SwapY(Var Pixels : pBytes; xSize,ySize : Integer);
Type
TRGB = record
R,G,B,A : Byte;
end;
Var
Temp : array of array of TRGB;
x,y,c : integer;
begin
 
SetLength(Temp,xSize,ySize);
c := -1;
for x := 0 to xSize-1 do
for y := 1 to ySize do
begin
Inc(c);
Temp[x,ySize-y].R := Pixels[c];
Inc(c);
Temp[x,ySize-y].G := Pixels[c];
Inc(c);
Temp[x,ySize-y].B := Pixels[c];
Inc(c);
Temp[x,ySize-y].A := Pixels[c];
end;
 
c := -1;
 
for x := 0 to xSize-1 do
for y := 0 to ySize-1 do
begin
Inc(c);
Pixels[c] := Temp[x,y].R;
Inc(c);
Pixels[c] := Temp[x,y].G;
Inc(c);
Pixels[c] := Temp[x,y].B;
Inc(c);
Pixels[c] := Temp[x,y].A;
end;
 
SetLength(Temp,0,0);
 
end;
 
function LoadDDS(Stream: TStream; Var Texture : Cardinal; Const NoPicMip : Boolean; Var Width,Height : Integer): boolean;
var
  hdr: TDDSHeader;
  mipMapCount, x, y, xSize, ySize: Cardinal;
  li: ^TDDSLoadInfo;
  data,pixels: PBytes;
  unpacked: PGLuints;
  size, ix, zz: Cardinal;
  palette: array[0..255] of Cardinal;
begin
  result := false;
  //  DDS is so simple to read, too
  Stream.Read(hdr, sizeof(hdr));
  if (hdr.dwMagic<>DDS_MAGIC) or (hdr.dwSize<>124) or
     ((hdr.dwFlags and DDSD_PIXELFORMAT)=0) or ((hdr.dwFlags and DDSD_CAPS)=0) then exit;
 
  if (addr(glTexParameteri)=NIL) or
     (addr(glCompressedTexImage2D)=NIL) or
     (addr(glPixelStorei)=NIL) then exit;
  xSize := hdr.dwWidth;
  ySize := hdr.dwHeight;
 
  if (PF_IS_DXT1(hdr.PixelFormat)) then li := @loadInfoDXT1 else
  if (PF_IS_DXT3(hdr.PixelFormat)) then li := @loadInfoDXT3 else
  if (PF_IS_DXT5(hdr.PixelFormat)) then li := @loadInfoDXT5 else
  if (PF_IS_BGRA8(hdr.PixelFormat)) then li := @loadInfoBGRA8 else
  if (PF_IS_BGR8(hdr.PixelFormat)) then li := @loadInfoBGR8 else
  if (PF_IS_BGR5A1(hdr.PixelFormat)) then li := @loadInfoBGR5A1 else
  if (PF_IS_BGR565(hdr.PixelFormat)) then li := @loadInfoBGR565 else
  if (PF_IS_INDEX8(hdr.PixelFormat)) then li := @loadInfoIndex8 else
  exit;
 
  x := xSize;
  y := ySize;
  Width := x;
  Height := y;
  GetMem(pixels, xSize*ySize*4);
 
 
  glGenTextures(1, @Texture);
  glBindTexture(GL_TEXTURE_2D, Texture);
 
  glEnable(GL_TEXTURE_2D);
 
//  glTexEnvi(GL_TEXTURE_ENV, GL_TEXTURE_ENV_MODE, GL_MODULATE);  {Texture blends with object background}
 
  if NoPicMip then begin
    glTexParameteri(GL_TEXTURE_2D, GL_TEXTURE_MAG_FILTER, GL_NEAREST);
  end
  else begin
    glTexParameteri(GL_TEXTURE_2D, GL_TEXTURE_MAG_FILTER, GL_LINEAR);
  end;
 
    glTexParameteri(GL_TEXTURE_2D, GL_TEXTURE_MAG_FILTER, GL_NEAREST);
    glTexParameteri(GL_TEXTURE_2D, GL_TEXTURE_MIN_FILTER, GL_NEAREST);
 
{$IFDEF GL_14}
  if GL_14 then
    glTexParameteri(GL_TEXTURE_2D, GL_GENERATE_MIPMAP, GL_FALSE);
{$ENDIF}
  if hdr.dwFlags and DDSD_MIPMAPCOUNT<>0 then mipMapCount := hdr.dwMipMapCount else mipMapCount := 1;
 
  if li.compressed then begin
    size := max(li.divSize, x ) div li.divSize * max(li.divSize, y) div li.divSize * li.blockBytes;
    GetMem(data, size);
    for ix:=0 to mipMapCount-1 do begin
      Stream.Read(data^, size);
      glCompressedTexImage2D(GL_TEXTURE_2D, ix, li.internalFormat, x, y, 0, size, data);
      glGetTexImage(GL_TEXTURE_2D, ix, GL_RGBA, GL_BYTE, pixels);
      SwapY(pixels,xSize,ySize);
      glTexImage2D(GL_TEXTURE_2D, ix, GL_RGBA, xsize, ysize, 0, GL_RGBA, GL_BYTE, pixels);
      x := (x+1) shr 1;
      y := (y+1) shr 1;
      size := max(li.divSize, x ) div li.divSize * max(li.divSize, y ) div li.divSize * li.blockBytes;
    end;
    FreeMem(data);
  end
  else if li.palette then begin
    size := hdr.dwPitchOrLinearSize * ySize;
    GetMem(data, size);
    GetMem(unpacked, size * sizeof(cardinal));
    Stream.Read(palette, 1024);
    for ix:=0 to mipMapCount-1 do begin
      Stream.Read(data^, size);
      for zz:=0 to size-1 do
        unpacked[zz] := palette[data[zz]];
      glPixelStorei(GL_UNPACK_ROW_LENGTH, y);
      glTexImage2D(GL_TEXTURE_2D, ix, li.internalFormat, x, y, 0, li.externalFormat, li.typ, unpacked);
      glGetTexImage(GL_TEXTURE_2D, ix, GL_RGBA, GL_BYTE, pixels);
      SwapY(pixels,xSize,ySize);
      glTexImage2D(GL_TEXTURE_2D, ix, GL_RGBA, xsize, ysize, 0, GL_RGBA, GL_BYTE, pixels);
      x := (x+1) shr 1;
      y := (y+1) shr 1;
      size := x * y * li.blockBytes;
    end;
    FreeMem(data);
    FreeMem(unpacked);
  end
  else begin
    if li.swap then
      glPixelStorei(GL_UNPACK_SWAP_BYTES, GL_TRUE);
    size := x * y * li.blockBytes;
    GetMem(data, size);
    for ix:=0 to mipMapCount-1 do begin
      Stream.Read(data^, size);
      glPixelStorei(GL_UNPACK_ROW_LENGTH, y);
      glTexImage2D(GL_TEXTURE_2D, ix, li.internalFormat, x, y, 0, li.externalFormat, li.typ, data);
      glGetTexImage(GL_TEXTURE_2D, ix, GL_RGBA, GL_BYTE, pixels);
      SwapY(pixels,xSize,ySize);
      glTexImage2D(GL_TEXTURE_2D, ix, GL_RGBA, xsize, ysize, 0, GL_RGBA, GL_BYTE, pixels);
      x := (x+1) shr 1;
      y := (y+1) shr 1;
      size := x * y * li.blockBytes;
    end;
    FreeMem(data);
    glPixelStorei(GL_UNPACK_SWAP_BYTES, GL_FALSE);
  end;
{$IFDEF GL_12}
  if GL_12 then
    glTexParameteri(GL_TEXTURE_2D, GL_TEXTURE_MAX_LEVEL, mipMapCount-1);
{$ENDIF}
  FreeMem(pixels);
 
  result := true;
end;
 

_________________
Free Map Editor - Game Requirements - Stucuk.Net
-Stu

Nach oben

Mars

Betreff des Beitrags:

Verfasst: Fr Okt 22, 2004 22:44

DGL Member

Registriert: Fr Dez 13, 2002 12:18
Beiträge: 1063

What do you mean with that? Does it crash, or does it show no effect?
Double check, that glGetTexImage returns valid data (just use the Delphi Debugger after preinitializing pixels with zero).
Your SwapY seems a bit overkill to me, since you won't need another copy of the texture just to flip the y-coordinate, it's wrong too, since you use y as inner loop variable to walk through temp vertically, while incrementing c will walk through pixels horizontally.
Try something like that:

Code:

 
Procedure SwapY(Pixels: pBytes; xSize, ySize: Integer);
var x, y: integer;
    P1, P2: ^Cardinal;
    Temp: Cardinal;
begin
  for y:=0 to Pred(ySize shr 1) do 
    for x:=0 to Pred(xSize) do begin
      P1 := Addr(Pixels^[(y*xSize + x)*4]);
      P2 := Addr(Pixels^[((ySize-y-1)*xSize + x)*4]);
      Temp := P1^;
      P1^ := P2^;
      P2^ := Temp;
    end;
end;
 

_________________
Viel Spaß beim Programmieren,
Mars
http://www.basegraph.com/

Nach oben

Stucuk

Betreff des Beitrags:

Verfasst: Sa Okt 23, 2004 00:16

DGL Member

Registriert: Mi Jul 21, 2004 22:39
Beiträge: 360
Wohnort: UK, Scotland

After trying ur SwapY it worked, thx.

_________________
Free Map Editor - Game Requirements - Stucuk.Net
-Stu

Nach oben

Seite 1 von 1

[ 5 Beiträge ]

Foren-Übersicht » English » English Programming Forum

Wer ist online?

Mitglieder in diesem Forum: 0 Mitglieder und 1 Gast

Du darfst keine neuen Themen in diesem Forum erstellen.
Du darfst keine Antworten zu Themen in diesem Forum erstellen.
Du darfst deine Beiträge in diesem Forum nicht ändern.
Du darfst deine Beiträge in diesem Forum nicht löschen.
Du darfst keine Dateianhänge in diesem Forum erstellen.