DGL • Thema anzeigen - Erstellen von Texturkoordinaten bei Bimtap-Schriften

Erstellen von Texturkoordinaten bei Bimtap-Schriften

Moderator: DGL-Team

Seite 1 von 1

[ 4 Beiträge ]

Vorheriges Thema | Nächstes Thema

Autor

Nachricht

KidPaddle

Betreff des Beitrags: Erstellen von Texturkoordinaten bei Bimtap-Schriften

Verfasst: Sa Jan 29, 2005 20:26

DGL Member

Registriert: Mo Jan 20, 2003 20:10
Beiträge: 424
Wohnort: nähe Starnberg

Ich erstelle in dem nachfolgenden Code aus einem Bild, 256x256, mit 16 Zeilen und 16 Spalten eine Schrift. Das funktioniert auch wunderbar.

Code:

 
procedure TGL2DTextureFont.BuildFont(aDC : HDC; const aTexture : String; aWidth : Integer = -1);
var
  iList            : Integer;
  ix, iy           : Integer;
  cx, cy           : TGLFloat;
  cwx, cwy         : TGLFloat;
  iWidth, iHeight  : Integer;
begin
  if not FileExists(aTexture) then begin
    raise Exception.CreateFmt('Font "%s" nicht gefunden!', [aTexture]);
  end;
 
  fTexture.LoadFromFile(aTexture);
  if fHasAlphaColor then begin
    fTexture.AddAlphaFromColorKey(fAlphaRed, fAlphaGreen, fAlphaBlue);
  end;
 
  iWidth  := fTexture.Width div fColCount;
  iHeight := fTexture.Height div fRowCount;
 
  fTexture.BuildMipMaps := False;
  fTexture.SetFilter(GL_LINEAR, GL_LINEAR);
  fTexture.FlipVert;
  fTexture.GenTexture();
 
  // Creating Display Lists
  fBase := glGenLists(fColCount * fRowCount);
  fTexture.Bind;
 
  cwx   := ((1.0 * iWidth) / fTexture.Width);
  cwy   := ((1.0 * iHeight) / fTexture.Height);
  iList := 0;
  for iy := 0 to Pred(fRowCount) do begin
    for ix := 0 to Pred(fColCount) do begin
      cx := ix * cwx;                       // X Position Of Character
      cy := 1 - iy * cwy;                   // Y Position Of Character
 
      glNewList(fBase + iList, GL_COMPILE); 
        glBegin(GL_QUADS);                  
 
          glTexCoord2f(cx, cy - cwy);       // Texture Coord (Bottom Left)
          glVertex2i(0, 0);                 // Vertex Coord (Bottom Left)
 
          glTexCoord2f(cx + cwx, cy - cwy); // Texture Coord (Bottom Right)
          glVertex2i(iWidth, 0);            // Vertex Coord (Bottom Right)
 
          glTexCoord2f(cx + cwx, cy);       // Texture Coord (Top Right)
          glVertex2i(iWidth, iHeight);      // Vertex Coord (Top Right)
 
          glTexCoord2f(cx, cy);             // Texture Coord (Top Left)
          glVertex2i(0, iHeight);           // Vertex Coord (Top Left)
 
        glEnd();                            
        if (aWidth > 0) then begin
          glTranslated(aWidth, 0, 0);
        end else begin
          glTranslated(iWidth, 0, 0); 
        end;
      glEndList();                          
      Inc(iList);
    end;
  end;
end;
 

Gezeichnet wird das ganze wie folgt:

Code:

 
procedure TGL2DTextureFont.Write(X, Y, Z : TGLFloat; const aText : String);
begin
  glPushAttrib(GL_TEXTURE_2D);
  glPushAttrib(GL_DEPTH_TEST);
  glLoadIdentity();                     
  glTranslated(x, y, 0);               
 
  glEnable(GL_TEXTURE_2D);
  glDisable(GL_DEPTH_TEST);
  fTexture.Bind;
 
  glPushAttrib(GL_BLEND);
  glEnable(GL_BLEND);
  glBlendFunc(GL_SRC_ALPHA, GL_ONE_MINUS_SRC_ALPHA );
 
  glColor3f(1.0, 1.0, 1.0);
  glListBase(fBase - Ord(fFirstChar));
  // Write The Text To The Screen
  glCallLists(Length(aText), GL_UNSIGNED_BYTE, PCHAR(aText));
 
  glPopAttrib;
  glPopAttrib;
  glPopAttrib;
end;
 

Jetzt möchte eine Schrift laden, die erst mit dem Leerzeichen beginnt und nur 64 Zeichen in einer Zeile hat. Die Textur hat 1 Zeile und 64 Spalten. Wenn ich diese verwende, werden mir nur leere weisse Felder angezeigt. Ich sitze schon einige Tagen dran und finden den Fehler einfach nicht.

Hat jemand eine Ahnung was ich verkehrt mache?

Gruß
KidPaddle

_________________
http://www.seban.de

Nach oben

Lossy eX

Betreff des Beitrags:

Verfasst: Sa Jan 29, 2005 23:50

DGL Member

Registriert: Do Dez 05, 2002 10:35
Beiträge: 4234
Wohnort: Dortmund

1 Zeile und 64 Spalten. Liegt es vielleicht daran, dass die Textur keine Potenz von 2 ist? Also deren Höhe und Breite?

Nach oben

KidPaddle

Betreff des Beitrags:

Verfasst: So Jan 30, 2005 10:42

DGL Member

Registriert: Mo Jan 20, 2003 20:10
Beiträge: 424
Wohnort: nähe Starnberg

Stimmt, mal wieder nicht daran gedacht. Ich werde das gleich heute Nachmittag ausprobieren, bin zur Zeit in der Arbeit.

Danke für den Schlag gegen die vordere Hirnplatte, äh Stirn.

Gruß
KidPaddle

PS. Ich wuste gar nicht das ich das Wort "Bimtap", siehe Titel, kenne....

_________________
http://www.seban.de

Nach oben

KidPaddle

Betreff des Beitrags:

Verfasst: So Jan 30, 2005 19:46

DGL Member

Registriert: Mo Jan 20, 2003 20:10
Beiträge: 424
Wohnort: nähe Starnberg

Das war def Fehler. Jetzt wird die Textur korrekt angezeigt.

Vielen Dank.

Gruß
KidPaddle

_________________
http://www.seban.de

Nach oben

Seite 1 von 1

[ 4 Beiträge ]

Foren-Übersicht » Programmierung » Einsteiger-Fragen

Wer ist online?

Mitglieder in diesem Forum: 0 Mitglieder und 3 Gäste

Du darfst keine neuen Themen in diesem Forum erstellen.
Du darfst keine Antworten zu Themen in diesem Forum erstellen.
Du darfst deine Beiträge in diesem Forum nicht ändern.
Du darfst deine Beiträge in diesem Forum nicht löschen.
Du darfst keine Dateianhänge in diesem Forum erstellen.