DGL • Thema anzeigen - Anfänger hat Problem

Anfänger hat Problem

Moderator: DGL-Team

Seite 1 von 1

[ 5 Beiträge ]

Vorheriges Thema | Nächstes Thema

Autor

Nachricht

Hässlon

Betreff des Beitrags: Anfänger hat Problem

Verfasst: Mo Mär 12, 2007 21:35

DGL Member

Registriert: So Mär 11, 2007 11:30
Beiträge: 2
Wohnort: Riesa (Dresden)

Hallo Community,
ich bin ein absoluter Anfänger mit openGL und Delphi, hab aber schon Erfahrung mit anderen Programmiersprachen und PASCAL. Ich bin vor ein paar Tagen auf diese Seite gestoßen und hab mich sofort für das Thema interressiert. Also hab ich mir die ersten beiden Lektionen des Tutorials durchgelesen und wollte das mal ausprobieren. Ich hab einen ersten Quelltext in mein Delphi 7 Pro eingegeben und gehofft, dass ein weißes Dreieck auf dem Bildschirm erscheint. Dem war aber nicht so. Ich bitte euch mir einen korrekten Code (möglichst mit Header) zu posten. Allerdings freue ich mich auch über jede andere Hilfe oder einen anderen Quelltext zum Testen meiner Software.

danke im Vorraus

Nach oben

aNTichRisT

Betreff des Beitrags: Re:

Verfasst: Mo Mär 12, 2007 22:05

DGL Member

Registriert: Do Nov 17, 2005 14:40
Beiträge: 63
Wohnort: Dötlingen

hi,
am einfachsten wäre es wohl, wenn du dir erst einmal eines der templates von dieser seite runterlädst. du findest sie unter files->templates. unter files->library findest du auch die aktuelle version des dglopengl-headers und auch die dglsdk, dort sind auch neben den meisten libraries, die man benötigt, einige kleine demos enthalten. ich hoffe, du kannst mit damit was anfangen...
ansonsten könntest du noch posten, was du bisher schon so an code produziert hast, dann kann dir bestimmt gesagt werden, wo da die fehler liegen

Joshua

Nach oben

Flash

Betreff des Beitrags:

Verfasst: Di Mär 13, 2007 00:22

Guitar Hero

Registriert: Do Sep 25, 2003 15:56
Beiträge: 7810
Wohnort: Sachsen - ERZ / C
Programmiersprache: Java (, Pascal)

Ja. Der Antichrist hats schon richtig gesagt. Deine Optionen sind unsere Template nehmen und fertig, oder die Hosen runter lassen und uns mal bisl quelltext zeigen. Das ding zum laufen zu bringen sollte nicht alzu schnwer sein. Wenn du den quickstart nachprogrammiert hast, solltest du zumindest alle wichtigen Teile schon zusammenhaben.

_________________
Blog: kevin-fleischer.de und fbaingermany.com

Nach oben

Hässlon

Betreff des Beitrags:

Verfasst: Di Mär 13, 2007 19:28

DGL Member

Registriert: So Mär 11, 2007 11:30
Beiträge: 2
Wohnort: Riesa (Dresden)

moin,
also erstmal möchte ich euch sehr für eure spontane Hilfe danken. allerdings funktioniert das ganze nicht so auf Anhieb. Nur um nochmal konkret zu sagen was ich gemacht hab: 1) Delphi installiert 2) dgl sdk runtergeladen, installiert und die ordner in die entsprechenden im Programmverzeichnis kopiert 3) nach eurem Rat auf der dgl-seite unter Files den Code für die Lektion 2 (siehe unten) runtergeladen und entpackt 3) den Quelltext mit Delphi geöffnet und auf RUN geklickt.

aber dann kommt das kuriose: nachdem ich die Schaltfläche gedrückt hatte, zeigte Delphi ca. eine Sekunde "RUNNING" in der Taskleiste an und ging dann wieder in den Normalzustand über. keine Fehlermeldung. nix. Damn. :evil:

ich hoffe ihr könnt mir helfen.

Code:

unit lesson2_1_vcl_main;
{******************************************************************************}
{                                                                              }
{       OpenGl Tutorial 2 - VCL                                                }
{                                                                              }
{ Copyright (C) 2002 Delphi OpenGl Community                                   }
{   11/03/2002: ported from API to VCL by Delphic                              }
{ All Rights Reserved.                                                         }
{                                                                              }
{       Obtained through:                                                      }
{       Delphi OpenGL Community(DGL)                                           }
{                                                                              }
{ You may retrieve the latest version of this file at the Delphi OpenGL        }
{ Community home page, located at http://dgl.quellcodes.de/                    }
{                                                                              }
{ The contents of this file are used with permission, subject to               }
{ the Mozilla Public License Version 1.1 (the "License"); you may              }
{ not use this file except in compliance with the License. You may             }
{ obtain a copy of the License at                                              }
{ http://www.mozilla.org/MPL/MPL-1.1.html                                      }
{                                                                              }
{ Software distributed under the License is distributed on an                  }
{ "AS IS" basis, WITHOUT WARRANTY OF ANY KIND, either express or               }
{ implied. See the License for the specific language governing                 }
{ rights and limitations under the License.                                    }
{                                                                              }
{******************************************************************************}
interface
 
uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
  dglopengl, Geometry, StdCtrls, ExtCtrls;
 
const
  //Entfernung der Clipping planes
  FarClipping   = 100.0;
  NearClipping  = 1.0;
 
  AppTitle = 'http://dgl.quellcodes.de/ - OpenGL Tutorial 2';
 
type
  TMainForm = class(TForm)
    procedure FormCreate(Sender: TObject);
    procedure FormShow(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
    procedure FormResize(Sender: TObject);
    procedure ApplicationEventsIdle(Sender: TObject; var Done: Boolean);
  private
    { Private-Deklarationen }
    OpenGLInitialized : Boolean; //Ist true, wenn OpenGL bereit zum zeichnen ist
    RC : HGLRC;         //OpenGL Rendering Context
 
    //Daten, für den Framecounter
    StartTick : Cardinal;
    Frames : LongInt;
 
  public
    { Public-Deklarationen }
  end;
 
var
  MainForm: TMainForm;
 
implementation
 
{$R *.DFM}
 
procedure TMainForm.FormCreate(Sender: TObject);
begin
  //OpenGL ist noch nicht bereit
  OpenGLInitialized := False;
  //Nur starten, wenn die Bibliotheken auch geladen sind
  if not LoadOpenGL then
    Halt(100)
end; (*FormCreate*)
 
procedure TMainForm.FormShow(Sender: TObject);
  procedure SetPixelFormat;
  var
    PixelFormat      : TGLuint;
    PFD              : pixelformatdescriptor;
  begin
    with pfd do
      begin
        nSize:= SizeOf( PIXELFORMATDESCRIPTOR );
        nVersion:= 1;
        dwFlags:= PFD_DRAW_TO_WINDOW
          or PFD_SUPPORT_OPENGL
          or PFD_DOUBLEBUFFER;
        iPixelType:= PFD_TYPE_RGBA;
        cColorBits:= 16;             //Farbtiefe
        cRedBits:= 0;
        cRedShift:= 0;
        cGreenBits:= 0;
        cBlueBits:= 0;
        cBlueShift:= 0;
        cAlphaBits:= 0;
        cAlphaShift:= 0;
        cAccumBits:= 0;              //Accumulation Buffer
        cAccumRedBits:= 0;
        cAccumGreenBits:= 0;
        cAccumBlueBits:= 0;
        cAccumAlphaBits:= 0;
        cDepthBits:= 16;             //Z-Buffer Tiefe
        cStencilBits:= 0;            //Stencil Buffer
        cAuxBuffers:= 0;
        iLayerType:= PFD_MAIN_PLANE;
        bReserved:= 0;
        dwLayerMask:= 0;
        dwVisibleMask:= 0;
        dwDamageMask:= 0
      end;
    //Pixel Format setzten
    PixelFormat := ChoosePixelFormat(Canvas.Handle, @pfd);
    if (PixelFormat=0) then
      MessageDlg('Es konnte kein passendes PixelFormat gefunden werden.', mtError, [mbOk], 0);
    if (not Windows.SetPixelFormat(Canvas.Handle,PixelFormat,@pfd)) then
      MessageDlg('PixelFormat konnte nicht gesetzt werden.', mtError, [mbOk], 0)
  end; (*SetPixelFormat*)
 
  procedure StartGl;
  begin
    //Rendering Context initialisieren
    RC := wglCreateContext(Canvas.Handle);
    if (RC=0) then
    begin
      MessageDlg('Rendering Context kann nicht erstellt werden.', mtError, [mbOk], 0);
      Halt(100)
    end;
 
    if (not wglMakeCurrent(Canvas.Handle, RC)) then
    begin
      MessageDlg('Rendering Context kann nicht aktiviert werden.', mtError, [mbOk], 0);
      Halt(100)
    end
  end; (*StartGl*)
 
  procedure SetupGL;
  begin
    glShadeModel(GL_SMOOTH);           // Aktiviert weiches Shading
    glClearColor(0.0, 0.0, 0.0, 0.5);    // Bildschirm löschen (schwarz)
    glClearDepth(1.0);             // Depth Buffer Setup
    glEnable(GL_DEPTH_TEST);           // Aktiviert Depth Testing
    glDepthFunc(GL_LEQUAL);        // Bestimmt den Typ des Depth Testing
    glHint(GL_PERSPECTIVE_CORRECTION_HINT, GL_NICEST);
                                           // Qualitativ bessere Koordinaten Interpolation
  end; (*SetupGL*)
 
begin
  RC := 0;
 
  SetPixelFormat;
  StartGL;
 
  //GL Extensions neu auslesen
  ClearExtensions;
  ReadExtensions;
 
  SetupGL;
 
  //Kleinkram initialisieren
  Frames := 0;
  StartTick := GetTickCount;
 
  //OnIdle setzen
  Application.OnIdle := ApplicationEventsIdle;
 
  //OpenGL ist nun bereit
  OpenGLInitialized := True
end; (*FormShow*)
 
procedure TMainForm.FormDestroy(Sender: TObject);
begin
  OpenGLInitialized := False;
  if RC<>0 then
    begin
      if (not wglMakeCurrent(Canvas.Handle,0)) then
        MessageDlg('Rendering Context konnte nicht abgewählt werden.', mtError, [mbOk], 0);
      if (not wglDeleteContext(RC)) then
        MessageDlg('Rendering Context konnte nicht freigegeben werden.', mtError, [mbOk], 0)
    end;
  RC:=0
end; (*Form Destroy*)
 
procedure TMainForm.FormResize(Sender: TObject);
begin
  glViewport(0, 0, ClientWidth, ClientHeight);
  //Projektionsmatrix resetten
  glMatrixMode(GL_PROJECTION);
  glLoadIdentity();
  //Perspektivische Darstellung
  gluPerspective(45.0,ClientWidth/ClientHeight,NearClipping,FarClipping);// Calculate The Aspect Ratio Of The Window
  glMatrixMode(GL_MODELVIEW);
  glLoadIdentity
end; (*FormResize*)
 
procedure TMainForm.ApplicationEventsIdle(Sender: TObject;
  var Done: Boolean);
 
var
  Error : LongInt; //Fehler?
 
begin
  //Abbrechen, wenn OpenGL noch nicht initialisiert ist
  if not OpenGLInitialized then Exit;
  //Immer schön neu zeichnen
  Done := False;
 
  glClearColor(0,0,0,0);
  glClear(GL_COLOR_BUFFER_BIT or GL_DEPTH_BUFFER_BIT);
 
  glLoadIdentity;
  glTranslatef( -1.5,  0,  -6);
 
  {TIP: Entferne die beiden oberen glColor3f. Das Dreieck wird dann "blau" gezeichnet
        werden! Wenn Sie beim starten ganz schnell gucken, wirst du feststellen, dass das
        Dreieck kurz weiß zu flackern scheint. Der Grund dafür ist, dass beim ersten Durchgang
        die beiden ersten Eckpunkte weiß gezeichnet werden und erst beim nächsten Durchgang
        blau gefärbt werden. Um dies zu vermeiden müßte man bereits vor dem Zeichnen dieser
        beiden Eckpunkte die Farbe auf blau setzen!}
 
  glBegin(GL_TRIANGLES);
      glColor3f(1,0,0);                // alle weiteren Vertice werden rot gezeichnet
      glVertex3f(-1.0,-1.0, 0.0);
      glColor3f(0,1,0);                // alle weiteren Verticen werden grün gezeichnet
      glVertex3f( 0.0, 1.0, 0.0);
      glColor3f(0,0,1);                // alle weiteren Verticen werden blau gezeichnet
      glVertex3f( 1.0,-1.0, 0.0);
  glEnd();
 
  //Error Handler
  Error := glgetError;
  if Error <> GL_NO_ERROR then
  begin
    Caption := gluErrorString(Error);
    //Rendering kurz anhalten
    Done := True;
    FlashWindow(Handle, True)
  end;
  //Frame Counter
  Inc(Frames);
  if GetTickCount - StartTick >=500 then
  begin
    Caption := Format('%s [%f FPS]', [AppTitle, Frames/(GetTickCount - StartTick)*1000]);
    Frames := 0;
    StartTick := GetTickCount
  end;
  //Und anzeigen
  SwapBuffers(Canvas.Handle)
end; (*ApplicationEventsIdle*)
 
end.
 
 

Nach oben

Flash

Betreff des Beitrags:

Verfasst: Di Mär 13, 2007 19:36

Guitar Hero

Registriert: Do Sep 25, 2003 15:56
Beiträge: 7810
Wohnort: Sachsen - ERZ / C
Programmiersprache: Java (, Pascal)

Öffne mal eins der Templates und probier das mal zu starten. Der Code mit dem Pixelformatdiscriptor sieht etwas ... angestaubt aus.

_________________
Blog: kevin-fleischer.de und fbaingermany.com

Nach oben

Seite 1 von 1

[ 5 Beiträge ]

Foren-Übersicht » Programmierung » Einsteiger-Fragen

Wer ist online?

Mitglieder in diesem Forum: 0 Mitglieder und 13 Gäste

Du darfst keine neuen Themen in diesem Forum erstellen.
Du darfst keine Antworten zu Themen in diesem Forum erstellen.
Du darfst deine Beiträge in diesem Forum nicht ändern.
Du darfst deine Beiträge in diesem Forum nicht löschen.
Du darfst keine Dateianhänge in diesem Forum erstellen.